src/parser/nit.sablecc3xx

   1
   2 /* This file is part of NIT ( http://www.nitlanguage.org ).
   3  *
   4  * Copyright 2008-2009 Jean Privat <jean@pryen.org>
   5  *
   6  * Licensed under the Apache License, Version 2.0 (the "License");
   7  * you may not use this file except in compliance with the License.
   8  * You may obtain a copy of the License at
   9  *
  10  *     http://www.apache.org/licenses/LICENSE-2.0
  11  *
  12  * Unless required by applicable law or agreed to in writing, software
  13  * distributed under the License is distributed on an "AS IS" BASIS,
  14  * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15  * See the License for the specific language governing permissions and
  16  * limitations under the License.
  17  */
  18
  19 /* This grammar defines the NIT language. */
  20 Package org.nitlanguage.gen;
  21
  22 /*****************************************************************************/
  23 Helpers
  24 /*****************************************************************************/
  25
  26 all = [0 .. 0xFF];
  27 lowercase = ['a' .. 'z'];
  28 uppercase = ['A' .. 'Z'];
  29 digit = ['0' .. '9'];
  30 hexdigit = ['0'..'9'] | ['a'..'f'] | ['A'..'F'];
  31 letter = lowercase | uppercase | digit | '_';
  32
  33 tab = 9;
  34 cr = 13;
  35 lf = 10;
  36 any = [all - [cr + lf]];
  37 eol_helper = cr lf | cr | lf; // This takes care of different platforms
  38
  39 // characers inside strings and super-strings (atomaton powaa)
  40 str_char
  41         = [any - [['"' + '{'] + '\']]
  42         | '\' any
  43         ;
  44 str_body = str_char*;
  45
  46 sstr_char
  47         = [any - [''' + '\']]
  48         | '\' any
  49         ;
  50
  51 sstr_body = sstr_char*;
  52
  53 long_str_char = str_char | cr | lf;
  54
  55 // because no substraction in sablecc3, complex long strings are difficult to express
  56 ls1 = '"' '"'? ;
  57 ls2 = '{' '{'? ;
  58 ls12 = ls1? (ls2 ls1)* ls2?;
  59
  60 long_str_part
  61         = ls12 long_str_char
  62         ;
  63
  64 long_str_body = long_str_part*;
  65 lsend1 = ls2? (ls1 ls2)* '"""' '"'*;
  66 lsend2 = ls1? (ls2 ls1)* '{{{' '{'*;
  67
  68 long_sstr_char = sstr_char | cr | lf;
  69 long_sstr_part
  70         = long_sstr_char
  71         | ''' long_sstr_char
  72         | ''' ''' long_sstr_char
  73         ;
  74
  75 long_sstr_body = long_sstr_part*;
  76
  77
  78 extern_code_char
  79         = [all - ['`' + '\']]
  80         | '\' all
  81         ;
  82 extern_code_body = extern_code_char*;
  83
  84 /*****************************************************************************/
  85 States
  86 /*****************************************************************************/
  87 initial;
  88
  89
  90 /*****************************************************************************/
  91 Tokens
  92 /*****************************************************************************/
  93
  94 blank = (' ' | tab)+;
  95
  96 eol = eol_helper;
  97 comment = '#' any* eol_helper?;
  98
  99 kwpackage = 'package';
 100 kwmodule = 'module';
 101 kwimport = 'import';
 102 kwclass = 'class';
 103 kwabstract = 'abstract';
 104 kwinterface = 'interface';
 105 kwenum = 'universal'|'enum';
 106 kwend = 'end';
 107 kwmeth = 'fun';
 108 kwtype = 'type';
 109 kwinit = 'init';
 110 kwredef = 'redef';
 111 kwis = 'is';
 112 kwdo = 'do';
 113 kwvar = 'var';
 114 kwextern = 'extern';
 115 kwpublic = 'public';
 116 kwprotected = 'protected';
 117 kwprivate = 'private';
 118 kwintrude = 'intrude';
 119 kwif = 'if';
 120 kwthen = 'then';
 121 kwelse = 'else';
 122 kwwhile = 'while';
 123 kwloop = 'loop';
 124 kwfor = 'for';
 125 kwin = 'in';
 126 kwand = 'and';
 127 kwor = 'or';
 128 kwnot = 'not';
 129 kwimplies = 'implies';
 130 kwreturn = 'return';
 131 kwcontinue = 'continue';
 132 kwbreak = 'break';
 133 kwabort = 'abort';
 134 kwassert = 'assert';
 135 kwnew = 'new';
 136 kwisa = 'isa';
 137 kwonce = 'once';
 138 kwsuper = 'super';
 139 kwself = 'self';
 140 kwtrue = 'true';
 141 kwfalse = 'false';
 142 kwnull = 'null';
 143 kwas = 'as';
 144 kwnullable = 'nullable';
 145 kwisset = 'isset';
 146 kwlabel = 'label';
 147 kwdebug = '__debug__';
 148
 149 opar = '(';
 150 cpar = ')';
 151 obra = '[';
 152 cbra = ']';
 153 comma = ',';
 154 column = ':';
 155 quad = '::';
 156 assign = '=';
 157 pluseq = '+=';
 158 minuseq = '-=';
 159 dotdotdot = '...';
 160 dotdot = '..';
 161 dot = '.';
 162 plus = '+';
 163 minus = '-';
 164 star = '*';
 165 starstar = '**';
 166 slash = '/';
 167 percent = '%';
 168 eq = '==';
 169 ne = '!=';
 170 lt = '<';
 171 le = '<=';
 172 ll = '<<';
 173 gt = '>';
 174 ge = '>=';
 175 gg = '>>';
 176 starship = '<=>';
 177 bang='!';
 178 at='@';
 179
 180 classid = uppercase letter*;
 181 id = lowercase letter*;
 182 attrid = '_' lowercase letter*;
 183
 184 number = digit+;
 185 hex_number = ('0x' | '0X') hexdigit+;
 186 float = digit* '.' digit+;
 187 string = '"' str_body '"' | '"' '"' '"' long_str_body lsend1 | ''' ''' ''' long_sstr_body ''' ''' ''';
 188 start_string = '"' str_body '{' | '"' '"' '"' long_str_body lsend2;
 189 mid_string = '}' str_body '{' | '}' '}' '}' long_str_body lsend2;
 190 end_string = '}' str_body '"' | '}' '}' '}' long_str_body lsend1;
 191 char = (''' [[any - '''] - '\'] ''') | (''' '\' any ''');
 192 bad_string = ('"'|'}') str_body | '"' '"' '"' long_str_body | ''' ''' ''' long_sstr_body;
 193 bad_char = ''' '\'? any;
 194
 195 extern_code_segment = '`' '{' extern_code_body '`' '}';
 196
 197 /*****************************************************************************/
 198 Ignored Tokens
 199 /*****************************************************************************/
 200
 201 blank;
 202
 203 /*****************************************************************************/
 204 Productions
 205 /*****************************************************************************/
 206
 207 /* MODULES *******************************************************************/
 208 module
 209         = moduledecl? [imports]:import* [extern_bodies]:extern_code_body* [classdefs]:topdef* implicit_main_class {-> New module(moduledecl, [imports.import], [extern_bodies.extern_code_block], [classdefs.classdef,implicit_main_class.classdef])};
 210
 211 moduledecl
 212         = [doc]:no redef visibility kwmodule no module_name annotation_withend [n2]:n1 {-> New moduledecl(doc.doc, redef.kwredef, visibility, kwmodule, module_name, annotation_withend.annotations)};
 213
 214 import
 215         = {std} [doc]:no redef visibility kwimport no module_name annotation_withend [n2]:n1 {-> New import.std(visibility, kwimport, module_name, annotation_withend.annotations)}
 216         | {no} [doc]:no redef visibility kwimport no kwend [n2]:n1 {-> New import.no(visibility, kwimport, kwend)}
 217         ;
 218
 219 topdef {-> classdef}
 220         = {classdef} classdef {-> classdef}
 221         | propdefs_toplevel {-> New classdef.top([propdefs_toplevel.propdef])}
 222         ;
 223
 224 implicit_main_class {-> classdef?}
 225         = implicit_main_meth {-> New classdef.main([implicit_main_meth.propdef])}
 226         | {null} n? {-> Null}
 227         ;
 228 implicit_main_meth {-> propdef}
 229         = [doc]:no stmts {-> New propdef.main_meth(Null, stmts.expr)}
 230         | {n} [doc]:no stmtsn {-> New propdef.main_meth(Null, stmtsn.expr)}
 231         ;
 232
 233 /* CLASSES *******************************************************************/
 234 classdef
 235         = [doc]:no redef visibility classkind no qclassid formaldefs line_annotations_forclass? extern_code_block? [superclasses]:superclass* propdefs* [n2]:no kwend {-> New classdef.std(doc.doc, redef.kwredef, visibility, classkind, qclassid.classid, [formaldefs.formaldef], line_annotations_forclass.annotations, extern_code_block, [superclasses.superclass], [propdefs.propdef], kwend)};
 236 redef {-> kwredef?}
 237         = kwredef? {-> kwredef};
 238 classkind
 239         = {concrete} kwclass
 240         | {abstract} kwabstract kwclass
 241         | {interface} kwinterface
 242         | {enum} kwenum
 243         | {extern} kwextern kwclass
 244         ;
 245
 246 formaldefs {-> formaldef*}
 247         = obra no formaldef formaldefs_tail* [n2]:no cbra {-> [formaldef, formaldefs_tail.formaldef]}
 248         | {null} {-> []}
 249         ;
 250 formaldefs_tail {-> formaldef}
 251         = comma no formaldef {-> formaldef};
 252 formaldef
 253         = classid annotations? typing_o {-> New formaldef(classid, typing_o.type, annotations)};
 254
 255 superclass {-> superclass}
 256         = {super} no kwsuper [n2]:no type annotation_withend {-> New superclass(kwsuper, type, annotation_withend.annotations)}
 257         ;
 258
 259 propdefs~toplevel {-> propdef}
 260         = propdef~toplevel n1 {-> propdef~toplevel.propdef}
 261         ;
 262 propdef~toplevel {-> propdef}
 263         = {meth} [doc]:no redef visibility kwmeth qmethid signature annotation_noend? kwdo stmtso kwend_o {-> New propdef.meth(doc.doc, redef.kwredef, visibility, kwmeth, Null, Null, qmethid.methid, signature, annotation_noend.annotations, Null, Null, stmtso.expr)}
 264         | {nobody} [doc]:no redef visibility kwmeth qmethid signature annotation_withend_nonull {-> New propdef.meth(doc.doc, redef.kwredef, visibility, kwmeth, Null, Null, qmethid.methid, signature.signature, annotation_withend_nonull.annotations, Null, Null, Null)}
 265 !toplevel| {intern_new} [doc]:no redef visibility kwnew qmethid? signature annotation_withend_nonull {-> New propdef.meth(doc.doc, redef.kwredef, visibility, Null, Null, kwnew, qmethid.methid, signature, annotation_withend_nonull.annotations, Null, Null, Null)}
 266 !toplevel| {new} [doc]:no redef visibility kwnew qmethid? signature annotation_noend? kwdo stmtso kwend_o {-> New propdef.meth(doc.doc, redef.kwredef, visibility, Null, Null, kwnew, qmethid.methid, signature, annotation_noend.annotations, Null, Null, stmtso.expr)}
 267         | {extern_implicit} [doc]:no redef visibility kwmeth qmethid signature annotation_noend? extern_calls extern_code_block {-> New propdef.meth(doc.doc, redef.kwredef, visibility, kwmeth, Null, Null, qmethid.methid, signature.signature, annotation_noend.annotations, extern_calls, extern_code_block, Null)}
 268 !toplevel| {var3} [doc]:no redef visibility kwvar id typing_o annotation_withend {-> New propdef.attr(doc.doc, redef.kwredef, visibility, kwvar, id, typing_o.type, Null, annotation_withend.annotations)}
 269 !toplevel| {var4} [doc]:no redef visibility kwvar id typing_o assign [n2]:no expr annotation_withend {-> New propdef.attr(doc.doc, redef.kwredef, visibility, kwvar, id, typing_o.type, expr.expr, annotation_withend.annotations)}
 270 !toplevel| {init} [doc]:no redef visibility kwinit qmethid? signature annotation_noend? kwdo stmtso kwend_o {-> New propdef.meth(doc.doc, redef.kwredef, visibility, Null, kwinit, Null, qmethid.methid, signature, annotation_noend.annotations, Null, Null, stmtso.expr)}
 271 !toplevel| {type} [doc]:no redef visibility kwtype classid typing annotation_withend {-> New propdef.type(doc.doc, redef.kwredef, visibility, kwtype, classid, typing.type, annotation_withend.annotations)}
 272 !toplevel| {extern_init_implicit} [doc]:no redef visibility kwnew qmethid? signature annotation_noend? extern_calls extern_code_block {-> New propdef.meth(doc.doc, redef.kwredef, visibility, Null, Null, kwnew, qmethid.methid, signature, annotation_noend.annotations, extern_calls, extern_code_block, Null)}
 273         ;
 274 annotation_withend~nonull {-> annotations?}
 275         = {oneliner} kwis many_annotations {-> many_annotations.annotations}
 276         | {more} kwis n1 line_annotations kwend {-> line_annotations.annotations}
 277 !nonull | {null} {-> Null}
 278         ;
 279 annotation_noend {-> annotations}
 280         = {oneliner} kwis many_annotations {-> many_annotations.annotations}
 281         | {more} kwis n1 line_annotations {-> line_annotations.annotations}
 282         ;
 283
 284 visibility
 285         = {public} {-> New visibility.public(Null)}
 286         | {public2} kwpublic no {-> New visibility.public(kwpublic)}
 287         | {private} kwprivate no {-> New visibility.private(kwprivate)}
 288         | {protected} kwprotected no {-> New visibility.protected(kwprotected)}
 289         | {intrude} kwintrude no {-> New visibility.intrude(kwintrude)}
 290         ;
 291
 292 methid~noid {-> methid}
 293         = {plus} plus {-> New methid.plus(plus)}
 294         | {minus} minus {-> New methid.minus(minus)}
 295         | {star} star {-> New methid.star(star)}
 296         | {starstar} starstar {-> New methid.starstar(starstar)}
 297         | {slash} slash {-> New methid.slash(slash)}
 298         | {percent} percent {-> New methid.percent(percent)}
 299         | {eq} eq {-> New methid.eq(eq)}
 300         | {ne} ne {-> New methid.ne(ne)}
 301         | {le} le {-> New methid.le(le)}
 302         | {ge} ge {-> New methid.ge(ge)}
 303         | {lt} lt {-> New methid.lt(lt)}
 304         | {gt} gt {-> New methid.gt(gt)}
 305         | {ll} ll {-> New methid.ll(ll)}
 306         | {gg} gg {-> New methid.gg(gg)}
 307         | {bra} obra cbra {-> New methid.bra(obra, cbra)}
 308         | {starship} starship {-> New methid.starship(starship)}
 309         | {assign} id assign {-> New methid.assign(id, assign)}
 310         | {braassign} obra cbra assign {-> New methid.braassign(obra, cbra, assign)}
 311 !noid   | {id} id {-> New methid.id(id)}
 312         ;
 313
 314 signature {-> signature}
 315         = opar no params cpar typing [no2]:no {-> New signature(opar, [params.param], cpar, typing.type)}
 316         | {noret} opar no params cpar [no2]:no {-> New signature(opar, [params.param], cpar, Null)}
 317         | {nopar} typing no {-> New signature(Null, [], Null, typing.type)}
 318         | {noparnoret} no {-> New signature(Null, [], Null, Null)}
 319         ;
 320
 321 params {-> param*}
 322         = param params_tail* [n2]:no {-> [param, params_tail.param] }
 323         | {null} {-> []}
 324         ;
 325 params_tail {-> param}
 326         = comma no param {-> param};
 327 param
 328         = {untyped} id annotations_o {-> New param(id, Null, Null, annotations_o.annotations)}
 329         | id annotations? typing dotdotdot? {-> New param(id, typing.type, dotdotdot, annotations)}
 330         ;
 331
 332 extern_calls {-> extern_calls?}
 333         = kwimport no extern_call extern_call_tail* {-> New extern_calls( kwimport, [extern_call, extern_call_tail.extern_call] )}
 334         | {null} {-> Null}
 335         ;
 336 extern_call_tail {-> extern_call}
 337         = comma no extern_call {-> extern_call};
 338 extern_call {-> extern_call}
 339         = {prop} extern_call_prop {-> extern_call_prop.extern_call}
 340         | {cast} extern_call_cast {-> extern_call_cast.extern_call}
 341         | {super} kwsuper {-> New extern_call.super( kwsuper )}
 342         ;
 343 extern_call_prop {-> extern_call}
 344         = {local} qmethid {-> New extern_call.local_prop( qmethid.methid )}
 345         | {full} type dot qmethid {-> New extern_call.full_prop( type, dot, qmethid.methid )}
 346         | {init} type {-> New extern_call.init_prop( type )}
 347         ;
 348 extern_call_cast {-> extern_call}
 349         = {as_cast} [from_type]:type dot kwas [n2]:no opar [n3]:no [to_type]:type [n4]:no cpar {-> New extern_call.cast_as(from_type, dot, kwas, to_type)}
 350         | {as_cast2}[from_type]:type dot kwas [n2]:no [to_type]:type {-> New extern_call.cast_as(from_type, dot, kwas, to_type)}
 351         | {as_nullable} type dot kwas [n2]:no opar [n3]:no kwnullable [n4]:no cpar {-> New extern_call.as_nullable( type, kwas, kwnullable)}
 352         | {as_nullable2}type dot kwas [n2]:no kwnullable {-> New extern_call.as_nullable( type, kwas, kwnullable)}
 353         | {as_not_nullable} type dot kwas [n2]:no opar [n3]:no kwnot [n4]:no kwnullable [n5]:no cpar {-> New extern_call.as_not_nullable( type, kwas, kwnot, kwnullable)}
 354         | {as_not_nullable2}type dot kwas [n2]:no kwnot [n3]:no kwnullable {-> New extern_call.as_not_nullable( type, kwas, kwnot, kwnullable)}
 355         ;
 356
 357 string_o {->string?} = string? {-> string};
 358
 359 in_language = kwin no string [n1]:no {-> New in_language(kwin, string)};
 360 extern_code_block = in_language? extern_code_segment;
 361 extern_code_block_o {-> extern_code_block?}
 362         = extern_code_block {-> extern_code_block}
 363         | {null} {-> Null}
 364         ;
 365 extern_code_body {-> extern_code_block} = no extern_code_block {-> extern_code_block};
 366
 367 /* TYPES *********************************************************************/
 368 type~nobra~nopar {-> type}
 369         = {simple} kwnullable? classid annotations_o~nopar {-> New type(kwnullable, classid, [], annotations_o~nopar.annotations)}
 370 !nobra  | {generic} kwnullable? classid obra no types [n2]:no cbra annotations_o~nopar {-> New type(kwnullable, classid, [types.type], annotations_o~nopar.annotations)}
 371         ;
 372 types {-> type*}
 373         = type types_tail* {-> [type, types_tail.type]};
 374 types_tail {-> type}
 375         = comma no type {-> type};
 376 typing {-> type}
 377         = column no type {-> type};
 378 typing_o {-> type?}
 379         = column no type {-> type}
 380         | {null} {-> Null}
 381         ;
 382
 383 /* STATMENTS *****************************************************************/
 384 stmtso~withelse~withend {-> expr?}
 385         = {block} n stmtsnend {-> stmtsnend.expr}
 386         | {emptyblock} n kwend {-> New expr.block([], kwend)}
 387         | {emptyoneline} kwend {-> New expr.block([], kwend)}
 388 !withend| {oneline} stmt~withelse {-> stmt~withelse.expr}
 389         ;
 390 stmts {-> expr}
 391         = stmt stmts_tail* {-> New expr.block([stmt.expr, stmts_tail.expr], Null)};
 392 stmtsn {-> expr}
 393         = stmt stmts_tail* n {-> New expr.block([stmt.expr, stmts_tail.expr], Null)};
 394 stmtsnend {-> expr}
 395         = stmt stmts_tail* n kwend {-> New expr.block([stmt.expr, stmts_tail.expr], kwend)};
 396 stmts_tail {-> expr}
 397         = n stmt {-> stmt.expr};
 398 stmt~withelse~noexpr~nopar {-> expr}
 399         = {vardecl} vardecl {-> vardecl.expr}
 400         | {assign} assignment~nopar {-> assignment~nopar.expr}
 401         | {return} kwreturn expr? {-> New expr.return(kwreturn, expr)}
 402         | {break} kwbreak label? {-> New expr.break(kwbreak, label)}
 403         | {abort} kwabort {-> New expr.abort(kwabort)}
 404         | {continue} kwcontinue label? {-> New expr.continue(kwcontinue, label)}
 405         | {do} do~withelse {-> do~withelse.expr}
 406 !noexpr | {if} if~withelse {-> if~withelse.expr}
 407         | {while} while~withelse {-> while~withelse.expr}
 408         | {loop} loop~withelse {-> loop~withelse.expr}
 409         | {for} for~withelse {-> for~withelse.expr}
 410         | {assert} assert~withelse {-> assert~withelse.expr}
 411 !noexpr | {call} recv qid args_nopar {-> New expr.call(recv.expr, qid.id, args_nopar.exprs)}
 412 !noexpr | {super} qualified_o kwsuper args_nopar {-> New expr.super(qualified_o.qualified, kwsuper, args_nopar.exprs)}
 413 !noexpr | {init} recv qualified? kwinit args_nopar {-> New expr.init(recv.expr, kwinit, args_nopar.exprs)}
 414         | {debug_type_is} kwdebug kwtype type column expr {-> New expr.debug_type(kwdebug, kwtype, expr.expr, type) }
 415         ;
 416
 417 label= kwlabel id?;
 418
 419 vardecl{-> expr}
 420         = kwvar id annotations? typing_o {-> New expr.vardecl(kwvar, id, typing_o.type, Null, Null, annotations)}
 421         | {assign} kwvar id annotations? typing_o assign no expr {-> New expr.vardecl(kwvar, id, typing_o.type, assign, expr.expr, annotations)}
 422         ;
 423
 424 assignment~nopar {-> expr}
 425         = {attr} recv~nopar qualified_o attrid assign expr {-> New expr.attr_assign(recv~nopar.expr, attrid, assign, expr)}
 426         | {call} recv~nopar qid args assign expr {-> New expr.call_assign(recv~nopar.expr, qid.id, args.exprs, assign,  expr)}
 427         | {bra} expr_atom~nopar braargs assign expr {-> New expr.bra_assign(expr_atom~nopar.expr, braargs.exprs, assign,  expr)}
 428         | {attr_re} recv~nopar qualified_o attrid assign_op expr {-> New expr.attr_reassign(recv~nopar.expr, attrid, assign_op,  expr)}
 429         | {call_re} recv~nopar qid args assign_op expr {-> New expr.call_reassign(recv~nopar.expr, qid.id, args.exprs, assign_op,  expr)}
 430         | {bra_re} expr_atom~nopar braargs assign_op expr {-> New expr.bra_reassign(expr_atom~nopar.expr, braargs.exprs, assign_op,  expr)}
 431         ;
 432 assign_op
 433         = {plus} pluseq
 434         | {minus} minuseq
 435         ;
 436
 437 do~withelse {-> expr}
 438         = kwdo stmtso_withend label {-> New expr.do(kwdo, stmtso_withend.expr, label)}
 439         | {nolabel} kwdo stmtso~withelse {-> New expr.do(kwdo, stmtso~withelse.expr, Null)}
 440         ;
 441
 442 if~withelse {-> expr}
 443         = {onelineelse} kwif no expr [n2]:no kwthen stmt_withelse kwelse stmtso~withelse {-> New expr.if(kwif, expr, stmt_withelse.expr, stmtso~withelse.expr)}
 444 !withelse       | {oneline} kwif no expr [n2]:no kwthen stmt {-> New expr.if(kwif, expr, stmt.expr, Null)}
 445 !withelse       | {block} kwif no expr [n2]:no kwthen [n3]:n stmtsn elsepartblock {-> New expr.if(kwif, expr, stmtsn.expr, elsepartblock.expr)}
 446 !withelse       | {emptyblock} kwif no expr [n2]:no kwthen [n3]:n? elsepartblock {-> New expr.if(kwif, expr, Null, elsepartblock.expr)}
 447         ;
 448 elsepartblock {-> expr?}
 449         = {else} kwelse stmtso {-> stmtso.expr}
 450         | {empty} kwend {-> New expr.block([], kwend)}
 451         ;
 452
 453 loop~withelse {-> expr}
 454         = kwloop stmtso_withend label {-> New expr.loop(kwloop, stmtso_withend.expr, label)}
 455         | {nolabel} kwloop stmtso~withelse {-> New expr.loop(kwloop, stmtso~withelse.expr, Null)}
 456         ;
 457
 458 while~withelse {-> expr}
 459         = kwwhile no expr [n2]:no kwdo stmtso_withend label {-> New expr.while(kwwhile, expr, kwdo, stmtso_withend.expr, label)}
 460         | {nolabel} kwwhile no expr [n2]:no kwdo stmtso~withelse {-> New expr.while(kwwhile, expr, kwdo, stmtso~withelse.expr, Null)}
 461         ;
 462
 463 for~withelse {-> expr}
 464         = kwfor no [ids]:idlist [n2]:no kwin [n3]:no expr [n4]:no kwdo stmtso_withend label {-> New expr.for(kwfor, [ids.id], expr, kwdo, stmtso_withend.expr, label)}
 465         | {nolabel} kwfor no [ids]:idlist [n2]:no kwin [n3]:no expr [n4]:no kwdo stmtso~withelse {-> New expr.for(kwfor, [ids.id], expr, kwdo, stmtso~withelse.expr, Null)}
 466         ;
 467
 468 assert~withelse {-> expr}
 469         = {else} kwassert assertid? expr kwelse stmtso~withelse {-> New expr.assert(kwassert, assertid.id, expr, stmtso~withelse.expr)}
 470 !withelse| {noelse} kwassert assertid? expr {-> New expr.assert(kwassert, assertid.id, expr, Null)}
 471         ;
 472 assertid {-> id}
 473         = id column {-> id};
 474
 475 /* EXPRESSIONS ***************************************************************/
 476 expr~nopar~nobra {-> expr}
 477         = expr_and~nopar~nobra {-> expr_and~nopar~nobra.expr}
 478         | {ifexpr} kwif [n1]:no expr [n2]:no kwthen [n3]:no [then]:expr [n4]:no kwelse [n5]:no [else]:expr~nopar~nobra {-> New expr.ifexpr(kwif, expr, kwthen, then, kwelse, else.expr)}
 479         ;
 480
 481 expr_and~nopar~nobra {-> expr}
 482         = expr_not~nopar~nobra {-> expr_not~nopar~nobra.expr}
 483         | {:or} expr_and~nopar~nobra :kwor :no expr_not~nopar~nobra
 484         | {:and} expr_and~nopar~nobra :kwand :no expr_not~nopar~nobra
 485         | {:or_else} expr_and~nopar~nobra :kwor :kwelse :no expr_not~nopar~nobra
 486         | {:implies} expr_and~nopar~nobra :kwimplies :no expr_not~nopar~nobra
 487         ;
 488
 489 expr_not~nopar~nobra {-> expr}
 490         = expr_eq~nopar~nobra {-> expr_eq~nopar~nobra.expr}
 491         | {not} kwnot no expr_not~nopar~nobra {-> New expr.not(kwnot, expr_not~nopar~nobra.expr)}
 492         ;
 493
 494 expr_eq~nopar~nobra {-> expr}
 495         = expr_add~nopar~nobra {-> expr_add~nopar~nobra.expr}
 496         | {:eq} expr_add~nopar~nobra :eq :no [expr2]:expr_add~nopar~nobra
 497         | {:ne} expr_add~nopar~nobra :ne :no [expr2]:expr_add~nopar~nobra
 498         | {:lt} expr_add~nopar~nobra :lt :no [expr2]:expr_add~nopar~nobra
 499         | {:le} expr_add~nopar~nobra :le :no [expr2]:expr_add~nopar~nobra
 500         | {:ll} expr_eq~nopar~nobra :ll :no [expr2]:expr_add~nopar~nobra
 501         | {:gt} expr_add~nopar~nobra :gt :no [expr2]:expr_add~nopar~nobra
 502         | {:ge} expr_add~nopar~nobra :ge :no [expr2]:expr_add~nopar~nobra
 503         | {:gg} expr_eq~nopar~nobra :gg :no [expr2]:expr_add~nopar~nobra
 504         | {:starship} expr_add~nopar~nobra :starship :no [expr2]:expr_add~nopar~nobra
 505         | {:isa} expr_add~nopar~nobra :kwisa :no type~nobra
 506         ;
 507
 508 expr_add~nopar~nobra {-> expr}
 509         =  expr_mul~nopar~nobra {-> expr_mul~nopar~nobra.expr}
 510         | {:plus} expr_add~nopar~nobra :plus :no [expr2]:expr_mul~nopar~nobra
 511         | {:minus} expr_add~nopar~nobra :minus :no [expr2]:expr_mul~nopar~nobra
 512         ;
 513
 514 expr_mul~nopar~nobra {-> expr}
 515         = expr_pow~nopar~nobra {-> expr_pow~nopar~nobra.expr}
 516         | {:star} expr_mul~nopar~nobra :star :no [expr2]:expr_pow~nopar~nobra
 517         | {:slash} expr_mul~nopar~nobra :slash :no [expr2]:expr_pow~nopar~nobra
 518         | {:percent} expr_mul~nopar~nobra :percent :no [expr2]:expr_pow~nopar~nobra
 519         ;
 520
 521 expr_pow~nopar~nobra {-> expr}
 522         = expr_minus~nopar~nobra {-> expr_minus~nopar~nobra.expr}
 523         | {:starstar} expr_minus~nopar~nobra :starstar :no [expr2]:expr_pow~nopar~nobra
 524         ;
 525
 526 expr_minus~nopar~nobra {-> expr}
 527         = expr_new~nopar~nobra {-> expr_new~nopar~nobra.expr}
 528         | {:uminus} minus expr_minus~nobra
 529         | {:once} kwonce :no expr_minus~nobra
 530         ;
 531
 532 expr_new~nopar~nobra {-> expr}
 533         = expr_atom~nopar~nobra {-> expr_atom~nopar~nobra.expr}
 534         | {new} kwnew no type~nobra_nopar args {-> New expr.new(kwnew, type~nobra_nopar.type, Null, args.exprs)}
 535         | {isset_attr} kwisset recv~nopar~nobra qualified_o attrid {-> New expr.isset_attr(kwisset, recv~nopar~nobra.expr, attrid)}
 536         ;
 537
 538 expr_atom~nopar~nobra {-> expr}
 539         = expr_single~nopar~nobra {-> expr_single~nopar~nobra.expr}
 540         | {attr} recv~nopar~nobra qualified_o attrid {-> New expr.attr(recv~nopar~nobra.expr, attrid)}
 541         | {call} recv~nopar~nobra qid args {-> New expr.call(recv~nopar~nobra.expr, qid.id, args.exprs)}
 542         | {super} qualified_o kwsuper args {-> New expr.super(qualified_o.qualified, kwsuper, args.exprs)}
 543         | {init} recv~nopar~nobra kwinit args {-> New expr.init(recv~nopar~nobra.expr, kwinit, args.exprs)}
 544 !nobra  | {bra} expr_atom~nopar braargs {-> New expr.bra(expr_atom~nopar.expr, braargs.exprs)}
 545         | {new} kwnew no type~nobra_nopar dot [n2]:no qid args {-> New expr.new(kwnew, type~nobra_nopar.type, qid.id, args.exprs)}
 546         | {as_cast} expr_atom~nopar~nobra dot no kwas [n2]:no opar [n3]:no type [n4]:no cpar {-> New expr.as_cast(expr_atom~nopar~nobra.expr, kwas, opar, type, cpar)}
 547         | {as_notnull} expr_atom~nopar~nobra dot no kwas [n2]:no opar [n3]:no kwnot [n4]:no kwnull [n5]:no cpar {-> New expr.as_notnull(expr_atom~nopar~nobra.expr, kwas, opar, kwnot, kwnull, cpar)}
 548         | {as_notnull2}expr_atom~nopar~nobra dot no kwas [n2]:no kwnot [n4]:no kwnull {-> New expr.as_notnull(expr_atom~nopar~nobra.expr, kwas, Null, kwnot, kwnull, Null)}
 549         | {vararg} [expr]:expr_atom~nopar~nobra dotdotdot {-> New expr.vararg(expr.expr, dotdotdot)}
 550         ;
 551
 552 expr_single~nopar~nobra {-> expr}
 553         = {self} kwself annotations_o {-> New expr.self(kwself, annotations_o.annotations)}
 554         | {true} kwtrue annotations_o {-> New expr.true(kwtrue, annotations_o.annotations)}
 555         | {false} kwfalse annotations_o {-> New expr.false(kwfalse, annotations_o.annotations)}
 556         | {null} kwnull annotations_o {-> New expr.null(kwnull, annotations_o.annotations)}
 557         | {int} number annotations_o {-> New expr.dec_int(number, annotations_o.annotations)}
 558         | {hex_int} hex_number annotations_o {-> New expr.hex_int(hex_number, annotations_o.annotations)}
 559         | {float} float annotations_o {-> New expr.float(float, annotations_o.annotations)}
 560         | {char} char annotations_o {-> New expr.char(char, annotations_o.annotations)}
 561         | {string} string annotations_o {-> New expr.string(string, annotations_o.annotations)}
 562         | {superstring} superstring  {-> superstring.expr}
 563 !nopar  | {par} expr_par {-> expr_par.expr}
 564 // !nopar to unambiguise 'foo[5].bar' between '(foo[5]).bar' and 'foo([5].bar),
 565 !nobra!nopar    | {range} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no cbra annotations_o {-> New expr.crange(obra, expr, expr2.expr, cbra, annotations_o.annotations)}
 566 !nobra!nopar    | {orange} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no [cbra]:obra annotations_o {-> New expr.orange(obra, expr, expr2.expr, cbra, annotations_o.annotations)}
 567 !nobra!nopar    | {array} obra no args_list typing_o cbra annotations_o {-> New expr.array(obra, args_list.exprs, typing_o.type, cbra, annotations_o.annotations)}
 568         ;
 569
 570 expr_par {-> expr}
 571         = {par} opar no any_expr [n2]:no cpar annotations_o {-> New expr.par(opar, any_expr.expr, cpar, annotations_o.annotations)}
 572         | {tuple} opar no many_expr [n2]:no cpar annotations_o {-> New expr.par(opar, many_expr.expr, cpar, annotations_o.annotations)}
 573         ;
 574
 575 many_expr {->expr}
 576         = any_expr many_expr_tail+ {-> New expr.many([any_expr.expr, many_expr_tail.expr])}
 577         ;
 578
 579 many_expr_tail {->expr}
 580         = comma no any_expr {-> any_expr.expr}
 581         ;
 582
 583 superstring {-> expr}
 584         = superstring_start superstring_middle* superstring_end annotations_o {-> New expr.superstring([superstring_start.expr, superstring_middle.expr, superstring_end.expr], annotations_o.annotations)};
 585 superstring_start {-> expr*}
 586         = start_string_p no expr [n2]:no {-> [start_string_p.expr, expr]}
 587         | {noexpr} start_string_p no {-> [start_string_p.expr]}
 588         ;
 589 start_string_p {-> expr}
 590         = start_string {-> New expr.start_string(start_string)};
 591 superstring_middle {-> expr*}
 592         = mid_string_p no expr [n2]:no {-> [mid_string_p.expr, expr]}
 593         | {noexpr} mid_string_p no {-> [mid_string_p.expr]}
 594         ;
 595 mid_string_p {-> expr}
 596         = mid_string {-> New expr.mid_string(mid_string)};
 597 superstring_end {-> expr}
 598         = end_string {-> New expr.end_string(end_string)};
 599
 600 /* ANNOTATIONS *******************************************************************/
 601
 602 annotations~nopar {-> annotations}
 603         = {one} at one_annotation~nopar {-> New annotations(at, Null, [one_annotation~nopar.annotation], Null)}
 604         | {many} at opar no annotation_list [n2]:no cpar {-> New annotations(at, opar, [annotation_list.annotation], cpar)}
 605         ;
 606 annotations_o~nopar {-> annotations?}
 607         = annotations~nopar {-> annotations~nopar.annotations}
 608         | {null} {-> Null}
 609         ;
 610
 611 one_annotation~nopar {-> annotation}
 612         = {alone} redef visibility atid annotations_o~nopar {-> New annotation(Null, redef.kwredef, visibility, atid, Null, [], Null, annotations_o~nopar.annotations)}
 613 // !nopar to unambiguise 'new T@foo(bar)' between 'new T@(foo(bar))' and 'new (T@foo)(bar)'
 614 !nopar  | {args} redef visibility atid opar no at_args [n2]:no cpar annotations_o~nopar {-> New annotation(Null, redef.kwredef, visibility, atid, opar, [at_args.expr], cpar, annotations_o~nopar.annotations)}
 615         ;
 616
 617 many_annotations {-> annotations}
 618         = {many} annotation_list {-> New annotations(Null, Null, [annotation_list.annotation], Null)}
 619         ;
 620
 621 annotation_list {-> annotation*}
 622         = {many} one_annotation_list annotations_tail* {-> [one_annotation_list.annotation, annotations_tail.annotation] }
 623         ;
 624
 625 one_annotation_list~nopar {-> annotation}
 626         = {alone} redef visibility atid annotations_o~nopar {-> New annotation(Null, redef.kwredef, visibility, atid, Null, [], Null, annotations_o~nopar.annotations)}
 627 // !nopar to unambiguise 'new T@foo(bar)' between 'new T@(foo(bar))' and 'new (T@foo)(bar)'
 628 !nopar  | {args} redef visibility atid opar no at_args [n2]:no cpar annotations_o~nopar {-> New annotation(Null, redef.kwredef, visibility, atid, opar, [at_args.expr], cpar, annotations_o~nopar.annotations)}
 629 !nopar  | {nopar} redef visibility atid at_arg_single {-> New annotation(Null, redef.kwredef, visibility, atid, Null, [at_arg_single.expr], Null, Null)}
 630         ;
 631 at_arg_single {-> expr}
 632 // FIXME: why expr_single but not expr_atom is not clear :(
 633         = {expr} [expr]:expr_single_nopar {-> expr.expr}
 634         ;
 635
 636 annotations_tail {-> annotation}
 637         = comma no one_annotation_list {-> one_annotation_list.annotation}
 638         ;
 639
 640 line_annotations {-> annotations}
 641         = line_annotation+ {-> New annotations(Null, Null, [line_annotation.annotation], Null) }
 642         ;
 643 line_annotation {-> annotation}
 644         = [doc]:no redef visibility atid annotations? n1 {-> New annotation(doc.doc, redef.kwredef, visibility, atid.atid, Null, [], Null, annotations)}
 645         | {args} [doc]:no redef visibility atid opar no at_args cpar annotations? n1 {-> New annotation(doc.doc, redef.kwredef, visibility, atid.atid, opar, [at_args.expr], cpar, annotations)}
 646         | {nopar} [doc]:no redef visibility atid at_args_nopar n1 {-> New annotation(doc.doc, redef.kwredef, visibility, atid.atid, Null, [at_args_nopar.expr], Null, Null)}
 647         ;
 648 line_annotations_forclass {-> annotations}
 649         = line_annotation_forclass+ {-> New annotations(Null, Null, [line_annotation_forclass.annotation], Null) }
 650         ;
 651 line_annotation_forclass {-> annotation}
 652         = [doc]:no atid_forclass annotations? n1 {-> New annotation(doc.doc, Null, Null, atid_forclass.atid, Null, [], Null, annotations)}
 653         | {args} [doc]:no atid_forclass opar no at_args cpar annotations? n1 {-> New annotation(doc.doc, Null, Null, atid_forclass.atid, opar, [at_args.expr], cpar, annotations)}
 654         | {nopar} [doc]:no atid_forclass at_args_nopar n1 {-> New annotation(doc.doc, Null, Null, atid_forclass.atid, Null, [at_args_nopar.expr], Null, Null)}
 655         ;
 656
 657 at_args~nopar {-> expr* }
 658         = {many} any_expr~nopar at_args_tail* {-> [any_expr~nopar.expr, at_args_tail.expr]}
 659         ;
 660
 661 at_args_tail {-> expr}
 662         = comma no any_expr {-> any_expr.expr}
 663         ;
 664
 665 any_expr~nopar {-> expr}
 666         = {type} type {-> New expr.type(type)}
 667         | {expr} expr~nopar {-> expr~nopar.expr}
 668         | {stmt} stmt_noexpr~nopar {-> stmt_noexpr~nopar.expr}
 669         | {methid} recv~nopar qmethid_noid {-> New expr.methid(recv~nopar.expr, qmethid_noid.methid)}
 670 !nopar  | {at} annotations {-> New expr.at(annotations.annotations)}
 671         ;
 672
 673 atid~forclass {-> atid}
 674         = {id}  id {-> New atid.id(id)}
 675 !forclass       | {kwextern} kwextern {-> New atid.kwextern(kwextern)}
 676 //      | {kwimport} kwimport {-> New atid.kwimport(kwimport)}
 677         | {kwabstract} kwabstract {-> New atid.kwabstract(kwabstract)}
 678         ;
 679
 680 /* MISC **********************************************************************/
 681
 682 recv~nopar~nobra {-> expr}
 683         = expr_atom~nopar~nobra dot no {-> expr_atom~nopar~nobra.expr}
 684         | {implicit} {-> New expr.implicit_self()}
 685         ;
 686
 687 args {-> exprs}
 688         = args_n {-> args_n.exprs}
 689         | {empty} {-> New exprs.list([])}
 690         ;
 691 args_n {-> exprs}
 692         = opar no expr_list cpar {-> New exprs.par(opar, [expr_list.expr], cpar) }
 693         | {emptypar} opar no cpar {-> New exprs.par(opar, [], cpar) }
 694         ;
 695 args_nopar {-> exprs}
 696         = opar no expr_list cpar {-> New exprs.par(opar, [expr_list.expr], cpar) }
 697         | {onearg} expr_nopar {-> New exprs.list([expr_nopar.expr])}
 698         | {emptypar} opar no cpar {-> New exprs.par(opar, [], cpar) }
 699         | {empty} {-> New exprs.list([])}
 700         ;
 701 braargs {-> exprs}
 702         = obra no expr_list cbra {-> New exprs.bra(obra, [expr_list.expr], cbra)};
 703 args_list {-> exprs}
 704         = expr_list {-> New exprs.list([expr_list.expr])};
 705 expr_list {-> expr*}
 706         = expr [n2]:no expr_tail* {-> [expr, expr_tail.expr]};
 707 expr_tail {-> expr}
 708         = comma no expr [n2]:no {-> expr};
 709 idlist {-> id*}
 710         = opar no idlist_nopar [n2]:no cpar {-> [idlist_nopar.id]}
 711         | {nopar} idlist_nopar {-> [idlist_nopar.id]}
 712         ;
 713 idlist_nopar {-> id*}
 714         = {single} id {-> [id]}
 715         | {more} idlist_nopar comma [n2]:no id {-> [idlist_nopar.id, id]}
 716         ;
 717
 718 module_name {-> module_name}
 719         = {mod} modquad* id {-> New module_name(Null, [modquad.id], id)}
 720         | {root} quad no modquad* id {-> New module_name(quad, [modquad.id], id)}
 721         ;
 722
 723 qualified
 724         = {cla} modquad* classquad {-> New qualified([modquad.id], classquad.classid)}
 725         | {mod} modquad+ {-> New qualified([modquad.id], Null)}
 726         ;
 727 qualified_o {-> qualified?}
 728         = qualified {-> qualified}
 729         | {null} {-> Null}
 730         ;
 731 qid {-> id}
 732         = qualified? id {-> id}
 733         ;
 734 qclassid {-> classid}
 735         = qualified? classid {-> classid}
 736         ;
 737 qmethid~noid {-> methid}
 738         = qualified? methid~noid {-> methid~noid.methid}
 739         ;
 740 modquad {-> id}
 741         = id quad no {-> id};
 742 classquad {-> classid}
 743         = classid quad no {-> classid};
 744
 745 kwend_o {-> kwend?}
 746         = kwend? {-> kwend}
 747         ;
 748
 749 n1      = {a} comment | {b} eol;
 750 n {-> doc?}
 751         = {a} n2? comment+ {-> New doc([comment])}
 752         | {b} n2 {-> Null}
 753         ;
 754 no {-> doc?}
 755         = {empty} {-> Null}
 756         | n {-> n.doc}
 757         ;
 758
 759 n2
 760         = {a} n2? comment+ eol+
 761         | {b} eol+
 762         ;
 763
 764 /*****************************************************************************/
 765 Abstract Syntax Tree
 766 /*****************************************************************************/
 767
 768 module  = moduledecl? [imports]:import* [extern_code_blocks]:extern_code_block* [classdefs]:classdef*;
 769
 770 moduledecl
 771         = doc? kwredef? visibility kwmodule [name]:module_name annotations?;
 772
 773 import  = {std} visibility kwimport [name]:module_name annotations?
 774         | {no} visibility kwimport kwend
 775         ;
 776
 777 visibility
 778         = {public} kwpublic?
 779         | {private} kwprivate
 780         | {protected} kwprotected
 781         | {intrude} kwintrude
 782         ;
 783
 784 classdef= {std} doc? kwredef? visibility classkind [id]:classid? [formaldefs]:formaldef* annotations? extern_code_block? [superclasses]:superclass* [propdefs]:propdef* kwend
 785         | {top} [propdefs]:propdef*
 786         | {main} [propdefs]:propdef*
 787         ;
 788 classkind
 789         = {concrete} kwclass
 790         | {abstract} kwabstract kwclass
 791         | {interface} kwinterface
 792         | {enum} kwenum
 793         | {extern} kwextern kwclass?
 794         ;
 795 formaldef = [id]:classid type? annotations?;
 796 superclass = kwsuper type annotations?;
 797
 798
 799 propdef = {attr} doc? kwredef? visibility kwvar [id2]:id type? expr? annotations?
 800         | {main_meth} kwredef? [block]:expr?
 801         | {type} doc? kwredef? visibility kwtype [id]:classid type annotations?
 802         | {meth} doc? kwredef? visibility kwmeth? kwinit? kwnew? methid? signature annotations? extern_calls? extern_code_block? [block]:expr?
 803         ;
 804
 805 methid = {id} id | {plus} plus | {minus} minus | {star} star | {starstar} starstar | {slash} slash | {percent} percent | {eq} eq | {ne} ne | {le} le | {ge} ge | {lt} lt | {gt} gt |  {ll} ll | {gg} gg | {bra} obra cbra | {starship} starship | {assign} id assign | {braassign} obra cbra assign;
 806
 807 signature = opar? [params]:param* cpar? type?;
 808
 809 param   = id type? dotdotdot? annotations?
 810         ;
 811
 812 type    = kwnullable? [id]:classid [types]:type* annotations?;
 813
 814 label = kwlabel id?;
 815
 816 expr    = {block} expr* kwend?
 817         | {vardecl} kwvar id type? assign? expr? annotations?
 818         | {return} kwreturn? expr?
 819         | {break} kwbreak label?
 820         | {abort} kwabort
 821         | {continue} kwcontinue? label?
 822         | {do} kwdo [block]:expr? label?
 823         | {if} kwif expr [then]:expr? [else]:expr?
 824         | {ifexpr} kwif expr kwthen [then]:expr kwelse [else]:expr
 825         | {while} kwwhile expr kwdo [block]:expr? label?
 826         | {loop} kwloop [block]:expr? label?
 827         | {for} kwfor [ids]:id* expr kwdo [block]:expr? label?
 828         | {assert} kwassert id? expr [else]:expr?
 829         | {once} kwonce expr
 830         | {send} expr
 831         | {binop} expr [expr2]:expr
 832         | {or} expr [expr2]:expr
 833         | {and} expr [expr2]:expr
 834         | {or_else} expr [expr2]:expr
 835         | {implies} expr [expr2]:expr
 836         | {not} kwnot expr
 837         | {eq} expr [expr2]:expr
 838         | {ne} expr [expr2]:expr
 839         | {lt} expr [expr2]:expr
 840         | {le} expr [expr2]:expr
 841         | {ll} expr [expr2]:expr
 842         | {gt} expr [expr2]:expr
 843         | {ge} expr [expr2]:expr
 844         | {gg} expr [expr2]:expr
 845         | {isa} expr type
 846         | {plus} expr [expr2]:expr
 847         | {minus} expr [expr2]:expr
 848         | {starship} expr [expr2]:expr
 849         | {star} expr [expr2]:expr
 850         | {starstar} expr [expr2]:expr
 851         | {slash} expr [expr2]:expr
 852         | {percent} expr [expr2]:expr
 853         | {uminus} minus expr
 854         | {new} kwnew type id? [args]:exprs
 855         | {attr} expr [id]:attrid
 856         | {attr_assign} expr [id]:attrid assign [value]:expr
 857         | {attr_reassign} expr [id]:attrid assign_op [value]:expr
 858         | {call} expr id [args]:exprs
 859         | {call_assign} expr id [args]:exprs assign [value]:expr
 860         | {call_reassign} expr id [args]:exprs assign_op [value]:expr
 861         | {super} qualified? kwsuper [args]:exprs
 862         | {init} expr kwinit [args]:exprs
 863         | {bra} expr [args]:exprs
 864         | {bra_assign} expr [args]:exprs assign [value]:expr
 865         | {bra_reassign} expr [args]:exprs assign_op [value]:expr
 866         | {var} id
 867         | {var_assign} id assign [value]:expr
 868         | {var_reassign} id assign_op [value]:expr
 869         | {range} expr [expr2]:expr annotations?
 870         | {crange} obra expr [expr2]:expr cbra annotations?
 871         | {orange} obra expr [expr2]:expr [cbra]:obra annotations?
 872         | {array} obra [exprs]:exprs type? cbra annotations?
 873         | {self} kwself annotations?
 874         | {implicit_self}
 875         | {true} kwtrue annotations?
 876         | {false} kwfalse annotations?
 877         | {null} kwnull annotations?
 878         | {dec_int} number annotations?
 879         | {hex_int} hex_number annotations?
 880         | {float} float annotations?
 881         | {char} char annotations?
 882         | {string} string annotations?
 883         | {start_string} [string]:start_string
 884         | {mid_string} [string]:mid_string
 885         | {end_string} [string]:end_string
 886         | {superstring} [exprs]:expr* annotations?
 887         | {par} opar expr cpar annotations?
 888         | {as_cast} expr kwas opar? type cpar?
 889         | {as_notnull} expr kwas opar? kwnot kwnull cpar?
 890         | {isset_attr} kwisset expr [id]:attrid
 891         | {debug_type} kwdebug kwtype expr type
 892         | {vararg} expr dotdotdot
 893         | {type} type
 894         | {methid} expr [id]:methid
 895         | {at} annotations
 896         | {many} [exprs]:expr*
 897         ;
 898 exprs
 899         = {list} [exprs]:expr*
 900         | {par} opar [exprs]:expr* cpar
 901         | {bra} obra [exprs]:expr* cbra
 902         ;
 903 assign_op
 904         = {plus} pluseq
 905         | {minus} minuseq
 906         ;
 907
 908 module_name = quad? [path]:id* id;
 909 extern_calls = kwimport [extern_calls]:extern_call*
 910         ;
 911 extern_call =
 912         | {super} kwsuper
 913         | {local_prop} methid
 914         | {full_prop} type dot? methid
 915         | {init_prop} type
 916         | {cast_as} [from_type]:type dot? kwas [to_type]:type
 917         | {as_nullable} type kwas kwnullable
 918         | {as_not_nullable} type kwas kwnot kwnullable
 919         ;
 920 in_language = kwin string;
 921 extern_code_block = in_language? extern_code_segment;
 922
 923 qualified = id* classid? ;
 924
 925 doc = comment+;
 926
 927 annotations = at? opar? [items]:annotation* cpar?;
 928
 929 annotation = doc? kwredef? visibility? atid opar? [args]:expr* cpar? annotations?;
 930
 931 atid = {id} id | {kwextern} [id]:kwextern | {kwabstract} [id]:kwabstract | {kwimport} [id]:kwimport;
 932
 933 /*****************************************************************************/
 934