src/model/model_visitor.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Simple visitor framework for Nit models.
  16 #
  17 # This module provides the `ModelVisitor` abstract class and
  18 # refines the classes of the `MEntity` hierarchy to add visiting related methods.
  19 #
  20 # A standard approach on complex visitor is to dispatch the `ModelVisitor::visit` on the
  21 # entities to do specific things.
  22 #
  23 # ~~~nitish
  24 # class FooVisitor
  25 #   super ModelVisitor
  26 #   redef fun visit(e) do e.foo_visit(self)
  27 # end
  28 #
  29 # redef class MEntity
  30 # do
  31 #   fun foo_vist(v: FooVisitor) do visit_all(v)
  32 # end
  33 #
  34 # redef class MClass
  35 # do
  36 #   redef fun foo_visit(v) do
  37 #      print self
  38 #      super
  39 #   end
  40 # end
  41 # ~~~
  42 module model_visitor
  43
  44 import model
  45
  46 # The abstract model visitor template.
  47 #
  48 # Specific visitor must implement the `visit` method to perform the work.
  49 abstract class ModelVisitor
  50         # Visit the entity `e`.
  51         #
  52         # This method setups `current_entity` and call `visit`.
  53         # If `e` is null, nothing is done.
  54         fun enter_visit(e: nullable MEntity) do
  55                 if e == null then return
  56                 var old_entity = current_entity
  57                 current_entity = e
  58                 visit(e)
  59                 current_entity = old_entity
  60         end
  61
  62         # The current visited entity
  63         var current_entity: nullable MEntity = null
  64
  65         # Method to define in specific visitor.
  66         #
  67         # It should not be called directly but used by `enter_visit`
  68         protected fun visit(e: MEntity) is abstract
  69
  70         # Filter classes and method on the visibility.
  71         #
  72         # If set, only the classes and method with at least the given
  73         # visibility level will be visited.
  74         var min_visibility: nullable MVisibility = null is writable
  75
  76         # Is `visibility` acceptable with regard to `min_visibility`?
  77         private fun accept_visitibily(visibility: MVisibility): Bool
  78         do
  79                 var min = min_visibility
  80                 return min == null or min <= visibility
  81         end
  82 end
  83
  84 redef class MEntity
  85         # Call `v.enter_visit` on all nested entities.
  86         #
  87         # See the specific implementation in the subclasses.
  88         fun visit_all(v: ModelVisitor) do end
  89 end
  90
  91 redef class Model
  92         # Visit all the packages of the model.
  93         redef fun visit_all(v) do
  94                 for x in mpackages do v.enter_visit(x)
  95         end
  96 end
  97
  98 redef class MPackage
  99         # Visit the root group of the package.
 100         redef fun visit_all(v) do
 101                 v.enter_visit(root)
 102         end
 103 end
 104
 105 redef class MGroup
 106         # Visit all the subgroups and modules of the group.
 107         redef fun visit_all(v) do
 108                 for x in in_nesting.direct_smallers do v.enter_visit(x)
 109                 for x in mmodules do v.enter_visit(x)
 110         end
 111 end
 112
 113 redef class MModule
 114         # Visit all the classes and class definitions of the module.
 115         #
 116         # On class introduction, the `MClass` then the `MClassDef` are visited.
 117         # On class refinement, only the `MClassDef` is visited (the `MClass` is visited in an imported module).
 118         # On class importation, nothing is visited (the `MClass` and the `MClassDef` are visited in imported modules).
 119         redef fun visit_all(v) do
 120                 for x in mclassdefs do
 121                         if not v.accept_visitibily(x.mclass.visibility) then return
 122                         if x.is_intro then v.enter_visit(x.mclass)
 123                         v.enter_visit(x)
 124                 end
 125         end
 126 end
 127
 128 redef class MClassDef
 129         # Visit all the classes and class definitions of the module.
 130         #
 131         # On property introduction, the `MProperty` then the `MPropDef` are visited.
 132         # On property redefinition, only the `MPropDef` is visited (the `MProperty` is visited in an inherited class).
 133         # On property inheritance, nothing is visited (the `MProperty` and the `MPropDef` are visited in inherited classes).
 134         redef fun visit_all(v) do
 135                 for x in mpropdefs do
 136                         if not v.accept_visitibily(x.mproperty.visibility) then return
 137                         if x.is_intro then v.enter_visit(x.mproperty)
 138                         v.enter_visit(x)
 139                 end
 140         end
 141 end