src/parser/nit.sablecc3xx

   1
   2 /* This file is part of NIT ( http://www.nitlanguage.org ).
   3  *
   4  * Copyright 2008-2009 Jean Privat <jean@pryen.org>
   5  *
   6  * Licensed under the Apache License, Version 2.0 (the "License");
   7  * you may not use this file except in compliance with the License.
   8  * You may obtain a copy of the License at
   9  *
  10  *     http://www.apache.org/licenses/LICENSE-2.0
  11  *
  12  * Unless required by applicable law or agreed to in writing, software
  13  * distributed under the License is distributed on an "AS IS" BASIS,
  14  * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15  * See the License for the specific language governing permissions and
  16  * limitations under the License.
  17  */
  18
  19 /* This grammar defines the NIT language. */
  20
  21 /*****************************************************************************/
  22 Helpers
  23 /*****************************************************************************/
  24
  25 all = [0 .. 0xFF];
  26 lowercase = ['a' .. 'z'];
  27 uppercase = ['A' .. 'Z'];
  28 digit = ['0' .. '9'];
  29 letter = lowercase | uppercase | digit | '_';
  30
  31 tab = 9;
  32 cr = 13;
  33 lf = 10;
  34 any = [all - [cr + lf]];
  35
  36 // characers inside strings and super-strings (atomaton powaa)
  37 str_char
  38         = [any - [['"' + '{'] + '\']]
  39         | '\' any
  40         ;
  41 str_body = str_char*;
  42
  43 eol_helper = cr lf | cr | lf; // This takes care of different platforms
  44
  45 /*****************************************************************************/
  46 States
  47 /*****************************************************************************/
  48 initial;
  49
  50
  51 /*****************************************************************************/
  52 Tokens
  53 /*****************************************************************************/
  54
  55 blank = (' ' | tab)+;
  56
  57 eol = eol_helper;
  58 comment = '#' any* eol_helper;
  59
  60 kwpackage = 'package';
  61 kwimport = 'import';
  62 kwclass = 'class';
  63 kwabstract = 'abstract';
  64 kwinterface = 'interface';
  65 kwuniversal = 'universal';
  66 kwspecial = 'special';
  67 kwend = 'end';
  68 kwmeth = 'fun';
  69 kwtype = 'type';
  70 kwinit = 'init';
  71 kwredef = 'redef';
  72 kwis = 'is';
  73 kwdo = 'do';
  74 kwreadable = 'readable';
  75 kwwritable = 'writable';
  76 kwvar = 'var';
  77 kwintern = 'intern';
  78 kwextern = 'extern';
  79 kwprotected = 'protected';
  80 kwprivate = 'private';
  81 kwintrude = 'intrude';
  82 kwif = 'if';
  83 kwthen = 'then';
  84 kwelse = 'else';
  85 kwwhile = 'while';
  86 kwloop = 'loop';
  87 kwfor = 'for';
  88 kwin = 'in';
  89 kwand = 'and';
  90 kwor = 'or';
  91 kwnot = 'not';
  92 kwreturn = 'return';
  93 kwcontinue = 'continue';
  94 kwbreak = 'break';
  95 kwabort = 'abort';
  96 kwassert = 'assert';
  97 kwnew = 'new';
  98 kwisa = 'isa';
  99 kwonce = 'once';
 100 kwsuper = 'super';
 101 kwself = 'self';
 102 kwtrue = 'true';
 103 kwfalse = 'false';
 104 kwnull = 'null';
 105 kwas = 'as';
 106 kwnullable = 'nullable';
 107 kwisset = 'isset';
 108 kwlabel = 'label';
 109
 110 opar = '(';
 111 cpar = ')';
 112 obra = '[';
 113 cbra = ']';
 114 comma = ',';
 115 column = ':';
 116 quad = '::';
 117 assign = '=';
 118 pluseq = '+=';
 119 minuseq = '-=';
 120 dotdotdot = '...';
 121 dotdot = '..';
 122 dot = '.';
 123 plus = '+';
 124 minus = '-';
 125 star = '*';
 126 slash = '/';
 127 percent = '%';
 128 eq = '==';
 129 ne = '!=';
 130 lt = '<';
 131 le = '<=';
 132 gt = '>';
 133 ge = '>=';
 134 starship = '<=>';
 135 bang='!';
 136
 137 classid = uppercase letter*;
 138 id = lowercase letter*;
 139 attrid = '_' lowercase letter*;
 140
 141 number = digit+;
 142 float = digit* '.' digit+;
 143 char = ''' [any - ''']* ''';
 144 string = '"' str_body '"';
 145 start_string = '"' str_body '{';
 146 mid_string = '}' str_body '{';
 147 end_string = '}' str_body '"';
 148
 149
 150 /*****************************************************************************/
 151 Ignored Tokens
 152 /*****************************************************************************/
 153
 154 blank;
 155
 156 /*****************************************************************************/
 157 Productions
 158 /*****************************************************************************/
 159
 160 /* MODULES *******************************************************************/
 161 module
 162         = packagedecl? [imports]:import* [classdefs]:classdef* implicit_top_class? implicit_main_class? {-> New module(packagedecl, [imports.import],[classdefs.classdef,implicit_top_class.classdef,implicit_main_class.classdef])};
 163
 164 packagedecl
 165         = [doc]:no kwpackage no id [n2]:n1 {-> New packagedecl(doc.doc, kwpackage, id)};
 166
 167 import
 168         = {std} [doc]:no visibility kwimport no id [n2]:n1              {-> New import.std(visibility, kwimport, id)}
 169         | {no} [doc]:no visibility kwimport no kwend [n2]:n1    {-> New import.no(visibility, kwimport, kwend)}
 170         ;
 171
 172 implicit_top_class {-> classdef}
 173         = propdefs_toplevel {-> New classdef.top([propdefs_toplevel.propdef])};
 174
 175 implicit_main_class {-> classdef?}
 176         = implicit_main_meth {-> New classdef.main([implicit_main_meth.propdef])}
 177         | {null} n {-> Null}
 178         ;
 179 implicit_main_meth {-> propdef}
 180         = [doc]:no stmts no {-> New propdef.main_meth(Null, stmts.expr)};
 181
 182 /* CLASSES *******************************************************************/
 183 classdef
 184         = [doc]:no redef visibility classkind no classid formaldefs? [specials]:special* propdefs? [n2]:no kwend {-> New classdef.std(doc.doc, redef.kwredef, visibility, classkind, classid, [formaldefs.formaldef], [specials.superclass], [propdefs.propdef])};
 185 redef {-> kwredef?}
 186         = kwredef? {-> kwredef};
 187 classkind
 188         = {concrete} kwclass
 189         | {abstract} kwabstract kwclass
 190         | {interface} kwinterface
 191         | {universal} kwuniversal
 192         ;
 193
 194 formaldefs {-> formaldef*}
 195         = obra no formaldef formaldefs_tail* [n2]:no cbra {-> [formaldef, formaldefs_tail.formaldef]};
 196 formaldefs_tail {-> formaldef}
 197         = comma no formaldef {-> formaldef};
 198 formaldef
 199         = classid typing? {-> New formaldef(classid, typing.type)};
 200
 201 special {-> superclass}
 202         = {special} no kwspecial [n2]:no type {-> New superclass(kwspecial, Null, type)}
 203         | {super} no kwsuper [n2]:no type {-> New superclass(Null, kwsuper, type)}
 204         ;
 205
 206 propdefs~toplevel {-> propdef*}
 207         = propdef~toplevel n1 propdefs_tail~toplevel* {-> [propdef~toplevel.propdef, propdefs_tail~toplevel.propdef]}
 208         ;
 209 propdefs_tail~toplevel {-> propdef}
 210         = propdef~toplevel n1 {-> propdef~toplevel.propdef}
 211         ;
 212 propdef~toplevel {-> propdef}
 213         = {meth} [doc]:no redef visibility kwmeth methid signature kwdo stmtso kwend? {-> New propdef.concrete_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature, stmtso.expr)}
 214         | {assign_return} [doc]:no redef visibility kwmeth methid_noassign signature_withret assign no assign_return {-> New propdef.concrete_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid_noassign.methid, signature_withret.signature, assign_return.expr)}
 215 !toplevel| {deferred} [doc]:no redef visibility kwmeth methid signature kwis kwabstract {-> New propdef.deferred_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature)}
 216 !toplevel| {intern} [doc]:no redef visibility kwmeth methid signature kwis kwintern {-> New propdef.intern_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature)}
 217         | {extern} [doc]:no redef visibility kwmeth methid signature kwis kwextern string? {-> New propdef.extern_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature, string)}
 218 !toplevel| {var} [doc]:no readable writable redef visibility kwvar attrid typing? {-> New propdef.attr(doc.doc, readable.able, writable.able, redef.kwredef, visibility, kwvar, attrid, typing.type, Null)}
 219 !toplevel| {var2} [doc]:no readable writable redef visibility kwvar attrid typing? assign [n2]:no expr {-> New propdef.attr(doc.doc, readable.able, writable.able, redef.kwredef, visibility, kwvar, attrid, typing.type, expr)}
 220 !toplevel| {init} [doc]:no redef visibility kwinit methid? signature kwdo stmtso kwend? {-> New propdef.concrete_init(doc.doc, redef.kwredef, visibility, kwinit, methid, signature, stmtso.expr)}
 221 !toplevel| {type} [doc]:no redef visibility kwtype classid typing {-> New propdef.type(doc.doc, redef.kwredef, visibility, kwtype, classid, typing.type)}
 222         ;
 223 readable {-> able?}
 224         = redef kwreadable {-> New able.read(redef.kwredef, kwreadable)}
 225         | {empty} {-> Null}
 226         ;
 227 writable {-> able?}
 228         = redef kwwritable {-> New able.write(redef.kwredef, kwwritable)}
 229         | {empty} {-> Null}
 230         ;
 231
 232 visibility
 233         = {public} {-> New visibility.public()}
 234         | {private} kwprivate no {-> New visibility.private(kwprivate)}
 235         | {protected} kwprotected no {-> New visibility.protected(kwprotected)}
 236         | {intrude} kwintrude no {-> New visibility.intrude(kwintrude)}
 237         ;
 238
 239 methid~noassign {-> methid}
 240         = {id} id {-> New methid.id(id)}
 241         | {plus} plus {-> New methid.plus(plus)}
 242         | {minus} minus {-> New methid.minus(minus)}
 243         | {star} star {-> New methid.star(star)}
 244         | {slash} slash {-> New methid.slash(slash)}
 245         | {percent} percent {-> New methid.percent(percent)}
 246         | {eq} eq {-> New methid.eq(eq)}
 247         | {ne} ne {-> New methid.ne(ne)}
 248         | {le} le {-> New methid.le(le)}
 249         | {ge} ge {-> New methid.ge(ge)}
 250         | {lt} lt {-> New methid.lt(lt)}
 251         | {gt} gt {-> New methid.gt(gt)}
 252         | {bra} obra cbra {-> New methid.bra(obra, cbra)}
 253         | {starship} starship {-> New methid.starship(starship)}
 254 !noassign       | {assign} id assign {-> New methid.assign(id, assign)}
 255 !noassign       | {braassign} obra cbra assign {-> New methid.braassign(obra, cbra, assign)}
 256         ;
 257
 258 signature~withret {-> signature}
 259         = params? typing closure_decls {-> New signature([params.param], typing.type, [closure_decls.closure_decl])}
 260         | {noclosures} params? typing no {-> New signature([params.param], typing.type, [])}
 261 !withret| {noret} params? closure_decls {-> New signature([params.param], Null, [closure_decls.closure_decl])}
 262 !withret| {noretnoclosures} params? no {-> New signature([params.param], Null, [])}
 263         ;
 264
 265 signature_noclosures {-> signature}
 266         = params? typing? {-> New signature([params.param], typing.type, [])};
 267
 268 params {-> param*}
 269         = opar no param params_tail* [n2]:no cpar {-> [param, params_tail.param]}
 270         | {empty} opar no cpar {-> []}
 271         ;
 272 params_tail {-> param}
 273         = comma no param {-> param};
 274 param
 275         = {untyped} id {-> New param(id, Null, Null)}
 276         | id typing dotdotdot? {-> New param(id, typing.type, dotdotdot)}
 277         ;
 278
 279 closure_decls {->closure_decl*}
 280         = no closure_decl+ {-> [closure_decl]};
 281 closure_decl
 282         = kwbreak? bang id signature_noclosures n {-> New closure_decl(kwbreak, bang, id, signature_noclosures.signature, Null)}
 283         | {optionnal} kwbreak? bang id signature_noclosures kwdo stmtso n {-> New closure_decl(kwbreak, bang, id, signature_noclosures.signature, stmtso.expr)}
 284         | {assign} kwbreak? bang id signature_noclosures assign no assign_continue n {-> New closure_decl(kwbreak, bang, id, signature_noclosures.signature, assign_continue.expr)}
 285         ;
 286
 287 assign_return{-> expr}
 288         = expr_final {-> New expr.return(Null, expr_final.expr)}
 289         ;
 290
 291
 292 /* TYPES *********************************************************************/
 293 type~nobra {-> type}
 294         = {simple} kwnullable? classid {-> New type(kwnullable, classid, [])}
 295 !nobra  | {generic} kwnullable? classid obra no types [n2]:no cbra {-> New type(kwnullable, classid, [types.type])}
 296         ;
 297 types {-> type*}
 298         = type types_tail* {-> [type, types_tail.type]};
 299 types_tail {-> type}
 300         = comma no type {-> type};
 301 typing {-> type}
 302         = column no type {-> type};
 303
 304 /* STATMENTS *****************************************************************/
 305 stmtso~withelse~withend {-> expr?}
 306         = {block} n stmts [n2]:n kwend {-> stmts.expr}
 307         | {emptyblock} n kwend {-> New expr.block([])}
 308         | {emptyoneline} kwend {-> New expr.block([])}
 309 !withend| {oneline} stmt~withelse {-> stmt~withelse.expr}
 310         ;
 311 stmts {-> expr}
 312         = stmt stmts_tail* {-> New expr.block([stmt.expr, stmts_tail.expr])};
 313 stmts_tail {-> expr}
 314         = n stmt {-> stmt.expr};
 315 stmt~withelse {-> expr}
 316         = {vardecl} vardecl~withelse {-> vardecl~withelse.expr}
 317         | {assign} assignment~withelse {-> assignment~withelse.expr}
 318         | {return} kwreturn expr_final~withelse? {-> New expr.return(kwreturn, expr_final~withelse.expr)}
 319         | {break} kwbreak label? expr_final~withelse? {-> New expr.break(kwbreak, label, expr_final~withelse.expr)}
 320         | {abort} kwabort {-> New expr.abort(kwabort)}
 321         | {continue} kwcontinue label? expr_final~withelse? {-> New expr.continue(kwcontinue, label, expr_final~withelse.expr)}
 322         | {do} do~withelse {-> do~withelse.expr}
 323         | {if} if~withelse {-> if~withelse.expr}
 324         | {while} while~withelse {-> while~withelse.expr}
 325         | {loop} loop~withelse {-> loop~withelse.expr}
 326         | {for} for~withelse {-> for~withelse.expr}
 327         | {assert} assert~withelse {-> assert~withelse.expr}
 328         | {call} recv id args_nopar closure_defs~withelse? {-> New expr.call(recv.expr, id, [args_nopar.expr], [closure_defs~withelse.closure_def])}
 329         | {super} qualified? kwsuper args_nopar {-> New expr.super(qualified, kwsuper, [args_nopar.expr])}
 330         | {init} recv kwinit args_nopar {-> New expr.init(recv.expr, kwinit, [args_nopar.expr])}
 331         ;
 332
 333 label= kwlabel id;
 334
 335 closure_defs~withelse {-> closure_def*}
 336         = {one} closure_def_last~withelse {-> [closure_def_last~withelse.closure_def]}
 337         | closure_def closure_defs~withelse {-> [closure_def, closure_defs~withelse.closure_def]}
 338         ;
 339
 340 closure_def_last~withelse {-> closure_def}
 341         = bang [id]:closure_id idlist? kwdo stmtso~withelse_withend label? {-> New closure_def(bang, id, [idlist.id], kwdo, stmtso~withelse_withend.expr, label)}
 342         | {noend} bang [id]:closure_id idlist? kwdo stmt~withelse {-> New closure_def(bang, id, [idlist.id], kwdo, stmt~withelse.expr, Null)}
 343         | {assign} bang [id]:closure_id idlist? assign no assign_continue~withelse {-> New closure_def(bang, id, [idlist.id], Null, assign_continue~withelse.expr, Null)}
 344         ;
 345
 346 closure_def {-> closure_def}
 347         = bang [id]:closure_id idlist? kwdo n stmts [n2]:n {-> New closure_def(bang, id, [idlist.id], kwdo, stmts.expr, Null)}
 348         | {empty} bang [id]:closure_id idlist? kwdo n {-> New closure_def(bang, id, [idlist.id], kwdo, Null, Null)}
 349         ;
 350 closure_id
 351         = {simple} id
 352         | {break} kwbreak
 353         ;
 354
 355 assign_continue~withelse{-> expr}
 356         = expr_final~withelse {-> New expr.continue(Null, Null, expr_final~withelse.expr)}
 357         ;
 358
 359 vardecl~withelse{-> expr}
 360         = kwvar id typing? {-> New expr.vardecl(kwvar, id, typing.type, Null, Null)}
 361         | {assign} kwvar id typing? assign no expr_final~withelse {-> New expr.vardecl(kwvar, id, typing.type, assign, expr_final~withelse.expr)}
 362         ;
 363
 364 assignment~withelse {-> expr}
 365         = {attr} recv attrid assign expr_final~withelse {-> New expr.attr_assign(recv.expr, attrid, assign, expr_final~withelse.expr)}
 366         | {call} recv id args assign expr_final~withelse {-> New expr.call_assign(recv.expr, id, [args.expr], assign,  expr_final~withelse.expr)}
 367         | {bra} expr_atom braargs assign expr_final~withelse {-> New expr.bra_assign(expr_atom.expr, [braargs.expr], assign,  expr_final~withelse.expr)}
 368         | {attr_re} recv attrid assign_op expr_final~withelse {-> New expr.attr_reassign(recv.expr, attrid, assign_op,  expr_final~withelse.expr)}
 369         | {call_re} recv id args assign_op expr_final~withelse {-> New expr.call_reassign(recv.expr, id, [args.expr], assign_op,  expr_final~withelse.expr)}
 370         | {bra_re} expr_atom braargs assign_op expr_final~withelse {-> New expr.bra_reassign(expr_atom.expr, [braargs.expr], assign_op,  expr_final~withelse.expr)}
 371         ;
 372 assign_op
 373         = {plus} pluseq
 374         | {minus} minuseq
 375         ;
 376
 377 do~withelse {-> expr}
 378         = kwdo stmtso~withelse_withend label? {-> New expr.do(kwdo, stmtso~withelse_withend.expr, label)}
 379         | {noend} kwdo stmt~withelse {-> New expr.do(kwdo, stmt~withelse.expr, Null)}
 380         ;
 381
 382 if~withelse {-> expr}
 383         = {onelineelse} kwif no expr [n2]:no kwthen stmt_withelse kwelse stmtso~withelse {-> New expr.if(kwif, expr, stmt_withelse.expr, stmtso~withelse.expr)}
 384 !withelse       | {oneline} kwif no expr [n2]:no kwthen stmt {-> New expr.if(kwif, expr, stmt.expr, Null)}
 385 !withelse       | {block} kwif no expr [n2]:no kwthen [n3]:n stmts [n4]:n elsepartblock {-> New expr.if(kwif, expr, stmts.expr, elsepartblock.expr)}
 386 !withelse       | {emptyblock} kwif no expr [n2]:no kwthen [n3]:n? elsepartblock {-> New expr.if(kwif, expr, Null, elsepartblock.expr)}
 387         ;
 388 elsepartblock {-> expr?}
 389         = {else} kwelse stmtso {-> stmtso.expr}
 390         | {empty} kwend {-> Null}
 391         ;
 392
 393 loop~withelse {-> expr}
 394         = kwloop stmtso~withelse_withend label? {-> New expr.loop(kwloop, stmtso~withelse_withend.expr, label)}
 395         | {noend} kwloop stmt~withelse {-> New expr.loop(kwloop, stmt~withelse.expr, Null)}
 396         ;
 397
 398 while~withelse {-> expr}
 399         = kwwhile no expr [n2]:no kwdo stmtso~withelse_withend label? {-> New expr.while(kwwhile, expr, kwdo, stmtso~withelse_withend.expr, label)}
 400         | {noend} kwwhile no expr [n2]:no kwdo stmt~withelse {-> New expr.while(kwwhile, expr, kwdo, stmt~withelse.expr, Null)}
 401         ;
 402
 403 for~withelse {-> expr}
 404         = kwfor no id [n2]:no kwin [n3]:no expr [n4]:no kwdo stmtso~withelse_withend label? {-> New expr.for(kwfor, id, expr, kwdo, stmtso~withelse_withend.expr, label)}
 405         | {noend} kwfor no id [n2]:no kwin [n3]:no expr [n4]:no kwdo stmt~withelse {-> New expr.for(kwfor, id, expr, kwdo, stmt~withelse.expr, Null)}
 406         ;
 407
 408 assert~withelse {-> expr}
 409         = {else} kwassert assertid? expr_final_withelse kwelse stmtso~withelse {-> New expr.assert(kwassert, assertid.id, expr_final_withelse.expr, stmtso~withelse.expr)}
 410 !withelse| {noelse} kwassert assertid? expr_final {-> New expr.assert(kwassert, assertid.id, expr_final.expr, Null)}
 411         ;
 412 assertid {-> id}
 413         = id column {-> id};
 414
 415 /* EXPRESSIONS ***************************************************************/
 416 expr_final~nopar~withelse~nobra {-> expr}
 417         = expr~nopar~nobra {-> expr~nopar~nobra.expr}
 418         | {closure_call} recv~nobra id args closure_defs~withelse {-> New expr.call(recv~nobra.expr, id, [args.expr], [closure_defs~withelse.closure_def])}
 419 !nobra!nopar    | {closure_bra} expr_atom braargs closure_defs~withelse {-> New expr.bra(expr_atom.expr, [braargs.expr], [closure_defs~withelse.closure_def])}
 420         ;
 421
 422 expr~nopar~nobra {-> expr}
 423         = expr_and~nopar~nobra {-> expr_and~nopar~nobra.expr}
 424         | {ifexpr} kwif [n1]:no expr [n2]:no kwthen [n3]:no [then]:expr [n4]:no kwelse [n5]:no [else]:expr~nopar~nobra {-> New expr.ifexpr(kwif, expr, kwthen, then, kwelse, else.expr)}
 425         ;
 426
 427 expr_and~nopar~nobra {-> expr}
 428         = expr_not~nopar~nobra {-> expr_not~nopar~nobra.expr}
 429         | {or} expr_and~nopar~nobra kwor no expr_not~nopar~nobra {-> New expr.or(expr_and~nopar~nobra.expr, expr_not~nopar~nobra.expr)}
 430         | {and} expr_and~nopar~nobra kwand no expr_not~nopar~nobra {-> New expr.and(expr_and~nopar~nobra.expr, expr_not~nopar~nobra.expr)}
 431         | {or_else} expr_and~nopar~nobra kwor kwelse no expr_not~nopar~nobra {-> New expr.or_else(expr_and~nopar~nobra.expr, expr_not~nopar~nobra.expr)}
 432         ;
 433
 434 expr_not~nopar~nobra {-> expr}
 435         = expr_eq~nopar~nobra {-> expr_eq~nopar~nobra.expr}
 436         | {not} kwnot no expr_not~nopar~nobra {-> New expr.not(kwnot, expr_not~nopar~nobra.expr)}
 437         ;
 438
 439 expr_eq~nopar~nobra {-> expr}
 440         = expr_add~nopar~nobra {-> expr_add~nopar~nobra.expr}
 441         | {eq} expr_add~nopar~nobra eq no [expr2]:expr_add~nopar~nobra {-> New expr.eq(expr_add~nopar~nobra.expr, expr2.expr)}
 442         | {ee} expr_add~nopar~nobra kwis no [expr2]:expr_add~nopar~nobra {-> New expr.ee(expr_add~nopar~nobra.expr, expr2.expr)}
 443         | {ne} expr_add~nopar~nobra ne no [expr2]:expr_add~nopar~nobra {-> New expr.ne(expr_add~nopar~nobra.expr, expr2.expr)}
 444         | {lt} expr_add~nopar~nobra lt no [expr2]:expr_add~nopar~nobra {-> New expr.lt(expr_add~nopar~nobra.expr, expr2.expr)}
 445         | {le} expr_add~nopar~nobra le no [expr2]:expr_add~nopar~nobra {-> New expr.le(expr_add~nopar~nobra.expr, expr2.expr)}
 446         | {gt} expr_add~nopar~nobra gt no [expr2]:expr_add~nopar~nobra {-> New expr.gt(expr_add~nopar~nobra.expr, expr2.expr)}
 447         | {ge} expr_add~nopar~nobra ge no [expr2]:expr_add~nopar~nobra {-> New expr.ge(expr_add~nopar~nobra.expr, expr2.expr)}
 448         | {starship} expr_add~nopar~nobra starship no [expr2]:expr_add~nopar~nobra {-> New expr.starship(expr_add~nopar~nobra.expr, expr2.expr)}
 449         | {isa} expr_add~nopar~nobra kwisa no type~nobra {-> New expr.isa(expr_add~nopar~nobra.expr, type~nobra.type)}
 450         ;
 451
 452 expr_add~nopar~nobra {-> expr}
 453         =  expr_mul~nopar~nobra {-> expr_mul~nopar~nobra.expr}
 454         | {plus} expr_add~nopar~nobra plus no [expr2]:expr_mul~nopar~nobra {-> New expr.plus(expr_add~nopar~nobra.expr, expr2.expr)}
 455         | {minus} expr_add~nopar~nobra minus no [expr2]:expr_mul~nopar~nobra {-> New expr.minus(expr_add~nopar~nobra.expr, expr2.expr)}
 456         ;
 457
 458 expr_mul~nopar~nobra {-> expr}
 459         = expr_minus~nopar~nobra {-> expr_minus~nopar~nobra.expr}
 460         | {star} expr_mul~nopar~nobra star no [expr2]:expr_minus~nopar~nobra {-> New expr.star(expr_mul~nopar~nobra.expr, expr2.expr)}
 461         | {slash} expr_mul~nopar~nobra slash no [expr2]:expr_minus~nopar~nobra {-> New expr.slash(expr_mul~nopar~nobra.expr, expr2.expr)}
 462         | {percent} expr_mul~nopar~nobra percent no [expr2]:expr_minus~nopar~nobra {-> New expr.percent(expr_mul~nopar~nobra.expr, expr2.expr)}
 463         ;
 464
 465 expr_minus~nopar~nobra {-> expr}
 466         = expr_new~nopar~nobra {-> expr_new~nopar~nobra.expr}
 467         | {minus} minus no expr_minus~nopar~nobra {-> New expr.uminus(minus, expr_minus~nopar~nobra.expr)}
 468         | {once} kwonce no expr_minus~nopar~nobra {-> New expr.once(kwonce, expr_minus~nopar~nobra.expr)}
 469         ;
 470
 471 expr_new~nopar~nobra {-> expr}
 472         = expr_atom~nopar~nobra {-> expr_atom~nopar~nobra.expr}
 473         | {new} kwnew no type~nobra args {-> New expr.new(kwnew, type~nobra.type, Null, [args.expr])}
 474         | {isset_attr} kwisset recv~nopar~nobra attrid {-> New expr.isset_attr(kwisset, recv~nopar~nobra.expr, attrid)}
 475         ;
 476
 477 expr_atom~nopar~nobra {-> expr}
 478         = {attr} recv~nopar~nobra attrid {-> New expr.attr(recv~nopar~nobra.expr, attrid)}
 479         | {call} recv~nopar~nobra id args {-> New expr.call(recv~nopar~nobra.expr, id, [args.expr], [])}
 480         | {super} qualified? kwsuper args {-> New expr.super(qualified, kwsuper, [args.expr])}
 481         | {init} recv~nopar~nobra kwinit args {-> New expr.init(recv~nopar~nobra.expr, kwinit, [args.expr])}
 482 !nobra  | {bra} expr_atom~nopar braargs {-> New expr.bra(expr_atom~nopar.expr, [braargs.expr], [])}
 483         | {new} kwnew no type~nobra dot [n2]:no id args {-> New expr.new(kwnew, type~nobra.type, id, [args.expr])}
 484 // FIXME: Why are these 3 !nopar mandatory?
 485 !nobra!nopar    | {range} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no cbra {-> New expr.crange(expr, expr2.expr)}
 486 !nobra!nopar    | {orange} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no [cbra]:obra  {-> New expr.orange(expr, expr2.expr)}
 487 !nobra!nopar    | {array} braargs {-> New expr.array([braargs.expr])}
 488         | {self} kwself {-> New expr.self(kwself)}
 489         | {true} kwtrue {-> New expr.true(kwtrue)}
 490         | {false} kwfalse {-> New expr.false(kwfalse)}
 491         | {null} kwnull {-> New expr.null(kwnull)}
 492         | {int} number  {-> New expr.int(number)}
 493         | {float} float  {-> New expr.float(float)}
 494         | {char} char  {-> New expr.char(char)}
 495         | {string} string  {-> New expr.string(string)}
 496         | {superstring} superstring  {-> superstring.expr}
 497 !nopar  | {par} opar expr cpar {-> expr}
 498         | {as_cast} expr_atom~nopar~nobra dot no kwas [n2]:no opar [n3]:no type [n4]:no cpar {-> New expr.as_cast(expr_atom~nopar~nobra.expr, kwas, type)}
 499         | {as_notnull} expr_atom~nopar~nobra dot no kwas [n2]:no opar [n3]:no kwnot [n4]:no kwnull [n5]:no cpar {-> New expr.as_notnull(expr_atom~nopar~nobra.expr, kwas, kwnot, kwnull)}
 500         ;
 501
 502 superstring {-> expr}
 503         = superstring_start superstring_middle* superstring_end {-> New expr.superstring([superstring_start.expr, superstring_middle.expr, superstring_end.expr])};
 504 superstring_start {-> expr*}
 505         = start_string_p no expr [n2]:no {-> [start_string_p.expr, expr]};
 506 start_string_p {-> expr}
 507         = start_string {-> New expr.start_string(start_string)};
 508 superstring_middle {-> expr*}
 509         = mid_string_p no expr [n2]:no {-> [mid_string_p.expr, expr]};
 510 mid_string_p {-> expr}
 511         = mid_string {-> New expr.mid_string(mid_string)};
 512 superstring_end {-> expr}
 513         = end_string {-> New expr.end_string(end_string)};
 514
 515 /* MISC **********************************************************************/
 516
 517 recv~nopar~nobra {-> expr}
 518         = expr_atom~nopar~nobra dot no {-> expr_atom~nopar~nobra.expr}
 519         | {implicit} {-> New expr.implicit_self()}
 520         ;
 521
 522 args {-> expr*}
 523         = opar no expr [n2]:no args_tail* cpar {-> [expr, args_tail.expr]}
 524         | {emptypar} opar no cpar {-> []}
 525         | {empty} {-> []}
 526         ;
 527 args_nopar {-> expr*}
 528         = opar no expr [n2]:no args_tail* cpar {-> [expr, args_tail.expr]}
 529         | {onearg} expr_nopar {-> [expr_nopar.expr]}
 530         | {emptypar} opar no cpar {-> []}
 531         | {empty} {-> []}
 532         ;
 533 braargs {-> expr*}
 534         = obra no expr [n2]:no args_tail* cbra {-> [expr, args_tail.expr]};
 535 args_tail {-> expr}
 536         = comma no expr [n2]:no {-> expr};
 537 idlist {-> id*}
 538         = opar idlist_nopar cpar {-> [idlist_nopar.id]}
 539         | {nopar} idlist_nopar {-> [idlist_nopar.id]}
 540         ;
 541 idlist_nopar {-> id*}
 542         = {single} id {-> [id]}
 543         | {more} idlist_nopar no comma [n2]:no id {-> [idlist_nopar.id, id]}
 544         ;
 545
 546 qualified
 547         = {cla} modquad* classquad {-> New qualified([modquad.id], classquad.classid)}
 548         | {mod} modquad+ {-> New qualified([modquad.id], Null)}
 549         ;
 550 modquad {-> id}
 551         = id quad no {-> id};
 552 classquad {-> classid}
 553         = classid quad no {-> classid};
 554
 555 n1      = {a} comment | {b} eol;
 556 n {-> doc?}
 557         = {a} n2? comment+ {-> New doc([comment])}
 558         | {b} n2 {-> Null}
 559         ;
 560 no {-> doc?}
 561         = {empty} {-> Null}
 562         | n {-> n.doc}
 563         ;
 564
 565 n2
 566         = {a} n2? comment+ eol+
 567         | {b} eol+
 568         ;
 569
 570 /*****************************************************************************/
 571 Abstract Syntax Tree
 572 /*****************************************************************************/
 573
 574 module  = packagedecl? [imports]:import* [classdefs]:classdef*;
 575
 576 packagedecl
 577         = doc? kwpackage id;
 578
 579 import  = {std} visibility kwimport id
 580         | {no} visibility kwimport kwend
 581         ;
 582
 583 visibility
 584         = {public}
 585         | {private} kwprivate
 586         | {protected} kwprotected
 587         | {intrude} kwintrude
 588         ;
 589
 590 classdef= {std} doc? kwredef? visibility classkind [id]:classid? [formaldefs]:formaldef* [superclasses]:superclass* [propdefs]:propdef*
 591         | {top} [propdefs]:propdef*
 592         | {main} [propdefs]:propdef*
 593         ;
 594 classkind
 595         = {concrete} kwclass
 596         | {abstract} kwabstract kwclass
 597         | {interface} kwinterface
 598         | {universal} kwuniversal
 599         ;
 600 formaldef = [id]:classid type?;
 601 superclass = kwspecial? kwsuper? type;
 602
 603
 604 propdef = {attr} doc? [readable]:able? [writable]:able? kwredef? visibility kwvar [id]:attrid type? expr?
 605         | {meth} doc? kwredef? visibility methid signature
 606         | {deferred_meth} doc? kwredef? visibility kwmeth methid signature
 607         | {intern_meth} doc? kwredef? visibility kwmeth methid signature
 608         | {extern_meth} doc? kwredef? visibility kwmeth methid signature [extern]:string?
 609         | {concrete_meth} doc? kwredef? visibility kwmeth methid signature [block]:expr?
 610         | {concrete_init} doc? kwredef? visibility kwinit methid? signature [block]:expr?
 611         | {main_meth} kwredef? [block]:expr?
 612         | {type} doc? kwredef? visibility kwtype [id]:classid type
 613         ;
 614
 615 able    = {read} kwredef? kwreadable
 616         | {write} kwredef? kwwritable
 617         ;
 618
 619 methid = {id} id | {plus} plus | {minus} minus | {star} star | {slash} slash | {percent} percent | {eq} eq | {ne} ne | {le} le | {ge} ge | {lt} lt | {gt} gt | {bra} obra cbra | {starship} starship | {assign} id assign | {braassign} obra cbra assign;
 620
 621 signature = [params]:param* type? [closure_decls]:closure_decl*;
 622
 623 param   = id type? dotdotdot?
 624         ;
 625
 626 closure_decl = kwbreak? bang id signature expr?
 627         ;
 628
 629 type    = kwnullable? [id]:classid [types]:type*;
 630
 631 label = kwlabel id;
 632
 633 expr    = {block} expr*
 634         | {vardecl} kwvar id type? assign? expr?
 635         | {return} kwreturn? expr?
 636         | {break} kwbreak label? expr?
 637         | {abort} kwabort
 638         | {continue} kwcontinue? label? expr?
 639         | {do} kwdo [block]:expr? label?
 640         | {if} kwif expr [then]:expr? [else]:expr?
 641         | {ifexpr} kwif expr kwthen [then]:expr kwelse [else]:expr
 642         | {while} kwwhile expr kwdo [block]:expr? label?
 643         | {loop} kwloop [block]:expr? label?
 644         | {for} kwfor id expr kwdo [block]:expr? label?
 645         | {assert} kwassert id? expr [else]:expr?
 646         | {once} kwonce expr
 647         | {send} expr
 648         | {binop} expr [expr2]:expr
 649         | {or} expr [expr2]:expr
 650         | {and} expr [expr2]:expr
 651         | {or_else} expr [expr2]:expr
 652         | {not} kwnot expr
 653         | {eq} expr [expr2]:expr
 654         | {ee} expr [expr2]:expr
 655         | {ne} expr [expr2]:expr
 656         | {lt} expr [expr2]:expr
 657         | {le} expr [expr2]:expr
 658         | {gt} expr [expr2]:expr
 659         | {ge} expr [expr2]:expr
 660         | {isa} expr type
 661         | {plus} expr [expr2]:expr
 662         | {minus} expr [expr2]:expr
 663         | {starship} expr [expr2]:expr
 664         | {star} expr [expr2]:expr
 665         | {slash} expr [expr2]:expr
 666         | {percent} expr [expr2]:expr
 667         | {uminus} minus expr
 668         | {new} kwnew type id? [args]:expr*
 669         | {attr} expr [id]:attrid
 670         | {attr_assign} expr [id]:attrid assign [value]:expr
 671         | {attr_reassign} expr [id]:attrid assign_op [value]:expr
 672         | {call} expr id [args]:expr* [closure_defs]:closure_def*
 673         | {call_assign} expr id [args]:expr* assign [value]:expr
 674         | {call_reassign} expr id [args]:expr* assign_op [value]:expr
 675         | {super} qualified? kwsuper [args]:expr*
 676         | {init} expr kwinit [args]:expr*
 677         | {bra} expr [args]:expr* [closure_defs]:closure_def*
 678         | {bra_assign} expr [args]:expr* assign [value]:expr
 679         | {bra_reassign} expr [args]:expr* assign_op [value]:expr
 680         | {closure_call} id [args]:expr* [closure_defs]:closure_def*
 681         | {var} id
 682         | {var_assign} id assign [value]:expr
 683         | {var_reassign} id assign_op [value]:expr
 684         | {range} expr [expr2]:expr
 685         | {crange} expr [expr2]:expr
 686         | {orange} expr [expr2]:expr
 687         | {array} [exprs]:expr*
 688         | {self} kwself
 689         | {implicit_self}
 690         | {true} kwtrue
 691         | {false} kwfalse
 692         | {null} kwnull
 693         | {int} number
 694         | {float} float
 695         | {char} char
 696         | {string} string
 697         | {start_string} [string]:start_string
 698         | {mid_string} [string]:mid_string
 699         | {end_string} [string]:end_string
 700         | {superstring} [exprs]:expr*
 701         | {par} expr
 702         | {as_cast} expr kwas type
 703         | {as_notnull} expr kwas kwnot kwnull
 704         | {isset_attr} kwisset expr [id]:attrid
 705         ;
 706 assign_op
 707         = {plus} pluseq
 708         | {minus} minuseq
 709         ;
 710
 711 closure_def
 712         = bang [id]:closure_id [ids]:id* kwdo? expr? label?
 713         ;
 714 closure_id
 715         = {simple} id
 716         | {break} kwbreak
 717         ;
 718
 719 qualified = id* classid? ;
 720
 721 doc = comment+;
 722
 723 /*****************************************************************************/
 724