lib/crypto/xor_ciphers.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # XOR oriented cryptographic ciphers and utilities.
  16 module xor_ciphers
  17
  18 redef class Bytes
  19         # Returns `self` xored with `key`
  20         #
  21         # The key is cycled through until the `self` has been completely xored.
  22         #
  23         #     assert "goodmorning".to_bytes.xorcipher(" ".to_bytes) == "GOODMORNING".bytes
  24         fun xorcipher(key: Bytes): Bytes do
  25                 var xored = new Bytes.with_capacity(self.length)
  26
  27                 for i in self.length.times do
  28                         xored.add(self[i] ^ key[i % key.length])
  29                 end
  30
  31                 return xored
  32         end
  33 end
  34
  35 redef class CString
  36         # In-place XOR `self` with `key`
  37         fun xor(key: CString, len: Int, key_length: Int, key_offset: nullable Int) do
  38                 if key_offset == null then key_offset = 0
  39
  40                 var key_pos = key_offset % key_length
  41
  42                 for i in [0 .. len[ do
  43                         self[i] = key[key_pos] ^ self[i]
  44                         key_pos += 1
  45                         if key_pos >= key_length then key_pos = 0
  46                 end
  47         end
  48 end
  49
  50 # Base class to modelize cryptographic ciphers
  51 abstract class Cipher
  52
  53         # Encrypted data
  54         var ciphertext = new Bytes.empty is writable
  55
  56         # Unencrypted data
  57         var plaintext = new Bytes.empty is writable
  58
  59         # Encrypt plaintext and populate `self.ciphertext`
  60         fun encrypt is abstract
  61
  62         # Decrypt ciphertext and populate `self.plaintext`
  63         fun decrypt is abstract
  64
  65 end
  66
  67 # Simple XOR cipher where the whole plaintext is XORed with a single byte.
  68 class SingleByteXorCipher
  69         super Cipher
  70
  71         # Cryptographic key used in encryption and decryption.
  72         var key: Byte = 0.to_b
  73
  74         redef fun encrypt do
  75                 var key_bytes = new Bytes.with_capacity(1)
  76                 key_bytes.add(key)
  77                 ciphertext = plaintext.xorcipher(key_bytes)
  78         end
  79
  80         redef fun decrypt do
  81                 var key_bytes = new Bytes.with_capacity(1)
  82                 key_bytes.add(key)
  83                 plaintext = ciphertext.xorcipher(key_bytes)
  84         end
  85 end
  86
  87 # XOR cipher where the key is repeated to match the length of the message.
  88 class RepeatingKeyXorCipher
  89         super Cipher
  90
  91         # Cryptographic key used in encryption and decryption.
  92         var key = new Bytes.empty
  93
  94         redef fun encrypt do
  95                 assert key.length > 0
  96                 ciphertext = plaintext.xorcipher(key)
  97         end
  98
  99         redef fun decrypt do
 100                 assert key.length > 0
 101                 plaintext = ciphertext.xorcipher(key)
 102         end
 103 end