src/compiler/separate_erasure_compiler.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Separate compilation of a Nit program with generic type erasure
  16 module separate_erasure_compiler
  17
  18 intrude import separate_compiler
  19
  20 # Add separate erased compiler specific options
  21 redef class ToolContext
  22         # --erasure
  23         var opt_erasure = new OptionBool("Erase generic types", "--erasure")
  24         # --rta
  25         var opt_rta = new OptionBool("Activate RTA (implicit with --global and --separate)", "--rta")
  26         # --no-check-erasure-cast
  27         var opt_no_check_erasure_cast = new OptionBool("Disable implicit casts on unsafe return with erasure-typing policy (dangerous)", "--no-check-erasure-cast")
  28
  29         redef init
  30         do
  31                 super
  32                 self.option_context.add_option(self.opt_erasure, self.opt_no_check_erasure_cast, opt_rta)
  33         end
  34
  35         redef fun process_options(args)
  36         do
  37                 super
  38
  39                 if opt_no_check_all.value then
  40                         opt_no_check_erasure_cast.value = true
  41                 end
  42         end
  43
  44         var erasure_compiler_phase = new ErasureCompilerPhase(self, null)
  45 end
  46
  47 class ErasureCompilerPhase
  48         super Phase
  49         redef fun process_mainmodule(mainmodule, given_mmodules) do
  50                 if not toolcontext.opt_erasure.value then return
  51
  52                 var modelbuilder = toolcontext.modelbuilder
  53                 var analysis = null
  54                 if toolcontext.opt_rta.value then
  55                         analysis = modelbuilder.do_rapid_type_analysis(mainmodule)
  56                 end
  57                 modelbuilder.run_separate_erasure_compiler(mainmodule, analysis)
  58         end
  59 end
  60
  61 redef class ModelBuilder
  62         fun run_separate_erasure_compiler(mainmodule: MModule, runtime_type_analysis: nullable RapidTypeAnalysis)
  63         do
  64                 var time0 = get_time
  65                 self.toolcontext.info("*** GENERATING C ***", 1)
  66
  67                 var compiler = new SeparateErasureCompiler(mainmodule, self, runtime_type_analysis)
  68                 compiler.do_compilation
  69                 compiler.display_stats
  70                 var time1 = get_time
  71                 self.toolcontext.info("*** END GENERATING C: {time1-time0} ***", 2)
  72                 write_and_make(compiler)
  73         end
  74 end
  75
  76 class SeparateErasureCompiler
  77         super SeparateCompiler
  78
  79         private var class_ids: Map[MClass, Int] is noinit
  80         private var class_colors: Map[MClass, Int] is noinit
  81         protected var vt_colors: Map[MVirtualTypeProp, Int] is noinit
  82
  83         init do
  84
  85                 # Class coloring
  86                 var poset = mainmodule.flatten_mclass_hierarchy
  87                 var mclasses = new HashSet[MClass].from(poset)
  88                 var colorer = new POSetColorer[MClass]
  89                 colorer.colorize(poset)
  90                 class_ids = colorer.ids
  91                 class_colors = colorer.colors
  92                 class_tables = self.build_class_typing_tables(mclasses)
  93
  94                 # lookup vt to build layout with
  95                 var vts = new HashMap[MClass, Set[MVirtualTypeProp]]
  96                 for mclass in mclasses do
  97                         vts[mclass] = new HashSet[MVirtualTypeProp]
  98                         for mprop in self.mainmodule.properties(mclass) do
  99                                 if mprop isa MVirtualTypeProp then
 100                                         vts[mclass].add(mprop)
 101                                 end
 102                         end
 103                 end
 104
 105                 # vt coloration
 106                 var vt_colorer = new POSetBucketsColorer[MClass, MVirtualTypeProp](poset, colorer.conflicts)
 107                 vt_colors = vt_colorer.colorize(vts)
 108                 vt_tables = build_vt_tables(mclasses)
 109         end
 110
 111         fun build_vt_tables(mclasses: Set[MClass]): Map[MClass, Array[nullable MPropDef]] do
 112                 var tables = new HashMap[MClass, Array[nullable MPropDef]]
 113                 for mclass in mclasses do
 114                         var table = new Array[nullable MPropDef]
 115                         # first, fill table from parents by reverse linearization order
 116                         var parents = new Array[MClass]
 117                         if mainmodule.flatten_mclass_hierarchy.has(mclass) then
 118                                 parents = mclass.in_hierarchy(mainmodule).greaters.to_a
 119                                 self.mainmodule.linearize_mclasses(parents)
 120                         end
 121                         for parent in parents do
 122                                 if parent == mclass then continue
 123                                 for mproperty in self.mainmodule.properties(parent) do
 124                                         if not mproperty isa MVirtualTypeProp then continue
 125                                         var color = vt_colors[mproperty]
 126                                         if table.length <= color then
 127                                                 for i in [table.length .. color[ do
 128                                                         table[i] = null
 129                                                 end
 130                                         end
 131                                         for mpropdef in mproperty.mpropdefs do
 132                                                 if mpropdef.mclassdef.mclass == parent then
 133                                                         table[color] = mpropdef
 134                                                 end
 135                                         end
 136                                 end
 137                         end
 138
 139                         # then override with local properties
 140                         for mproperty in self.mainmodule.properties(mclass) do
 141                                 if not mproperty isa MVirtualTypeProp then continue
 142                                 var color = vt_colors[mproperty]
 143                                 if table.length <= color then
 144                                         for i in [table.length .. color[ do
 145                                                 table[i] = null
 146                                         end
 147                                 end
 148                                 for mpropdef in mproperty.mpropdefs do
 149                                         if mpropdef.mclassdef.mclass == mclass then
 150                                                 table[color] = mpropdef
 151                                         end
 152                                 end
 153                         end
 154                         tables[mclass] = table
 155                 end
 156                 return tables
 157         end
 158
 159         # Build class tables
 160         fun build_class_typing_tables(mclasses: Set[MClass]): Map[MClass, Array[nullable MClass]] do
 161                 var tables = new HashMap[MClass, Array[nullable MClass]]
 162                 for mclass in mclasses do
 163                         var table = new Array[nullable MClass]
 164                         var supers = new Array[MClass]
 165                         if mainmodule.flatten_mclass_hierarchy.has(mclass) then
 166                                 supers = mclass.in_hierarchy(mainmodule).greaters.to_a
 167                         end
 168                         for sup in supers do
 169                                 var color = class_colors[sup]
 170                                 if table.length <= color then
 171                                         for i in [table.length .. color[ do
 172                                                 table[i] = null
 173                                         end
 174                                 end
 175                                 table[color] = sup
 176                         end
 177                         tables[mclass] = table
 178                 end
 179                 return tables
 180         end
 181
 182         redef fun compile_header_structs do
 183                 self.header.add_decl("typedef void(*nitmethod_t)(void); /* general C type representing a Nit method. */")
 184                 self.compile_header_attribute_structs
 185                 self.header.add_decl("struct class \{ int id; const char *name; int box_kind; int color; const struct vts_table *vts_table; const struct type_table *type_table; nitmethod_t vft[]; \}; /* general C type representing a Nit class. */")
 186                 self.header.add_decl("struct type_table \{ int size; int table[]; \}; /* colorized type table. */")
 187                 self.header.add_decl("struct vts_entry \{ short int is_nullable; const struct class *class; \}; /* link (nullable or not) between the vts and is bound. */")
 188                 self.header.add_decl("struct vts_table \{ int dummy; const struct vts_entry vts[]; \}; /* vts list of a C type representation. */")
 189                 self.header.add_decl("typedef struct instance \{ const struct class *class; nitattribute_t attrs[1]; \} val; /* general C type representing a Nit instance. */")
 190         end
 191
 192         redef fun compile_class_to_c(mclass: MClass)
 193         do
 194                 var mtype = mclass.intro.bound_mtype
 195                 var c_name = mclass.c_name
 196
 197                 var vft = self.method_tables[mclass]
 198                 var attrs = self.attr_tables[mclass]
 199                 var class_table = self.class_tables[mclass]
 200                 var v = self.new_visitor
 201
 202                 var rta = runtime_type_analysis
 203                 var is_dead = false # mclass.kind == abstract_kind or mclass.kind == interface_kind
 204                 if not is_dead and rta != null and not rta.live_classes.has(mclass) and mtype.ctype == "val*" and mclass.name != "NativeArray" then
 205                         is_dead = true
 206                 end
 207
 208                 v.add_decl("/* runtime class {c_name} */")
 209
 210                 self.provide_declaration("class_{c_name}", "extern const struct class class_{c_name};")
 211                 v.add_decl("extern const struct type_table type_table_{c_name};")
 212
 213                 # Build class vft
 214                 v.add_decl("const struct class class_{c_name} = \{")
 215                 v.add_decl("{class_ids[mclass]},")
 216                 v.add_decl("\"{mclass.name}\", /* class_name_string */")
 217                 v.add_decl("{self.box_kind_of(mclass)}, /* box_kind */")
 218                 v.add_decl("{class_colors[mclass]},")
 219                 if not is_dead then
 220                         if build_class_vts_table(mclass) then
 221                                 v.require_declaration("vts_table_{c_name}")
 222                                 v.add_decl("&vts_table_{c_name},")
 223                         else
 224                                 v.add_decl("NULL,")
 225                         end
 226                         v.add_decl("&type_table_{c_name},")
 227                         v.add_decl("\{")
 228                         for i in [0 .. vft.length[ do
 229                                 var mpropdef = vft[i]
 230                                 if mpropdef == null then
 231                                         v.add_decl("NULL, /* empty */")
 232                                 else
 233                                         assert mpropdef isa MMethodDef
 234                                         if rta != null and not rta.live_methoddefs.has(mpropdef) then
 235                                                 v.add_decl("NULL, /* DEAD {mclass.intro_mmodule}:{mclass}:{mpropdef} */")
 236                                                 continue
 237                                         end
 238                                         if true or mpropdef.mclassdef.bound_mtype.ctype != "val*" then
 239                                                 v.require_declaration("VIRTUAL_{mpropdef.c_name}")
 240                                                 v.add_decl("(nitmethod_t)VIRTUAL_{mpropdef.c_name}, /* pointer to {mclass.intro_mmodule}:{mclass}:{mpropdef} */")
 241                                         else
 242                                                 v.require_declaration("{mpropdef.c_name}")
 243                                                 v.add_decl("(nitmethod_t){mpropdef.c_name}, /* pointer to {mclass.intro_mmodule}:{mclass}:{mpropdef} */")
 244                                         end
 245                                 end
 246                         end
 247                         v.add_decl("\}")
 248                 end
 249                 v.add_decl("\};")
 250
 251                 # Build class type table
 252
 253                 v.add_decl("const struct type_table type_table_{c_name} = \{")
 254                 v.add_decl("{class_table.length},")
 255                 v.add_decl("\{")
 256                 for msuper in class_table do
 257                         if msuper == null then
 258                                 v.add_decl("-1, /* empty */")
 259                         else
 260                                 v.add_decl("{self.class_ids[msuper]}, /* {msuper} */")
 261                         end
 262                 end
 263                 v.add_decl("\}")
 264                 v.add_decl("\};")
 265
 266                 if mtype.ctype != "val*" or mtype.mclass.name == "Pointer" then
 267                         #Build instance struct
 268                         self.header.add_decl("struct instance_{c_name} \{")
 269                         self.header.add_decl("const struct class *class;")
 270                         self.header.add_decl("{mtype.ctype} value;")
 271                         self.header.add_decl("\};")
 272
 273                         #Build BOX
 274                         self.provide_declaration("BOX_{c_name}", "val* BOX_{c_name}({mtype.ctype});")
 275                         v.add_decl("/* allocate {mtype} */")
 276                         v.add_decl("val* BOX_{mtype.c_name}({mtype.ctype} value) \{")
 277                         v.add("struct instance_{c_name}*res = nit_alloc(sizeof(struct instance_{c_name}));")
 278                         v.require_declaration("class_{c_name}")
 279                         v.add("res->class = &class_{c_name};")
 280                         v.add("res->value = value;")
 281                         v.add("return (val*)res;")
 282                         v.add("\}")
 283
 284                         if mtype.mclass.name != "Pointer" then return
 285
 286                         v = new_visitor
 287                         self.provide_declaration("NEW_{c_name}", "{mtype.ctype} NEW_{c_name}();")
 288                         v.add_decl("/* allocate {mtype} */")
 289                         v.add_decl("{mtype.ctype} NEW_{c_name}() \{")
 290                         if is_dead then
 291                                 v.add_abort("{mclass} is DEAD")
 292                         else
 293                                 var res = v.new_named_var(mtype, "self")
 294                                 res.is_exact = true
 295                                 v.add("{res} = nit_alloc(sizeof(struct instance_{mtype.c_name}));")
 296                                 v.require_declaration("class_{c_name}")
 297                                 v.add("{res}->class = &class_{c_name};")
 298                                 v.add("((struct instance_{mtype.c_name}*){res})->value = NULL;")
 299                                 v.add("return {res};")
 300                         end
 301                         v.add("\}")
 302                         return
 303                 else if mclass.name == "NativeArray" then
 304                         #Build instance struct
 305                         self.header.add_decl("struct instance_{c_name} \{")
 306                         self.header.add_decl("const struct class *class;")
 307                         self.header.add_decl("int length;")
 308                         self.header.add_decl("val* values[];")
 309                         self.header.add_decl("\};")
 310
 311                         #Build NEW
 312                         self.provide_declaration("NEW_{c_name}", "{mtype.ctype} NEW_{c_name}(int length);")
 313                         v.add_decl("/* allocate {mtype} */")
 314                         v.add_decl("{mtype.ctype} NEW_{c_name}(int length) \{")
 315                         var res = v.get_name("self")
 316                         v.add_decl("struct instance_{c_name} *{res};")
 317                         var mtype_elt = mtype.arguments.first
 318                         v.add("{res} = nit_alloc(sizeof(struct instance_{c_name}) + length*sizeof({mtype_elt.ctype}));")
 319                         v.require_declaration("class_{c_name}")
 320                         v.add("{res}->class = &class_{c_name};")
 321                         v.add("{res}->length = length;")
 322                         v.add("return (val*){res};")
 323                         v.add("\}")
 324                         return
 325                 else if mtype.mclass.kind == extern_kind and mtype.mclass.name != "NativeString" then
 326                         var pointer_type = mainmodule.pointer_type
 327
 328                         self.provide_declaration("NEW_{c_name}", "{mtype.ctype} NEW_{c_name}();")
 329                         v.add_decl("/* allocate {mtype} */")
 330                         v.add_decl("{mtype.ctype} NEW_{c_name}() \{")
 331                         if is_dead then
 332                                 v.add_abort("{mclass} is DEAD")
 333                         else
 334                                 var res = v.new_named_var(mtype, "self")
 335                                 res.is_exact = true
 336                                 v.add("{res} = nit_alloc(sizeof(struct instance_{pointer_type.c_name}));")
 337                                 #v.add("{res}->type = type;")
 338                                 v.require_declaration("class_{c_name}")
 339                                 v.add("{res}->class = &class_{c_name};")
 340                                 v.add("((struct instance_{pointer_type.c_name}*){res})->value = NULL;")
 341                                 v.add("return {res};")
 342                         end
 343                         v.add("\}")
 344                         return
 345                 end
 346
 347                 #Build NEW
 348                 self.provide_declaration("NEW_{c_name}", "{mtype.ctype} NEW_{c_name}(void);")
 349                 v.add_decl("/* allocate {mtype} */")
 350                 v.add_decl("{mtype.ctype} NEW_{c_name}(void) \{")
 351                 if is_dead then
 352                         v.add_abort("{mclass} is DEAD")
 353                 else
 354
 355                         var res = v.new_named_var(mtype, "self")
 356                         res.is_exact = true
 357                         v.add("{res} = nit_alloc(sizeof(struct instance) + {attrs.length}*sizeof(nitattribute_t));")
 358                         v.require_declaration("class_{c_name}")
 359                         v.add("{res}->class = &class_{c_name};")
 360                         self.generate_init_attr(v, res, mtype)
 361                         v.set_finalizer res
 362                         v.add("return {res};")
 363                 end
 364                 v.add("\}")
 365         end
 366
 367         private fun build_class_vts_table(mclass: MClass): Bool do
 368                 if self.vt_tables[mclass].is_empty then return false
 369
 370                 self.provide_declaration("vts_table_{mclass.c_name}", "extern const struct vts_table vts_table_{mclass.c_name};")
 371
 372                 var v = new_visitor
 373                 v.add_decl("const struct vts_table vts_table_{mclass.c_name} = \{")
 374                 v.add_decl("0, /* dummy */")
 375                 v.add_decl("\{")
 376
 377                 for vt in self.vt_tables[mclass] do
 378                         if vt == null then
 379                                 v.add_decl("\{-1, NULL\}, /* empty */")
 380                         else
 381                                 var is_null = 0
 382                                 var bound = retrieve_vt_bound(mclass.intro.bound_mtype, vt.as(MVirtualTypeDef).bound)
 383                                 while bound isa MNullableType do
 384                                         bound = retrieve_vt_bound(mclass.intro.bound_mtype, bound.mtype)
 385                                         is_null = 1
 386                                 end
 387                                 var vtclass = bound.as(MClassType).mclass
 388                                 v.require_declaration("class_{vtclass.c_name}")
 389                                 v.add_decl("\{{is_null}, &class_{vtclass.c_name}\}, /* {vt} */")
 390                         end
 391                 end
 392                 v.add_decl("\},")
 393                 v.add_decl("\};")
 394                 return true
 395         end
 396
 397         private fun retrieve_vt_bound(anchor: MClassType, mtype: nullable MType): MType do
 398                 if mtype == null then
 399                         print "NOT YET IMPLEMENTED: retrieve_vt_bound on null"
 400                         abort
 401                 end
 402                 if mtype isa MVirtualType then
 403                         return mtype.anchor_to(mainmodule, anchor)
 404                 else if mtype isa MParameterType then
 405                         return mtype.anchor_to(mainmodule, anchor)
 406                 else
 407                         return mtype
 408                 end
 409         end
 410
 411         redef fun compile_types
 412         do
 413                 compile_color_consts(vt_colors)
 414         end
 415
 416         redef fun new_visitor do return new SeparateErasureCompilerVisitor(self)
 417
 418         # Stats
 419
 420         private var class_tables: Map[MClass, Array[nullable MClass]] is noinit
 421         private var vt_tables: Map[MClass, Array[nullable MPropDef]] is noinit
 422
 423         redef fun display_sizes
 424         do
 425                 print "# size of subtyping tables"
 426                 print "\ttotal \tholes"
 427                 var total = 0
 428                 var holes = 0
 429                 for t, table in class_tables do
 430                         total += table.length
 431                         for e in table do if e == null then holes += 1
 432                 end
 433                 print "\t{total}\t{holes}"
 434
 435                 print "# size of resolution tables"
 436                 print "\ttotal \tholes"
 437                 total = 0
 438                 holes = 0
 439                 for t, table in vt_tables do
 440                         total += table.length
 441                         for e in table do if e == null then holes += 1
 442                 end
 443                 print "\t{total}\t{holes}"
 444
 445                 print "# size of methods tables"
 446                 print "\ttotal \tholes"
 447                 total = 0
 448                 holes = 0
 449                 for t, table in method_tables do
 450                         total += table.length
 451                         for e in table do if e == null then holes += 1
 452                 end
 453                 print "\t{total}\t{holes}"
 454
 455                 print "# size of attributes tables"
 456                 print "\ttotal \tholes"
 457                 total = 0
 458                 holes = 0
 459                 for t, table in attr_tables do
 460                         total += table.length
 461                         for e in table do if e == null then holes += 1
 462                 end
 463                 print "\t{total}\t{holes}"
 464         end
 465 end
 466
 467 class SeparateErasureCompilerVisitor
 468         super SeparateCompilerVisitor
 469
 470         redef fun compile_callsite(callsite, arguments)
 471         do
 472                 var res = super
 473                 if callsite.erasure_cast and not self.compiler.as(SeparateErasureCompiler).modelbuilder.toolcontext.opt_no_check_erasure_cast.value then
 474                         assert res != null
 475                         var mtype = callsite.msignature.return_mtype
 476                         assert mtype != null
 477                         self.add("/* Erasure cast for return {res} isa {mtype} */")
 478                         var cond = self.type_test(res, mtype, "erasure")
 479                         self.add("if (!{cond}) \{")
 480                         #var x = self.class_name_string(res)
 481                         #var y = self.class_name_string(arguments.first)
 482                         #self.add("PRINT_ERROR(\"Erasure cast: expected {mtype} (self is %s), got %s for {res}\\n\", {y}, {x});")
 483                         self.add_abort("Cast failed")
 484                         self.add("\}")
 485                 end
 486                 return res
 487         end
 488
 489         redef fun init_instance(mtype)
 490         do
 491                 self.require_declaration("NEW_{mtype.mclass.c_name}")
 492                 return self.new_expr("NEW_{mtype.mclass.c_name}()", mtype)
 493         end
 494
 495         redef fun type_test(value, mtype, tag)
 496         do
 497                 self.add("/* type test for {value.inspect} isa {mtype} */")
 498
 499                 var res = self.new_var(bool_type)
 500
 501                 var cltype = self.get_name("cltype")
 502                 self.add_decl("int {cltype};")
 503                 var idtype = self.get_name("idtype")
 504                 self.add_decl("int {idtype};")
 505
 506                 var maybe_null = self.maybe_null(value)
 507                 var accept_null = "0"
 508                 if mtype isa MNullableType then
 509                         mtype = mtype.mtype
 510                         accept_null = "1"
 511                 end
 512                 if mtype isa MParameterType then
 513                         # Here we get the bound of the the formal type (eh, erasure...)
 514                         mtype = mtype.resolve_for(self.frame.mpropdef.mclassdef.bound_mtype, self.frame.mpropdef.mclassdef.bound_mtype, self.frame.mpropdef.mclassdef.mmodule, false)
 515                         if mtype isa MNullableType then
 516                                 mtype = mtype.mtype
 517                                 accept_null = "1"
 518                         end
 519                 end
 520
 521                 if value.mcasttype.is_subtype(self.frame.mpropdef.mclassdef.mmodule, self.frame.mpropdef.mclassdef.bound_mtype, mtype) then
 522                         self.add("{res} = 1; /* easy {value.inspect} isa {mtype}*/")
 523                         if compiler.modelbuilder.toolcontext.opt_typing_test_metrics.value then
 524                                 self.compiler.count_type_test_skipped[tag] += 1
 525                                 self.add("count_type_test_skipped_{tag}++;")
 526                         end
 527                         return res
 528                 end
 529
 530                 var class_ptr
 531                 if value.mtype.ctype == "val*" then
 532                         class_ptr = "{value}->class->"
 533                 else
 534                         var mclass = value.mtype.as(MClassType).mclass
 535                         self.require_declaration("class_{mclass.c_name}")
 536                         class_ptr = "class_{mclass.c_name}."
 537                 end
 538
 539                 if mtype isa MClassType then
 540                         self.require_declaration("class_{mtype.mclass.c_name}")
 541                         self.add("{cltype} = class_{mtype.mclass.c_name}.color;")
 542                         self.add("{idtype} = class_{mtype.mclass.c_name}.id;")
 543                         if compiler.modelbuilder.toolcontext.opt_typing_test_metrics.value then
 544                                 self.compiler.count_type_test_resolved[tag] += 1
 545                                 self.add("count_type_test_resolved_{tag}++;")
 546                         end
 547                 else if mtype isa MVirtualType then
 548                         var recv = self.frame.arguments.first
 549                         var recv_ptr
 550                         if recv.mtype.ctype == "val*" then
 551                                 recv_ptr = "{recv}->class->"
 552                         else
 553                                 var mclass = recv.mtype.as(MClassType).mclass
 554                                 self.require_declaration("class_{mclass.c_name}")
 555                                 recv_ptr = "class_{mclass.c_name}."
 556                         end
 557                         var entry = self.get_name("entry")
 558                         self.add("struct vts_entry {entry};")
 559                         self.require_declaration(mtype.mproperty.const_color)
 560                         self.add("{entry} = {recv_ptr}vts_table->vts[{mtype.mproperty.const_color}];")
 561                         self.add("{cltype} = {entry}.class->color;")
 562                         self.add("{idtype} = {entry}.class->id;")
 563                         if maybe_null and accept_null == "0" then
 564                                 var is_nullable = self.get_name("is_nullable")
 565                                 self.add_decl("short int {is_nullable};")
 566                                 self.add("{is_nullable} = {entry}.is_nullable;")
 567                                 accept_null = is_nullable.to_s
 568                         end
 569                         if compiler.modelbuilder.toolcontext.opt_typing_test_metrics.value then
 570                                 self.compiler.count_type_test_unresolved[tag] += 1
 571                                 self.add("count_type_test_unresolved_{tag}++;")
 572                         end
 573                 else
 574                         self.debug("type_test({value.inspect}, {mtype})")
 575                         abort
 576                 end
 577
 578                 # check color is in table
 579                 if maybe_null then
 580                         self.add("if({value} == NULL) \{")
 581                         self.add("{res} = {accept_null};")
 582                         self.add("\} else \{")
 583                 end
 584                 self.add("if({cltype} >= {class_ptr}type_table->size) \{")
 585                 self.add("{res} = 0;")
 586                 self.add("\} else \{")
 587                 self.add("{res} = {class_ptr}type_table->table[{cltype}] == {idtype};")
 588                 self.add("\}")
 589                 if maybe_null then
 590                         self.add("\}")
 591                 end
 592
 593                 return res
 594         end
 595
 596         redef fun unbox_extern(value, mtype)
 597         do
 598                 if mtype isa MClassType and mtype.mclass.kind == extern_kind and
 599                    mtype.mclass.name != "NativeString" then
 600                         var pointer_type = compiler.mainmodule.pointer_type
 601                         var res = self.new_var_extern(mtype)
 602                         self.add "{res} = ((struct instance_{pointer_type.c_name}*){value})->value; /* unboxing {value.mtype} */"
 603                         return res
 604                 else
 605                         return value
 606                 end
 607         end
 608
 609         redef fun box_extern(value, mtype)
 610         do
 611                 if mtype isa MClassType and mtype.mclass.kind == extern_kind and
 612                    mtype.mclass.name != "NativeString" then
 613                         var valtype = compiler.mainmodule.pointer_type
 614                         var res = self.new_var(mtype)
 615                         if compiler.runtime_type_analysis != null and not compiler.runtime_type_analysis.live_types.has(value.mtype.as(MClassType)) then
 616                                 self.add("/*no boxing of {value.mtype}: {value.mtype} is not live! */")
 617                                 self.add("PRINT_ERROR(\"Dead code executed!\\n\"); show_backtrace(1);")
 618                                 return res
 619                         end
 620                         self.require_declaration("BOX_{valtype.c_name}")
 621                         self.add("{res} = BOX_{valtype.c_name}({value}); /* boxing {value.mtype} */")
 622                         self.require_declaration("class_{mtype.c_name}")
 623                         self.add("{res}->class = &class_{mtype.c_name};")
 624                         return res
 625                 else
 626                         return value
 627                 end
 628         end
 629
 630         redef fun class_name_string(value)
 631         do
 632                 var res = self.get_name("var_class_name")
 633                 self.add_decl("const char* {res};")
 634                 if value.mtype.ctype == "val*" then
 635                         self.add "{res} = {value} == NULL ? \"null\" : {value}->class->name;"
 636                 else
 637                         self.require_declaration("class_{value.mtype.c_name}")
 638                         self.add "{res} = class_{value.mtype.c_name}.name;"
 639                 end
 640                 return res
 641         end
 642
 643         redef fun native_array_instance(elttype, length)
 644         do
 645                 var nclass = self.get_class("NativeArray")
 646                 var mtype = nclass.get_mtype([elttype])
 647                 var res = self.new_var(mtype)
 648                 res.is_exact = true
 649                 self.require_declaration("NEW_{nclass.c_name}")
 650                 self.add("{res} = NEW_{nclass.c_name}({length});")
 651                 return res
 652         end
 653
 654         redef fun calloc_array(ret_type, arguments)
 655         do
 656                 var ret = ret_type.as(MClassType)
 657                 self.require_declaration("NEW_{ret.mclass.c_name}")
 658                 self.ret(self.new_expr("NEW_{ret.mclass.c_name}({arguments[1]})", ret_type))
 659         end
 660 end