src/model/mmodule.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2012 Jean Privat <jean@pryen.org>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # modules and module hierarchies in the metamodel
  18 module mmodule
  19
  20 import poset
  21 import location
  22 import mproject
  23 private import more_collections
  24
  25 # The container class of a Nit object-oriented model.
  26 # A model knows modules, classes and properties and can retrieve them.
  27 redef class Model
  28         # All known modules
  29         var mmodules: Array[MModule] = new Array[MModule]
  30
  31         # placebo for old module nesting hierarchy.
  32         # where mainmodule < mainmodule::nestedmodule
  33         #
  34         # TODO REMOVE, rely on mgroup instead
  35         var mmodule_nesting_hierarchy: POSet[MModule] = new POSet[MModule]
  36
  37         # Full module importation hierarchy including private or nested links.
  38         var mmodule_importation_hierarchy: POSet[MModule] = new POSet[MModule]
  39
  40         # Collections of modules grouped by their short names
  41         private var mmodules_by_name: MultiHashMap[String, MModule] = new MultiHashMap[String, MModule]
  42
  43         # Return all module named `name`
  44         # If such a module does not exist, null is returned (instead of an empty array)
  45         #
  46         # Visibility or modules are not considered
  47         fun get_mmodules_by_name(name: String): nullable Array[MModule]
  48         do
  49                 if mmodules_by_name.has_key(name) then
  50                         return mmodules_by_name[name]
  51                 else
  52                         return null
  53                 end
  54         end
  55 end
  56
  57 redef class MGroup
  58         # The loaded modules of this group
  59         var mmodules = new Array[MModule]
  60
  61         # Placebo stuff to find the owner (module with same name)
  62         # null is returned if there is no owner, or if it is not loaded yet
  63         fun fuzzy_owner: nullable MModule
  64         do
  65                 for m in mmodules do if m.name == name then return m
  66                 return null
  67         end
  68 end
  69
  70 # A Nit module is usually associated with a Nit source file.
  71 class MModule
  72         # The model considered
  73         var model: Model
  74
  75         # placebo for old module nesting hierarchy
  76         # return null if self is not nested (ie. is a top-level module)
  77         #
  78         # TODO REMOVE, rely on mgroup instead
  79         var direct_owner: nullable MModule
  80
  81         # The group of module in the project if any
  82         var mgroup: nullable MGroup
  83
  84         # The short name of the module
  85         var name: String
  86
  87         # The origin of the definition
  88         var location: Location
  89
  90         # Alias for `name`
  91         redef fun to_s do return self.name
  92
  93         # placebo for old module nesting hierarchy
  94         # The view of the module in the `model.mmodule_nesting_hierarchy`
  95         #
  96         # TODO REMOVE, rely on mgroup instead
  97         var in_nesting: POSetElement[MModule]
  98
  99         # The view of the module in the `model.mmodule_importation_hierarchy`
 100         var in_importation: POSetElement[MModule]
 101
 102         # The canonical name of the module
 103         # Example: `"project::name"`
 104         fun full_name: String
 105         do
 106                 var mgroup = self.mgroup
 107                 if mgroup == null or mgroup.mproject.name == self.name then
 108                         return self.name
 109                 else
 110                         return "{mgroup.mproject.name}::{self.name}"
 111                 end
 112         end
 113
 114         # Create a new empty module and register it to a model
 115         init(model: Model, mgroup: nullable MGroup, name: String, location: Location)
 116         do
 117                 self.model = model
 118                 self.name = name
 119                 self.location = location
 120                 model.mmodules_by_name.add_one(name, self)
 121                 model.mmodules.add(self)
 122                 self.in_nesting = model.mmodule_nesting_hierarchy.add_node(self)
 123                 self.mgroup = mgroup
 124                 if mgroup != null then
 125                         mgroup.mmodules.add(self)
 126                         # placebo for old module nesting hierarchy
 127                         var direct_owner = mgroup.fuzzy_owner
 128                         if direct_owner == self then
 129                                 # The module is the new owner of its own group, thus adopt the other modules
 130                                 for m in mgroup.mmodules do
 131                                         if m == self then continue
 132                                         m.direct_owner = self
 133                                         model.mmodule_nesting_hierarchy.add_edge(self, m)
 134                                 end
 135                                 # The potential owner is the the fuzzy_owner of the parent group
 136                                 if mgroup.parent != null then direct_owner = mgroup.parent.fuzzy_owner
 137                         end
 138                         if direct_owner != self and direct_owner != null then
 139                                 self.direct_owner = direct_owner
 140                                 model.mmodule_nesting_hierarchy.add_edge(direct_owner, self)
 141                         end
 142                 end
 143                 self.in_importation = model.mmodule_importation_hierarchy.add_node(self)
 144         end
 145
 146         # Register the imported modules (ie "import some_module")
 147         # This function can only invoked once by mmodule.
 148         # The visibility must be set with `set_visibility_for`.
 149         fun set_imported_mmodules(imported_mmodules: Array[MModule])
 150         do
 151                 assert unique_invocation: self.in_importation.direct_greaters.is_empty
 152                 for m in imported_mmodules do
 153                         self.model.mmodule_importation_hierarchy.add_edge(self, m)
 154                 end
 155         end
 156
 157         private var intrude_mmodules: HashSet[MModule] = new HashSet[MModule]
 158         private var public_mmodules: HashSet[MModule] = new HashSet[MModule]
 159         private var private_mmodules: HashSet[MModule] = new HashSet[MModule]
 160
 161         # Return the visibility level of an imported module `m`
 162         fun visibility_for(m: MModule): MVisibility
 163         do
 164                 if m == self then return intrude_visibility
 165                 if self.intrude_mmodules.has(m) then return intrude_visibility
 166                 if self.public_mmodules.has(m) then return public_visibility
 167                 if self.private_mmodules.has(m) then return private_visibility
 168                 return none_visibility
 169         end
 170
 171         # Set the visibility of an imported module
 172         # REQUIRE: the visibility of the modules imported by `m` are already set for `m`
 173         fun set_visibility_for(m: MModule, v: MVisibility)
 174         do
 175                 if v == intrude_visibility then
 176                         self.intrude_mmodules.add(m)
 177                         self.intrude_mmodules.add_all(m.intrude_mmodules)
 178                         self.public_mmodules.add_all(m.public_mmodules)
 179                         self.private_mmodules.add_all(m.private_mmodules)
 180                 else if v == public_visibility then
 181                         self.public_mmodules.add(m)
 182                         self.public_mmodules.add_all(m.intrude_mmodules)
 183                         self.public_mmodules.add_all(m.public_mmodules)
 184                 else if v == private_visibility then
 185                         self.private_mmodules.add(m)
 186                         self.private_mmodules.add_all(m.intrude_mmodules)
 187                         self.private_mmodules.add_all(m.public_mmodules)
 188                 else
 189                         print "{self} visibility for {m} = {v}"
 190                         abort # invalid visibility
 191                 end
 192         end
 193
 194         # placebo for old module nesting hierarchy
 195         fun public_owner: nullable MModule
 196         do
 197                 var mgroup = self.mgroup
 198                 if mgroup == null then return null
 199                 mgroup = mgroup.mproject.root
 200                 if mgroup.mmodules.is_empty then return null
 201                 var res = mgroup.fuzzy_owner
 202                 if res == self then return null
 203                 return res
 204         end
 205
 206         # Return true if a class or a property introduced in `intro_mmodule` with a visibility of `visibility` is visible in self.
 207         fun is_visible(intro_mmodule: MModule, visibility: MVisibility): Bool
 208         do
 209                 var v = visibility_for(intro_mmodule)
 210                 if v == intrude_visibility then
 211                         return visibility >= private_visibility
 212                 else if v == public_visibility then
 213                         return visibility > private_visibility
 214                 else if v == private_visibility then
 215                         return visibility > private_visibility
 216                 else if v == none_visibility then
 217                         return false
 218                 else
 219                         abort
 220                 end
 221         end
 222 end