examples/opengles2_hello_triangle.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2014 Alexis Laferrière <alexis.laf@xymus.net>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Basic example of OpenGL ES 2.0 usage from the book OpenGL ES 2.0 Programming Guide.
  18 #
  19 # Code reference:
  20 # https://code.google.com/p/opengles-book-samples/source/browse/trunk/LinuxX11/Chapter_2/Hello_Triangle/Hello_Triangle.c
  21 module opengles2_hello_triangle
  22
  23 import glesv2
  24 import egl
  25 import mnit_linux # for sdl
  26 import x11
  27
  28 if "NIT_TESTING".environ == "true" then exit(0)
  29
  30 var window_width = 800
  31 var window_height = 600
  32
  33 #
  34 ## SDL
  35 #
  36 var sdl_display = new SDLDisplay(window_width, window_height)
  37 var sdl_wm_info = new SDLSystemWindowManagerInfo
  38 var x11_window_handle = sdl_wm_info.x11_window_handle
  39
  40 #
  41 ## X11
  42 #
  43 var x_display = x_open_default_display
  44 assert x_display != 0 else print "x11 fail"
  45
  46 #
  47 ## EGL
  48 #
  49 var egl_display = new EGLDisplay(x_display)
  50 assert egl_display.is_valid else print "EGL display is not valid"
  51 egl_display.initialize
  52
  53 print "EGL version: {egl_display.version}"
  54 print "EGL vendor: {egl_display.vendor}"
  55 print "EGL extensions: {egl_display.extensions.join(", ")}"
  56 print "EGL client APIs: {egl_display.client_apis.join(", ")}"
  57
  58 assert egl_display.is_valid else print egl_display.error
  59
  60 var config_chooser = new EGLConfigChooser
  61 #config_chooser.surface_type_egl
  62 config_chooser.blue_size = 8
  63 config_chooser.green_size = 8
  64 config_chooser.red_size = 8
  65 #config_chooser.alpha_size = 8
  66 #config_chooser.depth_size = 8
  67 #config_chooser.stencil_size = 8
  68 #config_chooser.sample_buffers = 1
  69 config_chooser.close
  70
  71 var configs = config_chooser.choose(egl_display)
  72 assert configs != null else print "choosing config failed: {egl_display.error}"
  73 assert not configs.is_empty else print "no EGL config"
  74
  75 var config = configs.first
  76
  77 var format = config.attribs(egl_display).native_visual_id
  78
  79 # TODO android part
  80 # Opengles1Display_midway_init(recv, format);
  81
  82 var surface = egl_display.create_window_surface(config, x11_window_handle, [0])
  83 assert surface.is_ok else print egl_display.error
  84
  85 var context = egl_display.create_context(config)
  86 assert context.is_ok else print egl_display.error
  87
  88 var make_current_res = egl_display.make_current(surface, surface, context)
  89 assert make_current_res
  90
  91 var width = surface.attribs(egl_display).width
  92 var height = surface.attribs(egl_display).height
  93 print "Width: {width}"
  94 print "Height: {height}"
  95
  96 assert egl_bind_opengl_es_api else print "eglBingAPI failed: {egl_display.error}"
  97
  98 #
  99 ## GLESv2
 100 #
 101
 102 print "Can compile shaders? {gl_shader_compiler}"
 103 assert_no_gl_error
 104
 105 assert gl_shader_compiler else print "Cannot compile shaders"
 106
 107 # gl program
 108 print gl_error.to_s
 109 var program = new GLProgram
 110 if not program.is_ok then
 111         print "Program is not ok: {gl_error.to_s}\nLog:"
 112         print program.info_log
 113         abort
 114 end
 115 assert_no_gl_error
 116
 117 # vertex shader
 118 var vertex_shader = new GLVertexShader
 119 assert vertex_shader.is_ok else print "Vertex shader is not ok: {gl_error}"
 120 vertex_shader.source = """
 121 attribute vec4 vPosition;
 122 void main()
 123 {
 124   gl_Position = vPosition;
 125 }                           """
 126 vertex_shader.compile
 127 assert vertex_shader.is_compiled else print "Vertex shader compilation failed with: {vertex_shader.info_log} {program.info_log}"
 128 assert_no_gl_error
 129
 130 # fragment shader
 131 var fragment_shader = new GLFragmentShader
 132 assert fragment_shader.is_ok else print "Fragment shader is not ok: {gl_error}"
 133 fragment_shader.source = """
 134 precision mediump float;
 135 void main()
 136 {
 137         gl_FragColor = vec4(1.0, 0.0, 0.0, 1.0);
 138 }
 139 """
 140 fragment_shader.compile
 141 assert fragment_shader.is_compiled else print "Fragment shader compilation failed with: {fragment_shader.info_log}"
 142 assert_no_gl_error
 143
 144 program.attach_shader vertex_shader
 145 program.attach_shader fragment_shader
 146 program.bind_attrib_location(0, "vPosition")
 147 program.link
 148 assert program.is_linked else print "Linking failed: {program.info_log}"
 149 assert_no_gl_error
 150
 151 # draw!
 152 var vertices = [0.0, 0.5, 0.0, -0.5, -0.5, 0.0, 0.5, -0.5, 0.0]
 153 var vertex_array = new VertexArray(0, 3, vertices)
 154 vertex_array.attrib_pointer
 155 gl_clear_color(0.5, 0.0, 0.5, 1.0)
 156 for i in [0..10000[ do
 157         printn "."
 158         assert_no_gl_error
 159         gl_viewport(0, 0, width, height)
 160         gl_clear_color_buffer
 161         program.use
 162         vertex_array.enable
 163         vertex_array.draw_arrays_triangles
 164         egl_display.swap_buffers(surface)
 165 end
 166
 167 # delete
 168 program.delete
 169 vertex_shader.delete
 170 fragment_shader.delete
 171
 172 #
 173 ## EGL
 174 #
 175 # close
 176 egl_display.make_current(new EGLSurface.none, new EGLSurface.none, new EGLContext.none)
 177 egl_display.destroy_context(context)
 178 egl_display.destroy_surface(surface)
 179
 180 #
 181 ## SDL
 182 #
 183 # close
 184 sdl_display.destroy