src/parser/nit.sablecc3xx

   1
   2 /* This file is part of NIT ( http://www.nitlanguage.org ).
   3  *
   4  * Copyright 2008-2009 Jean Privat <jean@pryen.org>
   5  *
   6  * Licensed under the Apache License, Version 2.0 (the "License");
   7  * you may not use this file except in compliance with the License.
   8  * You may obtain a copy of the License at
   9  *
  10  *     http://www.apache.org/licenses/LICENSE-2.0
  11  *
  12  * Unless required by applicable law or agreed to in writing, software
  13  * distributed under the License is distributed on an "AS IS" BASIS,
  14  * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15  * See the License for the specific language governing permissions and
  16  * limitations under the License.
  17  */
  18
  19 /* This grammar defines the NIT language. */
  20
  21 /*****************************************************************************/
  22 Helpers
  23 /*****************************************************************************/
  24
  25 all = [0 .. 0xFF];
  26 lowercase = ['a' .. 'z'];
  27 uppercase = ['A' .. 'Z'];
  28 digit = ['0' .. '9'];
  29 letter = lowercase | uppercase | digit | '_';
  30
  31 tab = 9;
  32 cr = 13;
  33 lf = 10;
  34 any = [all - [cr + lf]];
  35
  36 // characers inside strings and super-strings (atomaton powaa)
  37 str_char
  38         = [any - [['"' + '{'] + '\']]
  39         | '\' any
  40         ;
  41 str_body = str_char*;
  42
  43 eol_helper = cr lf | cr | lf; // This takes care of different platforms
  44
  45 /*****************************************************************************/
  46 States
  47 /*****************************************************************************/
  48 initial;
  49
  50
  51 /*****************************************************************************/
  52 Tokens
  53 /*****************************************************************************/
  54
  55 blank = (' ' | tab)+;
  56
  57 eol = eol_helper;
  58 comment = '#' any* eol_helper;
  59
  60 kwpackage = 'package';
  61 kwimport = 'import';
  62 kwclass = 'class';
  63 kwabstract = 'abstract';
  64 kwinterface = 'interface';
  65 kwuniversal = 'universal';
  66 kwspecial = 'special';
  67 kwend = 'end';
  68 kwmeth = 'fun';
  69 kwtype = 'type';
  70 kwinit = 'init';
  71 kwredef = 'redef';
  72 kwis = 'is';
  73 kwdo = 'do';
  74 kwreadable = 'readable';
  75 kwwritable = 'writable';
  76 kwvar = 'var';
  77 kwintern = 'intern';
  78 kwextern = 'extern';
  79 kwprotected = 'protected';
  80 kwprivate = 'private';
  81 kwintrude = 'intrude';
  82 kwif = 'if';
  83 kwthen = 'then';
  84 kwelse = 'else';
  85 kwwhile = 'while';
  86 kwfor = 'for';
  87 kwin = 'in';
  88 kwand = 'and';
  89 kwor = 'or';
  90 kwnot = 'not';
  91 kwreturn = 'return';
  92 kwcontinue = 'continue';
  93 kwbreak = 'break';
  94 kwabort = 'abort';
  95 kwassert = 'assert';
  96 kwnew = 'new';
  97 kwisa = 'isa';
  98 kwonce = 'once';
  99 kwsuper = 'super';
 100 kwself = 'self';
 101 kwtrue = 'true';
 102 kwfalse = 'false';
 103 kwnull = 'null';
 104 kwas = 'as';
 105 kwwith = 'with';
 106 kwnullable = 'nullable';
 107 kwisset = 'isset';
 108 kwlabel = 'label';
 109
 110 opar = '(';
 111 cpar = ')';
 112 obra = '[';
 113 cbra = ']';
 114 comma = ',';
 115 column = ':';
 116 quad = '::';
 117 assign = '=';
 118 pluseq = '+=';
 119 minuseq = '-=';
 120 dotdotdot = '...';
 121 dotdot = '..';
 122 dot = '.';
 123 plus = '+';
 124 minus = '-';
 125 star = '*';
 126 slash = '/';
 127 percent = '%';
 128 eq = '==';
 129 ne = '!=';
 130 lt = '<';
 131 le = '<=';
 132 gt = '>';
 133 ge = '>=';
 134 starship = '<=>';
 135
 136 classid = uppercase letter*;
 137 id = lowercase letter*;
 138 attrid = '_' lowercase letter*;
 139
 140 number = digit+;
 141 float = digit* '.' digit+;
 142 char = ''' [any - ''']* ''';
 143 string = '"' str_body '"';
 144 start_string = '"' str_body '{';
 145 mid_string = '}' str_body '{';
 146 end_string = '}' str_body '"';
 147
 148
 149 /*****************************************************************************/
 150 Ignored Tokens
 151 /*****************************************************************************/
 152
 153 blank;
 154
 155 /*****************************************************************************/
 156 Productions
 157 /*****************************************************************************/
 158
 159 /* MODULES *******************************************************************/
 160 module
 161         = packagedecl? [imports]:import* [classdefs]:classdef* implicit_top_class? implicit_main_class? {-> New module(packagedecl, [imports.import],[classdefs.classdef,implicit_top_class.classdef,implicit_main_class.classdef])};
 162
 163 packagedecl
 164         = [doc]:no kwpackage no id [n2]:n1 {-> New packagedecl(doc.doc, kwpackage, id)};
 165
 166 import
 167         = {std} [doc]:no visibility kwimport no id [n2]:n1              {-> New import.std(visibility, kwimport, id)}
 168         | {no} [doc]:no visibility kwimport no kwend [n2]:n1    {-> New import.no(visibility, kwimport, kwend)}
 169         ;
 170
 171 implicit_top_class {-> classdef}
 172         = propdefs_toplevel {-> New classdef.top([propdefs_toplevel.propdef])};
 173
 174 implicit_main_class {-> classdef?}
 175         = implicit_main_meth {-> New classdef.main([implicit_main_meth.propdef])}
 176         | {null} n {-> Null}
 177         ;
 178 implicit_main_meth {-> propdef}
 179         = [doc]:no stmts no {-> New propdef.main_meth(Null, stmts.expr)};
 180
 181 /* CLASSES *******************************************************************/
 182 classdef
 183         = [doc]:no redef visibility classkind no classid formaldefs? [specials]:special* propdefs? [n2]:no kwend {-> New classdef.std(doc.doc, redef.kwredef, visibility, classkind, classid, [formaldefs.formaldef], [specials.superclass], [propdefs.propdef])};
 184 redef {-> kwredef?}
 185         = kwredef? {-> kwredef};
 186 classkind
 187         = {concrete} kwclass
 188         | {abstract} kwabstract kwclass
 189         | {interface} kwinterface
 190         | {universal} kwuniversal
 191         ;
 192
 193 formaldefs {-> formaldef*}
 194         = obra no formaldef formaldefs_tail* [n2]:no cbra {-> [formaldef, formaldefs_tail.formaldef]};
 195 formaldefs_tail {-> formaldef}
 196         = comma no formaldef {-> formaldef};
 197 formaldef
 198         = classid typing? {-> New formaldef(classid, typing.type)};
 199
 200 special {-> superclass}
 201         = no kwspecial [n2]:no type {-> New superclass(kwspecial, type)};
 202
 203 propdefs~toplevel {-> propdef*}
 204         = propdef~toplevel n1 propdefs_tail~toplevel* {-> [propdef~toplevel.propdef, propdefs_tail~toplevel.propdef]}
 205         ;
 206 propdefs_tail~toplevel {-> propdef}
 207         = propdef~toplevel n1 {-> propdef~toplevel.propdef}
 208         ;
 209 propdef~toplevel {-> propdef}
 210         = {meth} [doc]:no redef visibility kwmeth methid signature kwdo stmtso kwend? {-> New propdef.concrete_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature, stmtso.expr)}
 211 !toplevel| {deferred} [doc]:no redef visibility kwmeth methid signature kwis kwabstract {-> New propdef.deferred_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature)}
 212 !toplevel| {intern} [doc]:no redef visibility kwmeth methid signature kwis kwintern {-> New propdef.intern_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature)}
 213         | {extern} [doc]:no redef visibility kwmeth methid signature kwis kwextern string? {-> New propdef.extern_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature, string)}
 214 !toplevel| {var} [doc]:no readable writable redef visibility kwvar attrid typing? {-> New propdef.attr(doc.doc, readable.able, writable.able, redef.kwredef, visibility, kwvar, attrid, typing.type, Null)}
 215 !toplevel| {var2} [doc]:no readable writable redef visibility kwvar attrid typing? assign [n2]:no expr {-> New propdef.attr(doc.doc, readable.able, writable.able, redef.kwredef, visibility, kwvar, attrid, typing.type, expr)}
 216 !toplevel| {init} [doc]:no redef visibility kwinit methid? signature kwdo stmtso kwend? {-> New propdef.concrete_init(doc.doc, redef.kwredef, visibility, kwinit, methid, signature, stmtso.expr)}
 217 !toplevel| {type} [doc]:no redef visibility kwtype classid typing {-> New propdef.type(doc.doc, redef.kwredef, visibility, kwtype, classid, typing.type)}
 218         ;
 219 readable {-> able?}
 220         = redef kwreadable {-> New able.read(redef.kwredef, kwreadable)}
 221         | {empty} {-> Null}
 222         ;
 223 writable {-> able?}
 224         = redef kwwritable {-> New able.write(redef.kwredef, kwwritable)}
 225         | {empty} {-> Null}
 226         ;
 227
 228 visibility
 229         = {public} {-> New visibility.public()}
 230         | {private} kwprivate no {-> New visibility.private(kwprivate)}
 231         | {protected} kwprotected no {-> New visibility.protected(kwprotected)}
 232         | {intrude} kwintrude no {-> New visibility.intrude(kwintrude)}
 233         ;
 234
 235 methid
 236         = {id} id
 237         | {plus} plus
 238         | {minus} minus
 239         | {star} star
 240         | {slash} slash
 241         | {percent} percent
 242         | {eq} eq
 243         | {ne} ne
 244         | {le} le
 245         | {ge} ge
 246         | {lt} lt
 247         | {gt} gt
 248         | {bra} obra cbra
 249         | {starship} starship
 250         | {assign} id assign
 251         | {braassign} obra cbra assign
 252         ;
 253
 254 signature
 255         = params? typing? closure_decls {-> New signature([params.param], typing.type, [closure_decls.closure_decl])}
 256         | {noclosures} params? typing? no {-> New signature([params.param], typing.type, [])}
 257         ;
 258
 259 signature_noclosures {-> signature}
 260         = params? typing? {-> New signature([params.param], typing.type, [])};
 261
 262 params {-> param*}
 263         = opar no param params_tail* [n2]:no cpar {-> [param, params_tail.param]}
 264         | {empty} opar no cpar {-> []}
 265         ;
 266 params_tail {-> param}
 267         = comma no param {-> param};
 268 param
 269         = {untyped} id {-> New param(id, Null, Null)}
 270         | id typing dotdotdot? {-> New param(id, typing.type, dotdotdot)}
 271         ;
 272
 273 closure_decls {->closure_decl*}
 274         = no closure_decl+ {-> [closure_decl]};
 275 closure_decl
 276         = kwwith kwbreak? [no2]:no id signature_noclosures n {-> New closure_decl(kwwith, kwbreak, id, signature_noclosures.signature, Null)}
 277         | {optionnal} kwwith kwbreak? [no2]:no id signature_noclosures kwdo stmtso n {-> New closure_decl(kwwith, kwbreak, id, signature_noclosures.signature, stmtso.expr)}
 278         ;
 279
 280 /* TYPES *********************************************************************/
 281 type~nobra {-> type}
 282         = {simple} kwnullable? classid {-> New type(kwnullable, classid, [])}
 283 !nobra  | {generic} kwnullable? classid obra no types [n2]:no cbra {-> New type(kwnullable, classid, [types.type])}
 284         ;
 285 types {-> type*}
 286         = type types_tail* {-> [type, types_tail.type]};
 287 types_tail {-> type}
 288         = comma no type {-> type};
 289 typing {-> type}
 290         = column no type {-> type};
 291
 292 /* STATMENTS *****************************************************************/
 293 stmtso~withelse~withend {-> expr?}
 294         = {block} n stmts [n2]:n kwend {-> stmts.expr}
 295         | {emptyblock} n kwend {-> New expr.block([])}
 296         | {emptyoneline} kwend {-> New expr.block([])}
 297 !withend| {oneline} stmt~withelse {-> stmt~withelse.expr}
 298         ;
 299 stmts {-> expr}
 300         = stmt stmts_tail* {-> New expr.block([stmt.expr, stmts_tail.expr])};
 301 stmts_tail {-> expr}
 302         = n stmt {-> stmt.expr};
 303 stmt~withelse {-> expr}
 304         = {vardecl} vardecl~withelse {-> vardecl~withelse.expr}
 305         | {assign} assignment~withelse {-> assignment~withelse.expr}
 306         | {return} kwreturn expr_final~withelse? {-> New expr.return(kwreturn, expr_final~withelse.expr)}
 307         | {break} kwbreak label? expr_final~withelse? {-> New expr.break(kwbreak, label, expr_final~withelse.expr)}
 308         | {abort} kwabort {-> New expr.abort(kwabort)}
 309         | {continue} kwcontinue label? expr_final~withelse? {-> New expr.continue(kwcontinue, label, expr_final~withelse.expr)}
 310         | {do} do~withelse {-> do~withelse.expr}
 311         | {if} if~withelse {-> if~withelse.expr}
 312         | {while} while~withelse {-> while~withelse.expr}
 313         | {for} for~withelse {-> for~withelse.expr}
 314         | {assert} assert~withelse {-> assert~withelse.expr}
 315         | {call} recv id args_nopar closure_defs~withelse? {-> New expr.call(recv.expr, id, [args_nopar.expr], [closure_defs~withelse.closure_def])}
 316         | {super} qualified? kwsuper args_nopar {-> New expr.super(qualified, kwsuper, [args_nopar.expr])}
 317         | {init} recv kwinit args_nopar {-> New expr.init(recv.expr, kwinit, [args_nopar.expr])}
 318         ;
 319
 320 label= kwlabel id;
 321
 322 closure_defs~withelse {-> closure_def*}
 323         = {one} closure_def_last~withelse {-> [closure_def_last~withelse.closure_def]}
 324         | closure_def closure_defs~withelse {-> [closure_def, closure_defs~withelse.closure_def]}
 325         ;
 326
 327 closure_def_last~withelse {-> closure_def}
 328         = kwwith idlist? kwdo stmtso~withelse_withend label? {-> New closure_def(kwwith, [idlist.id], kwdo, stmtso~withelse_withend.expr, label)}
 329         | {noend} kwwith idlist? kwdo stmt~withelse {-> New closure_def(kwwith, [idlist.id], kwdo, stmt~withelse.expr, Null)}
 330         ;
 331
 332 closure_def {-> closure_def}
 333         = kwwith idlist? kwdo n stmts [n2]:n {-> New closure_def(kwwith, [idlist.id], kwdo, stmts.expr, Null)}
 334         | {empty} kwwith idlist? kwdo n {-> New closure_def(kwwith, [idlist.id], kwdo, Null, Null)}
 335         ;
 336
 337 vardecl~withelse{-> expr}
 338         = kwvar id typing? {-> New expr.vardecl(kwvar, id, typing.type, Null, Null)}
 339         | {assign} kwvar id typing? assign no expr_final~withelse {-> New expr.vardecl(kwvar, id, typing.type, assign, expr_final~withelse.expr)}
 340         ;
 341
 342 assignment~withelse {-> expr}
 343         = {attr} recv attrid assign expr_final~withelse {-> New expr.attr_assign(recv.expr, attrid, assign, expr_final~withelse.expr)}
 344         | {call} recv id args assign expr_final~withelse {-> New expr.call_assign(recv.expr, id, [args.expr], assign,  expr_final~withelse.expr)}
 345         | {bra} expr_atom braargs assign expr_final~withelse {-> New expr.bra_assign(expr_atom.expr, [braargs.expr], assign,  expr_final~withelse.expr)}
 346         | {attr_re} recv attrid assign_op expr_final~withelse {-> New expr.attr_reassign(recv.expr, attrid, assign_op,  expr_final~withelse.expr)}
 347         | {call_re} recv id args assign_op expr_final~withelse {-> New expr.call_reassign(recv.expr, id, [args.expr], assign_op,  expr_final~withelse.expr)}
 348         | {bra_re} expr_atom braargs assign_op expr_final~withelse {-> New expr.bra_reassign(expr_atom.expr, [braargs.expr], assign_op,  expr_final~withelse.expr)}
 349         ;
 350 assign_op
 351         = {plus} pluseq
 352         | {minus} minuseq
 353         ;
 354
 355 do~withelse {-> expr}
 356         = kwdo stmtso~withelse_withend label? {-> New expr.do(kwdo, stmtso~withelse_withend.expr, label)}
 357         | {noend} kwdo stmt~withelse {-> New expr.do(kwdo, stmt~withelse.expr, Null)}
 358         ;
 359
 360 if~withelse {-> expr}
 361         = {onelineelse} kwif no expr [n2]:no kwthen stmt_withelse kwelse stmtso~withelse {-> New expr.if(kwif, expr, stmt_withelse.expr, stmtso~withelse.expr)}
 362 !withelse       | {oneline} kwif no expr [n2]:no kwthen stmt {-> New expr.if(kwif, expr, stmt.expr, Null)}
 363 !withelse       | {block} kwif no expr [n2]:no kwthen [n3]:n stmts [n4]:n elsepartblock {-> New expr.if(kwif, expr, stmts.expr, elsepartblock.expr)}
 364 !withelse       | {emptyblock} kwif no expr [n2]:no kwthen [n3]:n? elsepartblock {-> New expr.if(kwif, expr, Null, elsepartblock.expr)}
 365         ;
 366 elsepartblock {-> expr?}
 367         = {else} kwelse stmtso {-> stmtso.expr}
 368         | {empty} kwend {-> Null}
 369         ;
 370
 371 while~withelse {-> expr}
 372         = kwwhile no expr [n2]:no kwdo stmtso~withelse_withend label? {-> New expr.while(kwwhile, expr, kwdo, stmtso~withelse_withend.expr, label)}
 373         | {noend} kwwhile no expr [n2]:no kwdo stmt~withelse {-> New expr.while(kwwhile, expr, kwdo, stmt~withelse.expr, Null)}
 374         ;
 375
 376 for~withelse {-> expr}
 377         = kwfor no id [n2]:no kwin [n3]:no expr [n4]:no kwdo stmtso~withelse_withend label? {-> New expr.for(kwfor, id, expr, kwdo, stmtso~withelse_withend.expr, label)}
 378         | {noend} kwfor no id [n2]:no kwin [n3]:no expr [n4]:no kwdo stmt~withelse {-> New expr.for(kwfor, id, expr, kwdo, stmt~withelse.expr, Null)}
 379         ;
 380
 381 assert~withelse {-> expr}
 382         = kwassert assertid? expr_final~withelse {-> New expr.assert(kwassert, assertid.id, expr_final~withelse.expr)};
 383 assertid {-> id}
 384         = id column {-> id};
 385
 386 /* EXPRESSIONS ***************************************************************/
 387 expr_final~nopar~withelse~nobra {-> expr}
 388         = expr~nopar~nobra {-> expr~nopar~nobra.expr}
 389         | {closure_call} recv~nobra id args closure_defs~withelse {-> New expr.call(recv~nobra.expr, id, [args.expr], [closure_defs~withelse.closure_def])}
 390 !nobra!nopar    | {closure_bra} expr_atom braargs closure_defs~withelse {-> New expr.bra(expr_atom.expr, [braargs.expr], [closure_defs~withelse.closure_def])}
 391         ;
 392
 393 expr~nopar~nobra {-> expr}
 394         = expr_and~nopar~nobra {-> expr_and~nopar~nobra.expr}
 395         | {ifexpr} kwif [n1]:no expr [n2]:no kwthen [n3]:no [then]:expr [n4]:no kwelse [n5]:no [else]:expr~nopar~nobra {-> New expr.ifexpr(kwif, expr, kwthen, then, kwelse, else.expr)}
 396         ;
 397
 398 expr_and~nopar~nobra {-> expr}
 399         = expr_not~nopar~nobra {-> expr_not~nopar~nobra.expr}
 400         | {or} expr_and~nopar~nobra kwor no expr_not~nopar~nobra {-> New expr.or(expr_and~nopar~nobra.expr, expr_not~nopar~nobra.expr)}
 401         | {and} expr_and~nopar~nobra kwand no expr_not~nopar~nobra {-> New expr.and(expr_and~nopar~nobra.expr, expr_not~nopar~nobra.expr)}
 402         ;
 403
 404 expr_not~nopar~nobra {-> expr}
 405         = expr_eq~nopar~nobra {-> expr_eq~nopar~nobra.expr}
 406         | {not} kwnot no expr_not~nopar~nobra {-> New expr.not(kwnot, expr_not~nopar~nobra.expr)}
 407         ;
 408
 409 expr_eq~nopar~nobra {-> expr}
 410         = expr_add~nopar~nobra {-> expr_add~nopar~nobra.expr}
 411         | {eq} expr_add~nopar~nobra eq no [expr2]:expr_add~nopar~nobra {-> New expr.eq(expr_add~nopar~nobra.expr, expr2.expr)}
 412         | {ee} expr_add~nopar~nobra kwis no [expr2]:expr_add~nopar~nobra {-> New expr.ee(expr_add~nopar~nobra.expr, expr2.expr)}
 413         | {ne} expr_add~nopar~nobra ne no [expr2]:expr_add~nopar~nobra {-> New expr.ne(expr_add~nopar~nobra.expr, expr2.expr)}
 414         | {lt} expr_add~nopar~nobra lt no [expr2]:expr_add~nopar~nobra {-> New expr.lt(expr_add~nopar~nobra.expr, expr2.expr)}
 415         | {le} expr_add~nopar~nobra le no [expr2]:expr_add~nopar~nobra {-> New expr.le(expr_add~nopar~nobra.expr, expr2.expr)}
 416         | {gt} expr_add~nopar~nobra gt no [expr2]:expr_add~nopar~nobra {-> New expr.gt(expr_add~nopar~nobra.expr, expr2.expr)}
 417         | {ge} expr_add~nopar~nobra ge no [expr2]:expr_add~nopar~nobra {-> New expr.ge(expr_add~nopar~nobra.expr, expr2.expr)}
 418         | {starship} expr_add~nopar~nobra starship no [expr2]:expr_add~nopar~nobra {-> New expr.starship(expr_add~nopar~nobra.expr, expr2.expr)}
 419         | {isa} expr_add~nopar~nobra kwisa no type~nobra {-> New expr.isa(expr_add~nopar~nobra.expr, type~nobra.type)}
 420         ;
 421
 422 expr_add~nopar~nobra {-> expr}
 423         =  expr_mul~nopar~nobra {-> expr_mul~nopar~nobra.expr}
 424         | {plus} expr_add~nopar~nobra plus no [expr2]:expr_mul~nopar~nobra {-> New expr.plus(expr_add~nopar~nobra.expr, expr2.expr)}
 425         | {minus} expr_add~nopar~nobra minus no [expr2]:expr_mul~nopar~nobra {-> New expr.minus(expr_add~nopar~nobra.expr, expr2.expr)}
 426         ;
 427
 428 expr_mul~nopar~nobra {-> expr}
 429         = expr_minus~nopar~nobra {-> expr_minus~nopar~nobra.expr}
 430         | {star} expr_mul~nopar~nobra star no [expr2]:expr_minus~nopar~nobra {-> New expr.star(expr_mul~nopar~nobra.expr, expr2.expr)}
 431         | {slash} expr_mul~nopar~nobra slash no [expr2]:expr_minus~nopar~nobra {-> New expr.slash(expr_mul~nopar~nobra.expr, expr2.expr)}
 432         | {percent} expr_mul~nopar~nobra percent no [expr2]:expr_minus~nopar~nobra {-> New expr.percent(expr_mul~nopar~nobra.expr, expr2.expr)}
 433         ;
 434
 435 expr_minus~nopar~nobra {-> expr}
 436         = expr_new~nopar~nobra {-> expr_new~nopar~nobra.expr}
 437         | {minus} minus no expr_minus~nopar~nobra {-> New expr.uminus(minus, expr_minus~nopar~nobra.expr)}
 438         | {once} kwonce no expr_minus~nopar~nobra {-> New expr.once(kwonce, expr_minus~nopar~nobra.expr)}
 439         ;
 440
 441 expr_new~nopar~nobra {-> expr}
 442         = expr_atom~nopar~nobra {-> expr_atom~nopar~nobra.expr}
 443         | {new} kwnew no type~nobra args {-> New expr.new(kwnew, type~nobra.type, Null, [args.expr])}
 444         | {isset_attr} kwisset recv~nopar~nobra attrid {-> New expr.isset_attr(kwisset, recv~nopar~nobra.expr, attrid)}
 445         ;
 446
 447 expr_atom~nopar~nobra {-> expr}
 448         = {attr} recv~nopar~nobra attrid {-> New expr.attr(recv~nopar~nobra.expr, attrid)}
 449         | {call} recv~nopar~nobra id args {-> New expr.call(recv~nopar~nobra.expr, id, [args.expr], [])}
 450         | {super} qualified? kwsuper args {-> New expr.super(qualified, kwsuper, [args.expr])}
 451         | {init} recv~nopar~nobra kwinit args {-> New expr.init(recv~nopar~nobra.expr, kwinit, [args.expr])}
 452 !nobra!nopar    | {bra} expr_atom braargs {-> New expr.bra(expr_atom.expr, [braargs.expr], [])}
 453         | {new} kwnew no type~nobra dot [n2]:no id args {-> New expr.new(kwnew, type~nobra.type, id, [args.expr])}
 454 !nobra!nopar    | {range} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no cbra {-> New expr.crange(expr, expr2.expr)}
 455 !nobra!nopar    | {orange} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no [cbra]:obra  {-> New expr.orange(expr, expr2.expr)}
 456 !nobra!nopar    | {array} braargs {-> New expr.array([braargs.expr])}
 457         | {self} kwself {-> New expr.self(kwself)}
 458         | {true} kwtrue {-> New expr.true(kwtrue)}
 459         | {false} kwfalse {-> New expr.false(kwfalse)}
 460         | {null} kwnull {-> New expr.null(kwnull)}
 461         | {int} number  {-> New expr.int(number)}
 462         | {float} float  {-> New expr.float(float)}
 463         | {char} char  {-> New expr.char(char)}
 464         | {string} string  {-> New expr.string(string)}
 465         | {superstring} superstring  {-> superstring.expr}
 466 !nopar  | {par} opar expr cpar {-> expr}
 467         | {as_cast} expr_atom~nopar~nobra dot no kwas [n2]:no opar [n3]:no type [n4]:no cpar {-> New expr.as_cast(expr_atom~nopar~nobra.expr, kwas, type)}
 468         | {as_notnull} expr_atom~nopar~nobra dot no kwas [n2]:no opar [n3]:no kwnot [n4]:no kwnull [n5]:no cpar {-> New expr.as_notnull(expr_atom~nopar~nobra.expr, kwas, kwnot, kwnull)}
 469         ;
 470
 471 superstring {-> expr}
 472         = superstring_start superstring_middle* superstring_end {-> New expr.superstring([superstring_start.expr, superstring_middle.expr, superstring_end.expr])};
 473 superstring_start {-> expr*}
 474         = start_string_p no expr [n2]:no {-> [start_string_p.expr, expr]};
 475 start_string_p {-> expr}
 476         = start_string {-> New expr.start_string(start_string)};
 477 superstring_middle {-> expr*}
 478         = mid_string_p no expr [n2]:no {-> [mid_string_p.expr, expr]};
 479 mid_string_p {-> expr}
 480         = mid_string {-> New expr.mid_string(mid_string)};
 481 superstring_end {-> expr}
 482         = end_string {-> New expr.end_string(end_string)};
 483
 484 /* MISC **********************************************************************/
 485
 486 recv~nopar~nobra {-> expr}
 487         = expr_atom~nopar~nobra dot no {-> expr_atom~nopar~nobra.expr}
 488         | {implicit} {-> New expr.implicit_self()}
 489         ;
 490
 491 args {-> expr*}
 492         = opar no expr [n2]:no args_tail* cpar {-> [expr, args_tail.expr]}
 493         | {emptypar} opar no cpar {-> []}
 494         | {empty} {-> []}
 495         ;
 496 args_nopar {-> expr*}
 497         = opar no expr [n2]:no args_tail* cpar {-> [expr, args_tail.expr]}
 498         | {onearg} expr_nopar {-> [expr_nopar.expr]}
 499         | {emptypar} opar no cpar {-> []}
 500         | {empty} {-> []}
 501         ;
 502 braargs {-> expr*}
 503         = obra no expr [n2]:no args_tail* cbra {-> [expr, args_tail.expr]};
 504 args_tail {-> expr}
 505         = comma no expr [n2]:no {-> expr};
 506 idlist {-> id*}
 507         = {single} id {-> [id]}
 508         | {more} idlist no comma [n2]:no id {-> [idlist.id, id]}
 509         ;
 510
 511 qualified
 512         = {cla} modquad* classquad {-> New qualified([modquad.id], classquad.classid)}
 513         | {mod} modquad+ {-> New qualified([modquad.id], Null)}
 514         ;
 515 modquad {-> id}
 516         = id quad no {-> id};
 517 classquad {-> classid}
 518         = classid quad no {-> classid};
 519
 520 n1      = {a} comment | {b} eol;
 521 n {-> doc?}
 522         = {a} n2? comment+ {-> New doc([comment])}
 523         | {b} n2 {-> Null}
 524         ;
 525 no {-> doc?}
 526         = {empty} {-> Null}
 527         | n {-> n.doc}
 528         ;
 529
 530 n2
 531         = {a} n2? comment+ eol+
 532         | {b} eol+
 533         ;
 534
 535 /*****************************************************************************/
 536 Abstract Syntax Tree
 537 /*****************************************************************************/
 538
 539 module  = packagedecl? [imports]:import* [classdefs]:classdef*;
 540
 541 packagedecl
 542         = doc? kwpackage id;
 543
 544 import  = {std} visibility kwimport id
 545         | {no} visibility kwimport kwend
 546         ;
 547
 548 visibility
 549         = {public}
 550         | {private} kwprivate
 551         | {protected} kwprotected
 552         | {intrude} kwintrude
 553         ;
 554
 555 classdef= {std} doc? kwredef? visibility classkind [id]:classid? [formaldefs]:formaldef* [superclasses]:superclass* [propdefs]:propdef*
 556         | {top} [propdefs]:propdef*
 557         | {main} [propdefs]:propdef*
 558         ;
 559 classkind
 560         = {concrete} kwclass
 561         | {abstract} kwabstract kwclass
 562         | {interface} kwinterface
 563         | {universal} kwuniversal
 564         ;
 565 formaldef = [id]:classid type?;
 566 superclass = kwspecial type;
 567
 568
 569 propdef = {attr} doc? [readable]:able? [writable]:able? kwredef? visibility kwvar [id]:attrid type? expr?
 570         | {meth} doc? kwredef? visibility methid signature
 571         | {deferred_meth} doc? kwredef? visibility kwmeth methid signature
 572         | {intern_meth} doc? kwredef? visibility kwmeth methid signature
 573         | {extern_meth} doc? kwredef? visibility kwmeth methid signature [extern]:string?
 574         | {concrete_meth} doc? kwredef? visibility kwmeth methid signature [block]:expr?
 575         | {concrete_init} doc? kwredef? visibility kwinit methid? signature [block]:expr?
 576         | {main_meth} kwredef? [block]:expr?
 577         | {type} doc? kwredef? visibility kwtype [id]:classid type
 578         ;
 579
 580 able    = {read} kwredef? kwreadable
 581         | {write} kwredef? kwwritable
 582         ;
 583
 584 methid = {id} id | {plus} plus | {minus} minus | {star} star | {slash} slash | {percent} percent | {eq} eq | {ne} ne | {le} le | {ge} ge | {lt} lt | {gt} gt | {bra} obra cbra | {starship} starship | {assign} id assign | {braassign} obra cbra assign;
 585
 586 signature = [params]:param* type? [closure_decls]:closure_decl*;
 587
 588 param   = id type? dotdotdot?
 589         ;
 590
 591 closure_decl = kwwith kwbreak? id signature expr?
 592         ;
 593
 594 type    = kwnullable? [id]:classid [types]:type*;
 595
 596 label = kwlabel id;
 597
 598 expr    = {block} expr*
 599         | {vardecl} kwvar id type? assign? expr?
 600         | {return} kwreturn expr?
 601         | {break} kwbreak label? expr?
 602         | {abort} kwabort
 603         | {continue} kwcontinue label? expr?
 604         | {do} kwdo [block]:expr? label?
 605         | {if} kwif expr [then]:expr? [else]:expr?
 606         | {ifexpr} kwif expr kwthen [then]:expr kwelse [else]:expr
 607         | {while} kwwhile expr kwdo [block]:expr? label?
 608         | {for} kwfor id expr kwdo [block]:expr? label?
 609         | {assert} kwassert id? expr
 610         | {once} kwonce expr
 611         | {send} expr
 612         | {binop} expr [expr2]:expr
 613         | {or} expr [expr2]:expr
 614         | {and} expr [expr2]:expr
 615         | {not} kwnot expr
 616         | {eq} expr [expr2]:expr
 617         | {ee} expr [expr2]:expr
 618         | {ne} expr [expr2]:expr
 619         | {lt} expr [expr2]:expr
 620         | {le} expr [expr2]:expr
 621         | {gt} expr [expr2]:expr
 622         | {ge} expr [expr2]:expr
 623         | {isa} expr type
 624         | {plus} expr [expr2]:expr
 625         | {minus} expr [expr2]:expr
 626         | {starship} expr [expr2]:expr
 627         | {star} expr [expr2]:expr
 628         | {slash} expr [expr2]:expr
 629         | {percent} expr [expr2]:expr
 630         | {uminus} minus expr
 631         | {new} kwnew type id? [args]:expr*
 632         | {attr} expr [id]:attrid
 633         | {attr_assign} expr [id]:attrid assign [value]:expr
 634         | {attr_reassign} expr [id]:attrid assign_op [value]:expr
 635         | {call} expr id [args]:expr* [closure_defs]:closure_def*
 636         | {call_assign} expr id [args]:expr* assign [value]:expr
 637         | {call_reassign} expr id [args]:expr* assign_op [value]:expr
 638         | {super} qualified? kwsuper [args]:expr*
 639         | {init} expr kwinit [args]:expr*
 640         | {bra} expr [args]:expr* [closure_defs]:closure_def*
 641         | {bra_assign} expr [args]:expr* assign [value]:expr
 642         | {bra_reassign} expr [args]:expr* assign_op [value]:expr
 643         | {closure_call} id [args]:expr* [closure_defs]:closure_def*
 644         | {var} id
 645         | {var_assign} id assign [value]:expr
 646         | {var_reassign} id assign_op [value]:expr
 647         | {range} expr [expr2]:expr
 648         | {crange} expr [expr2]:expr
 649         | {orange} expr [expr2]:expr
 650         | {array} [exprs]:expr*
 651         | {self} kwself
 652         | {implicit_self}
 653         | {true} kwtrue
 654         | {false} kwfalse
 655         | {null} kwnull
 656         | {int} number
 657         | {float} float
 658         | {char} char
 659         | {string} string
 660         | {start_string} [string]:start_string
 661         | {mid_string} [string]:mid_string
 662         | {end_string} [string]:end_string
 663         | {superstring} [exprs]:expr*
 664         | {par} expr
 665         | {as_cast} expr kwas type
 666         | {as_notnull} expr kwas kwnot kwnull
 667         | {isset_attr} kwisset expr [id]:attrid
 668         ;
 669 assign_op
 670         = {plus} pluseq
 671         | {minus} minuseq
 672         ;
 673
 674 closure_def
 675         = kwwith id* kwdo expr? label?
 676         ;
 677
 678 qualified = id* classid? ;
 679
 680 doc = comment+;
 681
 682 /*****************************************************************************/
 683