src/parser/nit.sablecc3xx

   1
   2 /* This file is part of NIT ( http://www.nitlanguage.org ).
   3  *
   4  * Copyright 2008-2009 Jean Privat <jean@pryen.org>
   5  *
   6  * Licensed under the Apache License, Version 2.0 (the "License");
   7  * you may not use this file except in compliance with the License.
   8  * You may obtain a copy of the License at
   9  *
  10  *     http://www.apache.org/licenses/LICENSE-2.0
  11  *
  12  * Unless required by applicable law or agreed to in writing, software
  13  * distributed under the License is distributed on an "AS IS" BASIS,
  14  * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15  * See the License for the specific language governing permissions and
  16  * limitations under the License.
  17  */
  18
  19 /* This grammar defines the NIT language. */
  20
  21 /*****************************************************************************/
  22 Helpers
  23 /*****************************************************************************/
  24
  25 all = [0 .. 0xFF];
  26 lowercase = ['a' .. 'z'];
  27 uppercase = ['A' .. 'Z'];
  28 digit = ['0' .. '9'];
  29 letter = lowercase | uppercase | digit | '_';
  30
  31 tab = 9;
  32 cr = 13;
  33 lf = 10;
  34 any = [all - [cr + lf]];
  35
  36 // characers inside strings and super-strings (atomaton powaa)
  37 str_char
  38         = [any - [['"' + '{'] + '\']]
  39         | '\' any
  40         ;
  41 str_body = str_char*;
  42
  43 eol_helper = cr lf | cr | lf; // This takes care of different platforms
  44
  45 /*****************************************************************************/
  46 States
  47 /*****************************************************************************/
  48 initial;
  49
  50
  51 /*****************************************************************************/
  52 Tokens
  53 /*****************************************************************************/
  54
  55 blank = (' ' | tab)+;
  56
  57 eol = eol_helper;
  58 comment = '#' any* eol_helper;
  59
  60 kwmodule = 'package'|'module';
  61 kwimport = 'import';
  62 kwclass = 'class';
  63 kwabstract = 'abstract';
  64 kwinterface = 'interface';
  65 kwuniversal = 'universal';
  66 kwspecial = 'special';
  67 kwend = 'end';
  68 kwmeth = 'fun';
  69 kwtype = 'type';
  70 kwinit = 'init';
  71 kwredef = 'redef';
  72 kwis = 'is';
  73 kwdo = 'do';
  74 kwreadable = 'readable';
  75 kwwritable = 'writable';
  76 kwvar = 'var';
  77 kwintern = 'intern';
  78 kwextern = 'extern';
  79 kwprotected = 'protected';
  80 kwprivate = 'private';
  81 kwintrude = 'intrude';
  82 kwif = 'if';
  83 kwthen = 'then';
  84 kwelse = 'else';
  85 kwwhile = 'while';
  86 kwloop = 'loop';
  87 kwfor = 'for';
  88 kwin = 'in';
  89 kwand = 'and';
  90 kwor = 'or';
  91 kwnot = 'not';
  92 kwreturn = 'return';
  93 kwcontinue = 'continue';
  94 kwbreak = 'break';
  95 kwabort = 'abort';
  96 kwassert = 'assert';
  97 kwnew = 'new';
  98 kwisa = 'isa';
  99 kwonce = 'once';
 100 kwsuper = 'super';
 101 kwself = 'self';
 102 kwtrue = 'true';
 103 kwfalse = 'false';
 104 kwnull = 'null';
 105 kwas = 'as';
 106 kwnullable = 'nullable';
 107 kwisset = 'isset';
 108 kwlabel = 'label';
 109
 110 opar = '(';
 111 cpar = ')';
 112 obra = '[';
 113 cbra = ']';
 114 comma = ',';
 115 column = ':';
 116 quad = '::';
 117 assign = '=';
 118 pluseq = '+=';
 119 minuseq = '-=';
 120 dotdotdot = '...';
 121 dotdot = '..';
 122 dot = '.';
 123 plus = '+';
 124 minus = '-';
 125 star = '*';
 126 slash = '/';
 127 percent = '%';
 128 eq = '==';
 129 ne = '!=';
 130 lt = '<';
 131 le = '<=';
 132 ll = '<<';
 133 gt = '>';
 134 ge = '>=';
 135 gg = '>>';
 136 starship = '<=>';
 137 bang='!';
 138
 139 classid = uppercase letter*;
 140 id = lowercase letter*;
 141 attrid = '_' lowercase letter*;
 142
 143 number = digit+;
 144 float = digit* '.' digit+;
 145 char = ''' [any - ''']* ''';
 146 string = '"' str_body '"';
 147 start_string = '"' str_body '{';
 148 mid_string = '}' str_body '{';
 149 end_string = '}' str_body '"';
 150
 151
 152 /*****************************************************************************/
 153 Ignored Tokens
 154 /*****************************************************************************/
 155
 156 blank;
 157
 158 /*****************************************************************************/
 159 Productions
 160 /*****************************************************************************/
 161
 162 /* MODULES *******************************************************************/
 163 module
 164         = moduledecl? [imports]:import* [classdefs]:classdef* implicit_top_class? implicit_main_class? {-> New module(moduledecl, [imports.import],[classdefs.classdef,implicit_top_class.classdef,implicit_main_class.classdef])};
 165
 166 moduledecl
 167         = [doc]:no kwmodule no id [n2]:n1 {-> New moduledecl(doc.doc, kwmodule, id)};
 168
 169 import
 170         = {std} [doc]:no visibility kwimport no id [n2]:n1              {-> New import.std(visibility, kwimport, id)}
 171         | {no} [doc]:no visibility kwimport no kwend [n2]:n1    {-> New import.no(visibility, kwimport, kwend)}
 172         ;
 173
 174 implicit_top_class {-> classdef}
 175         = propdefs_toplevel+ {-> New classdef.top([propdefs_toplevel.propdef])};
 176
 177 implicit_main_class {-> classdef?}
 178         = implicit_main_meth {-> New classdef.main([implicit_main_meth.propdef])}
 179         | {null} n {-> Null}
 180         ;
 181 implicit_main_meth {-> propdef}
 182         = [doc]:no stmts {-> New propdef.main_meth(Null, stmts.expr)}
 183         | {n} [doc]:no stmtsn {-> New propdef.main_meth(Null, stmtsn.expr)}
 184         ;
 185
 186 /* CLASSES *******************************************************************/
 187 classdef
 188         = [doc]:no redef visibility classkind no classid formaldefs? [specials]:special* propdefs* [n2]:no kwend {-> New classdef.std(doc.doc, redef.kwredef, visibility, classkind, classid, [formaldefs.formaldef], [specials.superclass], [propdefs.propdef])};
 189 redef {-> kwredef?}
 190         = kwredef? {-> kwredef};
 191 classkind
 192         = {concrete} kwclass
 193         | {abstract} kwabstract kwclass
 194         | {interface} kwinterface
 195         | {universal} kwuniversal
 196         ;
 197
 198 formaldefs {-> formaldef*}
 199         = obra no formaldef formaldefs_tail* [n2]:no cbra {-> [formaldef, formaldefs_tail.formaldef]};
 200 formaldefs_tail {-> formaldef}
 201         = comma no formaldef {-> formaldef};
 202 formaldef
 203         = classid typing? {-> New formaldef(classid, typing.type)};
 204
 205 special {-> superclass}
 206         = {special} no kwspecial [n2]:no type {-> New superclass(kwspecial, Null, type)}
 207         | {super} no kwsuper [n2]:no type {-> New superclass(Null, kwsuper, type)}
 208         ;
 209
 210 propdefs~toplevel {-> propdef}
 211         = propdef~toplevel n1 {-> propdef~toplevel.propdef}
 212         ;
 213 propdef~toplevel {-> propdef}
 214         = {meth} [doc]:no redef visibility kwmeth methid signature kwdo stmtso kwend? {-> New propdef.concrete_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature, stmtso.expr)}
 215         | {assign_return} [doc]:no redef visibility kwmeth methid signature_withret assign no assign_return {-> New propdef.concrete_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature_withret.signature, assign_return.expr)}
 216 !toplevel| {deferred} [doc]:no redef visibility kwmeth methid signature kwis kwabstract {-> New propdef.deferred_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature)}
 217 !toplevel| {intern} [doc]:no redef visibility kwmeth methid signature kwis kwintern {-> New propdef.intern_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature)}
 218         | {extern} [doc]:no redef visibility kwmeth methid signature kwis kwextern string? {-> New propdef.extern_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature, string)}
 219 !toplevel| {var} [doc]:no readable? writable? redef visibility kwvar attrid typing? {-> New propdef.attr(doc.doc, readable.able, writable.able, redef.kwredef, visibility, kwvar, attrid, Null, typing.type, Null)}
 220 !toplevel| {var2} [doc]:no readable? writable? redef visibility kwvar attrid typing? assign [n2]:no expr {-> New propdef.attr(doc.doc, readable.able, writable.able, redef.kwredef, visibility, kwvar, attrid, Null, typing.type, expr)}
 221 !toplevel| {var3} [doc]:no redef visibility kwvar id typing? writable2? {-> New propdef.attr(doc.doc, Null, writable2.able, redef.kwredef, visibility, kwvar, Null, id, typing.type, Null)}
 222 !toplevel| {var4} [doc]:no redef visibility kwvar id typing? writable2? assign [n2]:no expr {-> New propdef.attr(doc.doc, Null, writable2.able, redef.kwredef, visibility, kwvar, Null, id, typing.type, expr)}
 223 !toplevel| {init} [doc]:no redef visibility kwinit methid? signature kwdo stmtso kwend? {-> New propdef.concrete_init(doc.doc, redef.kwredef, visibility, kwinit, methid, signature, stmtso.expr)}
 224 !toplevel| {type} [doc]:no redef visibility kwtype classid typing {-> New propdef.type(doc.doc, redef.kwredef, visibility, kwtype, classid, typing.type)}
 225         ;
 226 readable {-> able}
 227         = redef kwreadable {-> New able.read(redef.kwredef, kwreadable)}
 228         ;
 229 writable {-> able}
 230         = redef kwwritable {-> New able.write(redef.kwredef, Null, kwwritable)}
 231         ;
 232 writable2 {-> able}
 233         = redef visibility kwwritable {-> New able.write(redef.kwredef, visibility, kwwritable)}
 234         ;
 235
 236 visibility
 237         = {public} {-> New visibility.public()}
 238         | {private} kwprivate no {-> New visibility.private(kwprivate)}
 239         | {protected} kwprotected no {-> New visibility.protected(kwprotected)}
 240         | {intrude} kwintrude no {-> New visibility.intrude(kwintrude)}
 241         ;
 242
 243 methid {-> methid}
 244         = {id} id {-> New methid.id(id)}
 245         | {plus} plus {-> New methid.plus(plus)}
 246         | {minus} minus {-> New methid.minus(minus)}
 247         | {star} star {-> New methid.star(star)}
 248         | {slash} slash {-> New methid.slash(slash)}
 249         | {percent} percent {-> New methid.percent(percent)}
 250         | {eq} eq {-> New methid.eq(eq)}
 251         | {ne} ne {-> New methid.ne(ne)}
 252         | {le} le {-> New methid.le(le)}
 253         | {ge} ge {-> New methid.ge(ge)}
 254         | {lt} lt {-> New methid.lt(lt)}
 255         | {gt} gt {-> New methid.gt(gt)}
 256         | {ll} ll {-> New methid.ll(ll)}
 257         | {gg} gg {-> New methid.gg(gg)}
 258         | {bra} obra cbra {-> New methid.bra(obra, cbra)}
 259         | {starship} starship {-> New methid.starship(starship)}
 260         | {assign} id assign {-> New methid.assign(id, assign)}
 261         | {braassign} obra cbra assign {-> New methid.braassign(obra, cbra, assign)}
 262         ;
 263
 264 signature~withret {-> signature}
 265         = params? typing closure_decls {-> New signature([params.param], typing.type, [closure_decls.closure_decl])}
 266         | {noclosures} params? typing no {-> New signature([params.param], typing.type, [])}
 267 !withret| {noret} params? closure_decls {-> New signature([params.param], Null, [closure_decls.closure_decl])}
 268 !withret| {noretnoclosures} params? no {-> New signature([params.param], Null, [])}
 269         ;
 270
 271 signature_noclosures {-> signature}
 272         = params? typing? {-> New signature([params.param], typing.type, [])};
 273
 274 params {-> param*}
 275         = opar no param params_tail* [n2]:no cpar {-> [param, params_tail.param]}
 276         | {empty} opar no cpar {-> []}
 277         ;
 278 params_tail {-> param}
 279         = comma no param {-> param};
 280 param
 281         = {untyped} id {-> New param(id, Null, Null)}
 282         | id typing dotdotdot? {-> New param(id, typing.type, dotdotdot)}
 283         ;
 284
 285 closure_decls {->closure_decl*}
 286         = no closure_decl+ {-> [closure_decl]};
 287 closure_decl
 288         = kwbreak? bang id signature_noclosures n {-> New closure_decl(kwbreak, bang, id, signature_noclosures.signature, Null)}
 289         | {optionnal} kwbreak? bang id signature_noclosures kwdo stmtso n {-> New closure_decl(kwbreak, bang, id, signature_noclosures.signature, stmtso.expr)}
 290         | {assign} kwbreak? bang id signature_noclosures assign no assign_continue n {-> New closure_decl(kwbreak, bang, id, signature_noclosures.signature, assign_continue.expr)}
 291         ;
 292
 293 assign_return{-> expr}
 294         = expr_final {-> New expr.return(Null, expr_final.expr)}
 295         ;
 296
 297
 298 /* TYPES *********************************************************************/
 299 type~nobra {-> type}
 300         = {simple} kwnullable? classid {-> New type(kwnullable, classid, [])}
 301 !nobra  | {generic} kwnullable? classid obra no types [n2]:no cbra {-> New type(kwnullable, classid, [types.type])}
 302         ;
 303 types {-> type*}
 304         = type types_tail* {-> [type, types_tail.type]};
 305 types_tail {-> type}
 306         = comma no type {-> type};
 307 typing {-> type}
 308         = column no type {-> type};
 309
 310 /* STATMENTS *****************************************************************/
 311 stmtso~withelse~withend {-> expr?}
 312         = {block} n stmtsn kwend {-> stmtsn.expr}
 313         | {emptyblock} n kwend {-> New expr.block([])}
 314         | {emptyoneline} kwend {-> New expr.block([])}
 315 !withend| {oneline} stmt~withelse {-> stmt~withelse.expr}
 316         ;
 317 stmts {-> expr}
 318         = stmt stmts_tail* {-> New expr.block([stmt.expr, stmts_tail.expr])};
 319 stmtsn {-> expr}
 320         = stmt stmts_tail* n {-> New expr.block([stmt.expr, stmts_tail.expr])};
 321 stmts_tail {-> expr}
 322         = n stmt {-> stmt.expr};
 323 stmt~withelse {-> expr}
 324         = {vardecl} vardecl~withelse {-> vardecl~withelse.expr}
 325         | {assign} assignment~withelse {-> assignment~withelse.expr}
 326         | {return} kwreturn expr_final~withelse? {-> New expr.return(kwreturn, expr_final~withelse.expr)}
 327         | {break} kwbreak label? expr_final~withelse? {-> New expr.break(kwbreak, label, expr_final~withelse.expr)}
 328         | {abort} kwabort {-> New expr.abort(kwabort)}
 329         | {continue} kwcontinue label? expr_final~withelse? {-> New expr.continue(kwcontinue, label, expr_final~withelse.expr)}
 330         | {do} do~withelse {-> do~withelse.expr}
 331         | {if} if~withelse {-> if~withelse.expr}
 332         | {while} while~withelse {-> while~withelse.expr}
 333         | {loop} loop~withelse {-> loop~withelse.expr}
 334         | {for} for~withelse {-> for~withelse.expr}
 335         | {assert} assert~withelse {-> assert~withelse.expr}
 336         | {call} recv id args_nopar closure_defs~withelse? {-> New expr.call(recv.expr, id, [args_nopar.expr], [closure_defs~withelse.closure_def])}
 337         | {super} qualified? kwsuper args_nopar {-> New expr.super(qualified, kwsuper, [args_nopar.expr])}
 338         | {init} recv kwinit args_nopar {-> New expr.init(recv.expr, kwinit, [args_nopar.expr])}
 339         ;
 340
 341 label= kwlabel id;
 342
 343 closure_defs~withelse {-> closure_def*}
 344         = {one} closure_def_last~withelse {-> [closure_def_last~withelse.closure_def]}
 345         | closure_def closure_defs~withelse {-> [closure_def, closure_defs~withelse.closure_def]}
 346         ;
 347
 348 closure_def_last~withelse {-> closure_def}
 349         = bang [id]:closure_id idlist? kwdo stmtso_withend label {-> New closure_def(bang, id, [idlist.id], kwdo, stmtso_withend.expr, label)}
 350         | {nolabel} bang [id]:closure_id idlist? kwdo stmtso~withelse {-> New closure_def(bang, id, [idlist.id], kwdo, stmtso~withelse.expr, Null)}
 351         | {assign} bang [id]:closure_id idlist? assign no assign_continue~withelse {-> New closure_def(bang, id, [idlist.id], Null, assign_continue~withelse.expr, Null)}
 352         ;
 353
 354 closure_def {-> closure_def}
 355         = bang [id]:closure_id idlist? kwdo n stmtsn {-> New closure_def(bang, id, [idlist.id], kwdo, stmtsn.expr, Null)}
 356         | {empty} bang [id]:closure_id idlist? kwdo n {-> New closure_def(bang, id, [idlist.id], kwdo, Null, Null)}
 357         ;
 358 closure_id
 359         = {simple} id
 360         | {break} kwbreak
 361         ;
 362
 363 assign_continue~withelse{-> expr}
 364         = expr_final~withelse {-> New expr.continue(Null, Null, expr_final~withelse.expr)}
 365         ;
 366
 367 vardecl~withelse{-> expr}
 368         = kwvar id typing? {-> New expr.vardecl(kwvar, id, typing.type, Null, Null)}
 369         | {assign} kwvar id typing? assign no expr_final~withelse {-> New expr.vardecl(kwvar, id, typing.type, assign, expr_final~withelse.expr)}
 370         ;
 371
 372 assignment~withelse {-> expr}
 373         = {attr} recv attrid assign expr_final~withelse {-> New expr.attr_assign(recv.expr, attrid, assign, expr_final~withelse.expr)}
 374         | {call} recv id args assign expr_final~withelse {-> New expr.call_assign(recv.expr, id, [args.expr], assign,  expr_final~withelse.expr)}
 375         | {bra} expr_atom braargs assign expr_final~withelse {-> New expr.bra_assign(expr_atom.expr, [braargs.expr], assign,  expr_final~withelse.expr)}
 376         | {attr_re} recv attrid assign_op expr_final~withelse {-> New expr.attr_reassign(recv.expr, attrid, assign_op,  expr_final~withelse.expr)}
 377         | {call_re} recv id args assign_op expr_final~withelse {-> New expr.call_reassign(recv.expr, id, [args.expr], assign_op,  expr_final~withelse.expr)}
 378         | {bra_re} expr_atom braargs assign_op expr_final~withelse {-> New expr.bra_reassign(expr_atom.expr, [braargs.expr], assign_op,  expr_final~withelse.expr)}
 379         ;
 380 assign_op
 381         = {plus} pluseq
 382         | {minus} minuseq
 383         ;
 384
 385 do~withelse {-> expr}
 386         = kwdo stmtso_withend label {-> New expr.do(kwdo, stmtso_withend.expr, label)}
 387         | {nolabel} kwdo stmtso~withelse {-> New expr.do(kwdo, stmtso~withelse.expr, Null)}
 388         ;
 389
 390 if~withelse {-> expr}
 391         = {onelineelse} kwif no expr [n2]:no kwthen stmt_withelse kwelse stmtso~withelse {-> New expr.if(kwif, expr, stmt_withelse.expr, stmtso~withelse.expr)}
 392 !withelse       | {oneline} kwif no expr [n2]:no kwthen stmt {-> New expr.if(kwif, expr, stmt.expr, Null)}
 393 !withelse       | {block} kwif no expr [n2]:no kwthen [n3]:n stmtsn elsepartblock {-> New expr.if(kwif, expr, stmtsn.expr, elsepartblock.expr)}
 394 !withelse       | {emptyblock} kwif no expr [n2]:no kwthen [n3]:n? elsepartblock {-> New expr.if(kwif, expr, Null, elsepartblock.expr)}
 395         ;
 396 elsepartblock {-> expr?}
 397         = {else} kwelse stmtso {-> stmtso.expr}
 398         | {empty} kwend {-> Null}
 399         ;
 400
 401 loop~withelse {-> expr}
 402         = kwloop stmtso_withend label {-> New expr.loop(kwloop, stmtso_withend.expr, label)}
 403         | {nolabel} kwloop stmtso~withelse {-> New expr.loop(kwloop, stmtso~withelse.expr, Null)}
 404         ;
 405
 406 while~withelse {-> expr}
 407         = kwwhile no expr [n2]:no kwdo stmtso_withend label {-> New expr.while(kwwhile, expr, kwdo, stmtso_withend.expr, label)}
 408         | {nolabel} kwwhile no expr [n2]:no kwdo stmtso~withelse {-> New expr.while(kwwhile, expr, kwdo, stmtso~withelse.expr, Null)}
 409         ;
 410
 411 for~withelse {-> expr}
 412         = kwfor no id [n2]:no kwin [n3]:no expr [n4]:no kwdo stmtso_withend label {-> New expr.for(kwfor, id, expr, kwdo, stmtso_withend.expr, label)}
 413         | {nolabel} kwfor no id [n2]:no kwin [n3]:no expr [n4]:no kwdo stmtso~withelse {-> New expr.for(kwfor, id, expr, kwdo, stmtso~withelse.expr, Null)}
 414         ;
 415
 416 assert~withelse {-> expr}
 417         = {else} kwassert assertid? expr_final_withelse kwelse stmtso~withelse {-> New expr.assert(kwassert, assertid.id, expr_final_withelse.expr, stmtso~withelse.expr)}
 418 !withelse| {noelse} kwassert assertid? expr_final {-> New expr.assert(kwassert, assertid.id, expr_final.expr, Null)}
 419         ;
 420 assertid {-> id}
 421         = id column {-> id};
 422
 423 /* EXPRESSIONS ***************************************************************/
 424 expr_final~nopar~withelse~nobra {-> expr}
 425         = expr~nopar~nobra {-> expr~nopar~nobra.expr}
 426         | {closure_call} recv~nobra id args closure_defs~withelse {-> New expr.call(recv~nobra.expr, id, [args.expr], [closure_defs~withelse.closure_def])}
 427 !nobra!nopar    | {closure_bra} expr_atom braargs closure_defs~withelse {-> New expr.bra(expr_atom.expr, [braargs.expr], [closure_defs~withelse.closure_def])}
 428         ;
 429
 430 expr~nopar~nobra {-> expr}
 431         = expr_and~nopar~nobra {-> expr_and~nopar~nobra.expr}
 432         | {ifexpr} kwif [n1]:no expr [n2]:no kwthen [n3]:no [then]:expr [n4]:no kwelse [n5]:no [else]:expr~nopar~nobra {-> New expr.ifexpr(kwif, expr, kwthen, then, kwelse, else.expr)}
 433         ;
 434
 435 expr_and~nopar~nobra {-> expr}
 436         = expr_not~nopar~nobra {-> expr_not~nopar~nobra.expr}
 437         | {or} expr_and~nopar~nobra kwor no expr_not~nopar~nobra {-> New expr.or(expr_and~nopar~nobra.expr, expr_not~nopar~nobra.expr)}
 438         | {and} expr_and~nopar~nobra kwand no expr_not~nopar~nobra {-> New expr.and(expr_and~nopar~nobra.expr, expr_not~nopar~nobra.expr)}
 439         | {or_else} expr_and~nopar~nobra kwor kwelse no expr_not~nopar~nobra {-> New expr.or_else(expr_and~nopar~nobra.expr, expr_not~nopar~nobra.expr)}
 440         ;
 441
 442 expr_not~nopar~nobra {-> expr}
 443         = expr_eq~nopar~nobra {-> expr_eq~nopar~nobra.expr}
 444         | {not} kwnot no expr_not~nopar~nobra {-> New expr.not(kwnot, expr_not~nopar~nobra.expr)}
 445         ;
 446
 447 expr_eq~nopar~nobra {-> expr}
 448         = expr_add~nopar~nobra {-> expr_add~nopar~nobra.expr}
 449         | {eq} expr_add~nopar~nobra eq no [expr2]:expr_add~nopar~nobra {-> New expr.eq(expr_add~nopar~nobra.expr, expr2.expr)}
 450         | {ee} expr_add~nopar~nobra kwis no [expr2]:expr_add~nopar~nobra {-> New expr.ee(expr_add~nopar~nobra.expr, expr2.expr)}
 451         | {ne} expr_add~nopar~nobra ne no [expr2]:expr_add~nopar~nobra {-> New expr.ne(expr_add~nopar~nobra.expr, expr2.expr)}
 452         | {lt} expr_add~nopar~nobra lt no [expr2]:expr_add~nopar~nobra {-> New expr.lt(expr_add~nopar~nobra.expr, expr2.expr)}
 453         | {le} expr_add~nopar~nobra le no [expr2]:expr_add~nopar~nobra {-> New expr.le(expr_add~nopar~nobra.expr, expr2.expr)}
 454         | {ll} expr_eq~nopar~nobra ll no [expr2]:expr_add~nopar~nobra {-> New expr.ll(expr_eq~nopar~nobra.expr, expr2.expr)}
 455         | {gt} expr_add~nopar~nobra gt no [expr2]:expr_add~nopar~nobra {-> New expr.gt(expr_add~nopar~nobra.expr, expr2.expr)}
 456         | {ge} expr_add~nopar~nobra ge no [expr2]:expr_add~nopar~nobra {-> New expr.ge(expr_add~nopar~nobra.expr, expr2.expr)}
 457         | {gg} expr_eq~nopar~nobra gg no [expr2]:expr_add~nopar~nobra {-> New expr.gg(expr_eq~nopar~nobra.expr, expr2.expr)}
 458         | {starship} expr_add~nopar~nobra starship no [expr2]:expr_add~nopar~nobra {-> New expr.starship(expr_add~nopar~nobra.expr, expr2.expr)}
 459         | {isa} expr_add~nopar~nobra kwisa no type~nobra {-> New expr.isa(expr_add~nopar~nobra.expr, type~nobra.type)}
 460         ;
 461
 462 expr_add~nopar~nobra {-> expr}
 463         =  expr_mul~nopar~nobra {-> expr_mul~nopar~nobra.expr}
 464         | {plus} expr_add~nopar~nobra plus no [expr2]:expr_mul~nopar~nobra {-> New expr.plus(expr_add~nopar~nobra.expr, expr2.expr)}
 465         | {minus} expr_add~nopar~nobra minus no [expr2]:expr_mul~nopar~nobra {-> New expr.minus(expr_add~nopar~nobra.expr, expr2.expr)}
 466         ;
 467
 468 expr_mul~nopar~nobra {-> expr}
 469         = expr_minus~nopar~nobra {-> expr_minus~nopar~nobra.expr}
 470         | {star} expr_mul~nopar~nobra star no [expr2]:expr_minus~nopar~nobra {-> New expr.star(expr_mul~nopar~nobra.expr, expr2.expr)}
 471         | {slash} expr_mul~nopar~nobra slash no [expr2]:expr_minus~nopar~nobra {-> New expr.slash(expr_mul~nopar~nobra.expr, expr2.expr)}
 472         | {percent} expr_mul~nopar~nobra percent no [expr2]:expr_minus~nopar~nobra {-> New expr.percent(expr_mul~nopar~nobra.expr, expr2.expr)}
 473         ;
 474
 475 expr_minus~nopar~nobra {-> expr}
 476         = expr_new~nopar~nobra {-> expr_new~nopar~nobra.expr}
 477         | {minus} minus no expr_minus~nopar~nobra {-> New expr.uminus(minus, expr_minus~nopar~nobra.expr)}
 478         | {once} kwonce no expr_minus~nopar~nobra {-> New expr.once(kwonce, expr_minus~nopar~nobra.expr)}
 479         ;
 480
 481 expr_new~nopar~nobra {-> expr}
 482         = expr_atom~nopar~nobra {-> expr_atom~nopar~nobra.expr}
 483         | {new} kwnew no type~nobra args {-> New expr.new(kwnew, type~nobra.type, Null, [args.expr])}
 484         | {isset_attr} kwisset recv~nopar~nobra attrid {-> New expr.isset_attr(kwisset, recv~nopar~nobra.expr, attrid)}
 485         ;
 486
 487 expr_atom~nopar~nobra {-> expr}
 488         = {attr} recv~nopar~nobra attrid {-> New expr.attr(recv~nopar~nobra.expr, attrid)}
 489         | {call} recv~nopar~nobra id args {-> New expr.call(recv~nopar~nobra.expr, id, [args.expr], [])}
 490         | {super} qualified? kwsuper args {-> New expr.super(qualified, kwsuper, [args.expr])}
 491         | {init} recv~nopar~nobra kwinit args {-> New expr.init(recv~nopar~nobra.expr, kwinit, [args.expr])}
 492 !nobra  | {bra} expr_atom~nopar braargs {-> New expr.bra(expr_atom~nopar.expr, [braargs.expr], [])}
 493         | {new} kwnew no type~nobra dot [n2]:no id args {-> New expr.new(kwnew, type~nobra.type, id, [args.expr])}
 494 // FIXME: Why are these 3 !nopar mandatory?
 495 !nobra!nopar    | {range} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no cbra {-> New expr.crange(expr, expr2.expr)}
 496 !nobra!nopar    | {orange} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no [cbra]:obra  {-> New expr.orange(expr, expr2.expr)}
 497 !nobra!nopar    | {array} braargs {-> New expr.array([braargs.expr])}
 498         | {self} kwself {-> New expr.self(kwself)}
 499         | {true} kwtrue {-> New expr.true(kwtrue)}
 500         | {false} kwfalse {-> New expr.false(kwfalse)}
 501         | {null} kwnull {-> New expr.null(kwnull)}
 502         | {int} number  {-> New expr.int(number)}
 503         | {float} float  {-> New expr.float(float)}
 504         | {char} char  {-> New expr.char(char)}
 505         | {string} string  {-> New expr.string(string)}
 506         | {superstring} superstring  {-> superstring.expr}
 507 !nopar  | {par} opar expr cpar {-> expr}
 508         | {as_cast} expr_atom~nopar~nobra dot no kwas [n2]:no opar [n3]:no type [n4]:no cpar {-> New expr.as_cast(expr_atom~nopar~nobra.expr, kwas, type)}
 509         | {as_notnull} expr_atom~nopar~nobra dot no kwas [n2]:no opar [n3]:no kwnot [n4]:no kwnull [n5]:no cpar {-> New expr.as_notnull(expr_atom~nopar~nobra.expr, kwas, kwnot, kwnull)}
 510         ;
 511
 512 superstring {-> expr}
 513         = superstring_start superstring_middle* superstring_end {-> New expr.superstring([superstring_start.expr, superstring_middle.expr, superstring_end.expr])};
 514 superstring_start {-> expr*}
 515         = start_string_p no expr [n2]:no {-> [start_string_p.expr, expr]};
 516 start_string_p {-> expr}
 517         = start_string {-> New expr.start_string(start_string)};
 518 superstring_middle {-> expr*}
 519         = mid_string_p no expr [n2]:no {-> [mid_string_p.expr, expr]};
 520 mid_string_p {-> expr}
 521         = mid_string {-> New expr.mid_string(mid_string)};
 522 superstring_end {-> expr}
 523         = end_string {-> New expr.end_string(end_string)};
 524
 525 /* MISC **********************************************************************/
 526
 527 recv~nopar~nobra {-> expr}
 528         = expr_atom~nopar~nobra dot no {-> expr_atom~nopar~nobra.expr}
 529         | {implicit} {-> New expr.implicit_self()}
 530         ;
 531
 532 args {-> expr*}
 533         = opar no expr [n2]:no args_tail* cpar {-> [expr, args_tail.expr]}
 534         | {emptypar} opar no cpar {-> []}
 535         | {empty} {-> []}
 536         ;
 537 args_nopar {-> expr*}
 538         = opar no expr [n2]:no args_tail* cpar {-> [expr, args_tail.expr]}
 539         | {onearg} expr_nopar {-> [expr_nopar.expr]}
 540         | {emptypar} opar no cpar {-> []}
 541         | {empty} {-> []}
 542         ;
 543 braargs {-> expr*}
 544         = obra no expr [n2]:no args_tail* cbra {-> [expr, args_tail.expr]};
 545 args_tail {-> expr}
 546         = comma no expr [n2]:no {-> expr};
 547 idlist {-> id*}
 548         = opar idlist_nopar cpar {-> [idlist_nopar.id]}
 549         | {nopar} idlist_nopar {-> [idlist_nopar.id]}
 550         ;
 551 idlist_nopar {-> id*}
 552         = {single} id {-> [id]}
 553         | {more} idlist_nopar no comma [n2]:no id {-> [idlist_nopar.id, id]}
 554         ;
 555
 556 qualified
 557         = {cla} modquad* classquad {-> New qualified([modquad.id], classquad.classid)}
 558         | {mod} modquad+ {-> New qualified([modquad.id], Null)}
 559         ;
 560 modquad {-> id}
 561         = id quad no {-> id};
 562 classquad {-> classid}
 563         = classid quad no {-> classid};
 564
 565 n1      = {a} comment | {b} eol;
 566 n {-> doc?}
 567         = {a} n2? comment+ {-> New doc([comment])}
 568         | {b} n2 {-> Null}
 569         ;
 570 no {-> doc?}
 571         = {empty} {-> Null}
 572         | n {-> n.doc}
 573         ;
 574
 575 n2
 576         = {a} n2? comment+ eol+
 577         | {b} eol+
 578         ;
 579
 580 /*****************************************************************************/
 581 Abstract Syntax Tree
 582 /*****************************************************************************/
 583
 584 module  = moduledecl? [imports]:import* [classdefs]:classdef*;
 585
 586 moduledecl
 587         = doc? kwmodule id;
 588
 589 import  = {std} visibility kwimport id
 590         | {no} visibility kwimport kwend
 591         ;
 592
 593 visibility
 594         = {public}
 595         | {private} kwprivate
 596         | {protected} kwprotected
 597         | {intrude} kwintrude
 598         ;
 599
 600 classdef= {std} doc? kwredef? visibility classkind [id]:classid? [formaldefs]:formaldef* [superclasses]:superclass* [propdefs]:propdef*
 601         | {top} [propdefs]:propdef*
 602         | {main} [propdefs]:propdef*
 603         ;
 604 classkind
 605         = {concrete} kwclass
 606         | {abstract} kwabstract kwclass
 607         | {interface} kwinterface
 608         | {universal} kwuniversal
 609         ;
 610 formaldef = [id]:classid type?;
 611 superclass = kwspecial? kwsuper? type;
 612
 613
 614 propdef = {attr} doc? [readable]:able? [writable]:able? kwredef? visibility kwvar [id]:attrid? [id2]:id? type? expr?
 615         | {meth} doc? kwredef? visibility methid signature
 616         | {deferred_meth} doc? kwredef? visibility kwmeth methid signature
 617         | {intern_meth} doc? kwredef? visibility kwmeth methid signature
 618         | {extern_meth} doc? kwredef? visibility kwmeth methid signature [extern]:string?
 619         | {concrete_meth} doc? kwredef? visibility kwmeth methid signature [block]:expr?
 620         | {concrete_init} doc? kwredef? visibility kwinit methid? signature [block]:expr?
 621         | {main_meth} kwredef? [block]:expr?
 622         | {type} doc? kwredef? visibility kwtype [id]:classid type
 623         ;
 624
 625 able    = {read} kwredef? kwreadable
 626         | {write} kwredef? visibility? kwwritable
 627         ;
 628
 629 methid = {id} id | {plus} plus | {minus} minus | {star} star | {slash} slash | {percent} percent | {eq} eq | {ne} ne | {le} le | {ge} ge | {lt} lt | {gt} gt |  {ll} ll | {gg} gg | {bra} obra cbra | {starship} starship | {assign} id assign | {braassign} obra cbra assign;
 630
 631 signature = [params]:param* type? [closure_decls]:closure_decl*;
 632
 633 param   = id type? dotdotdot?
 634         ;
 635
 636 closure_decl = kwbreak? bang id signature expr?
 637         ;
 638
 639 type    = kwnullable? [id]:classid [types]:type*;
 640
 641 label = kwlabel id;
 642
 643 expr    = {block} expr*
 644         | {vardecl} kwvar id type? assign? expr?
 645         | {return} kwreturn? expr?
 646         | {break} kwbreak label? expr?
 647         | {abort} kwabort
 648         | {continue} kwcontinue? label? expr?
 649         | {do} kwdo [block]:expr? label?
 650         | {if} kwif expr [then]:expr? [else]:expr?
 651         | {ifexpr} kwif expr kwthen [then]:expr kwelse [else]:expr
 652         | {while} kwwhile expr kwdo [block]:expr? label?
 653         | {loop} kwloop [block]:expr? label?
 654         | {for} kwfor id expr kwdo [block]:expr? label?
 655         | {assert} kwassert id? expr [else]:expr?
 656         | {once} kwonce expr
 657         | {send} expr
 658         | {binop} expr [expr2]:expr
 659         | {or} expr [expr2]:expr
 660         | {and} expr [expr2]:expr
 661         | {or_else} expr [expr2]:expr
 662         | {not} kwnot expr
 663         | {eq} expr [expr2]:expr
 664         | {ee} expr [expr2]:expr
 665         | {ne} expr [expr2]:expr
 666         | {lt} expr [expr2]:expr
 667         | {le} expr [expr2]:expr
 668         | {ll} expr [expr2]:expr
 669         | {gt} expr [expr2]:expr
 670         | {ge} expr [expr2]:expr
 671         | {gg} expr [expr2]:expr
 672         | {isa} expr type
 673         | {plus} expr [expr2]:expr
 674         | {minus} expr [expr2]:expr
 675         | {starship} expr [expr2]:expr
 676         | {star} expr [expr2]:expr
 677         | {slash} expr [expr2]:expr
 678         | {percent} expr [expr2]:expr
 679         | {uminus} minus expr
 680         | {new} kwnew type id? [args]:expr*
 681         | {attr} expr [id]:attrid
 682         | {attr_assign} expr [id]:attrid assign [value]:expr
 683         | {attr_reassign} expr [id]:attrid assign_op [value]:expr
 684         | {call} expr id [args]:expr* [closure_defs]:closure_def*
 685         | {call_assign} expr id [args]:expr* assign [value]:expr
 686         | {call_reassign} expr id [args]:expr* assign_op [value]:expr
 687         | {super} qualified? kwsuper [args]:expr*
 688         | {init} expr kwinit [args]:expr*
 689         | {bra} expr [args]:expr* [closure_defs]:closure_def*
 690         | {bra_assign} expr [args]:expr* assign [value]:expr
 691         | {bra_reassign} expr [args]:expr* assign_op [value]:expr
 692         | {closure_call} id [args]:expr* [closure_defs]:closure_def*
 693         | {var} id
 694         | {var_assign} id assign [value]:expr
 695         | {var_reassign} id assign_op [value]:expr
 696         | {range} expr [expr2]:expr
 697         | {crange} expr [expr2]:expr
 698         | {orange} expr [expr2]:expr
 699         | {array} [exprs]:expr*
 700         | {self} kwself
 701         | {implicit_self}
 702         | {true} kwtrue
 703         | {false} kwfalse
 704         | {null} kwnull
 705         | {int} number
 706         | {float} float
 707         | {char} char
 708         | {string} string
 709         | {start_string} [string]:start_string
 710         | {mid_string} [string]:mid_string
 711         | {end_string} [string]:end_string
 712         | {superstring} [exprs]:expr*
 713         | {par} expr
 714         | {as_cast} expr kwas type
 715         | {as_notnull} expr kwas kwnot kwnull
 716         | {isset_attr} kwisset expr [id]:attrid
 717         ;
 718 assign_op
 719         = {plus} pluseq
 720         | {minus} minuseq
 721         ;
 722
 723 closure_def
 724         = bang [id]:closure_id [ids]:id* kwdo? expr? label?
 725         ;
 726 closure_id
 727         = {simple} id
 728         | {break} kwbreak
 729         ;
 730
 731 qualified = id* classid? ;
 732
 733 doc = comment+;
 734
 735 /*****************************************************************************/
 736