src/ffi/c.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2012-2014 Alexis Laferrière <alexis.laf@xymus.net>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Support for nesting C code within a Nit program using its FFI
  18 module c
  19
  20 import ffi_base
  21
  22 redef class FFILanguageAssignationPhase
  23         var c_language: FFILanguage = new CLanguage(self)
  24 end
  25
  26 class CLanguage
  27         super FFILanguage
  28
  29         redef fun identify_language(n) do return n.is_c
  30
  31         redef fun compile_module_block(block, ecc, mmodule)
  32         do
  33                 if block.is_c_header then
  34                         ecc.header_custom.add( block.location.as_line_pragma )
  35                         ecc.header_custom.add( block.code )
  36                 else if block.is_c_body then
  37                         ecc.body_custom.add( block.location.as_line_pragma )
  38                         ecc.body_impl.add( block.code )
  39                 end
  40         end
  41
  42         redef fun compile_extern_method(block, m, ecc, mmodule)
  43         do
  44                 var fc = new ExternCFunction(m, mmodule)
  45                 fc.decls.add( block.location.as_line_pragma )
  46                 fc.exprs.add( block.code )
  47                 ecc.add_exported_function( fc )
  48         end
  49
  50         redef fun compile_extern_class(block, m, ecc, mmodule) do end
  51
  52         redef fun get_ftype(block, m) do return new ForeignCType(block.code)
  53
  54         redef fun compile_callback(callback, mmodule, mainmodule, ecc)
  55         do
  56                 callback.compile_callback_to_c(mainmodule, ecc)
  57         end
  58 end
  59
  60 redef class AExternCodeBlock
  61         fun is_c: Bool do return language_name == null or
  62                 language_name_lowered == "c" or language_name_lowered.has_prefix( "c " )
  63
  64         fun is_c_body: Bool do return language_name == null or
  65                 language_name_lowered == "c" or language_name_lowered ==  "c body"
  66
  67         fun is_c_header: Bool do return language_name_lowered == "c header"
  68 end
  69
  70 redef class Location
  71         fun as_line_pragma: String do return "#line {line_start-1} \"{file.filename}\"\n"
  72 end
  73
  74 redef class MModule
  75         # FIXME make nullable the key of `cflags`, `ldflags` and `cppflags` when
  76         # supported by the bootstrap
  77
  78         # Custom options for the C compiler (CFLAGS)
  79         var cflags = new MultiHashMap[String, String]
  80
  81         # Custom options for the C linker (LDFLAGS)
  82         var ldflags = new MultiHashMap[String, String]
  83
  84         # Additional libraries needed for the compilation
  85         # Will be used with pkg-config
  86         var pkgconfigs = new Array[String]
  87 end
  88
  89 class ForeignCType
  90         super ForeignType
  91
  92         redef var ctype: String
  93 end
  94
  95 redef class NitniCallback
  96         fun compile_callback_to_c(mmodule: MModule, ffi_ccu: CCompilationUnit) do end
  97 end
  98
  99 redef class Object
 100         # Context when calling user C code from generated code
 101         fun to_c_call_context: ToCCallContext do return once new ToCCallContext
 102
 103         # Context when calling generated code from user C code
 104         fun from_c_call_context: FromCCallContext do return once new FromCCallContext
 105 end
 106
 107 redef class MExplicitCall
 108         redef fun compile_callback_to_c(mmodule, ffi_ccu)
 109         do
 110                 var mproperty = mproperty.as(MMethod)
 111
 112                 var full_cname = mproperty.build_cname(recv_mtype, mmodule, null, long_signature)
 113                 var friendly_cname = mproperty.build_cname(recv_mtype, mmodule, null, short_signature)
 114                 ffi_ccu.body_decl.add("#define {friendly_cname} {full_cname}\n")
 115         end
 116 end
 117
 118 # Context when calling user C code from generated code
 119 class ToCCallContext
 120         super CallContext
 121
 122         # TODO: private init because singleton instance (see `to_c_call_context`)
 123
 124         redef fun name_mtype(mtype)
 125         do
 126                 if mtype isa MClassType and mtype.mclass.kind == extern_kind then return "void *"
 127                 return mtype.cname
 128         end
 129 end
 130
 131 # Context when calling generated code from user C code
 132 class FromCCallContext
 133         super CallContext
 134
 135         # TODO: private init because singleton instance (see `from_c_call_context`)
 136
 137         redef fun name_mtype(mtype) do return mtype.cname
 138 end
 139
 140 class ExternCFunction
 141         super CFunction
 142
 143         var method: AMethPropdef
 144
 145         init (method: AMethPropdef, mmodule: MModule)
 146         do
 147                 self.method = method
 148
 149                 var recv_mtype = method.mpropdef.mclassdef.bound_mtype
 150                 var csignature = method.mpropdef.mproperty.build_csignature(recv_mtype, mmodule, "___impl", long_signature, from_c_call_context)
 151
 152                 super( csignature )
 153         end
 154 end