src/loader.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2012 Jean Privat <jean@pryen.org>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Load nit source files and build the associated model
  18 module loader
  19
  20 import modelbuilder_base
  21
  22 redef class ToolContext
  23         # Option --path
  24         var opt_path = new OptionArray("Set include path for loaders (may be used more than once)", "-I", "--path")
  25
  26         # Option --only-metamodel
  27         var opt_only_metamodel = new OptionBool("Stop after meta-model processing", "--only-metamodel")
  28
  29         # Option --only-parse
  30         var opt_only_parse = new OptionBool("Only proceed to parse step of loaders", "--only-parse")
  31
  32         redef init
  33         do
  34                 super
  35                 option_context.add_option(opt_path, opt_only_parse, opt_only_metamodel)
  36         end
  37 end
  38
  39 redef class ModelBuilder
  40         redef init
  41         do
  42                 super
  43
  44                 # Setup the paths value
  45                 paths.append(toolcontext.opt_path.value)
  46
  47                 var path_env = "NIT_PATH".environ
  48                 if not path_env.is_empty then
  49                         paths.append(path_env.split_with(':'))
  50                 end
  51
  52                 var nit_dir = toolcontext.nit_dir
  53                 var libname = "{nit_dir}/lib"
  54                 if libname.file_exists then paths.add(libname)
  55         end
  56
  57         # Load a bunch of modules.
  58         # `modules` can contains filenames or module names.
  59         # Imported modules are automatically loaded and modelized.
  60         # The result is the corresponding model elements.
  61         # Errors and warnings are printed with the toolcontext.
  62         #
  63         # Note: class and property model element are not analysed.
  64         fun parse(modules: Sequence[String]): Array[MModule]
  65         do
  66                 var time0 = get_time
  67                 # Parse and recursively load
  68                 self.toolcontext.info("*** PARSE ***", 1)
  69                 var mmodules = new ArraySet[MModule]
  70                 for a in modules do
  71                         var nmodule = self.load_module(a)
  72                         if nmodule == null then continue # Skip error
  73                         # Load imported module
  74                         build_module_importation(nmodule)
  75
  76                         mmodules.add(nmodule.mmodule.as(not null))
  77                 end
  78                 var time1 = get_time
  79                 self.toolcontext.info("*** END PARSE: {time1-time0} ***", 2)
  80
  81                 self.toolcontext.check_errors
  82
  83                 if toolcontext.opt_only_parse.value then
  84                         self.toolcontext.info("*** ONLY PARSE...", 1)
  85                         exit(0)
  86                 end
  87
  88                 return mmodules.to_a
  89         end
  90
  91         # The list of directories to search for top level modules
  92         # The list is initially set with :
  93         #   * the toolcontext --path option
  94         #   * the NIT_PATH environment variable
  95         #   * `toolcontext.nit_dir`
  96         # Path can be added (or removed) by the client
  97         var paths = new Array[String]
  98
  99         # Like (an used by) `get_mmodule_by_name` but just return the ModulePath
 100         private fun search_mmodule_by_name(anode: nullable ANode, mgroup: nullable MGroup, name: String): nullable ModulePath
 101         do
 102                 # First, look in groups
 103                 var c = mgroup
 104                 while c != null do
 105                         var dirname = c.filepath
 106                         if dirname == null then break # virtual group
 107                         if dirname.has_suffix(".nit") then break # singleton project
 108
 109                         # Second, try the directory to find a file
 110                         var try_file = dirname + "/" + name + ".nit"
 111                         if try_file.file_exists then
 112                                 var res = self.identify_file(try_file.simplify_path)
 113                                 assert res != null
 114                                 return res
 115                         end
 116
 117                         # Third, try if the requested module is itself a group
 118                         try_file = dirname + "/" + name + "/" + name + ".nit"
 119                         if try_file.file_exists then
 120                                 var res = self.identify_file(try_file.simplify_path)
 121                                 assert res != null
 122                                 return res
 123                         end
 124
 125                         c = c.parent
 126                 end
 127
 128                 # Look at some known directories
 129                 var lookpaths = self.paths
 130
 131                 # Look in the directory of the group project also (even if not explicitely in the path)
 132                 if mgroup != null then
 133                         # path of the root group
 134                         var dirname = mgroup.mproject.root.filepath
 135                         if dirname != null then
 136                                 dirname = dirname.join_path("..").simplify_path
 137                                 if not lookpaths.has(dirname) and dirname.file_exists then
 138                                         lookpaths = lookpaths.to_a
 139                                         lookpaths.add(dirname)
 140                                 end
 141                         end
 142                 end
 143
 144                 var candidate = search_module_in_paths(anode.hot_location, name, lookpaths)
 145
 146                 if candidate == null then
 147                         if mgroup != null then
 148                                 error(anode, "Error: cannot find module {name} from {mgroup.name}. tried {lookpaths.join(", ")}")
 149                         else
 150                                 error(anode, "Error: cannot find module {name}. tried {lookpaths.join(", ")}")
 151                         end
 152                         return null
 153                 end
 154                 return candidate
 155         end
 156
 157         # Get a module by its short name; if required, the module is loaded, parsed and its hierarchies computed.
 158         # If `mgroup` is set, then the module search starts from it up to the top level (see `paths`);
 159         # if `mgroup` is null then the module is searched in the top level only.
 160         # If no module exists or there is a name conflict, then an error on `anode` is displayed and null is returned.
 161         fun get_mmodule_by_name(anode: nullable ANode, mgroup: nullable MGroup, name: String): nullable MModule
 162         do
 163                 var path = search_mmodule_by_name(anode, mgroup, name)
 164                 if path == null then return null # Forward error
 165                 var res = self.load_module(path.filepath)
 166                 if res == null then return null # Forward error
 167                 # Load imported module
 168                 build_module_importation(res)
 169                 return res.mmodule.as(not null)
 170         end
 171
 172         # Search a module `name` from path `lookpaths`.
 173         # If found, the path of the file is returned
 174         private fun search_module_in_paths(location: nullable Location, name: String, lookpaths: Collection[String]): nullable ModulePath
 175         do
 176                 var candidate: nullable String = null
 177                 for dirname in lookpaths do
 178                         var try_file = (dirname + "/" + name + ".nit").simplify_path
 179                         if try_file.file_exists then
 180                                 if candidate == null then
 181                                         candidate = try_file
 182                                 else if candidate != try_file then
 183                                         # try to disambiguate conflicting modules
 184                                         var abs_candidate = module_absolute_path(candidate)
 185                                         var abs_try_file = module_absolute_path(try_file)
 186                                         if abs_candidate != abs_try_file then
 187                                                 toolcontext.error(location, "Error: conflicting module file for {name}: {candidate} {try_file}")
 188                                         end
 189                                 end
 190                         end
 191                         try_file = (dirname + "/" + name + "/" + name + ".nit").simplify_path
 192                         if try_file.file_exists then
 193                                 if candidate == null then
 194                                         candidate = try_file
 195                                 else if candidate != try_file then
 196                                         # try to disambiguate conflicting modules
 197                                         var abs_candidate = module_absolute_path(candidate)
 198                                         var abs_try_file = module_absolute_path(try_file)
 199                                         if abs_candidate != abs_try_file then
 200                                                 toolcontext.error(location, "Error: conflicting module file for {name}: {candidate} {try_file}")
 201                                         end
 202                                 end
 203                         end
 204                 end
 205                 if candidate == null then return null
 206                 return identify_file(candidate)
 207         end
 208
 209         # cache for `identify_file` by realpath
 210         private var identified_files = new HashMap[String, nullable ModulePath]
 211
 212         # Identify a source file
 213         # Load the associated project and groups if required
 214         private fun identify_file(path: String): nullable ModulePath
 215         do
 216                 # special case for not a nit file
 217                 if path.file_extension != "nit" then
 218                         # search in known -I paths
 219                         var res = search_module_in_paths(null, path, self.paths)
 220                         if res != null then return res
 221
 222                         # Found nothins? maybe it is a group...
 223                         var candidate = null
 224                         if path.file_exists then
 225                                 var mgroup = get_mgroup(path)
 226                                 if mgroup != null then
 227                                         var owner_path = mgroup.filepath.join_path(mgroup.name + ".nit")
 228                                         if owner_path.file_exists then candidate = owner_path
 229                                 end
 230                         end
 231
 232                         if candidate == null then
 233                                 toolcontext.error(null, "Error: cannot find module `{path}`.")
 234                                 return null
 235                         end
 236                         path = candidate
 237                 end
 238
 239                 # Fast track, the path is already known
 240                 var pn = path.basename(".nit")
 241                 var rp = module_absolute_path(path)
 242                 if identified_files.has_key(rp) then return identified_files[rp]
 243
 244                 # Search for a group
 245                 var mgrouppath = path.join_path("..").simplify_path
 246                 var mgroup = get_mgroup(mgrouppath)
 247
 248                 if mgroup == null then
 249                         # singleton project
 250                         var mproject = new MProject(pn, model)
 251                         mgroup = new MGroup(pn, mproject, null) # same name for the root group
 252                         mgroup.filepath = path
 253                         mproject.root = mgroup
 254                         toolcontext.info("found project `{pn}` at {path}", 2)
 255                 end
 256
 257                 var res = new ModulePath(pn, path, mgroup)
 258                 mgroup.module_paths.add(res)
 259
 260                 identified_files[rp] = res
 261                 return res
 262         end
 263
 264         # groups by path
 265         private var mgroups = new HashMap[String, nullable MGroup]
 266
 267         # return the mgroup associated to a directory path
 268         # if the directory is not a group null is returned
 269         private fun get_mgroup(dirpath: String): nullable MGroup
 270         do
 271                 var rdp = module_absolute_path(dirpath)
 272                 if mgroups.has_key(rdp) then
 273                         return mgroups[rdp]
 274                 end
 275
 276                 # Hack, a group is determined by:
 277                 # * the presence of a honomymous nit file
 278                 # * the fact that the directory is named `src`
 279                 var pn = rdp.basename(".nit")
 280                 var mp = dirpath.join_path(pn + ".nit").simplify_path
 281
 282                 var dirpath2 = dirpath
 283                 if not mp.file_exists then
 284                         if pn == "src" then
 285                                 # With a src directory, the group name is the name of the parent directory
 286                                 dirpath2 = rdp.dirname
 287                                 pn = dirpath2.basename("")
 288                         else
 289                                 return null
 290                         end
 291                 end
 292
 293                 # check parent directory
 294                 var parentpath = dirpath.join_path("..").simplify_path
 295                 var parent = get_mgroup(parentpath)
 296
 297                 var mgroup
 298                 if parent == null then
 299                         # no parent, thus new project
 300                         var mproject = new MProject(pn, model)
 301                         mgroup = new MGroup(pn, mproject, null) # same name for the root group
 302                         mproject.root = mgroup
 303                         toolcontext.info("found project `{mproject}` at {dirpath}", 2)
 304                 else
 305                         mgroup = new MGroup(pn, parent.mproject, parent)
 306                         toolcontext.info("found sub group `{mgroup.full_name}` at {dirpath}", 2)
 307                 end
 308                 var readme = dirpath2.join_path("README.md")
 309                 if not readme.file_exists then readme = dirpath2.join_path("README")
 310                 if readme.file_exists then
 311                         var mdoc = new MDoc
 312                         var s = new IFStream.open(readme)
 313                         while not s.eof do
 314                                 mdoc.content.add(s.read_line)
 315                         end
 316                         mgroup.mdoc = mdoc
 317                         mdoc.original_mentity = mgroup
 318                 end
 319                 mgroup.filepath = dirpath
 320                 mgroups[rdp] = mgroup
 321                 return mgroup
 322         end
 323
 324         # Transform relative paths (starting with '../') into absolute paths
 325         private fun module_absolute_path(path: String): String do
 326                 return getcwd.join_path(path).simplify_path
 327         end
 328
 329         # Try to load a module AST using a path.
 330         # Display an error if there is a problem (IO / lexer / parser) and return null
 331         fun load_module_ast(filename: String): nullable AModule
 332         do
 333                 if filename.file_extension != "nit" then
 334                         self.toolcontext.error(null, "Error: file {filename} is not a valid nit module.")
 335                         return null
 336                 end
 337                 if not filename.file_exists then
 338                         self.toolcontext.error(null, "Error: file {filename} not found.")
 339                         return null
 340                 end
 341
 342                 self.toolcontext.info("load module {filename}", 2)
 343
 344                 # Load the file
 345                 var file = new IFStream.open(filename)
 346                 var lexer = new Lexer(new SourceFile(filename, file))
 347                 var parser = new Parser(lexer)
 348                 var tree = parser.parse
 349                 file.close
 350
 351                 # Handle lexer and parser error
 352                 var nmodule = tree.n_base
 353                 if nmodule == null then
 354                         var neof = tree.n_eof
 355                         assert neof isa AError
 356                         error(neof, neof.message)
 357                         return null
 358                 end
 359
 360                 return nmodule
 361         end
 362
 363         # Try to load a module modules using a path.
 364         # Display an error if there is a problem (IO / lexer / parser) and return null.
 365         # Note: usually, you do not need this method, use `get_mmodule_by_name` instead.
 366         #
 367         # The MModule is created however, the importation is not performed,
 368         # therefore you should call `build_module_importation`.
 369         fun load_module(filename: String): nullable AModule
 370         do
 371                 # Look for the module
 372                 var file = identify_file(filename)
 373                 if file == null then return null # forward error
 374
 375                 # Already known and loaded? then return it
 376                 var mmodule = file.mmodule
 377                 if mmodule != null then
 378                         return mmodule2nmodule[mmodule]
 379                 end
 380
 381                 # Load it manually
 382                 var nmodule = load_module_ast(file.filepath)
 383                 if nmodule == null then return null # forward error
 384
 385                 # build the mmodule and load imported modules
 386                 mmodule = build_a_mmodule(file.mgroup, file.name, nmodule)
 387
 388                 if mmodule == null then return null # forward error
 389
 390                 # Update the file information
 391                 file.mmodule = mmodule
 392
 393                 return nmodule
 394         end
 395
 396         # Injection of a new module without source.
 397         # Used by the interpreted
 398         fun load_rt_module(parent: nullable MModule, nmodule: AModule, mod_name: String): nullable AModule
 399         do
 400                 # Create the module
 401
 402                 var mgroup = null
 403                 if parent != null then mgroup = parent.mgroup
 404                 var mmodule = new MModule(model, mgroup, mod_name, nmodule.location)
 405                 nmodule.mmodule = mmodule
 406                 nmodules.add(nmodule)
 407                 self.mmodule2nmodule[mmodule] = nmodule
 408
 409                 if parent!= null then
 410                         var imported_modules = new Array[MModule]
 411                         imported_modules.add(parent)
 412                         mmodule.set_visibility_for(parent, intrude_visibility)
 413                         mmodule.set_imported_mmodules(imported_modules)
 414                 else
 415                         build_module_importation(nmodule)
 416                 end
 417
 418                 return nmodule
 419         end
 420
 421         # Visit the AST and create the `MModule` object
 422         private fun build_a_mmodule(mgroup: nullable MGroup, mod_name: String, nmodule: AModule): nullable MModule
 423         do
 424                 # Check the module name
 425                 var decl = nmodule.n_moduledecl
 426                 if decl == null then
 427                         #warning(nmodule, "Warning: Missing 'module' keyword") #FIXME: NOT YET FOR COMPATIBILITY
 428                 else
 429                         var decl_name = decl.n_name.n_id.text
 430                         if decl_name != mod_name then
 431                                 error(decl.n_name, "Error: module name missmatch; declared {decl_name} file named {mod_name}")
 432                         end
 433                 end
 434
 435                 # Create the module
 436                 var mmodule = new MModule(model, mgroup, mod_name, nmodule.location)
 437                 nmodule.mmodule = mmodule
 438                 nmodules.add(nmodule)
 439                 self.mmodule2nmodule[mmodule] = nmodule
 440
 441                 if decl != null then
 442                         var ndoc = decl.n_doc
 443                         if ndoc != null then
 444                                 var mdoc = ndoc.to_mdoc
 445                                 mmodule.mdoc = mdoc
 446                                 mdoc.original_mentity = mmodule
 447                         else
 448                                 advice(decl, "missing-doc", "Documentation warning: Undocumented module `{mmodule}`")
 449                         end
 450                 end
 451
 452                 return mmodule
 453         end
 454
 455         # Analysis the module importation and fill the module_importation_hierarchy
 456         #
 457         # Unless you used `load_module`, the importation is already done and this method does a no-op.
 458         fun build_module_importation(nmodule: AModule)
 459         do
 460                 if nmodule.is_importation_done then return
 461                 nmodule.is_importation_done = true
 462                 var mmodule = nmodule.mmodule.as(not null)
 463                 var stdimport = true
 464                 var imported_modules = new Array[MModule]
 465                 for aimport in nmodule.n_imports do
 466                         stdimport = false
 467                         if not aimport isa AStdImport then
 468                                 continue
 469                         end
 470                         var mgroup = mmodule.mgroup
 471                         if aimport.n_name.n_quad != null then mgroup = null # Start from top level
 472                         for grp in aimport.n_name.n_path do
 473                                 var path = search_mmodule_by_name(grp, mgroup, grp.text)
 474                                 if path == null then return # Skip error
 475                                 mgroup = path.mgroup
 476                         end
 477                         var mod_name = aimport.n_name.n_id.text
 478                         var sup = self.get_mmodule_by_name(aimport.n_name, mgroup, mod_name)
 479                         if sup == null then continue # Skip error
 480                         aimport.mmodule = sup
 481                         imported_modules.add(sup)
 482                         var mvisibility = aimport.n_visibility.mvisibility
 483                         if mvisibility == protected_visibility then
 484                                 error(aimport.n_visibility, "Error: only properties can be protected.")
 485                                 return
 486                         end
 487                         if sup == mmodule then
 488                                 error(aimport.n_name, "Error: Dependency loop in module {mmodule}.")
 489                         end
 490                         if sup.in_importation < mmodule then
 491                                 error(aimport.n_name, "Error: Dependency loop between modules {mmodule} and {sup}.")
 492                                 return
 493                         end
 494                         mmodule.set_visibility_for(sup, mvisibility)
 495                 end
 496                 if stdimport then
 497                         var mod_name = "standard"
 498                         var sup = self.get_mmodule_by_name(nmodule, null, mod_name)
 499                         if sup != null then # Skip error
 500                                 imported_modules.add(sup)
 501                                 mmodule.set_visibility_for(sup, public_visibility)
 502                         end
 503                 end
 504                 self.toolcontext.info("{mmodule} imports {imported_modules.join(", ")}", 3)
 505                 mmodule.set_imported_mmodules(imported_modules)
 506
 507                 # Force standard to be public if imported
 508                 for sup in mmodule.in_importation.greaters do
 509                         if sup.name == "standard" then
 510                                 mmodule.set_visibility_for(sup, public_visibility)
 511                         end
 512                 end
 513
 514                 # TODO: Correctly check for useless importation
 515                 # It is even doable?
 516                 var directs = mmodule.in_importation.direct_greaters
 517                 for nim in nmodule.n_imports do
 518                         if not nim isa AStdImport then continue
 519                         var im = nim.mmodule
 520                         if im == null then continue
 521                         if directs.has(im) then continue
 522                         # This generates so much noise that it is simpler to just comment it
 523                         #warning(nim, "Warning: possible useless importation of {im}")
 524                 end
 525         end
 526
 527         # All the loaded modules
 528         var nmodules = new Array[AModule]
 529
 530         # Register the nmodule associated to each mmodule
 531         # FIXME: why not refine the `MModule` class with a nullable attribute?
 532         var mmodule2nmodule = new HashMap[MModule, AModule]
 533 end
 534
 535 # placeholder to a module file identified but not always loaded in a project
 536 private class ModulePath
 537         # The name of the module
 538         # (it's the basename of the filepath)
 539         var name: String
 540
 541         # The human path of the module
 542         var filepath: String
 543
 544         # The group (and the project) of the possible module
 545         var mgroup: MGroup
 546
 547         # The loaded module (if any)
 548         var mmodule: nullable MModule = null
 549
 550         redef fun to_s do return filepath
 551 end
 552
 553 redef class MGroup
 554         # modules paths associated with the group
 555         private var module_paths = new Array[ModulePath]
 556 end
 557
 558 redef class AStdImport
 559         # The imported module once determined
 560         var mmodule: nullable MModule = null
 561 end
 562
 563 redef class AModule
 564         # The associated MModule once build by a `ModelBuilder`
 565         var mmodule: nullable MModule
 566         # Flag that indicate if the importation is already completed
 567         var is_importation_done: Bool = false
 568 end