lib/html.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # HTML output facilities
  16 module html
  17
  18 # A html page
  19 #
  20 # You can define subclass and override methods head and body
  21 #
  22 # class MyPage
  23 #       super HTMLPage
  24 #       redef body do add("p").text("Hello World!")
  25 # end
  26 #
  27 # HTMLPage use fluent interface so you can chain calls as:
  28 #       add("div").attr("id", "mydiv").text("My Div")
  29 class HTMLPage
  30         super Streamable
  31
  32         # Define head content
  33         fun head do end
  34         # Define body content
  35         fun body do end
  36
  37         private var root = new HTMLTag("html")
  38         private var current: HTMLTag = root
  39         private var stack = new List[HTMLTag]
  40
  41         redef fun write_to(stream) do
  42                 root.children.clear
  43                 open("head")
  44                 head
  45                 close("head")
  46                 open("body")
  47                 body
  48                 close("body")
  49                 stream.write "<!DOCTYPE html>"
  50                 root.write_to(stream)
  51         end
  52
  53         # Add a html tag to the current element
  54         # add("div").attr("id", "mydiv").text("My Div")
  55         fun add(tag: String): HTMLTag do
  56                 var node = new HTMLTag(tag)
  57                 current.add(node)
  58                 return node
  59         end
  60
  61         # Add a raw html string
  62         # add_html("<a href='#top'>top</a>")
  63         fun add_html(html: String) do current.add(new HTMLRaw(html))
  64
  65         # Open a html tag
  66         # open("ul")
  67         # add("li").text("item1")
  68         # add("li").text("item2")
  69         # close("ul")
  70         fun open(tag: String): HTMLTag do
  71                 stack.push(current)
  72                 current = add(tag)
  73                 return current
  74         end
  75
  76         # Close previously opened tag
  77         # Ensure: tag = previous.tag
  78         fun close(tag: String) do
  79                 if not tag == current.tag then
  80                         print "Error: Trying to close '{tag}', last opened tag was '{current.tag}'."
  81                         abort
  82                 end
  83                 current = stack.pop
  84         end
  85 end
  86
  87 class HTMLTag
  88         super Streamable
  89
  90         # HTML tagname: 'div' for <div></div>
  91         var tag: String
  92         init(tag: String) do
  93                 self.tag = tag
  94                 self.is_void = (once ["area", "base", "br", "col", "command", "embed", "hr", "img", "input", "keygen", "link", "meta", "param", "source", "track", "wbr"]).has(tag)
  95         end
  96
  97         # Is the HTML element a void element?
  98         #
  99         #     assert (new HTMLTag("img")).is_void    == true
 100         #     assert (new HTMLTag("p")).is_void      == false
 101         var is_void: Bool
 102
 103         init with_attrs(tag: String, attrs: Map[String, String]) do
 104                 self.tag = tag
 105                 self.attrs = attrs
 106         end
 107
 108         # Tag attributes map
 109         var attrs: Map[String, String] = new HashMap[String, String]
 110
 111         # Get the attributed value of 'prop' or null if 'prop' is undifened
 112         #     var img = new HTMLTag("img")
 113         #     img.attr("src", "./image.png").attr("alt", "image")
 114         #     assert img.get_attr("src")     == "./image.png"
 115         fun get_attr(key: String): nullable String do
 116                 if not attrs.has_key(key) then return null
 117                 return attrs[key]
 118         end
 119
 120         # Set a 'value' for 'key'
 121         #     var img = new HTMLTag("img")
 122         #     img.attr("src", "./image.png").attr("alt", "image")
 123         #     assert img.write_to_string      == """<img src="./image.png" alt="image"/>"""
 124         fun attr(key: String, value: String): HTMLTag do
 125                 attrs[key] = value
 126                 return self
 127         end
 128
 129         # Add a CSS class to the HTML tag
 130         #     var img = new HTMLTag("img")
 131         #     img.add_class("logo").add_class("fullpage")
 132         #     assert img.write_to_string      == """<img class="logo fullpage"/>"""
 133         fun add_class(klass: String): HTMLTag do
 134                 classes.add(klass)
 135                 return self
 136         end
 137
 138         # CSS classes
 139         var classes: Set[String] = new HashSet[String]
 140
 141         # Add multiple CSS classes
 142         #     var img = new HTMLTag("img")
 143         #     img.add_classes(["logo", "fullpage"])
 144         #     assert img.write_to_string      == """<img class="logo fullpage"/>"""
 145         fun add_classes(classes: Collection[String]): HTMLTag do
 146                 self.classes.add_all(classes)
 147                 return self
 148         end
 149
 150         # Set a CSS 'value' for 'prop'
 151         #     var img = new HTMLTag("img")
 152         #     img.css("border", "2px solid black").css("position", "absolute")
 153         #     assert img.write_to_string      == """<img style="border: 2px solid black; position: absolute"/>"""
 154         fun css(prop: String, value: String): HTMLTag do
 155                 css_props[prop] = value
 156                 return self
 157         end
 158         private var css_props: Map[String, String] = new HashMap[String, String]
 159
 160         # Get CSS value for 'prop'
 161         #     var img = new HTMLTag("img")
 162         #     img.css("border", "2px solid black").css("position", "absolute")
 163         #     assert img.get_css("border")    == "2px solid black"
 164         #     assert img.get_css("color")     == null
 165         fun get_css(prop: String): nullable String do
 166                 if not css_props.has_key(prop) then return null
 167                 return css_props[prop]
 168         end
 169
 170         # Replace `self` by `parent`.
 171         #
 172         #     var elem = new HTMLTag("li")
 173         #     elem.add_outer(new HTMLTag("ul"))
 174         #     assert elem.write_to_string == "<ul><li></li></ul>"
 175         fun add_outer(parent: HTMLTag) do
 176                 # copy self in new object
 177                 var child = new HTMLTag(self.tag)
 178                 child.attrs = self.attrs
 179                 child.classes = self.classes
 180                 child.css_props = self.css_props
 181                 child.children = self.children
 182                 # add copy in parent children elements
 183                 parent.children.add(child)
 184                 # replace self by parent
 185                 self.tag = parent.tag
 186                 self.attrs = parent.attrs
 187                 self.classes = parent.classes
 188                 self.css_props = parent.css_props
 189                 self.is_void = parent.is_void
 190                 self.children = parent.children
 191         end
 192
 193         # Add a HTML 'child' to self
 194         #     var ul = new HTMLTag("ul")
 195         #     ul.add(new HTMLTag("li"))
 196         #     assert ul.write_to_string    == "<ul><li></li></ul>"
 197         fun add(child: HTMLTag) do children.add(child)
 198
 199         # List of children HTML elements
 200         var children: Set[HTMLTag] = new HashSet[HTMLTag]
 201
 202         # Clear all child and set the text of element
 203         #     var p = new HTMLTag("p")
 204         #     p.text("Hello World!")
 205         #     assert p.write_to_string      ==  "<p>Hello World!</p>"
 206         # Text is escaped see: `standard::String::html_escape`
 207         fun text(txt: String): HTMLTag do
 208
 209                 children.clear
 210                 append(txt)
 211                 return self
 212         end
 213
 214         # Append text to element
 215         #     var p = new HTMLTag("p")
 216         #     p.append("Hello")
 217         #     p.add(new HTMLTag("br"))
 218         #     p.append("World!")
 219         #     assert p.write_to_string      ==  "<p>Hello<br/>World!</p>"
 220         # Text is escaped see: standard::String::html_escape
 221         fun append(txt: String): HTMLTag do
 222                 add(new HTMLRaw(txt.html_escape))
 223                 return self
 224         end
 225
 226         # Append raw HTML to element
 227         #
 228         #     var p = new HTMLTag("p")
 229         #     p.append("Hello")
 230         #     p.add_raw_html("<bla/>foo")
 231         #     assert p.write_to_string   == "<p>Hello<bla/>foo</p>"
 232         #
 233         # Note: the HTML in insered as it, no verification is done.
 234         fun add_raw_html(txt: String): HTMLTag do
 235                 add(new HTMLRaw(txt))
 236                 return self
 237         end
 238
 239         redef fun write_to(stream) do
 240                 var res = new Array[String]
 241                 render_in(res)
 242                 for r in res do
 243                         stream.write(r)
 244                 end
 245         end
 246
 247         # In order to avoid recursive concatenation,
 248         # this function collects in `res` all the small fragments of `String`
 249         private fun render_in(res: Sequence[String])
 250         do
 251                 res.add "<"
 252                 res.add tag
 253                 render_attrs_in(res)
 254                 if is_void and children.is_empty then
 255                         res.add "/>"
 256                 else
 257                         res.add ">"
 258                         for child in children do child.render_in(res)
 259                         res.add "</"
 260                         res.add tag
 261                         res.add ">"
 262                 end
 263         end
 264
 265         private fun render_attrs_in(res: Sequence[String]) do
 266                 if attrs.has_key("class") or not classes.is_empty then
 267                         res.add " class=\""
 268                         for cls in classes do
 269                                 res.add cls.html_escape
 270                                 res.add " "
 271                         end
 272                         if attrs.has_key("class") then
 273                                 res.add attrs["class"].html_escape
 274                                 res.add " "
 275                         end
 276                         if res.last == " " then res.pop
 277                         res.add "\""
 278                 end
 279
 280                 if attrs.has_key("style") or not css_props.is_empty then
 281                         res.add " style=\""
 282                         for k, v in css_props do
 283                                 res.add k.html_escape
 284                                 res.add ": "
 285                                 res.add v.html_escape
 286                                 res.add "; "
 287                         end
 288                         if attrs.has_key("style") then
 289                                 res.add(attrs["style"].html_escape)
 290                         end
 291                         if res.last == "; " then res.pop
 292                         res.add "\""
 293                 end
 294
 295                 if attrs.is_empty then return
 296
 297                 for key, value in attrs do
 298                         if key == "class" or key == "style" then continue
 299                         res.add " "
 300                         res.add key.html_escape
 301                         res.add "=\""
 302                         res.add value.html_escape
 303                         res.add "\""
 304                 end
 305         end
 306 end
 307
 308 private class HTMLRaw
 309         super HTMLTag
 310
 311         private var content: String
 312         init(content: String) do self.content = content
 313         redef fun render_in(res) do res.add content
 314 end