contrib/asteronits/src/asteronits.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Portable game to destroy asteroids
  16 module asteronits is
  17         app_name "Asteronits"
  18         app_namespace "org.nitlanguage.asteronits"
  19         app_version(1, 0, git_revision)
  20
  21         android_manifest_activity """android:screenOrientation="sensorLandscape""""
  22         android_api_target 10
  23 end
  24
  25 import gamnit::flat
  26
  27 import game_logic
  28 import spritesheet
  29
  30 redef class Spritesheet
  31         # Largest meteors, organized by color
  32         var meteors_big: Array[Array[Texture]] = [
  33                 [meteor_brown_big1, meteor_brown_big2, meteor_brown_big3, meteor_brown_big4],
  34                 [meteor_grey_big1, meteor_grey_big2, meteor_grey_big3, meteor_grey_big4]]
  35
  36         # Medium size meteors, organized by color
  37         var meteors_med: Array[Array[Texture]] = [
  38                 [meteor_brown_med1, meteor_brown_med3],
  39                 [meteor_grey_med1, meteor_grey_med2]]
  40
  41         # Small meteors, organized by color
  42         var meteors_small: Array[Array[Texture]] = [
  43                 [meteor_brown_small1, meteor_brown_small2],
  44                 [meteor_grey_small1, meteor_grey_small2]]
  45
  46         # Tiny meteors, organized by color
  47         #
  48         # TODO use these in particles
  49         var meteors_tiny: Array[Array[Texture]] = [
  50                 [meteor_brown_tiny1, meteor_brown_tiny2],
  51                 [meteor_grey_tiny1, meteor_grey_tiny2]]
  52
  53         # Available ships
  54         var ships: Array[Texture] = [enemy_green1]
  55 end
  56
  57 redef class App
  58
  59         # Current world in play
  60         var world = new World(12, 2, display.aspect_ratio) is lazy
  61
  62         # Sound effects
  63         private var fx_fire = new Sound("sounds/fire.ogg")
  64         private var fx_explosion_ship = new Sound("sounds/explosion_ship.wav")
  65         private var fx_explosion_asteroids = new Sound("sounds/explosion_asteroids.wav")
  66
  67         redef fun on_create
  68         do
  69                 super
  70
  71                 # Move the camera to show all the world world in the screen range
  72                 world_camera.reset_height(world.half_height * 2.0)
  73         end
  74
  75         # Main spritesheet with ships, asteroids and beams
  76         var spritesheet = new Spritesheet
  77
  78         redef fun update(dt)
  79         do
  80                 # Update game logic
  81                 world.do_turn dt
  82
  83                 # Setup new world if all asteroids are destroyed
  84                 if world.asteroids.is_empty then
  85                         sprites.clear
  86                         world = new World(world.n_asteroids*2, world.n_asteroid_parts+1, display.aspect_ratio)
  87                 end
  88         end
  89
  90         redef fun accept_event(event)
  91         do
  92                 if event isa QuitEvent then
  93                         exit 0
  94                 else if event isa KeyEvent then
  95                         var thrust = event.thrust
  96                         if thrust != 0.0 then
  97                                 app.world.ship.applied_thrust = if event.is_down then thrust else 0.0
  98                                 return true
  99                         end
 100
 101                         var rot = event.rotation
 102                         if rot != 0.0 then
 103                                 app.world.ship.applied_rotation = if event.is_down then rot else 0.0
 104                                 return true
 105                         end
 106
 107                         if event.name == "space" and event.is_down then
 108                                 app.world.ship.fire
 109                                 return true
 110                         else if event.name == "escape" then
 111                                 exit 0
 112                         else if event.name == "." and event.is_down then
 113                                 dynamic_resolution_ratio *= 2.0
 114                                 print dynamic_resolution_ratio
 115                         else if event.name == "," and event.is_down then
 116                                 dynamic_resolution_ratio /= 2.0
 117                                 print dynamic_resolution_ratio
 118                         end
 119                 end
 120
 121                 return false
 122         end
 123 end
 124
 125 redef class SpacialObject
 126         # Main `Sprite` to draw for this object
 127         var sprite: Sprite is noinit
 128
 129         # All `Sprites` composing this object
 130         var sprites: Collection[Sprite] = new Ref[Sprite](sprite) is lazy
 131
 132         init do app.sprites.add_all sprites
 133
 134         redef fun do_turn(dt)
 135         do
 136                 super
 137                 sprite.rotation = rotation - pi/2.0
 138         end
 139
 140         redef fun destroy
 141         do
 142                 super
 143                 for s in sprites do app.sprites.remove s
 144         end
 145 end
 146
 147 redef class Asteroid
 148
 149         init
 150         do
 151                 # Select texture from `size` and `color`
 152                 var tex = if size == 3 then
 153                                 app.spritesheet.meteors_big[color].rand
 154                         else if size == 2 then
 155                                 app.spritesheet.meteors_med[color].rand
 156                         else app.spritesheet.meteors_small[color].rand
 157
 158                 sprite = new Sprite(tex, center)
 159                 super
 160         end
 161
 162         redef fun destroy
 163         do
 164                 super
 165                 app.fx_explosion_asteroids.play
 166         end
 167 end
 168
 169 redef class Bullet
 170         init
 171         do
 172                 sprite = new Sprite(app.spritesheet.laser_blue01, center)
 173                 super
 174         end
 175 end
 176
 177 redef class Ship
 178         init
 179         do
 180                 sprite = new Sprite(app.spritesheet.ships.rand, center)
 181                 sprites = [sprite, thrust_sprite]
 182
 183                 super
 184         end
 185
 186         private var thrust_sprite = new Sprite(app.spritesheet.fire09, new Point3d[Float](0.0, 0.0, 0.0))
 187
 188         private var sprites_with_fire: Array[Sprite] = [thrust_sprite, sprite] is lazy
 189
 190         redef fun do_turn(dt)
 191         do
 192                 super
 193
 194                 # Update position of the thrust sprite
 195                 var dist_to_engine = 45.0
 196                 thrust_sprite.center.x = center.x - dist_to_engine*rotation.cos
 197                 thrust_sprite.center.y = center.y - dist_to_engine*rotation.sin
 198                 thrust_sprite.center.z = center.z
 199                 thrust_sprite.rotation = rotation - pi/2.0
 200
 201                 # Show or hide the thrust sprite
 202                 if applied_thrust > 0.0 then
 203                         thrust_sprite.alpha = 1.0
 204
 205                 else if thrust_sprite.alpha > 0.0 then
 206                         thrust_sprite.alpha -= dt*4.0
 207                         if thrust_sprite.alpha < 0.0 then thrust_sprite.alpha = 0.0
 208                 end
 209
 210                 # HACK, the "enemy" ship used for the player points downwards
 211                 sprite.rotation += pi
 212         end
 213
 214         redef fun fire
 215         do
 216                 super
 217                 app.fx_fire.play
 218         end
 219
 220         redef fun hit
 221         do
 222                 super
 223                 app.fx_explosion_ship.play
 224         end
 225 end
 226
 227 redef class KeyEvent
 228
 229         # How does this event affect the ship thrust?
 230         fun thrust: Float
 231         do
 232                 if name == "up" or name == "w" then return 1.0
 233                 return 0.0
 234         end
 235
 236         # How does this event affect the ship thrust?
 237         fun rotation: Float
 238         do
 239                 if name == "right" or name == "d" then return -1.0
 240                 if name == "left" or name == "a" then return 1.0
 241                 return 0.0
 242         end
 243 end