src/doc/html_templates/html_templates.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 # http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Introduces templates that compose the documentation HTML rendering.
  16 module html_templates
  17
  18 import html_model
  19 import html::bootstrap
  20 import doc_phases::doc_structure
  21 import doc_phases::doc_hierarchies
  22 import doc_phases::doc_graphs
  23 import doc_phases::doc_intros_redefs
  24 import doc_phases::doc_lin
  25
  26 # Renders the page as HTML.
  27 redef class DocPage
  28         super Template
  29
  30         # Page url.
  31         var html_url: String is writable, noinit
  32
  33         # Directory where css, js and other assets can be found.
  34         var shareurl: String is writable, noinit
  35
  36         # Attributes of the body tag element.
  37         var body_attrs = new Array[TagAttribute]
  38
  39         # Top menu template if any.
  40         var topmenu: DocTopMenu is writable, noinit
  41
  42         # Sidebar template if any.
  43         var sidebar: nullable DocSideBar = null is writable
  44
  45         # Footer content if any.
  46         var footer: nullable Writable = null is writable
  47
  48         # JS scripts to append at the end of the body
  49         var scripts = new Array[TplScript]
  50
  51         # Renders the html `<head>`.
  52         private fun render_head do
  53                 var css = (self.shareurl / "css").html_escape
  54                 var vendors = (self.shareurl / "vendors").html_escape
  55
  56                 addn "<!DOCTYPE html>"
  57                 addn "<head>"
  58                 addn " <meta charset='utf-8'/>"
  59                 addn " <!--link rel='stylesheet' href='{css}/Nitdoc.UI.css' type='text/css'/-->"
  60                 addn " <link rel='stylesheet' href='{vendors}/bootstrap/css/bootstrap.min.css'/>"
  61                 addn " <link rel='stylesheet' href='{css}/nitdoc.bootstrap.css'/>"
  62                 addn " <link rel='stylesheet' href='{css}/nitdoc.css'/>"
  63                 addn " <link rel='stylesheet' href='{css}/Nitdoc.QuickSearch.css'/>"
  64                 addn " <link rel='stylesheet' href='{css}/Nitdoc.ModalBox.css'/>"
  65                 addn " <link rel='stylesheet' href='{css}/Nitdoc.GitHub.css'/>"
  66                 addn " <title>{title.html_escape}</title>"
  67                 addn "</head>"
  68                 add "<body"
  69                 for attr in body_attrs do add attr
  70                 addn ">"
  71         end
  72
  73         # Renders the footer and content.
  74         private fun render_content do
  75                 add root
  76                 if footer != null then
  77                         addn "<div class='well footer'>"
  78                         add footer.as(not null)
  79                         addn "</div>"
  80                 end
  81         end
  82
  83         # Render JS scripts
  84         private fun render_footer do
  85                 var vendors = (self.shareurl / "vendors").html_escape
  86                 var js = (self.shareurl / "js").html_escape
  87
  88                 addn "<script src='{vendors}/jquery/jquery-1.11.1.min.js'></script>"
  89                 addn "<script src='{vendors}/jquery/jquery-ui-1.10.4.custom.min.js'></script>"
  90                 addn "<script src='{vendors}/bootstrap/js/bootstrap.min.js'></script>"
  91                 addn "<script data-main='{js}/nitdoc' src='{js}/lib/require.js'></script>"
  92                 for script in scripts do add script
  93                 addn """<script>
  94                         $(function () {
  95                                 $("[data-toggle='tooltip']").tooltip();
  96                                 $("[data-toggle='popover']").popover();
  97                         });
  98                 </script>"""
  99                 addn "</body>"
 100                 addn "</html>"
 101         end
 102
 103         # Render the whole page
 104         redef fun rendering do
 105                 render_head
 106                 addn "<div class='container-fluid'>"
 107                 addn " <div class='row'>"
 108                 add topmenu
 109                 addn " </div>"
 110                 addn " <div class='row' id='content'>"
 111                 var sidebar = self.sidebar
 112                 if sidebar != null then
 113                         addn "<div class='col col-xs-3 col-lg-2'>"
 114                         add sidebar
 115                         addn "</div>"
 116                         addn "<div class='col col-xs-9 col-lg-10' data-spy='scroll' data-target='.summary'>"
 117                         render_content
 118                         addn "</div>"
 119                 else
 120                         addn "<div class='col col-xs-12'>"
 121                         render_content
 122                         addn "</div>"
 123                 end
 124                 addn " </div>"
 125                 addn "</div>"
 126                 render_footer
 127         end
 128
 129         # Render table of content for this page.
 130         fun html_toc: UnorderedList do
 131                 var lst = new UnorderedList
 132                 lst.css_classes.add "nav"
 133                 for child in root.children do
 134                         child.render_toc_item(lst)
 135                 end
 136                 return lst
 137         end
 138 end
 139
 140 # Top menu bar template.
 141 #
 142 # FIXME should be a Bootstrap component template
 143 # At this moment, the topmenu structure stills to specific to Nitdoc to use the
 144 # generic component.
 145 class DocTopMenu
 146         super UnorderedList
 147
 148         # Brand link to display in first position of the top menu.
 149         #
 150         # This is where you want to put your logo.
 151         var brand: nullable Writable is noinit, writable
 152
 153         # Active menu item.
 154         #
 155         # Depends on the current page, this allows to hilighted the current item.
 156         #
 157         # FIXME should be using Boostrap breadcrumbs component.
 158         # This will still like this to avoid diff and be changed in further fixes
 159         # when we will modify the output.
 160         var active_item: nullable ListItem is noinit, writable
 161
 162         redef fun rendering do
 163                 addn "<nav id='topmenu' class='navbar navbar-default navbar-fixed-top' role='navigation'>"
 164                 addn " <div class='container-fluid'>"
 165                 addn "  <div class='navbar-header'>"
 166                 add "   <button type='button' class='navbar-toggle' "
 167                 addn "       data-toggle='collapse' data-target='#topmenu-collapse'>"
 168                 addn "    <span class='sr-only'>Toggle menu</span>"
 169                 addn "    <span class='icon-bar'></span>"
 170                 addn "    <span class='icon-bar'></span>"
 171                 addn "    <span class='icon-bar'></span>"
 172                 addn "   </button>"
 173                 if brand != null then
 174                         add "<span class='navbar-brand'>"
 175                         add brand.write_to_string
 176                         add "</span>"
 177                 end
 178                 addn "  </div>"
 179                 addn "  <div class='collapse navbar-collapse' id='topmenu-collapse'>"
 180                 addn "   <ul class='nav navbar-nav'>"
 181                 for item in items do
 182                         if item == active_item then item.css_classes.add "active"
 183                         add item.write_to_string
 184                 end
 185                 addn "   </ul>"
 186                 addn "  </div>"
 187                 addn " </div>"
 188                 addn "</nav>"
 189         end
 190 end
 191
 192 # Nitdoc sidebar template.
 193 class DocSideBar
 194         super Template
 195
 196         # Sidebar contains `DocSideBox`.
 197         var boxes = new Array[DocSideBox]
 198
 199         redef fun rendering do
 200                 if boxes.is_empty then return
 201                 addn "<div id='sidebar'>"
 202                 for box in boxes do add box
 203                 addn "</div>"
 204         end
 205 end
 206
 207 # Something that can be put in a DocSideBar.
 208 class DocSideBox
 209         super Template
 210
 211         # Box HTML id, used for Bootstrap collapsing feature.
 212         #
 213         # Use `html_title.to_cmangle` by default.
 214         var id: String is lazy do return title.write_to_string.to_cmangle
 215
 216         # Title of the box to display.
 217         var title: Writable
 218
 219         # Content to display in the box.
 220         var content: Writable
 221
 222         # Is the box opened by default?
 223         #
 224         # Otherwise, the user will have to clic on the title to display the content.
 225         #
 226         # Default is `true`.
 227         var is_open = true is writable
 228
 229         redef fun rendering do
 230                 var open = ""
 231                 if is_open then open = "in"
 232                 addn "<div class='panel'>"
 233                 addn " <div class='panel-heading'>"
 234                 add "  <a data-toggle='collapse' data-parent='#sidebar'"
 235                 add "   data-target='#box_{id}' href='#'>"
 236                 add title
 237                 addn "  </a>"
 238                 addn " </div>"
 239                 addn " <div id='box_{id}' class='summary panel-body collapse {open}'>"
 240                 add content
 241                 addn " </div>"
 242                 addn "</div>"
 243         end
 244 end
 245
 246 redef class DocComposite
 247         super Template
 248
 249         # HTML anchor id
 250         var html_id: String is writable, lazy do return id
 251
 252         # Title to display if any.
 253         #
 254         # This title can be decorated with HTML.
 255         var html_title: nullable Writable is writable, lazy do return title
 256
 257         # Subtitle to display if any.
 258         var html_subtitle: nullable Writable is noinit, writable
 259
 260         # Render the element title and subtitle.
 261         private fun render_title do
 262                 if html_title != null then
 263                 var header = new Header(hlvl, html_title.write_to_string)
 264                 header.css_classes.add "signature"
 265                 if hlvl == 2 then header.css_classes.add "well well-sm"
 266                 addn header
 267                 end
 268                 if html_subtitle != null then
 269                         addn "<div class='info subtitle'>"
 270                         addn html_subtitle.write_to_string
 271                         addn "</div>"
 272                 end
 273         end
 274
 275         # Render the element body.
 276         private fun render_body do
 277                 for child in children do addn child.write_to_string
 278         end
 279
 280         redef fun rendering do
 281                 if is_hidden then return
 282                 render_title
 283                 render_body
 284         end
 285
 286         # Level <hX> for HTML heading.
 287         private fun hlvl: Int do return depth
 288
 289         # A short, undecorated title that goes in the table of contents.
 290         #
 291         # By default, returns `html_title.to_s`, subclasses should redefine it.
 292         var html_toc_title: nullable String is lazy, writable do
 293                 if html_title == null then return toc_title
 294                 return html_title.write_to_string
 295         end
 296
 297         # Render this element in a table of contents.
 298         private fun render_toc_item(lst: UnorderedList) do
 299                 if is_toc_hidden or html_toc_title == null then return
 300
 301                 var content = new Template
 302                 content.add new Link("#{html_id}", html_toc_title.to_s)
 303                 if not children.is_empty then
 304                         var sublst = new UnorderedList
 305                         sublst.css_classes.add "nav"
 306                         for child in children do
 307                                 child.render_toc_item(sublst)
 308                         end
 309                         content.add sublst
 310                 end
 311                 lst.add_li new ListItem(content)
 312         end
 313
 314         # ID used in HTML tab labels.
 315         #
 316         # We sanitize it for Boostrap JS panels that do not like ":" and "." in ids.
 317         var html_tab_id: String is lazy do
 318                 var id = html_id.replace(":", "")
 319                 id = id.replace(".", "")
 320                 return "{id}-tab"
 321         end
 322 end
 323
 324 redef class DocRoot
 325         redef fun rendering do
 326                 for child in children do addn child.write_to_string
 327         end
 328 end
 329
 330 redef class DocSection
 331         super BSComponent
 332
 333         redef fun rendering do
 334                 if is_hidden then
 335                         addn "<a id=\"{html_id}\"></a>"
 336                         return
 337                 end
 338                 addn "<section{render_css_classes} id=\"{html_id}\">"
 339                 render_title
 340                 render_body
 341                 addn "</section>"
 342         end
 343 end
 344
 345 redef class DocArticle
 346         super BSComponent
 347
 348         redef fun rendering do
 349                 if is_hidden then return
 350                 addn "<article{render_css_classes} id=\"{html_id}\">"
 351                 render_title
 352                 render_body
 353                 addn "</article>"
 354         end
 355 end
 356
 357 redef class TabbedGroup
 358         redef fun render_body do
 359                 var tabs = new DocTabs("{html_id}.tabs", "")
 360                 for child in children do
 361                         if child.is_hidden then continue
 362                         var title = child.html_toc_title or else child.toc_title or else ""
 363                         tabs.add_panel new DocTabPanel(child.html_tab_id, title, child)
 364                 end
 365                 addn tabs
 366         end
 367 end
 368
 369 redef class PanelGroup
 370         redef var html_title = null
 371         redef var toc_title is lazy do return title or else ""
 372         redef var is_toc_hidden = true
 373 end
 374
 375 redef class HomeArticle
 376         redef var html_title = "Overview"
 377
 378         # HTML content to display on the home page.
 379         #
 380         # This attribute is set by the `doc_render` phase who knows the context.
 381         var content: nullable String is noinit, writable
 382
 383         redef fun render_body do
 384                 var content = self.content
 385                 if content != null then add content
 386                 super
 387         end
 388 end
 389
 390 redef class IndexArticle
 391         redef var html_title = "Index"
 392
 393         redef fun render_body do
 394                 addn "<div class='container-fluid'>"
 395                 addn " <div class='row'>"
 396                 render_list("Modules", mmodules)
 397                 render_list("Classes", mclasses)
 398                 render_list("Properties", mprops)
 399                 addn "</div>"
 400                 addn "</div>"
 401         end
 402
 403         # Displays a list from the content of `mentities`.
 404         private fun render_list(title: String, mentities: Array[MEntity]) do
 405                 if mentities.is_empty then return
 406                 addn "<div class='col-xs-4'>"
 407                 addn new Header(3, title)
 408                 var lst = new UnorderedList
 409                 for mentity in mentities do
 410                         if mentity isa MProperty then
 411                                 var tpl = new Template
 412                                 tpl.add mentity.intro.html_link
 413                                 tpl.add " ("
 414                                 tpl.add mentity.intro.mclassdef.mclass.html_link
 415                                 tpl.add ")"
 416                                 lst.add_li new ListItem(tpl)
 417                         else
 418                                 lst.add_li new ListItem(mentity.html_link)
 419                         end
 420                 end
 421                 addn lst
 422                 addn "</div>"
 423         end
 424 end
 425
 426 redef class MEntityComposite
 427         redef var html_title is lazy do return mentity.nitdoc_name
 428 end
 429
 430 redef class MEntitySection
 431         redef var html_title is lazy do return mentity.html_name
 432         redef var html_subtitle is lazy do return mentity.html_declaration
 433 end
 434
 435 redef class ConcernSection
 436         redef var html_title is lazy do return "in {mentity.nitdoc_name}"
 437 end
 438
 439 redef class ImportationListSection
 440         redef var html_title is lazy do return "Dependencies"
 441 end
 442
 443 redef class InheritanceListSection
 444         redef var html_title is lazy do return "Inheritance"
 445 end
 446
 447 redef class IntroArticle
 448         redef var html_title = null
 449
 450         # Link to source to display if any.
 451         var html_source_link: nullable Writable is noinit, writable
 452
 453         redef fun render_body do
 454                 var tabs = new DocTabs("{html_id}.tabs", "")
 455                 var comment = mentity.html_comment
 456                 if comment != null then
 457                         tabs.add_panel new DocTabPanel("{html_tab_id}-comment", "Comment", comment)
 458                 end
 459                 for child in children do
 460                         if child.is_hidden then continue
 461                         var title = child.html_toc_title or else child.toc_title or else ""
 462                         tabs.add_panel new DocTabPanel(child.html_tab_id, title, child)
 463                 end
 464                 var lnk = html_source_link
 465                 if lnk != null then
 466                         tabs.drop_list.items.add new ListItem(lnk)
 467                 end
 468                 addn tabs
 469         end
 470 end
 471
 472 redef class ConcernsArticle
 473         redef var html_title = "Concerns"
 474         redef fun render_body do add concerns.html_list
 475 end
 476
 477 redef class DefinitionListArticle
 478         redef var html_title is lazy do
 479                 var title = new Template
 480                 title.add mentity.html_icon
 481                 title.add mentity.html_link
 482                 return title
 483         end
 484
 485         redef var html_subtitle is lazy do return mentity.html_namespace
 486         redef var html_toc_title is lazy do return mentity.html_name
 487 end
 488
 489 redef class DefinitionArticle
 490         redef var html_title is lazy do return mentity.html_name
 491         redef var html_subtitle is lazy do return mentity.html_declaration
 492
 493         # Does `self` display only it's title and no body?
 494         #
 495         # FIXME diff hack
 496         var is_no_body: Bool = false is writable
 497
 498         # Does `self` display only the short content as definition?
 499         #
 500         # FIXME diff hack
 501         var is_short_comment: Bool = false is writable
 502
 503         # Link to source to display if any.
 504         var html_source_link: nullable Writable is noinit, writable
 505
 506         redef fun render_body do
 507                 var tabs = new DocTabs("{html_id}.tabs", "")
 508                 if not is_no_body then
 509                         var comment
 510                         if is_short_comment then
 511                                 comment = mentity.html_short_comment
 512                         else
 513                                 comment = mentity.html_comment
 514                         end
 515                         if comment != null then
 516                                 tabs.add_panel new DocTabPanel("{html_tab_id}-comment", "Comment", comment)
 517                         end
 518                 end
 519                 for child in children do
 520                         if child.is_hidden then continue
 521                         var title = child.html_toc_title or else child.toc_title or else ""
 522                         tabs.add_panel new DocTabPanel(child.html_tab_id, title, child)
 523                 end
 524                 var lnk = html_source_link
 525                 if lnk != null then
 526                         tabs.drop_list.items.add new ListItem(lnk)
 527                 end
 528                 addn tabs
 529         end
 530 end
 531
 532 redef class IntrosRedefsSection
 533         redef var toc_title do return "Intros / Redefs"
 534         redef var html_title = null
 535         redef var html_subtitle = null
 536 end
 537
 538 redef class MEntitiesListArticle
 539         redef fun render_body do
 540                 var lst = new UnorderedList
 541                 lst.css_classes.add "list-unstyled list-definition"
 542                 for mentity in mentities do
 543                         lst.add_li mentity.html_list_item
 544                 end
 545                 add lst
 546         end
 547 end
 548
 549 redef class DefinitionLinArticle
 550         redef var html_title is lazy do return "Linearization"
 551
 552         redef fun render_body do
 553                 var lst = new UnorderedList
 554                 lst.css_classes.add "list-unstyled list-labeled"
 555                 for mentity in mentities do
 556                         if not mentity isa MPropDef then continue # TODO handle all mentities
 557                         var tpl = new Template
 558                         tpl.add mentity.mclassdef.html_namespace
 559                         var comment = mentity.mclassdef.html_short_comment
 560                         if comment != null then
 561                                 tpl.add ": "
 562                                 tpl.add comment
 563                         end
 564                         var li = new ListItem(tpl)
 565                         li.css_classes.add "signature"
 566                         lst.add_li li
 567                 end
 568                 add lst
 569         end
 570 end
 571
 572 redef class GraphArticle
 573         redef var html_title = null
 574
 575         # HTML map used to display link.
 576         #
 577         # This attribute is set by the `doc_render` phase who knows the context.
 578         var map: String is noinit, writable
 579
 580         redef fun render_body do
 581                 addn "<div class=\"text-center\">"
 582                 addn " <img src='{graph_id}.png' usemap='#{graph_id}' style='margin:auto'"
 583                 addn "  alt='{title or else ""}'/>"
 584                 add map
 585                 addn "</div>"
 586         end
 587 end