src/semantize/auto_super_init.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2012 Jean Privat <jean@pryen.org>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Computing of super-constructors that must be implicitly called at the begin of constructors.
  18 # The current rules are a bit crazy but whatever.
  19 module auto_super_init
  20
  21 import typing
  22 private import annotation
  23
  24 redef class ToolContext
  25         # Phase that inject `super` in constructors that need it.
  26         var auto_super_init_phase: Phase = new AutoSuperInitPhase(self, [typing_phase])
  27 end
  28
  29 private class AutoSuperInitPhase
  30         super Phase
  31         redef fun process_npropdef(npropdef) do if npropdef isa AMethPropdef then npropdef.do_auto_super_init(toolcontext.modelbuilder)
  32 end
  33
  34 private class AutoSuperInitVisitor
  35         super Visitor
  36         redef fun visit(n)
  37         do
  38                 n.accept_auto_super_init(self)
  39                 n.visit_all(self)
  40         end
  41
  42         var has_explicit_super_init: nullable ANode = null
  43
  44         # The method is broken, so avoid to display additional errors
  45         var is_broken = false
  46 end
  47
  48
  49 redef class AMethPropdef
  50         # In case of introduced constructor, the list of implicit auto super init constructors invoked (if needed)
  51         var auto_super_inits: nullable Array[CallSite] = null
  52
  53         # In case of redefined constructors, is an implicit call-to-super required?
  54         var auto_super_call = false
  55
  56         # Collect initializers and build the auto-init
  57         fun do_auto_super_init(modelbuilder: ModelBuilder)
  58         do
  59                 var mclassdef = self.parent.as(AClassdef).mclassdef
  60                 if mclassdef == null then return # skip error
  61                 var mpropdef = self.mpropdef
  62                 if mpropdef == null then return # skip error
  63                 var mmodule = mpropdef.mclassdef.mmodule
  64                 var anchor = mclassdef.bound_mtype
  65                 var recvtype = mclassdef.mclass.mclass_type
  66
  67                 # Get the annotation, but check its pertinence before returning
  68                 var nosuper = get_single_annotation("nosuper", modelbuilder)
  69
  70                 # Collect only for constructors
  71                 if not mpropdef.mproperty.is_init or mpropdef.mproperty.is_new then
  72                         if nosuper != null then modelbuilder.error(nosuper, "Error: `nosuper` only allowed in `init`.")
  73                         return
  74                 end
  75
  76                 # Now we search for the absence of any explicit super-init invocation
  77                 #  * via a "super"
  78                 #  * via a call of an other init
  79                 var nblock = self.n_block
  80                 if nblock != null then
  81                         var v = new AutoSuperInitVisitor
  82                         v.enter_visit(nblock)
  83                         var anode = v.has_explicit_super_init
  84                         if anode != null then
  85                                 if nosuper != null then modelbuilder.error(anode, "Error: method is annotated `nosuper` but a super-constructor call is present.")
  86                                 return
  87                         end
  88                         if v.is_broken then return # skip
  89                 end
  90
  91                 if nosuper != null then return
  92
  93                 # Still here? So it means that we must add an implicit super-call on redefinitions.
  94                 if not mpropdef.is_intro then
  95                         auto_super_call = true
  96                         mpropdef.has_supercall = true
  97                         modelbuilder.toolcontext.info("Auto-super call for {mpropdef}", 4)
  98                         return
  99                 end
 100
 101                 # Still here? So it means that we must determine what super inits need to be automatically invoked
 102                 # The code that follow is required to deal with complex cases with old-style and new-style inits
 103
 104                 # Look for old-style super constructors
 105                 var auto_super_inits = new Array[CallSite]
 106                 for msupertype in mclassdef.supertypes do
 107                         # FIXME: the order is quite arbitrary
 108                         if not msupertype.mclass.kind.need_init then continue
 109                         msupertype = msupertype.anchor_to(mmodule, mclassdef.bound_mtype)
 110                         var candidate = modelbuilder.try_get_mproperty_by_name2(self, mmodule, msupertype, mpropdef.mproperty.name)
 111                         if candidate == null then
 112                                 candidate = modelbuilder.try_get_mproperty_by_name2(self, mmodule, msupertype, "init")
 113                         end
 114                         if candidate == null then
 115                                 modelbuilder.error(self, "Error: cannot do an implicit constructor call in `{mpropdef}`; there is no constructor named `{mpropdef.mproperty.name}` in `{msupertype}`.")
 116                                 return
 117                         end
 118                         assert candidate isa MMethod
 119
 120                         # Skip new-style init
 121                         if candidate.is_root_init then continue
 122
 123                         var candidatedefs = candidate.lookup_definitions(mmodule, anchor)
 124                         var candidatedef = candidatedefs.first
 125                         # TODO, we drop the others propdefs in the callsite, that is not great :(
 126
 127                         var msignature = candidatedef.new_msignature or else candidatedef.msignature
 128                         msignature = msignature.resolve_for(recvtype, anchor, mmodule, true)
 129
 130                         var callsite = new CallSite(hot_location, recvtype, mmodule, anchor, true, candidate, candidatedef, msignature, false)
 131                         auto_super_inits.add(callsite)
 132                         modelbuilder.toolcontext.info("Old-style auto-super init for {mpropdef} to {candidate.full_name}", 4)
 133                 end
 134
 135                 # No old style? The look for new-style super constructors (called from a old style constructor)
 136                 var the_root_init_mmethod = modelbuilder.the_root_init_mmethod
 137                 if the_root_init_mmethod != null and auto_super_inits.is_empty then
 138                         var candidatedefs = the_root_init_mmethod.lookup_definitions(mmodule, anchor)
 139
 140                         # Search the longest-one and checks for conflict
 141                         var candidatedef = candidatedefs.first
 142                         if candidatedefs.length > 1 then
 143                                 # Check for conflict in the order of initializers
 144                                 # Each initializer list must me a prefix of the longest list
 145                                 # part 1. find the longest list
 146                                 for spd in candidatedefs do
 147                                         if spd.initializers.length > candidatedef.initializers.length then candidatedef = spd
 148                                 end
 149                                 # compare
 150                                 for spd in candidatedefs do
 151                                         var i = 0
 152                                         for p in spd.initializers do
 153                                                 if p != candidatedef.initializers[i] then
 154                                                         modelbuilder.error(self, "Error: cannot do an implicit constructor call to conflicting inherited inits `{spd}({spd.initializers.join(", ")}`) and `{candidatedef}({candidatedef.initializers.join(", ")}`). NOTE: Do not mix old-style and new-style init!")
 155                                                         return
 156                                                 end
 157                                                 i += 1
 158                                         end
 159                                 end
 160                         end
 161
 162                         var msignature = candidatedef.new_msignature or else candidatedef.msignature
 163                         msignature = msignature.resolve_for(recvtype, anchor, mmodule, true)
 164
 165                         var callsite = new CallSite(hot_location, recvtype, mmodule, anchor, true, the_root_init_mmethod, candidatedef, msignature, false)
 166                         auto_super_inits.add(callsite)
 167                         modelbuilder.toolcontext.info("Auto-super init for {mpropdef} to {the_root_init_mmethod.full_name}", 4)
 168                 end
 169                 if auto_super_inits.is_empty then
 170                         modelbuilder.error(self, "Error: no constructors to call implicitly in `{mpropdef}`. Call one explicitly.")
 171                         return
 172                 end
 173
 174                 # Can the super-constructors be called?
 175                 for auto_super_init in auto_super_inits do
 176                         var auto_super_init_def = auto_super_init.mpropdef
 177                         var msig = mpropdef.msignature.as(not null)
 178                         var supermsig = auto_super_init.msignature
 179                         if supermsig.arity > msig.arity then
 180                                 modelbuilder.error(self, "Error: cannot do an implicit constructor call to `{auto_super_init_def}{supermsig}`. Expected at least `{supermsig.arity}` arguments, got `{msig.arity}`.")
 181                                 continue
 182                         end
 183                         var i = 0
 184                         for sp in supermsig.mparameters do
 185                                 var p = msig.mparameters[i]
 186                                 var sub = p.mtype
 187                                 var sup = sp.mtype
 188                                 if not sub.is_subtype(mmodule, anchor, sup) then
 189                                         modelbuilder.error(self, "Error: cannot do an implicit constructor call to `{auto_super_init_def}{supermsig}`. Expected argument #{i} of type `{sp.mtype}`, got implicit argument `{p.name}` of type `{p.mtype}`.")
 190                                         break
 191                                 end
 192                                 i += 1
 193                         end
 194                 end
 195                 self.auto_super_inits = auto_super_inits
 196         end
 197
 198 end
 199
 200 redef class ANode
 201         private fun accept_auto_super_init(v: AutoSuperInitVisitor) do end
 202 end
 203
 204
 205 redef class ASendExpr
 206         redef fun accept_auto_super_init(v)
 207         do
 208                 var callsite = self.callsite
 209                 if callsite == null then
 210                         v.is_broken = true
 211                         return
 212                 end
 213                 if callsite.mproperty.is_init then
 214                         v.has_explicit_super_init = self
 215                 end
 216         end
 217 end
 218
 219 redef class ASuperExpr
 220         redef fun accept_auto_super_init(v)
 221         do
 222                 # If the super is a standard call-next-method then there it is considered am explicit super init call
 223                 # The the super is a "super int" then it is also an explicit super init call
 224                 v.has_explicit_super_init = self
 225         end
 226 end