src/metrics/self_metrics.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2012 Jean Privat <jean@pryen.org>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Metrics about the usage of explicit and implicit self
  18 module self_metrics
  19
  20 import metrics_base
  21
  22 redef class ToolContext
  23         var self_metrics_phase: Phase = new SelfMetricsPhase(self, null)
  24 end
  25
  26 private class SelfMetricsPhase
  27         super Phase
  28         redef fun process_mainmodule(mainmodule, given_mmodules)
  29         do
  30                 if not toolcontext.opt_self.value and not toolcontext.opt_all.value then return
  31                 compute_self_metrics(toolcontext.modelbuilder)
  32         end
  33 end
  34
  35 private class ASelfVisitor
  36         super Visitor
  37         var total: Int = 0
  38         var implicits: Int = 0
  39
  40         redef fun visit(n)
  41         do
  42                 if n isa ASelfExpr then
  43                         self.total += 1
  44                         if n isa AImplicitSelfExpr then
  45                                 self.implicits += 1
  46                         end
  47                 end
  48                 n.visit_all(self)
  49         end
  50 end
  51
  52 # Visit the AST and print metics about the usage of self.
  53 fun compute_self_metrics(modelbuilder: ModelBuilder)
  54 do
  55         print "--- Explicit vs. Implicit Self ---"
  56         # Visit all the source code to collect data
  57         var visitor = new ASelfVisitor
  58         for nmodule in modelbuilder.nmodules do
  59                 for nclassdef in nmodule.n_classdefs do
  60                         visitor.enter_visit(nclassdef)
  61                 end
  62         end
  63         print "Total number of self: {visitor.total}"
  64         print "Total number of implicit self: {visitor.implicits} ({div(visitor.implicits*100,visitor.total)}%)"
  65 end