lib/glesv2/glesv2.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2014 Alexis Laferrière <alexis.laf@xymus.net>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # OpenGL graphics rendering library for embedded systems, version 2.0
  18 #
  19 # This is a low-level wrapper, it can be useful for developers already familiar
  20 # with the C API of OpenGL. Most developers will prefer to use higher level
  21 # wrappers such as `mnit` and `gammit`.
  22 #
  23 # Defines the annotations `glsl_vertex_shader` and `glsl_fragment_shader`
  24 # applicable on string literals to check shader code using `glslangValidator`.
  25 # The tool must be in PATH. It can be downloaded from
  26 # https://www.khronos.org/opengles/sdk/tools/Reference-Compiler/
  27 #
  28 # Most services of this module are a direct wrapper of the underlying
  29 # C library. If a method or class is not documented in Nit, refer to
  30 # the official documentation by the Khronos Group at:
  31 # http://www.khronos.org/opengles/sdk/docs/man/
  32 module glesv2 is
  33         pkgconfig
  34         new_annotation glsl_vertex_shader
  35         new_annotation glsl_fragment_shader
  36 end
  37
  38
  39 in "C Header" `{
  40         #include <GLES2/gl2.h>
  41 `}
  42
  43 # OpenGL ES program to which we attach shaders
  44 extern class GLProgram `{GLuint`}
  45         # Create a new program
  46         #
  47         # The newly created instance should be checked using `is_ok`.
  48         new `{ return glCreateProgram(); `}
  49
  50         # Is this a valid program?
  51         fun is_ok: Bool `{ return glIsProgram(recv); `}
  52
  53         # Attach a `shader` to this program
  54         fun attach_shader(shader: GLShader) `{ glAttachShader(recv, shader); `}
  55
  56         # Set the location for the attribute by `name`
  57         fun bind_attrib_location(index: Int, name: String) import String.to_cstring `{
  58                 GLchar *c_name = String_to_cstring(name);
  59                 glBindAttribLocation(recv, index, c_name);
  60         `}
  61
  62         # Get the location of the attribute by `name`
  63         #
  64         # Returns `-1` if there is no active attribute named `name`.
  65         fun attrib_location(name: String): Int import String.to_cstring `{
  66                 GLchar *c_name = String_to_cstring(name);
  67                 return glGetAttribLocation(recv, c_name);
  68         `}
  69
  70         # Get the location of the uniform by `name`
  71         #
  72         # Returns `-1` if there is no active uniform named `name`.
  73         fun uniform_location(name: String): Int import String.to_cstring `{
  74                 GLchar *c_name = String_to_cstring(name);
  75                 return glGetUniformLocation(recv, c_name);
  76         `}
  77
  78         # Query information on this program
  79         fun query(pname: Int): Int `{
  80                 int val;
  81                 glGetProgramiv(recv, pname, &val);
  82                 return val;
  83         `}
  84
  85         # Try to link this program
  86         #
  87         # Check result using `in_linked` and `info_log`.
  88         fun link `{ glLinkProgram(recv); `}
  89
  90         # Is this program linked?
  91         fun is_linked: Bool do return query(0x8B82) != 0
  92
  93         # Use this program for the following operations
  94         fun use `{ glUseProgram(recv); `}
  95
  96         # Delete this program
  97         fun delete `{ glDeleteProgram(recv); `}
  98
  99         # Has this program been deleted?
 100         fun is_deleted: Bool do return query(0x8B80) != 0
 101
 102         # Validate whether this program can be executed in the current OpenGL state
 103         #
 104         # Check results using `is_validated` and `info_log`.
 105         fun validate `{ glValidateProgram(recv); `}
 106
 107         # Boolean result of `validate`, must be called after `validate`
 108         fun is_validated: Bool do return query(0x8B83) != 0
 109
 110         # Retrieve the information log of this program
 111         #
 112         # Useful with `link` and `validate`
 113         fun info_log: String import NativeString.to_s `{
 114                 int size;
 115                 glGetProgramiv(recv, GL_INFO_LOG_LENGTH, &size);
 116                 GLchar *msg = malloc(size);
 117                 glGetProgramInfoLog(recv, size, NULL, msg);
 118                 return NativeString_to_s(msg);
 119         `}
 120
 121         # Number of active uniform in this program
 122         #
 123         # This should be the number of uniforms declared in all shader, except
 124         # unused uniforms which may have been optimized out.
 125         fun n_active_uniforms: Int do return query(0x8B86)
 126
 127         # Length of the longest uniform name in this program, including `\n`
 128         fun active_uniform_max_length: Int do return query(0x8B87)
 129
 130         # Number of active attributes in this program
 131         #
 132         # This should be the number of uniforms declared in all shader, except
 133         # unused uniforms which may have been optimized out.
 134         fun n_active_attributes: Int do return query(0x8B89)
 135
 136         # Length of the longest uniform name in this program, including `\n`
 137         fun active_attribute_max_length: Int do return query(0x8B8A)
 138
 139         # Number of shaders attached to this program
 140         fun n_attached_shaders: Int do return query(0x8B85)
 141
 142         # Name of the active attribute at `index`
 143         fun active_attrib_name(index: Int): String
 144         do
 145                 var max_size = active_attribute_max_length
 146                 return active_attrib_name_native(index, max_size).to_s
 147         end
 148         private fun active_attrib_name_native(index, max_size: Int): NativeString `{
 149                 char *name = malloc(max_size);
 150                 glGetActiveAttrib(recv, index, max_size, NULL, NULL, NULL, name);
 151                 return name;
 152         `}
 153
 154         # Size of the active attribute at `index`
 155         fun active_attrib_size(index: Int): Int `{
 156                 int size;
 157                 glGetActiveAttrib(recv, index, 0, NULL, NULL, &size, NULL);
 158                 return size;
 159         `}
 160
 161         # Type of the active attribute at `index`
 162         #
 163         # May only be float related data types (single float, vectors and matrix).
 164         fun active_attrib_type(index: Int): GLFloatDataType `{
 165                 GLenum type;
 166                 glGetActiveAttrib(recv, index, 0, NULL, &type, NULL, NULL);
 167                 return type;
 168         `}
 169
 170         # Name of the active uniform at `index`
 171         fun active_uniform_name(index: Int): String
 172         do
 173                 var max_size = active_attribute_max_length
 174                 return active_uniform_name_native(index, max_size).to_s
 175         end
 176         private fun active_uniform_name_native(index, max_size: Int): NativeString `{
 177                 char *name = malloc(max_size);
 178                 glGetActiveUniform(recv, index, max_size, NULL, NULL, NULL, name);
 179                 return name;
 180         `}
 181
 182         # Size of the active uniform at `index`
 183         fun active_uniform_size(index: Int): Int `{
 184                 int size;
 185                 glGetActiveUniform(recv, index, 0, NULL, NULL, &size, NULL);
 186                 return size;
 187         `}
 188
 189         # Type of the active uniform at `index`
 190         #
 191         # May be any data type supported by OpenGL ES 2.0 shaders.
 192         fun active_uniform_type(index: Int): GLDataType `{
 193                 GLenum type;
 194                 glGetActiveUniform(recv, index, 0, NULL, &type, NULL, NULL);
 195                 return type;
 196         `}
 197 end
 198
 199 # Abstract OpenGL ES shader object, implemented by `GLFragmentShader` and `GLVertexShader`
 200 extern class GLShader `{GLuint`}
 201         # Set the source of the shader
 202         fun source=(code: NativeString) `{
 203                 glShaderSource(recv, 1, (GLchar const **)&code, NULL);
 204         `}
 205
 206         # Source of the shader, if available
 207         #
 208         # Returns `null` if the source is not available, usually when the shader
 209         # was created from a binary file.
 210         fun source: nullable String
 211         do
 212                 var size = query(0x8B88)
 213                 if size == 0 then return null
 214                 return source_native(size).to_s
 215         end
 216
 217         private fun source_native(size: Int): NativeString `{
 218                 GLchar *code = malloc(size);
 219                 glGetShaderSource(recv, size, NULL, code);
 220                 return code;
 221         `}
 222
 223         # Query information on this shader
 224         protected fun query(pname: Int): Int `{
 225                 int val;
 226                 glGetShaderiv(recv, pname, &val);
 227                 return val;
 228         `}
 229
 230         # Try to compile `source` into a binary GPU program
 231         #
 232         # Check the result using `is_compiled` and `info_log`
 233         fun compile `{ glCompileShader(recv); `}
 234
 235         # Has this shader been compiled?
 236         fun is_compiled: Bool do return query(0x8B81) != 0
 237
 238         # Delete this shader
 239         fun delete `{ glDeleteShader(recv); `}
 240
 241         # Has this shader been deleted?
 242         fun is_deleted: Bool do return query(0x8B80) != 0
 243
 244         # Is this a valid shader?
 245         fun is_ok: Bool `{ return glIsShader(recv); `}
 246
 247         # Retrieve the information log of this shader
 248         #
 249         # Useful with `link` and `validate`
 250         fun info_log: String import NativeString.to_s `{
 251                 int size;
 252                 glGetShaderiv(recv, GL_INFO_LOG_LENGTH, &size);
 253                 GLchar *msg = malloc(size);
 254                 glGetShaderInfoLog(recv, size, NULL, msg);
 255                 return NativeString_to_s(msg);
 256         `}
 257 end
 258
 259 # An OpenGL ES 2.0 fragment shader
 260 extern class GLFragmentShader
 261         super GLShader
 262
 263         # Create a new fragment shader
 264         #
 265         # The newly created instance should be checked using `is_ok`.
 266         new `{ return glCreateShader(GL_FRAGMENT_SHADER); `}
 267 end
 268
 269 # An OpenGL ES 2.0 vertex shader
 270 extern class GLVertexShader
 271         super GLShader
 272
 273         # Create a new fragment shader
 274         #
 275         # The newly created instance should be checked using `is_ok`.
 276         new `{ return glCreateShader(GL_VERTEX_SHADER); `}
 277 end
 278
 279 # An array of `Float` associated to a program variable
 280 class VertexArray
 281         var index: Int
 282
 283         # Number of data per vertex
 284         var count: Int
 285
 286         protected var glfloat_array: GLfloatArray
 287
 288         init(index, count: Int, array: Array[Float])
 289         do
 290                 self.index = index
 291                 self.count = count
 292                 self.glfloat_array = new GLfloatArray(array)
 293         end
 294
 295         fun attrib_pointer do attrib_pointer_intern(index, count, glfloat_array)
 296         private fun attrib_pointer_intern(index, count: Int, array: GLfloatArray) `{
 297                 glVertexAttribPointer(index, count, GL_FLOAT, GL_FALSE, 0, array);
 298         `}
 299
 300         fun enable do enable_intern(index)
 301         private fun enable_intern(index: Int) `{ glEnableVertexAttribArray(index); `}
 302
 303         fun draw_arrays_triangles do draw_arrays_triangles_intern(index, count)
 304         private fun draw_arrays_triangles_intern(index, count: Int) `{
 305                 glDrawArrays(GL_TRIANGLES, index, count);
 306         `}
 307 end
 308
 309 # Low level array of `Float`
 310 extern class GLfloatArray `{GLfloat *`}
 311         new (array: Array[Float]) import Array[Float].length, Array[Float].[] `{
 312                 int i;
 313                 int len = Array_of_Float_length(array);
 314                 GLfloat *vertex_array = malloc(sizeof(GLfloat)*len);
 315                 for (i = 0; i < len; i ++) vertex_array[i] = Array_of_Float__index(array, i);
 316                 return vertex_array;
 317         `}
 318 end
 319
 320 # General type for OpenGL enumerations
 321 extern class GLEnum `{ GLenum `}
 322
 323         redef fun hash `{ return recv; `}
 324
 325         redef fun ==(o) do return o != null and is_same_type(o) and o.hash == self.hash
 326 end
 327
 328 # An OpenGL ES 2.0 error code
 329 extern class GLError
 330         super GLEnum
 331         fun is_ok: Bool do return is_no_error
 332         fun is_no_error: Bool `{ return recv == GL_NO_ERROR; `}
 333         fun is_invalid_enum: Bool `{ return recv == GL_INVALID_ENUM; `}
 334         fun is_invalid_value: Bool `{ return recv == GL_INVALID_VALUE; `}
 335         fun is_invalid_operation: Bool `{ return recv == GL_INVALID_OPERATION; `}
 336         fun is_invalid_framebuffer_operation: Bool `{ return recv == GL_INVALID_FRAMEBUFFER_OPERATION; `}
 337         fun is_out_of_memory: Bool `{ return recv == GL_OUT_OF_MEMORY; `}
 338
 339         redef fun to_s
 340         do
 341                 if is_no_error then return "No error"
 342                 if is_invalid_enum then return "Invalid enum"
 343                 if is_invalid_value then return "Invalid value"
 344                 if is_invalid_operation then return "Invalid operation"
 345                 if is_invalid_framebuffer_operation then return "invalid framebuffer operation"
 346                 if is_out_of_memory then return "Out of memory"
 347                 return "Truely unknown error"
 348         end
 349 end
 350
 351 protected fun assert_no_gl_error
 352 do
 353         var error = gl.error
 354         if not error.is_ok then
 355                 print "GL error: {error}"
 356                 abort
 357         end
 358 end
 359
 360 redef class Sys
 361         private var gles = new GLES is lazy
 362 end
 363
 364 # Entry points to OpenGL ES 2.0 services
 365 fun gl: GLES do return sys.gles
 366
 367 # OpenGL ES 2.0 services
 368 class GLES
 369
 370         # Clear the color buffer to `red`, `green`, `blue` and `alpha`
 371         fun clear_color(red, green, blue, alpha: Float) `{
 372                 glClearColor(red, green, blue, alpha);
 373         `}
 374
 375         # Set the viewport
 376         fun viewport(x, y, width, height: Int) `{ glViewport(x, y, width, height); `}
 377
 378         # Clear the `buffer`
 379         fun clear(buffer: GLBuffer) `{ glClear(buffer); `}
 380
 381         # Last error from OpenGL ES 2.0
 382         fun error: GLError `{ return glGetError(); `}
 383
 384         # Query the boolean value at `key`
 385         private fun get_bool(key: Int): Bool `{
 386                 GLboolean val;
 387                 glGetBooleanv(key, &val);
 388                 return val == GL_TRUE;
 389         `}
 390
 391         # Query the floating point value at `key`
 392         private fun get_float(key: Int): Float `{
 393                 GLfloat val;
 394                 glGetFloatv(key, &val);
 395                 return val;
 396         `}
 397
 398         # Query the integer value at `key`
 399         private fun get_int(key: Int): Int `{
 400                 GLint val;
 401                 glGetIntegerv(key, &val);
 402                 return val;
 403         `}
 404
 405         # Does this driver support shader compilation?
 406         #
 407         # Should always return `true` in OpenGL ES 2.0 and 3.0.
 408         fun shader_compiler: Bool do return get_bool(0x8DFA)
 409 end
 410
 411 # Float related data types of OpenGL ES 2.0 shaders
 412 #
 413 # Only data types supported by shader attributes, as seen with
 414 # `GLProgram::active_attrib_type`.
 415 extern class GLFloatDataType
 416         super GLEnum
 417
 418         fun is_float: Bool `{ return recv == GL_FLOAT; `}
 419         fun is_float_vec2: Bool `{ return recv == GL_FLOAT_VEC2; `}
 420         fun is_float_vec3: Bool `{ return recv == GL_FLOAT_VEC3; `}
 421         fun is_float_vec4: Bool `{ return recv == GL_FLOAT_VEC4; `}
 422         fun is_float_mat2: Bool `{ return recv == GL_FLOAT_MAT2; `}
 423         fun is_float_mat3: Bool `{ return recv == GL_FLOAT_MAT3; `}
 424         fun is_float_mat4: Bool `{ return recv == GL_FLOAT_MAT4; `}
 425
 426         # Instances of `GLFloatDataType` can be equal to instances of `GLDataType`
 427         redef fun ==(o)
 428         do
 429                 return o != null and o isa GLFloatDataType and o.hash == self.hash
 430         end
 431 end
 432
 433 # All data types of OpenGL ES 2.0 shaders
 434 #
 435 # These types can be used by shader uniforms, as seen with
 436 # `GLProgram::active_uniform_type`.
 437 extern class GLDataType
 438         super GLFloatDataType
 439
 440         fun is_int: Bool `{ return recv == GL_INT; `}
 441         fun is_int_vec2: Bool `{ return recv == GL_INT_VEC2; `}
 442         fun is_int_vec3: Bool `{ return recv == GL_INT_VEC3; `}
 443         fun is_int_vec4: Bool `{ return recv == GL_INT_VEC4; `}
 444         fun is_bool: Bool `{ return recv == GL_BOOL; `}
 445         fun is_bool_vec2: Bool `{ return recv == GL_BOOL_VEC2; `}
 446         fun is_bool_vec3: Bool `{ return recv == GL_BOOL_VEC3; `}
 447         fun is_bool_vec4: Bool `{ return recv == GL_BOOL_VEC4; `}
 448         fun is_sampler_2d: Bool `{ return recv == GL_SAMPLER_2D; `}
 449         fun is_sampler_cube: Bool `{ return recv == GL_SAMPLER_CUBE; `}
 450 end
 451
 452 # Set of buffers as a bitwise OR mask, used by `GLES::clear`
 453 #
 454 # ~~~
 455 # var buffers = (new GLBuffer).color.depth
 456 # gl.clear buffers
 457 # ~~~
 458 extern class GLBuffer `{ GLbitfield `}
 459         # Get an empty set of buffers
 460         new `{ return 0; `}
 461
 462         # Add the color buffer to the returned buffer set
 463         fun color: GLBuffer `{ return recv | GL_COLOR_BUFFER_BIT; `}
 464
 465         # Add the depth buffer to the returned buffer set
 466         fun depth: GLBuffer `{ return recv | GL_DEPTH_BUFFER_BIT; `}
 467
 468         # Add the stencil buffer to the returned buffer set
 469         fun stencil: GLBuffer `{ return recv | GL_STENCIL_BUFFER_BIT; `}
 470 end