src/nitcatalog.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Basic catalog generator for Nit packages
  16 #
  17 # See: <http://nitlanguage.org/catalog/>
  18 #
  19 # The tool scans packages and generates the HTML files of a catalog.
  20 #
  21 # See `catalog` for details
  22 module nitcatalog
  23
  24 import loader # Scan&load packages, groups and modules
  25 import doc::doc_down # Display mdoc
  26 import catalog
  27
  28 # A HTML page in a catalog
  29 #
  30 # This is just a template with the header pre-filled and the footer injected at rendering.
  31 # Therefore, once instantiated, the content can just be added to it.
  32 class CatalogPage
  33         super Template
  34
  35         # The associated catalog, used to groups options and other global data
  36         var catalog: Catalog
  37
  38         # Placeholder to include additional things before the `</head>`.
  39         var more_head = new Template
  40
  41         # Relative path to the root directory (with the index file).
  42         #
  43         # Use "" for pages in the root directory
  44         # Use ".." for pages in a subdirectory
  45         var rootpath: String
  46
  47         redef init
  48         do
  49                 add """
  50 <!DOCTYPE html>
  51 <html>
  52 <head>
  53         <meta charset="utf-8">
  54         <link rel="stylesheet" media="all" href="https://maxcdn.bootstrapcdn.com/bootstrap/3.3.1/css/bootstrap.min.css">
  55         <link rel="stylesheet" media="all" href="{{{rootpath / "style.css"}}}">
  56 """
  57                 add more_head
  58
  59                 add """
  60 </head>
  61 <body>
  62 <div class='container-fluid'>
  63  <div class='row'>
  64   <nav id='topmenu' class='navbar navbar-default navbar-fixed-top' role='navigation'>
  65    <div class='container-fluid'>
  66     <div class='navbar-header'>
  67      <button type='button' class='navbar-toggle' data-toggle='collapse' data-target='#topmenu-collapse'>
  68       <span class='sr-only'>Toggle menu</span>
  69       <span class='icon-bar'></span>
  70       <span class='icon-bar'></span>
  71       <span class='icon-bar'></span>
  72      </button>
  73      <span class='navbar-brand'><a href="http://nitlanguage.org/">Nitlanguage.org</a></span>
  74     </div>
  75     <div class='collapse navbar-collapse' id='topmenu-collapse'>
  76      <ul class='nav navbar-nav'>
  77       <li><a href="{{{rootpath / "index.html"}}}">Catalog</a></li>
  78      </ul>
  79     </div>
  80    </div>
  81   </nav>
  82  </div>
  83 """
  84         end
  85
  86         # Inject piwik HTML code if required
  87         private fun add_piwik
  88         do
  89                 var tracker_url = catalog.piwik_tracker
  90                 if tracker_url == null then return
  91
  92                 var site_id = catalog.piwik_site_id
  93
  94                 tracker_url = tracker_url.trim
  95                 if tracker_url.chars.last != '/' then tracker_url += "/"
  96                 add """
  97 <!-- Piwik -->
  98 <script type="text/javascript">
  99 var _paq = _paq || [];
 100 _paq.push(['trackPageView']);
 101 _paq.push(['enableLinkTracking']);
 102 (function() {
 103 var u=(("https:" == document.location.protocol) ? "https" : "http") + "://{{{tracker_url.escape_to_c}}}";
 104 _paq.push(['setTrackerUrl', u+'piwik.php']);
 105 _paq.push(['setSiteId', {{{site_id}}}]);
 106 var d=document, g=d.createElement('script'), s=d.getElementsByTagName('script')[0]; g.type='text/javascript';
 107 g.defer=true; g.async=true; g.src=u+'piwik.js'; s.parentNode.insertBefore(g,s);
 108 })();
 109
 110 </script>
 111 <noscript><p><img src="http://{{{tracker_url.html_escape}}}piwik.php?idsite={{{site_id}}}" style="border:0;" alt="" /></p></noscript>
 112 <!-- End Piwik Code -->
 113 """
 114
 115         end
 116
 117         redef fun rendering
 118         do
 119                 add """
 120 </div> <!-- container-fluid -->
 121 <script src='https://code.jquery.com/jquery-latest.min.js'></script>
 122 <script src='https://maxcdn.bootstrapcdn.com/bootstrap/3.3.1/js/bootstrap.min.js'></script>
 123 <script src='https://cdnjs.cloudflare.com/ajax/libs/bootstrap-table/1.8.1/bootstrap-table-all.min.js'></script>
 124 """
 125                 add_piwik
 126                 add """
 127
 128 </body>
 129 </html>
 130 """
 131         end
 132 end
 133
 134 redef class NitdocDecorator
 135         redef fun add_image(v, link, name, comment)
 136         do
 137                 # Keep absolute links as is
 138                 if link.has_prefix("http://") or link.has_prefix("https://") then
 139                         super
 140                         return
 141                 end
 142
 143                 do
 144                         # Get the directory of the doc object to deal with the relative link
 145                         var mdoc = current_mdoc
 146                         if mdoc == null then break
 147                         var source = mdoc.location.file
 148                         if source == null then break
 149                         var path = source.filename
 150                         var stat = path.file_stat
 151                         if stat == null then break
 152                         if not stat.is_dir then path = path.dirname
 153
 154                         # Get the full path to the local resource
 155                         var fulllink = path / link.to_s
 156                         stat = fulllink.file_stat
 157                         if stat == null then break
 158
 159                         # Get a collision-free catalog name for the resource
 160                         var hash = fulllink.md5
 161                         var ext = fulllink.file_extension
 162                         if ext != null then hash = hash + "." + ext
 163
 164                         # Copy the local resource in the resource directory of the catalog
 165                         var res = catalog.outdir / "res" / hash
 166                         fulllink.file_copy_to(res)
 167
 168                         # Hijack the link in the html.
 169                         link = ".." / "res" / hash
 170                         super(v, link, name, comment)
 171                         return
 172                 end
 173
 174                 # Something went bad
 175                 catalog.modelbuilder.toolcontext.error(current_mdoc.location, "Error: cannot find local image `{link}`")
 176                 super
 177         end
 178
 179         # The registered catalog
 180         #
 181         # It is used to deal with relative links in images.
 182         var catalog: Catalog is noautoinit
 183 end
 184
 185 redef class Catalog
 186         redef init
 187         do
 188                 # Register `self` to the global NitdocDecorator
 189                 # FIXME this is ugly. But no better idea at the moment.
 190                 modelbuilder.model.nitdoc_md_processor.emitter.decorator.as(NitdocDecorator).catalog = self
 191         end
 192
 193         # The output directory where to generate pages
 194         var outdir: String is noautoinit
 195
 196         # Return a empty `CatalogPage`.
 197         fun new_page(rootpath: String): CatalogPage
 198         do
 199                 return new CatalogPage(self, rootpath)
 200         end
 201
 202         # Recursively generate a level in the file tree of the *content* section
 203         private fun gen_content_level(ot: OrderedTree[MConcern], os: Array[Object], res: Template)
 204         do
 205                 res.add "<ul>\n"
 206                 for o in os do
 207                         res.add "<li>"
 208                         if o isa MGroup then
 209                                 var d = ""
 210                                 var mdoc = o.mdoc
 211                                 if mdoc != null then d = ": {mdoc.html_synopsis.write_to_string}"
 212                                 res.add "<strong>{o.name}</strong>{d} ({o.filepath.to_s})"
 213                         else if o isa MModule then
 214                                 var d = ""
 215                                 var mdoc = o.mdoc
 216                                 if mdoc != null then d = ": {mdoc.html_synopsis.write_to_string}"
 217                                 res.add "<strong>{o.name}</strong>{d} ({o.filepath.to_s})"
 218                         else
 219                                 abort
 220                         end
 221                         var subs = ot.sub.get_or_null(o)
 222                         if subs != null then gen_content_level(ot, subs, res)
 223                         res.add "</li>\n"
 224                 end
 225                 res.add "</ul>\n"
 226         end
 227
 228         # Generate a full HTML page for a package
 229         fun generate_page(mpackage: MPackage): Writable
 230         do
 231                 var res = new_page("..")
 232                 var name = mpackage.name.html_escape
 233                 res.more_head.add """<title>{{{name}}}</title>"""
 234
 235                 res.add """
 236 <div class="content">
 237 <h1 class="package-name">{{{name}}}</h1>
 238 """
 239                 var mdoc = mpackage.mdoc_or_fallback
 240                 if mdoc != null then res.add mdoc.html_documentation
 241
 242                 res.add "<h2>Content</h2>"
 243                 var ot = new OrderedTree[MConcern]
 244                 for g in mpackage.mgroups do
 245                         var pa = g.parent
 246                         if g.is_interesting then
 247                                 ot.add(pa, g)
 248                                 pa = g
 249                         end
 250                         for mp in g.mmodules do
 251                                 ot.add(pa, mp)
 252                         end
 253                 end
 254                 ot.sort_with(alpha_comparator)
 255                 gen_content_level(ot, ot.roots, res)
 256
 257
 258                 res.add """
 259 </div>
 260 <div class="sidebar">
 261 <ul class="box">
 262 """
 263                 var tryit = mpackage.metadata("upstream.tryit")
 264                 if tryit != null then
 265                         var e = tryit.html_escape
 266                         res.add "<li><a href=\"{e}\">Try<span style=\"color:white\">n</span>it!</a></li>\n"
 267                 end
 268                 var apk = mpackage.metadata("upstream.apk")
 269                 if apk != null then
 270                         var e = apk.html_escape
 271                         res.add "<li><a href=\"{e}\">Android apk</a></li>\n"
 272                 end
 273
 274                 res.add """</ul>\n<ul class="box">\n"""
 275
 276                 var homepage = mpackage.metadata("upstream.homepage")
 277                 if homepage != null then
 278                         var e = homepage.html_escape
 279                         res.add "<li><a href=\"{e}\">{e}</a></li>\n"
 280                 end
 281                 for maintainer in mpackage.maintainers do
 282                         res.add "<li>{maintainer.to_html}</li>"
 283                 end
 284                 var license = mpackage.metadata("package.license")
 285                 if license != null then
 286                         var e = license.html_escape
 287                         res.add "<li><a href=\"http://opensource.org/licenses/{e}\">{e}</a> license</li>\n"
 288                 end
 289                 res.add "</ul>\n"
 290
 291                 res.add "<h3>Source Code</h3>\n<ul class=\"box\">\n"
 292                 var browse = mpackage.metadata("upstream.browse")
 293                 if browse != null then
 294                         var e = browse.html_escape
 295                         res.add "<li><a href=\"{e}\">{e}</a></li>\n"
 296                 end
 297                 var git = mpackage.metadata("upstream.git")
 298                 if git != null then
 299                         var e = git.html_escape
 300                         res.add "<li><tt>{e}</tt></li>\n"
 301                 end
 302                 var last_date = mpackage.last_date
 303                 if last_date != null then
 304                         var e = last_date.html_escape
 305                         res.add "<li>most recent commit: {e}</li>\n"
 306                 end
 307                 var first_date = mpackage.first_date
 308                 if first_date != null then
 309                         var e = first_date.html_escape
 310                         res.add "<li>oldest commit: {e}</li>\n"
 311                 end
 312                 var commits = commits[mpackage]
 313                 if commits != 0 then
 314                         res.add "<li>{commits} commits</li>\n"
 315                 end
 316                 res.add "</ul>\n"
 317
 318                 res.add "<h3>Tags</h3>\n"
 319                 var ts2 = new Array[String]
 320                 for t in mpackage.tags do
 321                         t = t.html_escape
 322                         ts2.add "<a href=\"../index.html#tag_{t}\">{t}</a>"
 323                 end
 324                 res.add_list(ts2, ", ", ", ")
 325
 326                 if deps.has(mpackage) then
 327                         var reqs = deps[mpackage].greaters.to_a
 328                         reqs.remove(mpackage)
 329                         alpha_comparator.sort(reqs)
 330                         res.add "<h3>Requirements</h3>\n"
 331                         if reqs.is_empty then
 332                                 res.add "none"
 333                         else
 334                                 var list = new Array[String]
 335                                 for r in reqs do
 336                                         var direct = deps.has_direct_edge(mpackage, r)
 337                                         var s = "<a href=\"{r}.html\">"
 338                                         if direct then s += "<strong>"
 339                                         s += r.to_s
 340                                         if direct then s += "</strong>"
 341                                         s += "</a>"
 342                                         list.add s
 343                                 end
 344                                 res.add_list(list, ", ", " and ")
 345                         end
 346
 347                         reqs = deps[mpackage].smallers.to_a
 348                         reqs.remove(mpackage)
 349                         alpha_comparator.sort(reqs)
 350                         res.add "<h3>Clients</h3>\n"
 351                         if reqs.is_empty then
 352                                 res.add "none"
 353                         else
 354                                 var list = new Array[String]
 355                                 for r in reqs do
 356                                         var direct = deps.has_direct_edge(r, mpackage)
 357                                         var s = "<a href=\"{r}.html\">"
 358                                         if direct then s += "<strong>"
 359                                         s += r.to_s
 360                                         if direct then s += "</strong>"
 361                                         s += "</a>"
 362                                         list.add s
 363                                 end
 364                                 res.add_list(list, ", ", " and ")
 365                         end
 366                 end
 367
 368                 var contributors = mpackage.contributors
 369                 if not contributors.is_empty then
 370                         res.add "<h3>Contributors</h3>\n<ul class=\"box\">"
 371                         for c in contributors do
 372                                 res.add "<li>{c.to_html}</li>"
 373                         end
 374                         res.add "</ul>"
 375                 end
 376
 377                 res.add """
 378 <h3>Stats</h3>
 379 <ul class="box">
 380 <li>{{{mmodules[mpackage]}}} modules</li>
 381 <li>{{{mclasses[mpackage]}}} classes</li>
 382 <li>{{{mmethods[mpackage]}}} methods</li>
 383 <li>{{{loc[mpackage]}}} lines of code</li>
 384 </ul>
 385 """
 386
 387                 res.add """
 388 </div>
 389 """
 390                 return res
 391         end
 392
 393         # Return a short HTML sequence for a package
 394         #
 395         # Intended to use in lists.
 396         fun li_package(p: MPackage): String
 397         do
 398                 var res = ""
 399                 var f = "p/{p.name}.html"
 400                 res += "<a href=\"{f}\">{p}</a>"
 401                 var d = p.mdoc_or_fallback
 402                 if d != null then res += " - {d.html_synopsis.write_to_string}"
 403                 return res
 404         end
 405
 406         # List packages by group.
 407         #
 408         # For each key of the `map` a `<h3>` is generated.
 409         # Each package is then listed.
 410         #
 411         # The list of keys is generated first to allow fast access to the correct `<h3>`.
 412         # `id_prefix` is used to give an id to the `<h3>` element.
 413         fun list_by(map: MultiHashMap[Object, MPackage], id_prefix: String): Template
 414         do
 415                 var res = new Template
 416                 var keys = map.keys.to_a
 417                 alpha_comparator.sort(keys)
 418                 var list = [for x in keys do "<a href=\"#{id_prefix}{x.to_s.html_escape}\">{x.to_s.html_escape}</a>"]
 419                 res.add_list(list, ", ", " and ")
 420
 421                 for k in keys do
 422                         var projs = map[k].to_a
 423                         alpha_comparator.sort(projs)
 424                         var e = k.to_s.html_escape
 425                         res.add "<h3 id=\"{id_prefix}{e}\">{e} ({projs.length})</h3>\n<ul>\n"
 426                         for p in projs do
 427                                 res.add "<li>"
 428                                 res.add li_package(p)
 429                                 res.add "</li>"
 430                         end
 431                         res.add "</ul>"
 432                 end
 433                 return res
 434         end
 435
 436         # List the 10 best packages from `cpt`
 437         fun list_best(cpt: Counter[MPackage]): Template
 438         do
 439                 var res = new Template
 440                 res.add "<ul>"
 441                 var best = cpt.sort
 442                 for i in [1..10] do
 443                         if i > best.length then break
 444                         var p = best[best.length-i]
 445                         res.add "<li>"
 446                         res.add li_package(p)
 447                         # res.add " ({cpt[p]})"
 448                         res.add "</li>"
 449                 end
 450                 res.add "</ul>"
 451                 return res
 452         end
 453
 454         # Produce a HTML table containig information on the packages
 455         #
 456         # `package_page` must have been called before so that information is computed.
 457         fun table_packages(mpackages: Array[MPackage]): Template
 458         do
 459                 alpha_comparator.sort(mpackages)
 460                 var res = new Template
 461                 res.add "<table data-toggle=\"table\" data-sort-name=\"name\" data-sort-order=\"desc\" width=\"100%\">\n"
 462                 res.add "<thead><tr>\n"
 463                 res.add "<th data-field=\"name\" data-sortable=\"true\">name</th>\n"
 464                 res.add "<th data-field=\"maint\" data-sortable=\"true\">maint</th>\n"
 465                 res.add "<th data-field=\"contrib\" data-sortable=\"true\">contrib</th>\n"
 466                 if deps.not_empty then
 467                         res.add "<th data-field=\"reqs\" data-sortable=\"true\">reqs</th>\n"
 468                         res.add "<th data-field=\"dreqs\" data-sortable=\"true\">direct<br>reqs</th>\n"
 469                         res.add "<th data-field=\"cli\" data-sortable=\"true\">clients</th>\n"
 470                         res.add "<th data-field=\"dcli\" data-sortable=\"true\">direct<br>clients</th>\n"
 471                 end
 472                 res.add "<th data-field=\"mod\" data-sortable=\"true\">modules</th>\n"
 473                 res.add "<th data-field=\"cla\" data-sortable=\"true\">classes</th>\n"
 474                 res.add "<th data-field=\"met\" data-sortable=\"true\">methods</th>\n"
 475                 res.add "<th data-field=\"loc\" data-sortable=\"true\">lines</th>\n"
 476                 res.add "<th data-field=\"score\" data-sortable=\"true\">score</th>\n"
 477                 res.add "</tr></thead>"
 478                 for p in mpackages do
 479                         res.add "<tr>"
 480                         res.add "<td><a href=\"p/{p.name}.html\">{p.name}</a></td>"
 481                         var maint = "?"
 482                         if p.maintainers.not_empty then maint = p.maintainers.first.name.html_escape
 483                         res.add "<td>{maint}</td>"
 484                         res.add "<td>{p.contributors.length}</td>"
 485                         if deps.not_empty then
 486                                 res.add "<td>{deps[p].greaters.length-1}</td>"
 487                                 res.add "<td>{deps[p].direct_greaters.length}</td>"
 488                                 res.add "<td>{deps[p].smallers.length-1}</td>"
 489                                 res.add "<td>{deps[p].direct_smallers.length}</td>"
 490                         end
 491                         res.add "<td>{mmodules[p]}</td>"
 492                         res.add "<td>{mclasses[p]}</td>"
 493                         res.add "<td>{mmethods[p]}</td>"
 494                         res.add "<td>{loc[p]}</td>"
 495                         res.add "<td>{score[p]}</td>"
 496                         res.add "</tr>\n"
 497                 end
 498                 res.add "</table>\n"
 499                 return res
 500         end
 501
 502         # Piwik tracker URL, if any
 503         var piwik_tracker: nullable String = null
 504
 505         # Piwik site ID
 506         # Used when `piwik_tracker` is set
 507         var piwik_site_id: Int = 1
 508 end
 509
 510 var model = new Model
 511 var tc = new ToolContext
 512
 513 var opt_dir = new OptionString("Directory where the HTML files are generated", "-d", "--dir")
 514 var opt_no_git = new OptionBool("Do not gather git information from the working directory", "--no-git")
 515 var opt_no_parse = new OptionBool("Do not parse nit files (no importation information)", "--no-parse")
 516 var opt_no_model = new OptionBool("Do not analyse nit files (no class/method information)", "--no-model")
 517
 518 # Piwik tracker URL.
 519 # If you want to monitor your visitors.
 520 var opt_piwik_tracker = new OptionString("Piwik tracker URL (ex: `nitlanguage.org/piwik/`)", "--piwik-tracker")
 521 # Piwik tracker site id.
 522 var opt_piwik_site_id = new OptionString("Piwik site ID", "--piwik-site-id")
 523
 524 tc.option_context.add_option(opt_dir, opt_no_git, opt_no_parse, opt_no_model, opt_piwik_tracker, opt_piwik_site_id)
 525
 526 tc.process_options(sys.args)
 527 tc.keep_going = true
 528
 529 var modelbuilder = new ModelBuilder(model, tc)
 530 var catalog = new Catalog(modelbuilder)
 531
 532 catalog.piwik_tracker = opt_piwik_tracker.value
 533 var piwik_site_id = opt_piwik_site_id.value
 534 if piwik_site_id != null then
 535         if catalog.piwik_tracker == null then
 536                 print_error "Warning: ignored `{opt_piwik_site_id}` because `{opt_piwik_tracker}` is not set."
 537         else if piwik_site_id.is_int then
 538                 print_error "Warning: ignored `{opt_piwik_site_id}`, an integer is required."
 539         else
 540                 catalog.piwik_site_id = piwik_site_id.to_i
 541         end
 542 end
 543
 544
 545 # Get files or groups
 546 var args = tc.option_context.rest
 547 if opt_no_parse.value then
 548         modelbuilder.scan_full(args)
 549 else
 550         modelbuilder.parse_full(args)
 551 end
 552
 553 # Scan packages and compute information
 554 for p in model.mpackages do
 555         var g = p.root
 556         assert g != null
 557         modelbuilder.scan_group(g)
 558
 559         # Load the module to process importation information
 560         if opt_no_parse.value then continue
 561
 562         catalog.deps.add_node(p)
 563         for gg in p.mgroups do for m in gg.mmodules do
 564                 for im in m.in_importation.direct_greaters do
 565                         var ip = im.mpackage
 566                         if ip == null or ip == p then continue
 567                         catalog.deps.add_edge(p, ip)
 568                 end
 569         end
 570 end
 571
 572 if not opt_no_git.value then for p in model.mpackages do
 573         catalog.git_info(p)
 574 end
 575
 576 # Run phases to modelize classes and properties (so we can count them)
 577 if not opt_no_model.value then
 578         modelbuilder.run_phases
 579 end
 580
 581 var out = opt_dir.value or else "catalog.out"
 582 (out/"p").mkdir
 583 (out/"res").mkdir
 584
 585 catalog.outdir = out
 586
 587 # Generate the css (hard coded)
 588 var css = """
 589 body {
 590 margin-top:                     15px;
 591 background-color:               #f8f8f8;
 592 }
 593
 594 a {
 595 color:                          #0D8921;
 596 text-decoration:                none;
 597 }
 598
 599 a:hover {
 600 color:                          #333;
 601 text-decoration:                none;
 602 }
 603
 604 h1 {
 605 font-weight:                    bold;
 606 color:                          #0D8921;
 607 font-size:                      22px;
 608 }
 609
 610 h2 {
 611 color:                          #6C6C6C;
 612 font-size:                      18px;
 613 border-bottom:                  solid 3px #CCC;
 614 }
 615
 616 h3 {
 617 color:                          #6C6C6C;
 618 font-size:                      15px;
 619 border-bottom:                  solid 1px #CCC;
 620 }
 621
 622 ul {
 623 list-style-type:                square;
 624 }
 625
 626 dd {
 627 color:                          #6C6C6C;
 628 margin-top:                     1em;
 629 margin-bottom:                  1em;
 630 }
 631
 632 pre {
 633 border:                         1px solid #CCC;
 634 font-family:                    Monospace;
 635 color:                          #2d5003;
 636 background-color:               rgb(250, 250, 250);
 637 }
 638
 639 code {
 640 font-family:                    Monospace;
 641 color:                          #2d5003;
 642 }
 643
 644 footer {
 645 margin-top:                     20px;
 646 }
 647
 648 .container {
 649 margin:                         0 auto;
 650 padding:                        0 20px;
 651 }
 652
 653 .content {
 654 float:                          left;
 655 margin-top:                     40px;
 656 width:                          65%;
 657 }
 658
 659 .sidebar {
 660 float:                          right;
 661 margin-top:                     40px;
 662 width:                          30%
 663 }
 664
 665 .sidebar h3 {
 666 color:                          #0D8921;
 667 font-size:                      18px;
 668 border-bottom:                  0px;
 669 }
 670
 671 .box {
 672 margin:                         0;
 673 padding:                        0;
 674 }
 675
 676 .box li {
 677 line-height:                    2.5;
 678 white-space:                    nowrap;
 679 overflow:                       hidden;
 680 text-overflow:                  ellipsis;
 681 padding-right:                  10px;
 682 border-bottom:                  1px solid rgba(0,0,0,0.2);
 683 }
 684 """
 685 css.write_to_file(out/"style.css")
 686
 687 # PAGES
 688
 689 for p in model.mpackages do
 690         # print p
 691         var f = "p/{p.name}.html"
 692         catalog.package_page(p)
 693         catalog.generate_page(p).write_to_file(out/f)
 694 end
 695
 696 # INDEX
 697
 698 var index = catalog.new_page("")
 699 index.more_head.add "<title>Packages in Nit</title>"
 700
 701 index.add """
 702 <div class="content">
 703 <h1>Packages in Nit</h1>
 704 """
 705
 706 index.add "<h2>Highlighted Packages</h2>\n"
 707 index.add catalog.list_best(catalog.score)
 708
 709 if catalog.deps.not_empty then
 710         index.add "<h2>Most Required</h2>\n"
 711         var reqs = new Counter[MPackage]
 712         for p in model.mpackages do
 713                 reqs[p] = catalog.deps[p].smallers.length - 1
 714         end
 715         index.add catalog.list_best(reqs)
 716 end
 717
 718 index.add "<h2>By First Tag</h2>\n"
 719 index.add catalog.list_by(catalog.cat2proj, "cat_")
 720
 721 index.add "<h2>By Any Tag</h2>\n"
 722 index.add catalog.list_by(catalog.tag2proj, "tag_")
 723
 724 index.add """
 725 </div>
 726 <div class="sidebar">
 727 <h3>Stats</h3>
 728 <ul class="box">
 729 <li>{{{model.mpackages.length}}} packages</li>
 730 <li>{{{catalog.maint2proj.length}}} maintainers</li>
 731 <li>{{{catalog.contrib2proj.length}}} contributors</li>
 732 <li>{{{catalog.tag2proj.length}}} tags</li>
 733 <li>{{{catalog.mmodules.sum}}} modules</li>
 734 <li>{{{catalog.mclasses.sum}}} classes</li>
 735 <li>{{{catalog.mmethods.sum}}} methods</li>
 736 <li>{{{catalog.loc.sum}}} lines of code</li>
 737 </ul>
 738 </div>
 739 """
 740
 741 index.write_to_file(out/"index.html")
 742
 743 # PEOPLE
 744
 745 var page = catalog.new_page("")
 746 page.more_head.add "<title>People of Nit</title>"
 747 page.add """<div class="content">\n<h1>People of Nit</h1>\n"""
 748 page.add "<h2>By Maintainer</h2>\n"
 749 page.add catalog.list_by(catalog.maint2proj, "maint_")
 750 page.add "<h2>By Contributor</h2>\n"
 751 page.add catalog.list_by(catalog.contrib2proj, "contrib_")
 752 page.add "</div>\n"
 753 page.write_to_file(out/"people.html")
 754
 755 # TABLE
 756
 757 page = catalog.new_page("")
 758 page.more_head.add "<title>Projets of Nit</title>"
 759 page.add """<div class="content">\n<h1>People of Nit</h1>\n"""
 760 page.add "<h2>Table of Projets</h2>\n"
 761 page.add catalog.table_packages(model.mpackages)
 762 page.add "</div>\n"
 763 page.write_to_file(out/"table.html")