src/counter.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Simple numerical statistical analysis and presentation
  16 module counter
  17
  18 import poset
  19
  20 # A counter counts occurrences of things
  21 # Use this instead of a HashMap[E, Int]
  22 class Counter[E: Object]
  23         super Map[E, Int]
  24
  25         # Total number of counted occurrences
  26         var total: Int = 0
  27
  28         private var map = new HashMap[E, Int]
  29
  30         # The number of counted occurrences of `e'
  31         redef fun [](e: E): Int
  32         do
  33                 var map = self.map
  34                 if map.has_key(e) then return map[e]
  35                 return 0
  36         end
  37
  38         redef fun []=(e: E, value: Int)
  39         do
  40                 total -= self[e]
  41                 self.map[e] = value
  42                 total += value
  43         end
  44
  45         redef fun keys do return map.keys
  46
  47         redef fun values do return map.values
  48
  49         # Count one more occurrence of `e'
  50         fun inc(e: E)
  51         do
  52                 self.map[e] = self[e] + 1
  53                 total += 1
  54         end
  55
  56         # Return an array of elements sorted by occurrences
  57         fun sort: Array[E]
  58         do
  59                 var res = map.keys.to_a
  60                 var sorter = new CounterSorter[E](self)
  61                 sorter.sort(res)
  62                 #res.sort !cmp a, b = map[a] <=> map[b]
  63                 return res
  64         end
  65
  66         # Display statistical information
  67         fun print_summary
  68         do
  69                 var list = self.sort
  70                 print " population: {list.length}"
  71                 if list.is_empty then return
  72                 print " minimum value: {self[list.first]}"
  73                 print " maximum value: {self[list.last]}"
  74                 print " total value: {self.total}"
  75                 print " average value: {div(self.total,list.length)}"
  76                 print " distribution:"
  77                 var count = 0
  78                 var sum = 0
  79                 var limit = self[list.first]
  80                 for t in list do
  81                         if self[t] > limit then
  82                                 print "  <={limit}: sub-population={count} ({div(count*100,list.length)}%); cumulated value={sum} ({div(sum*100,self.total)}%)"
  83                                 count = 0
  84                                 sum = 0
  85                                 while self[t] > limit do
  86                                         limit = limit * 2
  87                                         if limit == 0 then limit = 1
  88                                 end
  89                         end
  90                         count += 1
  91                         sum += self[t]
  92                 end
  93                 print "  <={limit}: sub-population={count} ({div(count*100,list.length)}%); cumulated value={sum} ({div(sum*100,self.total)}%)"
  94         end
  95 end
  96
  97 private class CounterSorter[E: Object]
  98         super AbstractSorter[E]
  99         var counter: Counter[E]
 100         redef fun compare(a,b) do return self.counter.map[a] <=> self.counter.map[b]
 101 end
 102
 103 redef class POSet[E]
 104         private fun show_counter(c: Counter[Int])
 105         do
 106                 var list = c.sort
 107                 (new ComparableSorter[Int]).sort(list)
 108                 for e in list do
 109                         print " {e} -> {c[e]} times ({div(c[e]*100, c.total)}%)"
 110                 end
 111         end
 112
 113         # Display exhaustive metrics about the poset
 114         fun print_metrics
 115         do
 116                 var nb_greaters = new Counter[E]
 117                 var nb_direct_greaters = new Counter[E]
 118                 var nb_smallers = new Counter[E]
 119                 var nb_direct_smallers = new Counter[E]
 120                 var nb_direct_edges = 0
 121                 var nb_edges = 0
 122                 for n in self do
 123                         var ne = self[n]
 124                         nb_edges += ne.greaters.length
 125                         nb_direct_edges += ne.direct_greaters.length
 126                         nb_greaters[n] = ne.greaters.length
 127                         nb_direct_greaters[n] = ne.direct_greaters.length
 128                         nb_smallers[n] = ne.smallers.length
 129                         nb_direct_smallers[n] = ne.direct_smallers.length
 130                 end
 131                 print "Number of nodes: {self.length}"
 132                 print "Number of edges: {nb_edges} ({div(nb_edges,self.length)} per node)"
 133                 print "Number of direct edges: {nb_direct_edges} ({div(nb_direct_edges,self.length)} per node)"
 134                 print "Distribution of greaters"
 135                 nb_greaters.print_summary
 136                 print "Distribution of direct greaters"
 137                 nb_direct_greaters.print_summary
 138                 print "Distribution of smallers"
 139                 nb_smallers.print_summary
 140                 print "Distribution of direct smallers"
 141                 nb_direct_smallers.print_summary
 142         end
 143 end
 144
 145 # Helper function to display n/d and handle division by 0
 146 fun div(n: Int, d: Int): String
 147 do
 148         if d == 0 then return "na"
 149         return ((100*n/d).to_f/100.0).to_precision(2)
 150 end