lib/gamnit/textures.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Services to load textures, create subtextures and manage their life-cycle
  16 module textures
  17
  18 import display
  19
  20 # Abstract gamnit texture
  21 abstract class Texture
  22
  23         # Prepare a texture located at `path` within the `assets` folder
  24         new (path: Text) do return new GamnitAssetTexture(path.to_s)
  25
  26         # Prepare and load a colorful small texture of 2x2 pixels
  27         new checker
  28         do
  29                 var pixels = [0xFFu8, 0x00u8, 0x00u8,
  30                               0x00u8, 0xFFu8, 0x00u8,
  31                               0x00u8, 0x00u8, 0xFFu8,
  32                               0xFFu8, 0xFFu8, 0xFFu8]
  33                 var cpixels = new CByteArray.from(pixels)
  34
  35                 var tex = new GamnitRootTexture
  36                 tex.width = 2.0
  37                 tex.height = 2.0
  38                 tex.load_from_pixels(cpixels.native_array, 2, 2, gl_RGB)
  39
  40                 cpixels.destroy
  41                 return tex
  42         end
  43
  44         # Root texture of which `self` is derived
  45         fun root: GamnitRootTexture is abstract
  46
  47         # Width in pixels of this texture
  48         var width = 0.0
  49
  50         # Height in pixels of this texture
  51         var height = 0.0
  52
  53         # Load this texture, force reloading it if `force`
  54         fun load(force: nullable Bool) do end
  55
  56         # Last error on this texture
  57         var error: nullable Error = null
  58
  59         # OpenGL handle to this texture
  60         var gl_texture: Int is noinit
  61
  62         # Prepare a subtexture from this texture
  63         fun subtexture(left, top, width, height: Numeric): GamnitSubtexture
  64         do
  65                 # Setup the subtexture
  66                 var subtex = new GamnitSubtexture(root, self, left.to_f, top.to_f, width.to_f, height.to_f)
  67                 return subtex
  68         end
  69
  70         fun offset_left: Float do return 0.0
  71         fun offset_top: Float do return 0.0
  72         fun offset_right: Float do return 1.0
  73         fun offset_bottom: Float do return 1.0
  74 end
  75
  76 # Texture with its own pixels
  77 class GamnitRootTexture
  78         super Texture
  79
  80         redef fun root do return self
  81
  82         # Has this texture been loaded yet?
  83         var loaded = false
  84
  85         init do all_root_textures.add self
  86
  87         private fun load_from_pixels(pixels: Pointer, width, height: Int, format: GLPixelFormat)
  88         do
  89                 var max_texture_size = glGetIntegerv(gl_MAX_TEXTURE_SIZE)
  90                 if width > max_texture_size or height > max_texture_size then
  91                         error = new Error("Texture {self} width or height is over the GL_MAX_TEXTURE_SIZE of {max_texture_size}")
  92                         return
  93                 end
  94
  95                 glPixelStorei(gl_UNPACK_ALIGNEMENT, 1)
  96                 var tex = glGenTextures(1)[0]
  97                 gl_texture = tex
  98
  99                 glBindTexture(gl_TEXTURE_2D, tex)
 100                 glTexImage2D(gl_TEXTURE_2D, 0, format, width, height, 0, format, gl_UNSIGNED_BYTE, pixels)
 101
 102                 # TODO make these settings attributes of the class
 103                 glTexParameteri(gl_TEXTURE_2D, gl_TEXTURE_MIN_FILTER, gl_NEAREST)
 104                 glTexParameteri(gl_TEXTURE_2D, gl_TEXTURE_MAG_FILTER, gl_NEAREST)
 105                 glTexParameteri(gl_TEXTURE_2D, gl_TEXTURE_WRAP_S, gl_REPEAT)
 106                 glTexParameteri(gl_TEXTURE_2D, gl_TEXTURE_WRAP_T, gl_REPEAT)
 107
 108                 glHint(gl_GENERATE_MIPMAP_HINT, gl_NICEST)
 109                 glGenerateMipmap(gl_TEXTURE_2D)
 110         end
 111
 112         # Has this resource been deleted?
 113         var deleted = false
 114
 115         # Delete this texture and free all its resources
 116         #
 117         # Use caution with this service as the subtextures may rely on the deleted data.
 118         fun delete
 119         do
 120                 if deleted or not loaded then return
 121
 122                 deleted = true
 123         end
 124 end
 125
 126 # Texture loaded from the assets folder
 127 class GamnitAssetTexture
 128         super GamnitRootTexture
 129
 130         # Path to this texture within the `assets` folder
 131         var path: String
 132
 133         redef fun load(force)
 134         do
 135                 if loaded and force != true then return
 136
 137                 load_from_platform
 138
 139                 loaded = true
 140         end
 141
 142         # Partially load this texture from platform-specific features
 143         #
 144         # This method should fill `width`, `height` and `pixels`.
 145         private fun load_from_platform is abstract
 146
 147         redef fun to_s do return "<{class_name} path:{path}>"
 148 end
 149
 150 # Texture derived from another texture, does not own its pixels
 151 class GamnitSubtexture
 152         super Texture
 153
 154         redef var root
 155
 156         # Parent texture, from which this texture was created
 157         var parent: Texture
 158
 159         # Left border of this texture compared to `parent`
 160         var left: Float
 161
 162         # Top border of this texture compared to `parent`
 163         var top: Float
 164
 165         private fun set_wh(width, height: Float)
 166         is autoinit do
 167                 self.width = width
 168                 self.height = height
 169         end
 170
 171         redef fun load(force) do root.load(force)
 172
 173         redef var offset_left = parent.offset_left + left / root.width is lazy
 174         redef var offset_top = parent.offset_top + top / root.height is lazy
 175         redef var offset_right = offset_left + width / root.width is lazy
 176         redef var offset_bottom = offset_top + height / root.height is lazy
 177 end
 178
 179 redef class Sys
 180         private var all_root_textures = new TextureSet
 181 end
 182
 183 # Group of `Texture`
 184 class TextureSet
 185         super HashSet[Texture]
 186
 187         # Load all texture of this set
 188         fun load_all do for t in self do t.load
 189 end