src/literal.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2012 Jean Privat <jean@pryen.org>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Parsing of literal values in the abstract syntax tree.
  18 module literal
  19
  20 import phase
  21
  22 redef class ToolContext
  23         # Parses literal values in the whole AST and produces errors if needed
  24         var literal_phase: Phase = new LiteralPhase(self, null)
  25 end
  26
  27 private class LiteralPhase
  28         super Phase
  29
  30         redef fun process_nmodule(nmodule) do nmodule.do_literal(toolcontext)
  31 end
  32
  33 redef class AModule
  34         # Visit the module to compute the real value of the literal-related node of the AST.
  35         # Warnings and errors are displayed on the toolcontext.
  36         fun do_literal(toolcontext: ToolContext)
  37         do
  38                 var v = new LiteralVisitor(toolcontext)
  39                 v.enter_visit(self)
  40         end
  41 end
  42
  43 private class LiteralVisitor
  44         super Visitor
  45
  46         var toolcontext: ToolContext
  47
  48         redef fun visit(n)
  49         do
  50                 n.accept_literal(self)
  51                 n.visit_all(self)
  52         end
  53 end
  54
  55 redef class ANode
  56         private fun accept_literal(v: LiteralVisitor) do end
  57 end
  58
  59 redef class AExpr
  60         # Get `self` as a `String`.
  61         # Return null if not a string.
  62         fun as_string: nullable String
  63         do
  64                 if not self isa AStringFormExpr then return null
  65                 return self.value.as(not null)
  66         end
  67
  68         # Get `self` as an `Int`.
  69         # Return null if not an integer.
  70         fun as_int: nullable Int
  71         do
  72                 if not self isa AIntExpr then return null
  73                 return self.value.as(not null)
  74         end
  75
  76         # Get `self` as a single identifier.
  77         # Return null if not a single identifier.
  78         fun as_id: nullable String
  79         do
  80                 if self isa AMethidExpr then
  81                         return self.collect_text
  82                 end
  83                 if not self isa ACallExpr then return null
  84                 if not self.n_expr isa AImplicitSelfExpr then return null
  85                 if not self.n_args.n_exprs.is_empty then return null
  86                 return self.n_id.text
  87         end
  88 end
  89
  90
  91 redef class AIntExpr
  92         # The value of the literal int once computed.
  93         var value: nullable Int
  94 end
  95
  96 redef class ADecIntExpr
  97         redef fun accept_literal(v)
  98         do
  99                 self.value = self.n_number.text.to_i
 100         end
 101 end
 102
 103 redef class AHexIntExpr
 104         redef fun accept_literal(v)
 105         do
 106                 self.value = self.n_hex_number.text.substring_from(2).to_hex
 107         end
 108 end
 109
 110 redef class AFloatExpr
 111         # The value of the literal float once computed.
 112         var value: nullable Float
 113         redef fun accept_literal(v)
 114         do
 115                 self.value = self.n_float.text.to_f
 116         end
 117 end
 118
 119 redef class ACharExpr
 120         # The value of the literal char once computed.
 121         var value: nullable Char
 122         redef fun accept_literal(v)
 123         do
 124                 var txt = self.n_char.text.unescape_nit
 125                 if txt.length != 3 then
 126                         v.toolcontext.error(self.hot_location, "Syntax Error: invalid character literal `{txt}`.")
 127                         return
 128                 end
 129                 self.value = txt.chars[1]
 130         end
 131 end
 132
 133 redef class AStringFormExpr
 134         # The value of the literal string once computed.
 135         var value: nullable String
 136         redef fun accept_literal(v)
 137         do
 138                 var txt = self.n_string.text
 139                 var behead = 1
 140                 var betail = 1
 141                 if txt.chars[0] == txt.chars[1] and txt.length >= 6 then
 142                         behead = 3
 143                         betail = 3
 144                         if txt.chars[0] == '"' and txt.chars[3] == '\n' then behead = 4 # ignore first \n in """
 145                 end
 146                 self.value = txt.substring(behead, txt.length - behead - betail).unescape_nit
 147         end
 148 end