src/parser_util.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Utils and tools related to parsers and AST
  16 module parser_util
  17
  18 intrude import parser
  19 import toolcontext
  20
  21 redef class ToolContext
  22         # Parse a full module given as a string
  23         # Fatal error if the `string` is not a syntactically correct module
  24         fun parse_module(string: String): AModule
  25         do
  26                 var source = new SourceFile.from_string("", string)
  27                 var lexer = new Lexer(source)
  28                 var parser = new Parser(lexer)
  29                 var tree = parser.parse
  30
  31                 var eof = tree.n_eof
  32                 if eof isa AError then
  33                         self.fatal_error(null, "Fatal Error: {eof.message}")
  34                         abort
  35                 end
  36                 return tree.n_base.as(not null)
  37         end
  38
  39         # Parse a full classdef given as a string
  40         # Fatal error if the `string` is not a syntactically correct class definition
  41         fun parse_classdef(string: String): AClassdef
  42         do
  43                 var nmodule = parse_module(string)
  44                 var nclassdefs = nmodule.n_classdefs
  45                 if nclassdefs.length != 1 then
  46                         self.fatal_error(null, "Fatal Error: not a classdef")
  47                         abort
  48                 end
  49                 return nclassdefs.first
  50         end
  51
  52         # Parse a full propdef given as a string
  53         # Fatal error if the `string` is not a syntactically correct property definition
  54         fun parse_propdef(string: String): APropdef
  55         do
  56                 var mod_string = "class Dummy\n{string}\nend"
  57                 var nclassdef = parse_classdef(mod_string)
  58                 var npropdefs = nclassdef.n_propdefs
  59                 if npropdefs.length != 1 then
  60                         self.fatal_error(null, "Fatal Error: not a propdef")
  61                         abort
  62                 end
  63                 return npropdefs.first
  64         end
  65
  66         # Parse a full statement block given as a string
  67         # Fatal error if the `string` is not a syntactically correct statement block
  68         fun parse_stmts(string: String): AExpr
  69         do
  70                 var mod_string = "do\n{string}\nend"
  71                 var nmodule = parse_module(mod_string)
  72                 var nblock = nmodule.n_classdefs.first.n_propdefs.first.as(AMethPropdef).n_block.as(ABlockExpr).n_expr.first.as(ADoExpr).n_block.as(not null)
  73                 return nblock
  74         end
  75
  76         # Parse a full expression given as a string
  77         # Fatal error if the `string` is not a syntactically correct expression
  78         fun parse_expr(string: String): AExpr
  79         do
  80                 var mod_string = "var dummy = \n{string}"
  81                 var nmodule = parse_module(mod_string)
  82                 var nexpr = nmodule.n_classdefs.first.n_propdefs.first.as(AMethPropdef).n_block.as(ABlockExpr).n_expr.first.as(AVardeclExpr).n_expr.as(not null)
  83                 return nexpr
  84         end
  85
  86         # Try to parse the `string` as something
  87         #
  88         # Returns the first possible syntacticaly correct type among:
  89         #
  90         # - a type `AType`
  91         # - a single `Token`
  92         # - an expression `AExpr`
  93         # - a block of statements `ABlockExpr`
  94         # - a full module `AModule`
  95         # - a `AError` if nothing else matches
  96         #
  97         #     var tc = new ToolContext
  98         #     assert tc.parse_something("foo") isa TId
  99         #     assert tc.parse_something("foo[bar]") isa AExpr
 100         #     assert tc.parse_something("Foo[Bar]") isa AType
 101         #     assert tc.parse_something("foo\nbar") isa ABlockExpr
 102         #     assert tc.parse_something("fun foo do bar\nfoo") isa AModule
 103         #     assert tc.parse_something("fun fun") isa AParserError
 104         #     assert tc.parse_something("?%^&") isa ALexerError
 105         fun parse_something(string: String): ANode
 106         do
 107                 var source = new SourceFile.from_string("", string)
 108                 var error
 109                 var tree
 110                 var eof
 111                 var lexer
 112
 113                 lexer = new InjectedLexer(source)
 114                 lexer.injected_before.add new TKwvar
 115                 lexer.injected_before.add new TId
 116                 lexer.injected_before.add new TColumn
 117                 lexer.injected_before.add new TClassid
 118                 lexer.injected_before.add new TObra
 119                 lexer.injected_after.add new TCbra
 120                 tree = (new Parser(lexer)).parse
 121                 eof = tree.n_eof
 122                 if not eof isa AError then
 123                         var ntype = tree.n_base.n_classdefs.first.n_propdefs.first.as(AMethPropdef).n_block.as(ABlockExpr).n_expr.first.as(AVardeclExpr).n_type.n_types.first
 124                         ntype.parent = null
 125                         return ntype
 126                 end
 127                 error = eof
 128
 129                 lexer = new Lexer(source)
 130                 var first = lexer.next
 131                 if not first isa EOF then
 132                         var second = lexer.next
 133                         if second isa EOF and not second isa AError then
 134                                 first.parent = null
 135                                 return first
 136                         end
 137                 end
 138
 139                 lexer = new InjectedLexer(source)
 140                 lexer.injected_before.add new TKwvar
 141                 lexer.injected_before.add new TId
 142                 lexer.injected_before.add new TAssign
 143                 lexer.injected_before.add new TOpar
 144                 lexer.injected_after.add new TCpar
 145                 tree = (new Parser(lexer)).parse
 146                 eof = tree.n_eof
 147                 if not eof isa AError then
 148                         var nexpr = tree.n_base.n_classdefs.first.n_propdefs.first.as(AMethPropdef).n_block.as(ABlockExpr).n_expr.first.as(AVardeclExpr).n_expr.as(AParExpr).n_expr
 149                         nexpr.parent = null
 150                         return nexpr
 151                 end
 152                 if eof.location > error.location then error = eof
 153
 154                 lexer = new InjectedLexer(source)
 155                 lexer.injected_before.add new TKwdo
 156                 lexer.injected_before.add new TEol
 157                 lexer.injected_after.add new TEol
 158                 lexer.injected_after.add new TKwend
 159                 tree = (new Parser(lexer)).parse
 160                 eof = tree.n_eof
 161                 if not eof isa AError then
 162                         var nblock = tree.n_base.n_classdefs.first.n_propdefs.first.as(AMethPropdef).n_block.as(ABlockExpr).n_expr.first.as(ADoExpr).n_block.as(ABlockExpr)
 163                         nblock.n_kwend = null # drop injected token
 164                         nblock.parent = null
 165                         return nblock
 166                 end
 167                 if eof.location > error.location then error = eof
 168
 169                 lexer = new Lexer(source)
 170                 tree = (new Parser(lexer)).parse
 171                 eof = tree.n_eof
 172                 if not eof isa AError then
 173                         return tree.n_base.as(not null)
 174                 end
 175                 if eof.location > error.location then error = eof
 176
 177                 return error
 178         end
 179
 180         # Parse the input of the user as something
 181         fun interactive_parse(prompt: String): ANode
 182         do
 183                 var oldtext = ""
 184
 185                 loop
 186                         printn prompt
 187                         printn " "
 188                         var s = sys.stdin.read_line
 189                         if s == "" then continue
 190                         if s.chars.first == ':' then
 191                                 var res = new TString
 192                                 res.text = s
 193                                 return res
 194                         end
 195
 196                         var text = oldtext + s + "\n"
 197                         oldtext = ""
 198                         var n = parse_something(text)
 199
 200                         if n isa AParserError and n.token isa EOF then
 201                                 # Unexpected end of file, thus continuing
 202                                 if oldtext == "" then prompt = "." * prompt.length
 203                                 oldtext = text
 204                                 continue
 205                         end
 206
 207                         return n
 208                 end
 209         end
 210 end
 211
 212 class InjectedLexer
 213         super Lexer
 214
 215         var injected_before = new List[Token]
 216         var injected_after = new List[Token]
 217         private var is_finished = false
 218
 219         redef fun get_token
 220         do
 221                 if not injected_before.is_empty then
 222                         var tok = injected_before.shift
 223                         return tok
 224                 end
 225                 if not is_finished then
 226                         var next = super
 227                         if not next isa EOF then return next
 228                         injected_after.push(next)
 229                         is_finished = true
 230                 end
 231
 232                 var tok = injected_after.shift
 233                 return tok
 234         end
 235 end
 236
 237 redef class ANode
 238         # Return an array of tokens that match a given text
 239         fun collect_tokens_by_text(text: String): Array[Token]
 240         do
 241                 var v = new CollectTokensByTextVisitor(text)
 242                 v.enter_visit(self)
 243                 return v.result
 244         end
 245
 246         # Return an array of node that are annotated
 247         # The attached node can be retrieved by two invocation of parent
 248         fun collect_annotations_by_name(name: String): Array[AAnnotation]
 249         do
 250                 var v = new CollectAnnotationsByNameVisitor(name)
 251                 v.enter_visit(self)
 252                 return v.result
 253         end
 254 end
 255
 256 private class CollectTokensByTextVisitor
 257         super Visitor
 258         var text: String
 259         init(text: String) do self.text = text
 260         var result = new Array[Token]
 261         redef fun visit(node)
 262         do
 263                 node.visit_all(self)
 264                 if node isa Token and node.text == text then result.add(node)
 265         end
 266 end
 267
 268 private class CollectAnnotationsByNameVisitor
 269         super Visitor
 270         var name: String
 271         init(name: String) do self.name = name
 272         var result = new Array[AAnnotation]
 273         redef fun visit(node)
 274         do
 275                 node.visit_all(self)
 276                 if node isa AAnnotation and node.n_atid.n_id.text == name then result.add(node)
 277         end
 278 end