lib/nitcorn/http_request_buffer.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Http request parsing for buffered inputs.
  16 module http_request_buffer
  17
  18 intrude import libevent
  19
  20 # Connection rebuilding HTTP requests
  21 #
  22 # Subclass should refine `read_full_request` and avoid `read_callback`.
  23 class HTTPConnection
  24         super Connection
  25
  26         private var in_request = false
  27         private var in_header = false
  28         private var in_body = false
  29         private var current_header = new Array[Writable]
  30         private var current_body = new Array[Writable]
  31         private var content_length = 0
  32         private var current_length = 0
  33
  34         # FIXME will not work if the header/body delimiter falls between two watermarks windows.
  35         redef fun read_callback(str)
  36         do
  37                 # is this the start of a request?
  38                 if not in_request then parse_start
  39
  40                 var body: String
  41                 # parsing header
  42                 if in_header then
  43                         body = parse_header(str)
  44                 else
  45                         body = str
  46                 end
  47
  48                 # parsing body
  49                 if in_body then parse_body(body)
  50         end
  51
  52         # Callback when a full HTTP request is received
  53         fun read_http_request(str: String) do end
  54
  55         # Prepare for a new request
  56         private fun parse_start do
  57                 in_request = true
  58                 # reset values
  59                 current_header.clear
  60                 current_body.clear
  61                 current_length = 0
  62                 content_length = 0
  63                 # next step is to find the header part
  64                 in_header = true
  65                 in_body = false
  66         end
  67
  68         # We are receiving the header of a request
  69         #
  70         # Return parsed body found in header window
  71         private fun parse_header(str: String): String do
  72                 # split in CRLF
  73                 var parts = str.split("\r\n\r\n")
  74                 # first part go in the header
  75                 current_header.add parts.shift
  76
  77                 # if there is more part we are done with headers
  78                 if not parts.is_empty then
  79                         # get content-length
  80                         parse_content_length current_header.join
  81                         # next step if to parse body
  82                         in_header = false
  83                         in_body = true
  84                         # return rest of the body
  85                         return parts.join("\r\n")
  86                 end
  87                 return ""
  88         end
  89
  90         # Extract and set `content_length` from header.
  91         private fun parse_content_length(head: String) do
  92                 var hlines = head.split("\r\n")
  93                 for hline in hlines do
  94                         var hparts = hline.split(": ")
  95                         if hparts.first == "Content-Length" then
  96                                 content_length = hparts[1].to_i
  97                         end
  98                 end
  99         end
 100
 101         # We are receiving body parts.
 102         private fun parse_body(str: String) do
 103                 current_length += str.byte_length
 104                 current_body.add str
 105                 if current_length >= content_length then
 106                         parse_end
 107                 end
 108         end
 109
 110         # We have reached the end of the body
 111         private fun parse_end do
 112                 var res = new FlatBuffer.with_capacity(content_length)
 113                 for ch in current_header do res.append ch.write_to_string
 114                 res.append "\r\n\r\n"
 115                 for cb in current_body do res.append cb.write_to_string
 116                 read_http_request res.to_s
 117                 in_request = false
 118         end
 119 end