lib/standard/file.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2004-2008 Jean Privat <jean@pryen.org>
   4 # Copyright 2008 Floréal Morandat <morandat@lirmm.fr>
   5 # Copyright 2008 Jean-Sébastien Gélinas <calestar@gmail.com>
   6 #
   7 # This file is free software, which comes along with NIT.  This software is
   8 # distributed in the hope that it will be useful, but WITHOUT ANY WARRANTY;
   9 # without  even  the implied warranty of  MERCHANTABILITY or  FITNESS FOR A
  10 # PARTICULAR PURPOSE.  You can modify it is you want,  provided this header
  11 # is kept unaltered, and a notification of the changes is added.
  12 # You  are  allowed  to  redistribute it and sell it, alone or is a part of
  13 # another product.
  14
  15 # File manipulations (create, read, write, etc.)
  16 module file
  17
  18 intrude import stream
  19 intrude import string
  20 import string_search
  21 import time
  22
  23 in "C Header" `{
  24         #include <dirent.h>
  25         #include <string.h>
  26         #include <sys/types.h>
  27         #include <sys/stat.h>
  28         #include <unistd.h>
  29 `}
  30
  31 redef class Object
  32 # Simple I/O
  33
  34         # Print `objects` on the standard output (`stdout`).
  35         protected fun printn(objects: Object...)
  36         do
  37                 stdout.write(objects.to_s)
  38         end
  39
  40         # Print an `object` on the standard output (`stdout`) and add a newline.
  41         protected fun print(object: Object)
  42         do
  43                 stdout.write(object.to_s)
  44                 stdout.write("\n")
  45         end
  46
  47         # Read a character from the standard input (`stdin`).
  48         protected fun getc: Char
  49         do
  50                 return stdin.read_char.ascii
  51         end
  52
  53         # Read a line from the standard input (`stdin`).
  54         protected fun gets: String
  55         do
  56                 return stdin.read_line
  57         end
  58
  59         # Return the working (current) directory
  60         protected fun getcwd: String do return file_getcwd.to_s
  61         private fun file_getcwd: NativeString is extern "string_NativeString_NativeString_file_getcwd_0"
  62 end
  63
  64 # File Abstract Stream
  65 abstract class FStream
  66         super IOS
  67         # The path of the file.
  68         readable var _path: nullable String = null
  69
  70         # The FILE *.
  71         var _file: nullable NativeFile = null
  72
  73         fun file_stat: FileStat
  74         do return _file.file_stat end
  75 end
  76
  77 # File input stream
  78 class IFStream
  79         super FStream
  80         super BufferedIStream
  81         # Misc
  82
  83         # Open the same file again.
  84         # The original path is reused, therefore the reopened file can be a different file.
  85         fun reopen
  86         do
  87                 if not eof then close
  88                 _file = new NativeFile.io_open_read(_path.to_cstring)
  89                 _end_reached = false
  90                 _buffer_pos = 0
  91                 _buffer.clear
  92         end
  93
  94         redef fun close
  95         do
  96                 var i = _file.io_close
  97                 _end_reached = true
  98         end
  99
 100         redef fun fill_buffer
 101         do
 102                 var nb = _file.io_read(_buffer._items, _buffer._capacity)
 103                 if nb <= 0 then
 104                         _end_reached = true
 105                         nb = 0
 106                 end
 107                 _buffer._length = nb
 108                 _buffer_pos = 0
 109         end
 110
 111         # End of file?
 112         redef readable var _end_reached: Bool = false
 113
 114         # Open the file at `path` for reading.
 115         init open(path: String)
 116         do
 117                 _path = path
 118                 prepare_buffer(10)
 119                 _file = new NativeFile.io_open_read(_path.to_cstring)
 120                 assert cant_open_file: _file != null
 121         end
 122
 123         private init do end
 124         private init without_file do end
 125 end
 126
 127 # File output stream
 128 class OFStream
 129         super FStream
 130         super OStream
 131
 132         redef fun write(s)
 133         do
 134                 assert _writable
 135                 write_native(s.to_cstring, s.length)
 136         end
 137
 138         redef fun is_writable do return _writable
 139
 140         redef fun close
 141         do
 142                 var i = _file.io_close
 143                 _writable = false
 144         end
 145
 146         # Is the file open in write mode
 147         var _writable: Bool
 148
 149         # Write `len` bytes from `native`.
 150         private fun write_native(native: NativeString, len: Int)
 151         do
 152                 assert _writable
 153                 var err = _file.io_write(native, len)
 154                 if err != len then
 155                         # Big problem
 156                         printn("Problem in writing : ", err, " ", len, "\n")
 157                 end
 158         end
 159
 160         # Open the file at `path` for writing.
 161         init open(path: String)
 162         do
 163                 _file = new NativeFile.io_open_write(path.to_cstring)
 164                 assert cant_open_file: _file != null
 165                 _path = path
 166                 _writable = true
 167         end
 168
 169         private init do end
 170         private init without_file do end
 171 end
 172
 173 ###############################################################################
 174
 175 class Stdin
 176         super IFStream
 177         private init do
 178                 _file = new NativeFile.native_stdin
 179                 _path = "/dev/stdin"
 180                 prepare_buffer(1)
 181         end
 182
 183         # Is these something to read? (non blocking)
 184         # FIXME: should be generalized
 185         fun poll_in: Bool is extern "file_stdin_poll_in"
 186 end
 187
 188 class Stdout
 189         super OFStream
 190         private init do
 191                 _file = new NativeFile.native_stdout
 192                 _path = "/dev/stdout"
 193                 _writable = true
 194         end
 195 end
 196
 197 class Stderr
 198         super OFStream
 199         private init do
 200                 _file = new NativeFile.native_stderr
 201                 _path = "/dev/stderr"
 202                 _writable = true
 203         end
 204 end
 205
 206 ###############################################################################
 207
 208 redef class Streamable
 209         # Like `write_to` but take care of creating the file
 210         fun write_to_file(filepath: String)
 211         do
 212                 var stream = new OFStream.open(filepath)
 213                 write_to(stream)
 214                 stream.close
 215         end
 216 end
 217
 218 redef class String
 219         # return true if a file with this names exists
 220         fun file_exists: Bool do return to_cstring.file_exists
 221
 222         # The status of a file. see POSIX stat(2).
 223         fun file_stat: FileStat do return to_cstring.file_stat
 224
 225         # The status of a file or of a symlink. see POSIX lstat(2).
 226         fun file_lstat: FileStat do return to_cstring.file_lstat
 227
 228         # Remove a file, return true if success
 229         fun file_delete: Bool do return to_cstring.file_delete
 230
 231         # Copy content of file at `self` to `dest`
 232         fun file_copy_to(dest: String)
 233         do
 234                 var input = new IFStream.open(self)
 235                 var output = new OFStream.open(dest)
 236
 237                 while not input.eof do
 238                         var buffer = input.read(1024)
 239                         output.write buffer
 240                 end
 241
 242                 input.close
 243                 output.close
 244         end
 245
 246         # Remove the trailing extension `ext`.
 247         #
 248         # `ext` usually starts with a dot but could be anything.
 249         #
 250         #     assert "file.txt".strip_extension(".txt")  == "file"
 251         #     assert "file.txt".strip_extension("le.txt")  == "fi"
 252         #     assert "file.txt".strip_extension("xt")  == "file.t"
 253         #
 254         # if `ext` is not present, `self` is returned unmodified.
 255         #
 256         #     assert "file.txt".strip_extension(".tar.gz")  == "file.txt"
 257         fun strip_extension(ext: String): String
 258         do
 259                 if has_suffix(ext) then
 260                         return substring(0, length - ext.length)
 261                 end
 262                 return self
 263         end
 264
 265         # Extract the basename of a path and remove the extension
 266         #
 267         #     assert "/path/to/a_file.ext".basename(".ext")         == "a_file"
 268         #     assert "path/to/a_file.ext".basename(".ext")          == "a_file"
 269         #     assert "path/to".basename(".ext")                     == "to"
 270         #     assert "path/to/".basename(".ext")                    == "to"
 271         #     assert "path".basename("")                        == "path"
 272         #     assert "/path".basename("")                       == "path"
 273         #     assert "/".basename("")                           == "/"
 274         #     assert "".basename("")                            == ""
 275         fun basename(ext: String): String
 276         do
 277                 var l = _length - 1 # Index of the last char
 278                 while l > 0 and self.chars[l] == '/' do l -= 1 # remove all trailing `/`
 279                 if l == 0 then return "/"
 280                 var pos = last_index_of_from('/', l)
 281                 var n = self
 282                 if pos >= 0 then
 283                         n = substring(pos+1, l-pos)
 284                 end
 285                 return n.strip_extension(ext)
 286         end
 287
 288         # Extract the dirname of a path
 289         #
 290         #     assert "/path/to/a_file.ext".dirname         == "/path/to"
 291         #     assert "path/to/a_file.ext".dirname          == "path/to"
 292         #     assert "path/to".dirname                     == "path"
 293         #     assert "path/to/".dirname                    == "path"
 294         #     assert "path".dirname                        == "."
 295         #     assert "/path".dirname                       == "/"
 296         #     assert "/".dirname                           == "/"
 297         #     assert "".dirname                            == "."
 298         fun dirname: String
 299         do
 300                 var l = _length - 1 # Index of the last char
 301                 while l > 0 and self.chars[l] == '/' do l -= 1 # remove all trailing `/`
 302                 var pos = last_index_of_from('/', l)
 303                 if pos > 0 then
 304                         return substring(0, pos)
 305                 else if pos == 0 then
 306                         return "/"
 307                 else
 308                         return "."
 309                 end
 310         end
 311
 312         # Return the canonicalized absolute pathname (see POSIX function `realpath`)
 313         fun realpath: String do
 314                 var cs = to_cstring.file_realpath
 315                 var res = cs.to_s_with_copy
 316                 # cs.free_malloc # FIXME memory leak
 317                 return res
 318         end
 319
 320         # Simplify a file path by remove useless ".", removing "//", and resolving ".."
 321         # ".." are not resolved if they start the path
 322         # starting "/" is not removed
 323         # trainling "/" is removed
 324         #
 325         # Note that the method only wonrk on the string:
 326         #  * no I/O access is performed
 327         #  * the validity of the path is not checked
 328         #
 329         #     assert "some/./complex/../../path/from/../to/a////file//".simplify_path        ==  "path/to/a/file"
 330         #     assert "../dir/file".simplify_path       ==  "../dir/file"
 331         #     assert "dir/../../".simplify_path        ==  ".."
 332         #     assert "dir/..".simplify_path            ==  "."
 333         #     assert "//absolute//path/".simplify_path ==  "/absolute/path"
 334         fun simplify_path: String
 335         do
 336                 var a = self.split_with("/")
 337                 var a2 = new Array[String]
 338                 for x in a do
 339                         if x == "." then continue
 340                         if x == "" and not a2.is_empty then continue
 341                         if x == ".." and not a2.is_empty and a2.last != ".." then
 342                                 a2.pop
 343                                 continue
 344                         end
 345                         a2.push(x)
 346                 end
 347                 if a2.is_empty then return "."
 348                 return a2.join("/")
 349         end
 350
 351         # Correctly join two path using the directory separator.
 352         #
 353         # Using a standard "{self}/{path}" does not work when `self` is the empty string.
 354         # This method ensure that the join is valid.
 355         #
 356         #     assert "hello".join_path("world")      ==  "hello/world"
 357         #     assert "hel/lo".join_path("wor/ld")      ==  "hel/lo/wor/ld"
 358         #     assert "".join_path("world")      ==  "world"
 359         #     assert "/hello".join_path("/world")      ==  "/world"
 360         #
 361         # Note: you may want to use `simplify_path` on the result
 362         #
 363         # Note: I you want to join a great number of path, you can write
 364         #
 365         #     [p1, p2, p3, p4].join("/")
 366         fun join_path(path: String): String
 367         do
 368                 if path.is_empty then return self
 369                 if self.is_empty then return path
 370                 if path.chars[0] == '/' then return path
 371                 return "{self}/{path}"
 372         end
 373
 374         # Create a directory (and all intermediate directories if needed)
 375         fun mkdir
 376         do
 377                 var dirs = self.split_with("/")
 378                 var path = new Buffer
 379                 if dirs.is_empty then return
 380                 if dirs[0].is_empty then
 381                         # it was a starting /
 382                         path.add('/')
 383                 end
 384                 for d in dirs do
 385                         if d.is_empty then continue
 386                         path.append(d)
 387                         path.add('/')
 388                         path.to_s.to_cstring.file_mkdir
 389                 end
 390         end
 391
 392         # Change the current working directory
 393         #
 394         #     "/etc".chdir
 395         #     assert getcwd == "/etc"
 396         #     "..".chdir
 397         #     assert getcwd == "/"
 398         #
 399         # TODO: errno
 400         fun chdir do to_cstring.file_chdir
 401
 402         # Return right-most extension (without the dot)
 403         #
 404         # Only the last extension is returned.
 405         # There is no special case for combined extensions.
 406         #
 407         #     assert "file.txt".file_extension      == "txt"
 408         #     assert "file.tar.gz".file_extension   == "gz"
 409         #
 410         # For file without extension, `null` is returned.
 411         # Hoever, for trailing dot, `""` is returned.
 412         #
 413         #     assert "file".file_extension          == null
 414         #     assert "file.".file_extension         == ""
 415         #
 416         # The starting dot of hidden files is never considered.
 417         #
 418         #     assert ".file.txt".file_extension     == "txt"
 419         #     assert ".file".file_extension         == null
 420         fun file_extension: nullable String
 421         do
 422                 var last_slash = last_index_of('.')
 423                 if last_slash > 0 then
 424                         return substring( last_slash+1, length )
 425                 else
 426                         return null
 427                 end
 428         end
 429
 430         # returns files contained within the directory represented by self
 431         fun files : Set[ String ] is extern import HashSet[String], HashSet[String].add, NativeString.to_s, String.to_cstring, HashSet[String].as(Set[String]) `{
 432                 char *dir_path;
 433                 DIR *dir;
 434
 435                 dir_path = String_to_cstring( recv );
 436                 if ((dir = opendir(dir_path)) == NULL)
 437                 {
 438                         perror( dir_path );
 439                         exit( 1 );
 440                 }
 441                 else
 442                 {
 443                         HashSet_of_String results;
 444                         String file_name;
 445                         struct dirent *de;
 446
 447                         results = new_HashSet_of_String();
 448
 449                         while ( ( de = readdir( dir ) ) != NULL )
 450                                 if ( strcmp( de->d_name, ".." ) != 0 &&
 451                                         strcmp( de->d_name, "." ) != 0 )
 452                                 {
 453                                         file_name = NativeString_to_s( strdup( de->d_name ) );
 454                                         HashSet_of_String_add( results, file_name );
 455                                 }
 456
 457                         closedir( dir );
 458                         return HashSet_of_String_as_Set_of_String( results );
 459                 }
 460         `}
 461 end
 462
 463 redef class NativeString
 464         private fun file_exists: Bool is extern "string_NativeString_NativeString_file_exists_0"
 465         private fun file_stat: FileStat is extern "string_NativeString_NativeString_file_stat_0"
 466         private fun file_lstat: FileStat `{
 467                 struct stat* stat_element;
 468                 int res;
 469                 stat_element = malloc(sizeof(struct stat));
 470                 res = lstat(recv, stat_element);
 471                 if (res == -1) return NULL;
 472                 return stat_element;
 473         `}
 474         private fun file_mkdir: Bool is extern "string_NativeString_NativeString_file_mkdir_0"
 475         private fun file_delete: Bool is extern "string_NativeString_NativeString_file_delete_0"
 476         private fun file_chdir is extern "string_NativeString_NativeString_file_chdir_0"
 477         private fun file_realpath: NativeString is extern "file_NativeString_realpath"
 478 end
 479
 480 extern FileStat `{ struct stat * `}
 481 # This class is system dependent ... must reify the vfs
 482         fun mode: Int is extern "file_FileStat_FileStat_mode_0"
 483         fun atime: Int is extern "file_FileStat_FileStat_atime_0"
 484         fun ctime: Int is extern "file_FileStat_FileStat_ctime_0"
 485         fun mtime: Int is extern "file_FileStat_FileStat_mtime_0"
 486         fun size: Int is extern "file_FileStat_FileStat_size_0"
 487
 488         fun is_reg: Bool `{ return S_ISREG(recv->st_mode); `}
 489         fun is_dir: Bool `{ return S_ISDIR(recv->st_mode); `}
 490         fun is_chr: Bool `{ return S_ISCHR(recv->st_mode); `}
 491         fun is_blk: Bool `{ return S_ISBLK(recv->st_mode); `}
 492         fun is_fifo: Bool `{ return S_ISFIFO(recv->st_mode); `}
 493         fun is_lnk: Bool `{ return S_ISLNK(recv->st_mode); `}
 494         fun is_sock: Bool `{ return S_ISSOCK(recv->st_mode); `}
 495 end
 496
 497 # Instance of this class are standard FILE * pointers
 498 private extern NativeFile `{ FILE* `}
 499         fun io_read(buf: NativeString, len: Int): Int is extern "file_NativeFile_NativeFile_io_read_2"
 500         fun io_write(buf: NativeString, len: Int): Int is extern "file_NativeFile_NativeFile_io_write_2"
 501         fun io_close: Int is extern "file_NativeFile_NativeFile_io_close_0"
 502         fun file_stat: FileStat is extern "file_NativeFile_NativeFile_file_stat_0"
 503
 504         new io_open_read(path: NativeString) is extern "file_NativeFileCapable_NativeFileCapable_io_open_read_1"
 505         new io_open_write(path: NativeString) is extern "file_NativeFileCapable_NativeFileCapable_io_open_write_1"
 506         new native_stdin is extern "file_NativeFileCapable_NativeFileCapable_native_stdin_0"
 507         new native_stdout is extern "file_NativeFileCapable_NativeFileCapable_native_stdout_0"
 508         new native_stderr is extern "file_NativeFileCapable_NativeFileCapable_native_stderr_0"
 509 end
 510
 511 # Standard input.
 512 fun stdin: Stdin do return once new Stdin
 513
 514 # Standard output.
 515 fun stdout: OFStream do return once new Stdout
 516
 517 # Standard output for error.
 518 fun stderr: OFStream do return once new Stderr