src/nitweb.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 # http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Runs a webserver based on nitcorn that render things from model.
  16 module nitweb
  17
  18 import popcorn::pop_config
  19 import popcorn::pop_auth
  20 import frontend
  21 import web
  22
  23 redef class NitwebConfig
  24
  25         # Github client id used for Github OAuth login.
  26         #
  27         # * key: `github.client_id`
  28         # * default: ``
  29         var github_client_id: String is lazy do return value_or_default("github.client.id", "")
  30
  31         # Github client secret used for Github OAuth login.
  32         #
  33         # * key: `github.client_secret`
  34         # * default: ``
  35         var github_client_secret: String is lazy do
  36                 return value_or_default("github.client.secret", "")
  37         end
  38 end
  39
  40 redef class ToolContext
  41
  42         # Path to app config file.
  43         var opt_config = new OptionString("Path to app config file", "--config")
  44
  45         # Host name to bind on (will overwrite the config one).
  46         var opt_host = new OptionString("Host to bind the server on", "--host")
  47
  48         # Port number to bind on (will overwrite the config one).
  49         var opt_port = new OptionInt("Port number to use", -1, "--port")
  50
  51         # Web rendering phase.
  52         var webphase: Phase = new NitwebPhase(self, null)
  53
  54         init do
  55                 super
  56                 option_context.add_option(opt_config, opt_host, opt_port)
  57         end
  58 end
  59
  60 # Phase that builds the model and wait for http request to serve pages.
  61 private class NitwebPhase
  62         super Phase
  63
  64         # Build the nitweb config from `toolcontext` options.
  65         fun build_config(toolcontext: ToolContext, mainmodule: MModule): NitwebConfig do
  66                 var config_file = toolcontext.opt_config.value
  67                 if config_file == null then config_file = "nitweb.ini"
  68                 var config = new NitwebConfig(
  69                         config_file,
  70                         toolcontext.modelbuilder.model,
  71                         mainmodule,
  72                         toolcontext.modelbuilder)
  73                 var opt_host = toolcontext.opt_host.value
  74                 if opt_host != null then config["app.host"] = opt_host
  75                 var opt_port = toolcontext.opt_port.value
  76                 if opt_port >= 0 then config["app.port"] = opt_port.to_s
  77                 return config
  78         end
  79
  80         redef fun process_mainmodule(mainmodule, mmodules)
  81         do
  82                 var config = build_config(toolcontext, mainmodule)
  83
  84                 var app = new App
  85
  86                 app.use_before("/*", new SessionInit)
  87                 app.use_before("/*", new RequestClock)
  88                 app.use("/api", new APIRouter(config))
  89                 app.use("/login", new GithubLogin(config.github_client_id))
  90                 app.use("/oauth", new GithubOAuthCallBack(config.github_client_id, config.github_client_secret))
  91                 app.use("/logout", new GithubLogout)
  92                 app.use("/*", new StaticHandler(toolcontext.share_dir / "nitweb", "index.html"))
  93                 app.use_after("/*", new ConsoleLog)
  94
  95                 app.listen(config.app_host, config.app_port)
  96         end
  97 end
  98
  99 # build toolcontext
 100 var toolcontext = new ToolContext
 101 var tpl = new Template
 102 tpl.add "Usage: nitweb [OPTION]... <file.nit>...\n"
 103 tpl.add "Run a webserver based on nitcorn that serves pages about model."
 104 toolcontext.tooldescription = tpl.write_to_string
 105
 106 # process options
 107 toolcontext.process_options(args)
 108 var arguments = toolcontext.option_context.rest
 109
 110 # build model
 111 var model = new Model
 112 var mbuilder = new ModelBuilder(model, toolcontext)
 113 var mmodules = mbuilder.parse_full(arguments)
 114
 115 # process
 116 if mmodules.is_empty then return
 117 mbuilder.run_phases
 118 toolcontext.run_global_phases(mmodules)