src/parser/nit.sablecc3xx

   1
   2 /* This file is part of NIT ( http://www.nitlanguage.org ).
   3  *
   4  * Copyright 2008-2009 Jean Privat <jean@pryen.org>
   5  *
   6  * Licensed under the Apache License, Version 2.0 (the "License");
   7  * you may not use this file except in compliance with the License.
   8  * You may obtain a copy of the License at
   9  *
  10  *     http://www.apache.org/licenses/LICENSE-2.0
  11  *
  12  * Unless required by applicable law or agreed to in writing, software
  13  * distributed under the License is distributed on an "AS IS" BASIS,
  14  * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15  * See the License for the specific language governing permissions and
  16  * limitations under the License.
  17  */
  18
  19 /* This grammar defines the NIT language. */
  20
  21 /*****************************************************************************/
  22 Helpers
  23 /*****************************************************************************/
  24
  25 all = [0 .. 0xFF];
  26 lowercase = ['a' .. 'z'];
  27 uppercase = ['A' .. 'Z'];
  28 digit = ['0' .. '9'];
  29 letter = lowercase | uppercase | digit | '_';
  30
  31 tab = 9;
  32 cr = 13;
  33 lf = 10;
  34 any = [all - [cr + lf]];
  35
  36 // characers inside strings and super-strings (atomaton powaa)
  37 str_char
  38         = [any - [['"' + '{'] + '\']]
  39         | '\' any
  40         ;
  41 str_body = str_char*;
  42
  43 eol_helper = cr lf | cr | lf; // This takes care of different platforms
  44
  45 /*****************************************************************************/
  46 States
  47 /*****************************************************************************/
  48 initial;
  49
  50
  51 /*****************************************************************************/
  52 Tokens
  53 /*****************************************************************************/
  54
  55 blank = (' ' | tab)+;
  56
  57 eol = eol_helper;
  58 comment = '#' any* eol_helper?;
  59
  60 kwmodule = 'package'|'module';
  61 kwimport = 'import';
  62 kwclass = 'class';
  63 kwabstract = 'abstract';
  64 kwinterface = 'interface';
  65 kwenum = 'universal'|'enum';
  66 kwspecial = 'special';
  67 kwend = 'end';
  68 kwmeth = 'fun';
  69 kwtype = 'type';
  70 kwinit = 'init';
  71 kwredef = 'redef';
  72 kwis = 'is';
  73 kwdo = 'do';
  74 kwreadable = 'readable';
  75 kwwritable = 'writable';
  76 kwvar = 'var';
  77 kwintern = 'intern';
  78 kwextern = 'extern';
  79 kwprotected = 'protected';
  80 kwprivate = 'private';
  81 kwintrude = 'intrude';
  82 kwif = 'if';
  83 kwthen = 'then';
  84 kwelse = 'else';
  85 kwwhile = 'while';
  86 kwloop = 'loop';
  87 kwfor = 'for';
  88 kwin = 'in';
  89 kwand = 'and';
  90 kwor = 'or';
  91 kwnot = 'not';
  92 kwreturn = 'return';
  93 kwcontinue = 'continue';
  94 kwbreak = 'break';
  95 kwabort = 'abort';
  96 kwassert = 'assert';
  97 kwnew = 'new';
  98 kwisa = 'isa';
  99 kwonce = 'once';
 100 kwsuper = 'super';
 101 kwself = 'self';
 102 kwtrue = 'true';
 103 kwfalse = 'false';
 104 kwnull = 'null';
 105 kwas = 'as';
 106 kwnullable = 'nullable';
 107 kwisset = 'isset';
 108 kwlabel = 'label';
 109
 110 opar = '(';
 111 cpar = ')';
 112 obra = '[';
 113 cbra = ']';
 114 comma = ',';
 115 column = ':';
 116 quad = '::';
 117 assign = '=';
 118 pluseq = '+=';
 119 minuseq = '-=';
 120 dotdotdot = '...';
 121 dotdot = '..';
 122 dot = '.';
 123 plus = '+';
 124 minus = '-';
 125 star = '*';
 126 slash = '/';
 127 percent = '%';
 128 eq = '==';
 129 ne = '!=';
 130 lt = '<';
 131 le = '<=';
 132 ll = '<<';
 133 gt = '>';
 134 ge = '>=';
 135 gg = '>>';
 136 starship = '<=>';
 137 bang='!';
 138
 139 classid = uppercase letter*;
 140 id = lowercase letter*;
 141 attrid = '_' lowercase letter*;
 142
 143 number = digit+;
 144 float = digit* '.' digit+;
 145 char = (''' [[any - '''] - '\'] ''') | (''' '\' any ''');
 146 string = '"' str_body '"';
 147 start_string = '"' str_body '{';
 148 mid_string = '}' str_body '{';
 149 end_string = '}' str_body '"';
 150 bad_char = ''' '\'? any;
 151 bad_string = ('"'|'}') str_body;
 152
 153
 154 /*****************************************************************************/
 155 Ignored Tokens
 156 /*****************************************************************************/
 157
 158 blank;
 159
 160 /*****************************************************************************/
 161 Productions
 162 /*****************************************************************************/
 163
 164 /* MODULES *******************************************************************/
 165 module
 166         = moduledecl? [imports]:import* [classdefs]:classdef* implicit_top_class? implicit_main_class? {-> New module(moduledecl, [imports.import],[classdefs.classdef,implicit_top_class.classdef,implicit_main_class.classdef])};
 167
 168 moduledecl
 169         = [doc]:no kwmodule no module_name [n2]:n1 {-> New moduledecl(doc.doc, kwmodule, module_name)};
 170
 171 import
 172         = {std} [doc]:no visibility kwimport no module_name [n2]:n1 {-> New import.std(visibility, kwimport, module_name)}
 173         | {no} [doc]:no visibility kwimport no kwend [n2]:n1 {-> New import.no(visibility, kwimport, kwend)}
 174         ;
 175
 176 implicit_top_class {-> classdef}
 177         = propdefs_toplevel+ {-> New classdef.top([propdefs_toplevel.propdef])};
 178
 179 implicit_main_class {-> classdef?}
 180         = implicit_main_meth {-> New classdef.main([implicit_main_meth.propdef])}
 181         | {null} n {-> Null}
 182         ;
 183 implicit_main_meth {-> propdef}
 184         = [doc]:no stmts {-> New propdef.main_meth(Null, stmts.expr)}
 185         | {n} [doc]:no stmtsn {-> New propdef.main_meth(Null, stmtsn.expr)}
 186         ;
 187
 188 /* CLASSES *******************************************************************/
 189 classdef
 190         = [doc]:no redef visibility classkind no classid formaldefs? [specials]:special* propdefs* [n2]:no kwend {-> New classdef.std(doc.doc, redef.kwredef, visibility, classkind, classid, [formaldefs.formaldef], [specials.superclass], [propdefs.propdef], kwend)};
 191 redef {-> kwredef?}
 192         = kwredef? {-> kwredef};
 193 classkind
 194         = {concrete} kwclass
 195         | {abstract} kwabstract kwclass
 196         | {interface} kwinterface
 197         | {enum} kwenum
 198         | {extern} kwextern
 199         ;
 200
 201 formaldefs {-> formaldef*}
 202         = obra no formaldef formaldefs_tail* [n2]:no cbra {-> [formaldef, formaldefs_tail.formaldef]};
 203 formaldefs_tail {-> formaldef}
 204         = comma no formaldef {-> formaldef};
 205 formaldef
 206         = classid typing? {-> New formaldef(classid, typing.type)};
 207
 208 special {-> superclass}
 209         = {special} no kwspecial [n2]:no type {-> New superclass(kwspecial, Null, type)}
 210         | {super} no kwsuper [n2]:no type {-> New superclass(Null, kwsuper, type)}
 211         ;
 212
 213 propdefs~toplevel {-> propdef}
 214         = propdef~toplevel n1 {-> propdef~toplevel.propdef}
 215         ;
 216 propdef~toplevel {-> propdef}
 217         = {meth} [doc]:no redef visibility kwmeth methid signature kwdo stmtso kwend? {-> New propdef.concrete_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature, stmtso.expr)}
 218         | {assign_return} [doc]:no redef visibility kwmeth methid signature_withret assign no assign_return {-> New propdef.concrete_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature_withret.signature, assign_return.expr)}
 219 !toplevel| {deferred} [doc]:no redef visibility kwmeth methid signature kwis kwabstract {-> New propdef.deferred_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature)}
 220 !toplevel| {intern} [doc]:no redef visibility kwmeth methid signature kwis kwintern {-> New propdef.intern_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature)}
 221         | {extern} [doc]:no redef visibility kwmeth methid signature kwis kwextern string? extern_calls? {-> New propdef.extern_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature, string, extern_calls)}
 222 !toplevel| {var} [doc]:no readable? writable? redef visibility kwvar attrid typing? {-> New propdef.attr(doc.doc, readable.able, writable.able, redef.kwredef, visibility, kwvar, attrid, Null, typing.type, Null)}
 223 !toplevel| {var2} [doc]:no readable? writable? redef visibility kwvar attrid typing? assign [n2]:no expr {-> New propdef.attr(doc.doc, readable.able, writable.able, redef.kwredef, visibility, kwvar, attrid, Null, typing.type, expr)}
 224 !toplevel| {var3} [doc]:no redef visibility kwvar id typing? writable2? {-> New propdef.attr(doc.doc, Null, writable2.able, redef.kwredef, visibility, kwvar, Null, id, typing.type, Null)}
 225 !toplevel| {var4} [doc]:no redef visibility kwvar id typing? writable2? assign [n2]:no expr {-> New propdef.attr(doc.doc, Null, writable2.able, redef.kwredef, visibility, kwvar, Null, id, typing.type, expr)}
 226 !toplevel| {init} [doc]:no redef visibility kwinit methid? signature kwdo stmtso kwend? {-> New propdef.concrete_init(doc.doc, redef.kwredef, visibility, kwinit, methid, signature, stmtso.expr)}
 227 !toplevel| {type} [doc]:no redef visibility kwtype classid typing {-> New propdef.type(doc.doc, redef.kwredef, visibility, kwtype, classid, typing.type)}
 228 !toplevel| {extern_init} [doc]:no redef visibility kwnew methid? signature kwis kwextern string? extern_calls? {-> New propdef.extern_init(doc.doc, redef.kwredef, visibility, kwnew, methid, signature, string, extern_calls)}
 229         ;
 230 readable {-> able}
 231         = redef kwreadable {-> New able.read(redef.kwredef, kwreadable)}
 232         ;
 233 writable {-> able}
 234         = redef kwwritable {-> New able.write(redef.kwredef, Null, kwwritable)}
 235         ;
 236 writable2 {-> able}
 237         = redef visibility kwwritable {-> New able.write(redef.kwredef, visibility, kwwritable)}
 238         ;
 239
 240 visibility
 241         = {public} {-> New visibility.public()}
 242         | {private} kwprivate no {-> New visibility.private(kwprivate)}
 243         | {protected} kwprotected no {-> New visibility.protected(kwprotected)}
 244         | {intrude} kwintrude no {-> New visibility.intrude(kwintrude)}
 245         ;
 246
 247 methid {-> methid}
 248         = {id} id {-> New methid.id(id)}
 249         | {plus} plus {-> New methid.plus(plus)}
 250         | {minus} minus {-> New methid.minus(minus)}
 251         | {star} star {-> New methid.star(star)}
 252         | {slash} slash {-> New methid.slash(slash)}
 253         | {percent} percent {-> New methid.percent(percent)}
 254         | {eq} eq {-> New methid.eq(eq)}
 255         | {ne} ne {-> New methid.ne(ne)}
 256         | {le} le {-> New methid.le(le)}
 257         | {ge} ge {-> New methid.ge(ge)}
 258         | {lt} lt {-> New methid.lt(lt)}
 259         | {gt} gt {-> New methid.gt(gt)}
 260         | {ll} ll {-> New methid.ll(ll)}
 261         | {gg} gg {-> New methid.gg(gg)}
 262         | {bra} obra cbra {-> New methid.bra(obra, cbra)}
 263         | {starship} starship {-> New methid.starship(starship)}
 264         | {assign} id assign {-> New methid.assign(id, assign)}
 265         | {braassign} obra cbra assign {-> New methid.braassign(obra, cbra, assign)}
 266         ;
 267
 268 signature~withret {-> signature}
 269         = opar no params? cpar typing [no2]:no closure_decls? {-> New signature(opar, [params.param], cpar, typing.type, [closure_decls.closure_decl])}
 270 !withret| {noret} opar no params? cpar [no2]:no closure_decls? {-> New signature(opar, [params.param], cpar, Null, [closure_decls.closure_decl])}
 271         | {nopar} typing no closure_decls? {-> New signature(Null, [], Null, typing.type, [closure_decls.closure_decl])}
 272 !withret| {noparnoret} no closure_decls? {-> New signature(Null, [], Null, Null, [closure_decls.closure_decl])}
 273         ;
 274
 275 signature_noclosures {-> signature}
 276         = opar no params? cpar typing? {-> New signature(opar, [params.param], cpar, typing.type, [])}
 277         | {nopar} typing? {-> New signature(Null, [], Null, typing.type, [])}
 278         ;
 279
 280 params {-> param*}
 281         = param params_tail* [n2]:no {-> [param, params_tail.param] }
 282         ;
 283 params_tail {-> param}
 284         = comma no param {-> param};
 285 param
 286         = {untyped} id {-> New param(id, Null, Null)}
 287         | id typing dotdotdot? {-> New param(id, typing.type, dotdotdot)}
 288         ;
 289
 290 closure_decls {->closure_decl*}
 291         = closure_decl+ {-> [closure_decl]};
 292 closure_decl
 293         = kwbreak? bang id signature_noclosures n {-> New closure_decl(kwbreak, bang, id, signature_noclosures.signature, Null)}
 294         | {optionnal} kwbreak? bang id signature_noclosures kwdo stmtso n {-> New closure_decl(kwbreak, bang, id, signature_noclosures.signature, stmtso.expr)}
 295         | {assign} kwbreak? bang id signature_noclosures assign no assign_continue n {-> New closure_decl(kwbreak, bang, id, signature_noclosures.signature, assign_continue.expr)}
 296         ;
 297
 298 assign_return{-> expr}
 299         = expr_final {-> New expr.return(Null, expr_final.expr)}
 300         ;
 301
 302 extern_calls {-> extern_calls}
 303         = kwimport no extern_call extern_call_tail* {-> New extern_calls( kwimport, [extern_call, extern_call_tail.extern_call] )}
 304         ;
 305 extern_call_tail {-> extern_call}
 306         = comma no extern_call {-> extern_call};
 307 extern_call {-> extern_call}
 308     = {prop} extern_call_prop {-> extern_call_prop.extern_call}
 309     | {cast} extern_call_cast {-> extern_call_cast.extern_call}
 310         | {super} kwsuper {-> New extern_call.super( kwsuper )}
 311     ;
 312 extern_call_prop {-> extern_call}
 313     = {local} methid {-> New extern_call.local_prop( methid )}
 314         | {full} classid quad methid {-> New extern_call.full_prop( classid, quad, methid )}
 315         | {init} classid {-> New extern_call.init_prop( classid )}
 316         ;
 317 extern_call_cast {-> extern_call}
 318     = {as_cast} [from_type]:type kwas [n2]:no opar [n3]:no [to_type]:type [n4]:no cpar {-> New extern_call.cast_as(from_type, kwas, to_type)}
 319         | {as_nullable} type kwas [n2]:no kwnullable {-> New extern_call.as_nullable( type, kwas, kwnullable)}
 320         | {as_not_nullable} type kwas [n2]:no kwnot [n3]:no kwnullable {-> New extern_call.as_not_nullable( type, kwas, kwnot, kwnullable)}
 321         ;
 322
 323
 324 /* TYPES *********************************************************************/
 325 type~nobra {-> type}
 326         = {simple} kwnullable? classid {-> New type(kwnullable, classid, [])}
 327 !nobra  | {generic} kwnullable? classid obra no types [n2]:no cbra {-> New type(kwnullable, classid, [types.type])}
 328         ;
 329 types {-> type*}
 330         = type types_tail* {-> [type, types_tail.type]};
 331 types_tail {-> type}
 332         = comma no type {-> type};
 333 typing {-> type}
 334         = column no type {-> type};
 335
 336 /* STATMENTS *****************************************************************/
 337 stmtso~withelse~withend {-> expr?}
 338         = {block} n stmtsnend {-> stmtsnend.expr}
 339         | {emptyblock} n kwend {-> New expr.block([], kwend)}
 340         | {emptyoneline} kwend {-> New expr.block([], kwend)}
 341 !withend| {oneline} stmt~withelse {-> stmt~withelse.expr}
 342         ;
 343 stmts {-> expr}
 344         = stmt stmts_tail* {-> New expr.block([stmt.expr, stmts_tail.expr], Null)};
 345 stmtsn {-> expr}
 346         = stmt stmts_tail* n {-> New expr.block([stmt.expr, stmts_tail.expr], Null)};
 347 stmtsnend {-> expr}
 348         = stmt stmts_tail* n kwend {-> New expr.block([stmt.expr, stmts_tail.expr], kwend)};
 349 stmts_tail {-> expr}
 350         = n stmt {-> stmt.expr};
 351 stmt~withelse {-> expr}
 352         = {vardecl} vardecl~withelse {-> vardecl~withelse.expr}
 353         | {assign} assignment~withelse {-> assignment~withelse.expr}
 354         | {return} kwreturn expr_final~withelse? {-> New expr.return(kwreturn, expr_final~withelse.expr)}
 355         | {break} kwbreak label? expr_final~withelse? {-> New expr.break(kwbreak, label, expr_final~withelse.expr)}
 356         | {abort} kwabort {-> New expr.abort(kwabort)}
 357         | {continue} kwcontinue label? expr_final~withelse? {-> New expr.continue(kwcontinue, label, expr_final~withelse.expr)}
 358         | {do} do~withelse {-> do~withelse.expr}
 359         | {if} if~withelse {-> if~withelse.expr}
 360         | {while} while~withelse {-> while~withelse.expr}
 361         | {loop} loop~withelse {-> loop~withelse.expr}
 362         | {for} for~withelse {-> for~withelse.expr}
 363         | {assert} assert~withelse {-> assert~withelse.expr}
 364         | {call} recv id args_nopar closure_defs~withelse? {-> New expr.call(recv.expr, id, args_nopar.exprs, [closure_defs~withelse.closure_def])}
 365         | {super} qualified? kwsuper args_nopar {-> New expr.super(qualified, kwsuper, args_nopar.exprs)}
 366         | {init} recv kwinit args_nopar {-> New expr.init(recv.expr, kwinit, args_nopar.exprs)}
 367         ;
 368
 369 label= kwlabel id;
 370
 371 closure_defs~withelse {-> closure_def*}
 372         = {one} closure_def_last~withelse {-> [closure_def_last~withelse.closure_def]}
 373         | closure_def closure_defs~withelse {-> [closure_def, closure_defs~withelse.closure_def]}
 374         ;
 375
 376 closure_def_last~withelse {-> closure_def}
 377         = bang [id]:closure_id idlist? kwdo stmtso_withend label {-> New closure_def(bang, id, [idlist.id], kwdo, stmtso_withend.expr, label)}
 378         | {nolabel} bang [id]:closure_id idlist? kwdo stmtso~withelse {-> New closure_def(bang, id, [idlist.id], kwdo, stmtso~withelse.expr, Null)}
 379         | {assign} bang [id]:closure_id idlist? assign no assign_continue~withelse {-> New closure_def(bang, id, [idlist.id], Null, assign_continue~withelse.expr, Null)}
 380         ;
 381
 382 closure_def {-> closure_def}
 383         = bang [id]:closure_id idlist? kwdo n stmtsn {-> New closure_def(bang, id, [idlist.id], kwdo, stmtsn.expr, Null)}
 384         | {empty} bang [id]:closure_id idlist? kwdo n {-> New closure_def(bang, id, [idlist.id], kwdo, Null, Null)}
 385         ;
 386 closure_id
 387         = {simple} id
 388         | {break} kwbreak
 389         ;
 390
 391 assign_continue~withelse{-> expr}
 392         = expr_final~withelse {-> New expr.continue(Null, Null, expr_final~withelse.expr)}
 393         ;
 394
 395 vardecl~withelse{-> expr}
 396         = kwvar id typing? {-> New expr.vardecl(kwvar, id, typing.type, Null, Null)}
 397         | {assign} kwvar id typing? assign no expr_final~withelse {-> New expr.vardecl(kwvar, id, typing.type, assign, expr_final~withelse.expr)}
 398         ;
 399
 400 assignment~withelse {-> expr}
 401         = {attr} recv attrid assign expr_final~withelse {-> New expr.attr_assign(recv.expr, attrid, assign, expr_final~withelse.expr)}
 402         | {call} recv id args assign expr_final~withelse {-> New expr.call_assign(recv.expr, id, args.exprs, assign,  expr_final~withelse.expr)}
 403         | {bra} expr_atom braargs assign expr_final~withelse {-> New expr.bra_assign(expr_atom.expr, braargs.exprs, assign,  expr_final~withelse.expr)}
 404         | {attr_re} recv attrid assign_op expr_final~withelse {-> New expr.attr_reassign(recv.expr, attrid, assign_op,  expr_final~withelse.expr)}
 405         | {call_re} recv id args assign_op expr_final~withelse {-> New expr.call_reassign(recv.expr, id, args.exprs, assign_op,  expr_final~withelse.expr)}
 406         | {bra_re} expr_atom braargs assign_op expr_final~withelse {-> New expr.bra_reassign(expr_atom.expr, braargs.exprs, assign_op,  expr_final~withelse.expr)}
 407         ;
 408 assign_op
 409         = {plus} pluseq
 410         | {minus} minuseq
 411         ;
 412
 413 do~withelse {-> expr}
 414         = kwdo stmtso_withend label {-> New expr.do(kwdo, stmtso_withend.expr, label)}
 415         | {nolabel} kwdo stmtso~withelse {-> New expr.do(kwdo, stmtso~withelse.expr, Null)}
 416         ;
 417
 418 if~withelse {-> expr}
 419         = {onelineelse} kwif no expr [n2]:no kwthen stmt_withelse kwelse stmtso~withelse {-> New expr.if(kwif, expr, stmt_withelse.expr, stmtso~withelse.expr)}
 420 !withelse       | {oneline} kwif no expr [n2]:no kwthen stmt {-> New expr.if(kwif, expr, stmt.expr, Null)}
 421 !withelse       | {block} kwif no expr [n2]:no kwthen [n3]:n stmtsn elsepartblock {-> New expr.if(kwif, expr, stmtsn.expr, elsepartblock.expr)}
 422 !withelse       | {emptyblock} kwif no expr [n2]:no kwthen [n3]:n? elsepartblock {-> New expr.if(kwif, expr, Null, elsepartblock.expr)}
 423         ;
 424 elsepartblock {-> expr?}
 425         = {else} kwelse stmtso {-> stmtso.expr}
 426         | {empty} kwend {-> New expr.block([], kwend)}
 427         ;
 428
 429 loop~withelse {-> expr}
 430         = kwloop stmtso_withend label {-> New expr.loop(kwloop, stmtso_withend.expr, label)}
 431         | {nolabel} kwloop stmtso~withelse {-> New expr.loop(kwloop, stmtso~withelse.expr, Null)}
 432         ;
 433
 434 while~withelse {-> expr}
 435         = kwwhile no expr [n2]:no kwdo stmtso_withend label {-> New expr.while(kwwhile, expr, kwdo, stmtso_withend.expr, label)}
 436         | {nolabel} kwwhile no expr [n2]:no kwdo stmtso~withelse {-> New expr.while(kwwhile, expr, kwdo, stmtso~withelse.expr, Null)}
 437         ;
 438
 439 for~withelse {-> expr}
 440         = kwfor no [ids]:idlist [n2]:no kwin [n3]:no expr [n4]:no kwdo stmtso_withend label {-> New expr.for(kwfor, [ids.id], expr, kwdo, stmtso_withend.expr, label)}
 441         | {nolabel} kwfor no [ids]:idlist [n2]:no kwin [n3]:no expr [n4]:no kwdo stmtso~withelse {-> New expr.for(kwfor, [ids.id], expr, kwdo, stmtso~withelse.expr, Null)}
 442         ;
 443
 444 assert~withelse {-> expr}
 445         = {else} kwassert assertid? expr_final_withelse kwelse stmtso~withelse {-> New expr.assert(kwassert, assertid.id, expr_final_withelse.expr, stmtso~withelse.expr)}
 446 !withelse| {noelse} kwassert assertid? expr_final {-> New expr.assert(kwassert, assertid.id, expr_final.expr, Null)}
 447         ;
 448 assertid {-> id}
 449         = id column {-> id};
 450
 451 /* EXPRESSIONS ***************************************************************/
 452 expr_final~nopar~withelse~nobra {-> expr}
 453         = expr~nopar~nobra {-> expr~nopar~nobra.expr}
 454         | {closure_call} recv~nobra id args closure_defs~withelse {-> New expr.call(recv~nobra.expr, id, args.exprs, [closure_defs~withelse.closure_def])}
 455 !nobra!nopar    | {closure_bra} expr_atom braargs closure_defs~withelse {-> New expr.bra(expr_atom.expr, braargs.exprs, [closure_defs~withelse.closure_def])}
 456         ;
 457
 458 expr~nopar~nobra {-> expr}
 459         = expr_and~nopar~nobra {-> expr_and~nopar~nobra.expr}
 460         | {ifexpr} kwif [n1]:no expr [n2]:no kwthen [n3]:no [then]:expr [n4]:no kwelse [n5]:no [else]:expr~nopar~nobra {-> New expr.ifexpr(kwif, expr, kwthen, then, kwelse, else.expr)}
 461         ;
 462
 463 expr_and~nopar~nobra {-> expr}
 464         = expr_not~nopar~nobra {-> expr_not~nopar~nobra.expr}
 465         | {or} expr_and~nopar~nobra kwor no expr_not~nopar~nobra {-> New expr.or(expr_and~nopar~nobra.expr, expr_not~nopar~nobra.expr)}
 466         | {and} expr_and~nopar~nobra kwand no expr_not~nopar~nobra {-> New expr.and(expr_and~nopar~nobra.expr, expr_not~nopar~nobra.expr)}
 467         | {or_else} expr_and~nopar~nobra kwor kwelse no expr_not~nopar~nobra {-> New expr.or_else(expr_and~nopar~nobra.expr, expr_not~nopar~nobra.expr)}
 468         ;
 469
 470 expr_not~nopar~nobra {-> expr}
 471         = expr_eq~nopar~nobra {-> expr_eq~nopar~nobra.expr}
 472         | {not} kwnot no expr_not~nopar~nobra {-> New expr.not(kwnot, expr_not~nopar~nobra.expr)}
 473         ;
 474
 475 expr_eq~nopar~nobra {-> expr}
 476         = expr_add~nopar~nobra {-> expr_add~nopar~nobra.expr}
 477         | {eq} expr_add~nopar~nobra eq no [expr2]:expr_add~nopar~nobra {-> New expr.eq(expr_add~nopar~nobra.expr, expr2.expr)}
 478         | {ee} expr_add~nopar~nobra kwis no [expr2]:expr_add~nopar~nobra {-> New expr.ee(expr_add~nopar~nobra.expr, expr2.expr)}
 479         | {ne} expr_add~nopar~nobra ne no [expr2]:expr_add~nopar~nobra {-> New expr.ne(expr_add~nopar~nobra.expr, expr2.expr)}
 480         | {lt} expr_add~nopar~nobra lt no [expr2]:expr_add~nopar~nobra {-> New expr.lt(expr_add~nopar~nobra.expr, expr2.expr)}
 481         | {le} expr_add~nopar~nobra le no [expr2]:expr_add~nopar~nobra {-> New expr.le(expr_add~nopar~nobra.expr, expr2.expr)}
 482         | {ll} expr_eq~nopar~nobra ll no [expr2]:expr_add~nopar~nobra {-> New expr.ll(expr_eq~nopar~nobra.expr, expr2.expr)}
 483         | {gt} expr_add~nopar~nobra gt no [expr2]:expr_add~nopar~nobra {-> New expr.gt(expr_add~nopar~nobra.expr, expr2.expr)}
 484         | {ge} expr_add~nopar~nobra ge no [expr2]:expr_add~nopar~nobra {-> New expr.ge(expr_add~nopar~nobra.expr, expr2.expr)}
 485         | {gg} expr_eq~nopar~nobra gg no [expr2]:expr_add~nopar~nobra {-> New expr.gg(expr_eq~nopar~nobra.expr, expr2.expr)}
 486         | {starship} expr_add~nopar~nobra starship no [expr2]:expr_add~nopar~nobra {-> New expr.starship(expr_add~nopar~nobra.expr, expr2.expr)}
 487         | {isa} expr_add~nopar~nobra kwisa no type~nobra {-> New expr.isa(expr_add~nopar~nobra.expr, type~nobra.type)}
 488         ;
 489
 490 expr_add~nopar~nobra {-> expr}
 491         =  expr_mul~nopar~nobra {-> expr_mul~nopar~nobra.expr}
 492         | {plus} expr_add~nopar~nobra plus no [expr2]:expr_mul~nopar~nobra {-> New expr.plus(expr_add~nopar~nobra.expr, expr2.expr)}
 493         | {minus} expr_add~nopar~nobra minus no [expr2]:expr_mul~nopar~nobra {-> New expr.minus(expr_add~nopar~nobra.expr, expr2.expr)}
 494         ;
 495
 496 expr_mul~nopar~nobra {-> expr}
 497         = expr_minus~nopar~nobra {-> expr_minus~nopar~nobra.expr}
 498         | {star} expr_mul~nopar~nobra star no [expr2]:expr_minus~nopar~nobra {-> New expr.star(expr_mul~nopar~nobra.expr, expr2.expr)}
 499         | {slash} expr_mul~nopar~nobra slash no [expr2]:expr_minus~nopar~nobra {-> New expr.slash(expr_mul~nopar~nobra.expr, expr2.expr)}
 500         | {percent} expr_mul~nopar~nobra percent no [expr2]:expr_minus~nopar~nobra {-> New expr.percent(expr_mul~nopar~nobra.expr, expr2.expr)}
 501         ;
 502
 503 expr_minus~nopar~nobra {-> expr}
 504         = expr_new~nopar~nobra {-> expr_new~nopar~nobra.expr}
 505         | {minus} minus no expr_minus~nopar~nobra {-> New expr.uminus(minus, expr_minus~nopar~nobra.expr)}
 506         | {once} kwonce no expr_minus~nopar~nobra {-> New expr.once(kwonce, expr_minus~nopar~nobra.expr)}
 507         ;
 508
 509 expr_new~nopar~nobra {-> expr}
 510         = expr_atom~nopar~nobra {-> expr_atom~nopar~nobra.expr}
 511         | {new} kwnew no type~nobra args {-> New expr.new(kwnew, type~nobra.type, Null, args.exprs)}
 512         | {isset_attr} kwisset recv~nopar~nobra attrid {-> New expr.isset_attr(kwisset, recv~nopar~nobra.expr, attrid)}
 513         ;
 514
 515 expr_atom~nopar~nobra {-> expr}
 516         = {attr} recv~nopar~nobra attrid {-> New expr.attr(recv~nopar~nobra.expr, attrid)}
 517         | {call} recv~nopar~nobra id args {-> New expr.call(recv~nopar~nobra.expr, id, args.exprs, [])}
 518         | {super} qualified? kwsuper args {-> New expr.super(qualified, kwsuper, args.exprs)}
 519         | {init} recv~nopar~nobra kwinit args {-> New expr.init(recv~nopar~nobra.expr, kwinit, args.exprs)}
 520 !nobra  | {bra} expr_atom~nopar braargs {-> New expr.bra(expr_atom~nopar.expr, braargs.exprs, [])}
 521         | {new} kwnew no type~nobra dot [n2]:no id args {-> New expr.new(kwnew, type~nobra.type, id, args.exprs)}
 522 // !nopar to unambiguise 'foo[5].bar' between '(foo[5]).bar' and 'foo([5].bar),
 523 !nobra!nopar    | {range} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no cbra {-> New expr.crange(obra, expr, expr2.expr, cbra)}
 524 !nobra!nopar    | {orange} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no [cbra]:obra  {-> New expr.orange(obra, expr, expr2.expr, cbra)}
 525 !nobra!nopar    | {array} braargs {-> New expr.array(braargs.exprs)}
 526         | {self} kwself {-> New expr.self(kwself)}
 527         | {true} kwtrue {-> New expr.true(kwtrue)}
 528         | {false} kwfalse {-> New expr.false(kwfalse)}
 529         | {null} kwnull {-> New expr.null(kwnull)}
 530         | {int} number  {-> New expr.int(number)}
 531         | {float} float  {-> New expr.float(float)}
 532         | {char} char  {-> New expr.char(char)}
 533         | {string} string  {-> New expr.string(string)}
 534         | {superstring} superstring  {-> superstring.expr}
 535 !nopar  | {par} opar expr cpar {-> New expr.par(opar, expr, cpar)}
 536         | {as_cast} expr_atom~nopar~nobra dot no kwas [n2]:no opar [n3]:no type [n4]:no cpar {-> New expr.as_cast(expr_atom~nopar~nobra.expr, kwas, opar, type, cpar)}
 537         | {as_notnull} expr_atom~nopar~nobra dot no kwas [n2]:no opar [n3]:no kwnot [n4]:no kwnull [n5]:no cpar {-> New expr.as_notnull(expr_atom~nopar~nobra.expr, kwas, opar, kwnot, kwnull, cpar)}
 538         ;
 539
 540 superstring {-> expr}
 541         = superstring_start superstring_middle* superstring_end {-> New expr.superstring([superstring_start.expr, superstring_middle.expr, superstring_end.expr])};
 542 superstring_start {-> expr*}
 543         = start_string_p no expr [n2]:no {-> [start_string_p.expr, expr]};
 544 start_string_p {-> expr}
 545         = start_string {-> New expr.start_string(start_string)};
 546 superstring_middle {-> expr*}
 547         = mid_string_p no expr [n2]:no {-> [mid_string_p.expr, expr]};
 548 mid_string_p {-> expr}
 549         = mid_string {-> New expr.mid_string(mid_string)};
 550 superstring_end {-> expr}
 551         = end_string {-> New expr.end_string(end_string)};
 552
 553 /* MISC **********************************************************************/
 554
 555 recv~nopar~nobra {-> expr}
 556         = expr_atom~nopar~nobra dot no {-> expr_atom~nopar~nobra.expr}
 557         | {implicit} {-> New expr.implicit_self()}
 558         ;
 559
 560 args {-> exprs}
 561         = opar no expr_list cpar {-> New exprs.par(opar, [expr_list.expr], cpar) }
 562         | {emptypar} opar no cpar {-> New exprs.par(opar, [], cpar) }
 563         | {empty} {-> New exprs.list([])}
 564         ;
 565 args_nopar {-> exprs}
 566         = opar no expr_list cpar {-> New exprs.par(opar, [expr_list.expr], cpar) }
 567         | {onearg} expr_nopar {-> New exprs.list([expr_nopar.expr])}
 568         | {emptypar} opar no cpar {-> New exprs.par(opar, [], cpar) }
 569         | {empty} {-> New exprs.list([])}
 570         ;
 571 braargs {-> exprs}
 572         = obra no expr_list cbra {-> New exprs.bra(obra, [expr_list.expr], cbra)};
 573 expr_list {-> expr*}
 574         = expr [n2]:no expr_tail* {-> [expr, expr_tail.expr]};
 575 expr_tail {-> expr}
 576         = comma no expr [n2]:no {-> expr};
 577 idlist {-> id*}
 578         = opar idlist_nopar cpar {-> [idlist_nopar.id]}
 579         | {nopar} idlist_nopar {-> [idlist_nopar.id]}
 580         ;
 581 idlist_nopar {-> id*}
 582         = {single} id {-> [id]}
 583         | {more} idlist_nopar no comma [n2]:no id {-> [idlist_nopar.id, id]}
 584         ;
 585
 586 module_name {-> module_name}
 587         = {mod} modquad* id {-> New module_name(Null, [modquad.id], id)}
 588         | {root} quad no modquad* id {-> New module_name(quad, [modquad.id], id)}
 589         ;
 590
 591 qualified
 592         = {cla} modquad* classquad {-> New qualified([modquad.id], classquad.classid)}
 593         | {mod} modquad+ {-> New qualified([modquad.id], Null)}
 594         ;
 595 modquad {-> id}
 596         = id quad no {-> id};
 597 classquad {-> classid}
 598         = classid quad no {-> classid};
 599
 600 n1      = {a} comment | {b} eol;
 601 n {-> doc?}
 602         = {a} n2? comment+ {-> New doc([comment])}
 603         | {b} n2 {-> Null}
 604         ;
 605 no {-> doc?}
 606         = {empty} {-> Null}
 607         | n {-> n.doc}
 608         ;
 609
 610 n2
 611         = {a} n2? comment+ eol+
 612         | {b} eol+
 613         ;
 614
 615 /*****************************************************************************/
 616 Abstract Syntax Tree
 617 /*****************************************************************************/
 618
 619 module  = moduledecl? [imports]:import* [classdefs]:classdef*;
 620
 621 moduledecl
 622         = doc? kwmodule [name]:module_name;
 623
 624 import  = {std} visibility kwimport [name]:module_name
 625         | {no} visibility kwimport kwend
 626         ;
 627
 628 visibility
 629         = {public}
 630         | {private} kwprivate
 631         | {protected} kwprotected
 632         | {intrude} kwintrude
 633         ;
 634
 635 classdef= {std} doc? kwredef? visibility classkind [id]:classid? [formaldefs]:formaldef* [superclasses]:superclass* [propdefs]:propdef* kwend
 636         | {top} [propdefs]:propdef*
 637         | {main} [propdefs]:propdef*
 638         ;
 639 classkind
 640         = {concrete} kwclass
 641         | {abstract} kwabstract kwclass
 642         | {interface} kwinterface
 643         | {enum} kwenum
 644         | {extern} kwextern
 645         ;
 646 formaldef = [id]:classid type?;
 647 superclass = kwspecial? kwsuper? type;
 648
 649
 650 propdef = {attr} doc? [readable]:able? [writable]:able? kwredef? visibility kwvar [id]:attrid? [id2]:id? type? expr?
 651         | {meth} doc? kwredef? visibility methid signature
 652         | {deferred_meth} doc? kwredef? visibility kwmeth methid signature
 653         | {intern_meth} doc? kwredef? visibility kwmeth methid signature
 654         | {extern_meth} doc? kwredef? visibility kwmeth methid signature [extern]:string? extern_calls?
 655         | {concrete_meth} doc? kwredef? visibility kwmeth methid signature [block]:expr?
 656         | {concrete_init} doc? kwredef? visibility kwinit methid? signature [block]:expr?
 657         | {extern_init} doc? kwredef? visibility kwnew methid? signature [extern]:string? extern_calls?
 658         | {main_meth} kwredef? [block]:expr?
 659         | {type} doc? kwredef? visibility kwtype [id]:classid type
 660         ;
 661
 662 able    = {read} kwredef? kwreadable
 663         | {write} kwredef? visibility? kwwritable
 664         ;
 665
 666 methid = {id} id | {plus} plus | {minus} minus | {star} star | {slash} slash | {percent} percent | {eq} eq | {ne} ne | {le} le | {ge} ge | {lt} lt | {gt} gt |  {ll} ll | {gg} gg | {bra} obra cbra | {starship} starship | {assign} id assign | {braassign} obra cbra assign;
 667
 668 signature = opar? [params]:param* cpar? type? [closure_decls]:closure_decl*;
 669
 670 param   = id type? dotdotdot?
 671         ;
 672
 673 closure_decl = kwbreak? bang id signature expr?
 674         ;
 675
 676 type    = kwnullable? [id]:classid [types]:type*;
 677
 678 label = kwlabel id;
 679
 680 expr    = {block} expr* kwend?
 681         | {vardecl} kwvar id type? assign? expr?
 682         | {return} kwreturn? expr?
 683         | {break} kwbreak label? expr?
 684         | {abort} kwabort
 685         | {continue} kwcontinue? label? expr?
 686         | {do} kwdo [block]:expr? label?
 687         | {if} kwif expr [then]:expr? [else]:expr?
 688         | {ifexpr} kwif expr kwthen [then]:expr kwelse [else]:expr
 689         | {while} kwwhile expr kwdo [block]:expr? label?
 690         | {loop} kwloop [block]:expr? label?
 691         | {for} kwfor [ids]:id* expr kwdo [block]:expr? label?
 692         | {assert} kwassert id? expr [else]:expr?
 693         | {once} kwonce expr
 694         | {send} expr
 695         | {binop} expr [expr2]:expr
 696         | {or} expr [expr2]:expr
 697         | {and} expr [expr2]:expr
 698         | {or_else} expr [expr2]:expr
 699         | {not} kwnot expr
 700         | {eq} expr [expr2]:expr
 701         | {ee} expr [expr2]:expr
 702         | {ne} expr [expr2]:expr
 703         | {lt} expr [expr2]:expr
 704         | {le} expr [expr2]:expr
 705         | {ll} expr [expr2]:expr
 706         | {gt} expr [expr2]:expr
 707         | {ge} expr [expr2]:expr
 708         | {gg} expr [expr2]:expr
 709         | {isa} expr type
 710         | {plus} expr [expr2]:expr
 711         | {minus} expr [expr2]:expr
 712         | {starship} expr [expr2]:expr
 713         | {star} expr [expr2]:expr
 714         | {slash} expr [expr2]:expr
 715         | {percent} expr [expr2]:expr
 716         | {uminus} minus expr
 717         | {new} kwnew type id? [args]:exprs
 718         | {attr} expr [id]:attrid
 719         | {attr_assign} expr [id]:attrid assign [value]:expr
 720         | {attr_reassign} expr [id]:attrid assign_op [value]:expr
 721         | {call} expr id [args]:exprs [closure_defs]:closure_def*
 722         | {call_assign} expr id [args]:exprs assign [value]:expr
 723         | {call_reassign} expr id [args]:exprs assign_op [value]:expr
 724         | {super} qualified? kwsuper [args]:exprs
 725         | {init} expr kwinit [args]:exprs
 726         | {bra} expr [args]:exprs [closure_defs]:closure_def*
 727         | {bra_assign} expr [args]:exprs assign [value]:expr
 728         | {bra_reassign} expr [args]:exprs assign_op [value]:expr
 729         | {closure_call} id [args]:exprs [closure_defs]:closure_def*
 730         | {var} id
 731         | {var_assign} id assign [value]:expr
 732         | {var_reassign} id assign_op [value]:expr
 733         | {range} expr [expr2]:expr
 734         | {crange} obra expr [expr2]:expr cbra
 735         | {orange} obra expr [expr2]:expr [cbra]:obra
 736         | {array} [exprs]:exprs
 737         | {self} kwself
 738         | {implicit_self}
 739         | {true} kwtrue
 740         | {false} kwfalse
 741         | {null} kwnull
 742         | {int} number
 743         | {float} float
 744         | {char} char
 745         | {string} string
 746         | {start_string} [string]:start_string
 747         | {mid_string} [string]:mid_string
 748         | {end_string} [string]:end_string
 749         | {superstring} [exprs]:expr*
 750         | {par} opar expr cpar
 751         | {as_cast} expr kwas opar type cpar
 752         | {as_notnull} expr kwas opar kwnot kwnull cpar
 753         | {isset_attr} kwisset expr [id]:attrid
 754         ;
 755 exprs
 756         = {list} [exprs]:expr*
 757         | {par} opar [exprs]:expr* cpar
 758         | {bra} obra [exprs]:expr* cbra
 759         ;
 760 assign_op
 761         = {plus} pluseq
 762         | {minus} minuseq
 763         ;
 764
 765 closure_def
 766         = bang [id]:closure_id [ids]:id* kwdo? expr? label?
 767         ;
 768 closure_id
 769         = {simple} id
 770         | {break} kwbreak
 771         ;
 772
 773 module_name = quad? [path]:id* id;
 774 extern_calls = kwimport [extern_calls]:extern_call*
 775         ;
 776 extern_call =
 777         | {super} kwsuper
 778         | {local_prop} methid
 779         | {full_prop} classid quad? methid
 780         | {init_prop} classid
 781         | {cast_as} [from_type]:type kwas [to_type]:type
 782         | {as_nullable} type kwas kwnullable
 783         | {as_not_nullable} type kwas kwnot kwnullable
 784         ;
 785
 786 qualified = id* classid? ;
 787
 788 doc = comment+;
 789
 790 /*****************************************************************************/
 791