lib/html.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # HTML output facilities
  16 module html
  17
  18 # A html page
  19 #
  20 # You can define subclass and override methods head and body
  21 #
  22 # class MyPage
  23 #       super HTMLPage
  24 #       redef body do add("p").text("Hello World!")
  25 # end
  26 #
  27 # HTMLPage use fluent interface so you can chain calls as:
  28 #       add("div").attr("id", "mydiv").text("My Div")
  29 class HTMLPage
  30         super Streamable
  31
  32         # Define head content
  33         fun head do end
  34         # Define body content
  35         fun body do end
  36
  37         private var root = new HTMLTag("html")
  38         private var current: HTMLTag = root
  39         private var stack = new List[HTMLTag]
  40
  41         redef fun write_to(stream) do
  42                 root.children.clear
  43                 open("head")
  44                 head
  45                 close("head")
  46                 open("body")
  47                 body
  48                 close("body")
  49                 stream.write "<!DOCTYPE html>"
  50                 root.write_to(stream)
  51         end
  52
  53         # Add a html tag to the current element
  54         # add("div").attr("id", "mydiv").text("My Div")
  55         fun add(tag: String): HTMLTag do
  56                 var node = new HTMLTag(tag)
  57                 current.add(node)
  58                 return node
  59         end
  60
  61         # Add a raw html string
  62         # add_html("<a href='#top'>top</a>")
  63         fun add_html(html: String) do current.add(new HTMLRaw(html))
  64
  65         # Open a html tag
  66         # open("ul")
  67         # add("li").text("item1")
  68         # add("li").text("item2")
  69         # close("ul")
  70         fun open(tag: String): HTMLTag do
  71                 stack.push(current)
  72                 current = add(tag)
  73                 return current
  74         end
  75
  76         # Close previously opened tag
  77         # Ensure: tag = previous.tag
  78         fun close(tag: String) do
  79                 if not tag == current.tag then
  80                         print "Error: Trying to close '{tag}', last opened tag was '{current.tag}'."
  81                         abort
  82                 end
  83                 current = stack.pop
  84         end
  85 end
  86
  87 class HTMLTag
  88         super Streamable
  89
  90         # HTML tagname: 'div' for <div></div>
  91         var tag: String
  92         init(tag: String) do
  93                 self.tag = tag
  94                 self.is_void = (once ["area", "base", "br", "col", "command", "embed", "hr", "img", "input", "keygen", "link", "meta", "param", "source", "track", "wbr"]).has(tag)
  95         end
  96
  97         # Is the HTML element a void element?
  98         #
  99         #     assert new HTMLTag("img").is_void    == true
 100         #     assert new HTMLTag("p").is_void      == false
 101         var is_void: Bool
 102
 103         init with_attrs(tag: String, attrs: Map[String, String]) do
 104                 self.tag = tag
 105                 self.attrs = attrs
 106         end
 107
 108         # Tag attributes map
 109         var attrs: Map[String, String] = new HashMap[String, String]
 110
 111         # Get the attributed value of 'prop' or null if 'prop' is undifened
 112         #     var img = new HTMLTag("img")
 113         #     img.attr("src", "./image.png").attr("alt", "image")
 114         #     assert img.get_attr("src")     == "./image.png"
 115         fun get_attr(key: String): nullable String do
 116                 if not attrs.has_key(key) then return null
 117                 return attrs[key]
 118         end
 119
 120         # Set a 'value' for 'key'
 121         #     var img = new HTMLTag("img")
 122         #     img.attr("src", "./image.png").attr("alt", "image")
 123         #     assert img.write_to_string      == """<img src="./image.png" alt="image"/>"""
 124         fun attr(key: String, value: String): HTMLTag do
 125                 attrs[key] = value
 126                 return self
 127         end
 128
 129         # Add a CSS class to the HTML tag
 130         #     var img = new HTMLTag("img")
 131         #     img.add_class("logo").add_class("fullpage")
 132         #     assert img.write_to_string      == """<img class="logo fullpage"/>"""
 133         fun add_class(klass: String): HTMLTag do
 134                 classes.add(klass)
 135                 return self
 136         end
 137
 138         # CSS classes
 139         var classes: Set[String] = new HashSet[String]
 140
 141         # Add multiple CSS classes
 142         #     var img = new HTMLTag("img")
 143         #     img.add_classes(["logo", "fullpage"])
 144         #     assert img.write_to_string      == """<img class="logo fullpage"/>"""
 145         fun add_classes(classes: Collection[String]): HTMLTag do
 146                 self.classes.add_all(classes)
 147                 return self
 148         end
 149
 150         # Set a CSS 'value' for 'prop'
 151         #     var img = new HTMLTag("img")
 152         #     img.css("border", "2px solid black").css("position", "absolute")
 153         #     assert img.write_to_string      == """<img style="border: 2px solid black; position: absolute"/>"""
 154         fun css(prop: String, value: String): HTMLTag do
 155                 css_props[prop] = value
 156                 return self
 157         end
 158         private var css_props: Map[String, String] = new HashMap[String, String]
 159
 160         # Get CSS value for 'prop'
 161         #     var img = new HTMLTag("img")
 162         #     img.css("border", "2px solid black").css("position", "absolute")
 163         #     assert img.get_css("border")    == "2px solid black"
 164         #     assert img.get_css("color")     == null
 165         fun get_css(prop: String): nullable String do
 166                 if not css_props.has_key(prop) then return null
 167                 return css_props[prop]
 168         end
 169
 170         # Add a HTML 'child' to self
 171         #     var ul = new HTMLTag("ul")
 172         #     ul.add(new HTMLTag("li"))
 173         #     assert ul.write_to_string    == "<ul><li></li></ul>"
 174         fun add(child: HTMLTag) do children.add(child)
 175
 176         # List of children HTML elements
 177         var children: Set[HTMLTag] = new HashSet[HTMLTag]
 178
 179         # Clear all child and set the text of element
 180         #     var p = new HTMLTag("p")
 181         #     p.text("Hello World!")
 182         #     assert p.write_to_string      ==  "<p>Hello World!</p>"
 183         # Text is escaped see: `standard::String::html_escape`
 184         fun text(txt: String): HTMLTag do
 185
 186                 children.clear
 187                 append(txt)
 188                 return self
 189         end
 190
 191         # Append text to element
 192         #     var p = new HTMLTag("p")
 193         #     p.append("Hello")
 194         #     p.add(new HTMLTag("br"))
 195         #     p.append("World!")
 196         #     assert p.write_to_string      ==  "<p>Hello<br/>World!</p>"
 197         # Text is escaped see: standard::String::html_escape
 198         fun append(txt: String): HTMLTag do
 199                 add(new HTMLRaw(txt.html_escape))
 200                 return self
 201         end
 202
 203         # Append raw HTML to element
 204         #     var p = new HTMLTag("p")
 205         #     p.append("Hello")
 206         #     p.add_raw_html("<bla/>")
 207         #     p.html #- "<p>Hello<bla/></p>"
 208         # Note: the HTML in insered as it, no verification is done
 209         fun add_raw_html(txt: String): HTMLTag do
 210                 add(new HTMLRaw(txt))
 211                 return self
 212         end
 213
 214         redef fun write_to(stream) do
 215                 var res = new Array[String]
 216                 render_in(res)
 217                 for r in res do
 218                         stream.write(r)
 219                 end
 220         end
 221
 222         # In order to avoid recursive concatenation,
 223         # this function collects in `res` all the small fragments of `String`
 224         private fun render_in(res: Sequence[String])
 225         do
 226                 res.add "<"
 227                 res.add tag
 228                 render_attrs_in(res)
 229                 if is_void and children.is_empty then
 230                         res.add "/>"
 231                 else
 232                         res.add ">"
 233                         for child in children do child.render_in(res)
 234                         res.add "</"
 235                         res.add tag
 236                         res.add ">"
 237                 end
 238         end
 239
 240         private fun render_attrs_in(res: Sequence[String]) do
 241                 if attrs.has_key("class") or not classes.is_empty then
 242                         res.add " class=\""
 243                         for cls in classes do
 244                                 res.add cls.html_escape
 245                                 res.add " "
 246                         end
 247                         if attrs.has_key("class") then
 248                                 res.add attrs["class"].html_escape
 249                                 res.add " "
 250                         end
 251                         if res.last == " " then res.pop
 252                         res.add "\""
 253                 end
 254
 255                 if attrs.has_key("style") or not css_props.is_empty then
 256                         res.add " style=\""
 257                         for k, v in css_props do
 258                                 res.add k.html_escape
 259                                 res.add ": "
 260                                 res.add v.html_escape
 261                                 res.add "; "
 262                         end
 263                         if attrs.has_key("style") then
 264                                 res.add(attrs["style"].html_escape)
 265                         end
 266                         if res.last == "; " then res.pop
 267                         res.add "\""
 268                 end
 269
 270                 if attrs.is_empty then return
 271
 272                 for key, value in attrs do
 273                         if key == "class" or key == "style" then continue
 274                         res.add " "
 275                         res.add key.html_escape
 276                         res.add "=\""
 277                         res.add value.html_escape
 278                         res.add "\""
 279                 end
 280         end
 281 end
 282
 283 private class HTMLRaw
 284         super HTMLTag
 285
 286         private var content: String
 287         init(content: String) do self.content = content
 288         redef fun render_in(res) do res.add content
 289 end