src/android_annotations.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2014 Alexis Laferrière <alexis.laf@xymus.net>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Annotations to gather metadata on Android projects. Get the metadata
  18 # by calling `ModelBuilder::android_project_for`.
  19 module android_annotations
  20
  21 import parser_util
  22 import modelbuilder
  23 import modelize_property
  24 import literal
  25 import typing
  26 private import annotation
  27
  28 # Metadata associated to an Android project
  29 class AndroidProject
  30         # Name of the resulting application
  31         var name: nullable String = null
  32
  33         # Java package used to identify the APK
  34         var java_package: nullable String = null
  35
  36         # Version of the Android application and APK
  37         var version: nullable String = null
  38
  39         # Numerical version code of the Android application and APK
  40         var version_code: Int = 0
  41
  42         # Custom lines to add to the AndroidManifest.xml in the <manifest> node
  43         var manifest_lines = new Array[String]
  44
  45         # Custom lines to add to the AndroidManifest.xml in the <application> node
  46         var manifest_application_lines = new Array[String]
  47
  48         # Minimum API level required for the application to run
  49         var min_api: nullable Int = null
  50
  51         # Build target API level
  52         var target_api: nullable Int = null
  53
  54         # Maximum API level on which the application will be allowed to run
  55         var max_api: nullable Int = null
  56
  57         redef fun to_s do return """
  58 name: {{{name or else "null"}}}
  59 namespace: {{{java_package or else "null"}}}
  60 version: {{{version or else "null"}}}"""
  61 end
  62
  63 redef class ModelBuilder
  64         # Get the `AndroidProject` gathered from `mmodule` and its importations
  65         fun android_project_for(mmodule: MModule): AndroidProject
  66         do
  67                 var project = new AndroidProject
  68
  69                 var annot = lookup_annotation_on_modules("app_name", mmodule)
  70                 if annot != null then project.name = annot.arg_as_string(self)
  71
  72                 annot =  lookup_annotation_on_modules("app_version", mmodule)
  73                 if annot != null then project.version =  annot.as_version(self)
  74
  75                 annot = lookup_annotation_on_modules("java_package", mmodule)
  76                 if annot != null then project.java_package = annot.arg_as_string(self)
  77
  78                 var annots = collect_annotations_on_modules("min_api_version", mmodule)
  79                 for an in annots do project.min_api = an.arg_as_int(self)
  80
  81                 annots = collect_annotations_on_modules("max_api_version", mmodule)
  82                 for an in annots do project.max_api = an.arg_as_int(self)
  83
  84                 annots = collect_annotations_on_modules("target_api_version", mmodule)
  85                 for an in annots do project.target_api = an.arg_as_int(self)
  86
  87                 annots = collect_annotations_on_modules("android_manifest", mmodule)
  88                 for an in annots do project.manifest_lines.add an.arg_as_string(self) or else ""
  89
  90                 annots = collect_annotations_on_modules("android_manifest_application", mmodule)
  91                 for an in annots do project.manifest_application_lines.add an.arg_as_string(self) or else ""
  92
  93                 # Get the date and time (down to the minute) as string
  94                 var local_time = new Tm.localtime
  95                 var local_time_s = local_time.strftime("%y%m%d%H%M")
  96                 project.version_code = local_time_s.to_i
  97
  98                 toolcontext.check_errors
  99
 100                 return project
 101         end
 102 end
 103
 104 redef class AAnnotation
 105         # Returns a version string (example: "1.5.6b42a7c") from an annotation `version(1, 5, git_revision)`.
 106         #
 107         # The user can enter as many fields as needed. The call to `git_revision` will be replaced by the short
 108         # revision number. If the working tree is dirty, it will append another field with "d" for dirty.
 109         private fun as_version(modelbuilder: ModelBuilder): String
 110         do
 111                 var annotation_name = n_atid.n_id.text
 112                 var version_fields = new Array[Object]
 113
 114                 var args = n_args
 115                 var platform_name
 116                 if args.length < 1 then
 117                         modelbuilder.error(self, "Annotation error: \"{name}\" expects at least a single argument.")
 118                         return ""
 119                 else
 120                         for arg in args do
 121                                 var format_error = "Annotation error: \"{name}\" expects its arguments to be of type Int or a call to `git_revision`"
 122
 123                                 var value
 124                                 value = arg.as_int
 125                                 if value != null then
 126                                         version_fields.add value
 127                                         continue
 128                                 end
 129
 130                                 value = arg.as_string
 131                                 if value != null then
 132                                         version_fields.add value
 133                                 end
 134
 135                                 value = arg.as_id
 136                                 if value == "git_revision" then
 137                                         # Get Git short revision
 138                                         var proc = new IProcess("git", "rev-parse", "--short", "HEAD")
 139                                         proc.wait
 140                                         assert proc.status == 0
 141                                         var lines = proc.read_all
 142                                         var revision = lines.split("\n").first
 143
 144                                         # Is it dirty?
 145                                         # If not, the return of `git diff --shortstat` is an empty line
 146                                         proc = new IProcess("git", "diff-index", "--quiet", "HEAD")
 147                                         proc.wait
 148                                         var dirty = proc.status != 0
 149                                         if dirty then revision += ".d"
 150
 151                                         version_fields.add revision
 152                                         continue
 153                                 end
 154
 155                                 modelbuilder.error(self, format_error)
 156                                 return ""
 157                         end
 158                 end
 159
 160                 return version_fields.join(".")
 161         end
 162 end