src/transform.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Thansformations that simplify the AST of expressions
  16 # This module transform complex AST `AExpr` nodes into simplier ones
  17 module transform
  18
  19 import astbuilder
  20 import auto_super_init
  21 import astvalidation
  22
  23 redef class ToolContext
  24         var transform_phase: Phase = new TransformPhase(self, [typing_phase, auto_super_init_phase])
  25 end
  26
  27 private class TransformPhase
  28         super Phase
  29
  30         redef fun process_npropdef(npropdef: APropdef)
  31         do
  32                 var val
  33
  34                 var v = new TransformVisitor(self, npropdef)
  35                 v.enter_visit(npropdef)
  36
  37                 val = new ASTValidationVisitor
  38                 val.enter_visit(npropdef)
  39         end
  40 end
  41
  42 private class TransformVisitor
  43         super Visitor
  44
  45         var phase: TransformPhase
  46         var mmodule: MModule
  47         var mclassdef: MClassDef
  48         var mpropdef: MPropDef
  49         var builder: ASTBuilder
  50
  51         init(phase: TransformPhase, npropdef: APropdef)
  52         do
  53                 self.phase = phase
  54                 self.mpropdef = npropdef.mpropdef.as(not null)
  55                 self.mclassdef = mpropdef.mclassdef
  56                 self.mmodule = mclassdef.mmodule
  57                 self.builder = new ASTBuilder(mmodule, mpropdef.mclassdef.bound_mtype)
  58         end
  59
  60         redef fun visit(node)
  61         do
  62                 if node isa AAnnotations then return
  63                 node.visit_all(self)
  64                 node.accept_transform_visitor(self)
  65         end
  66
  67         # Get a primitive class or display a fatal error on `location`.
  68         fun get_class(location: AExpr, name: String): MClass
  69         do
  70                 return mmodule.get_primitive_class(name)
  71         end
  72
  73         # Get a primitive method or display a fatal error on `location`.
  74         fun get_method(location: AExpr, name: String, recv: MClass): MMethod
  75         do
  76                 return phase.toolcontext.modelbuilder.force_get_primitive_method(location, name, recv, mmodule)
  77         end
  78 end
  79
  80 redef class ANode
  81         private fun accept_transform_visitor(v: TransformVisitor)
  82         do
  83         end
  84 end
  85
  86 redef class AVardeclExpr
  87         # `var x = y` is replaced with `x = y`
  88         #
  89         # Declarations are only useful for scope rules
  90         # Once names are associated with real objects, ther declaration become useless
  91         # Therefore, if there is no initial value, then just detach it
  92         # Else, replace it with a simple assignment
  93         redef fun accept_transform_visitor(v)
  94         do
  95                 var nexpr = n_expr
  96                 if nexpr == null then
  97                         detach
  98                 else
  99                         var nvar = v.builder.make_var_assign(self.variable.as(not null), nexpr)
 100                         replace_with(nvar)
 101                 end
 102         end
 103 end
 104
 105 redef class AIfexprExpr
 106         # is replaced with `AIfExpr`
 107         # Expression if and statement-if use two distinct classes for historical reasons
 108         # However, on can replace the `AIfexprExpr` with the simpler `AIfExpr`
 109         redef fun accept_transform_visitor(v)
 110         do
 111                 var nif = v.builder.make_if(n_expr, self.mtype)
 112                 nif.n_then.add(n_then)
 113                 nif.n_else.add(n_else)
 114
 115                 replace_with(nif)
 116         end
 117 end
 118
 119 redef class AOrExpr
 120         # `x or y` is replaced with `if x then x else y`
 121         redef fun accept_transform_visitor(v)
 122         do
 123                 var nif = v.builder.make_if(n_expr, self.mtype)
 124                 nif.n_then.add(n_expr.make_var_read)
 125                 nif.n_else.add(n_expr2)
 126
 127                 replace_with(nif)
 128         end
 129 end
 130
 131 redef class AImpliesExpr
 132         redef fun accept_transform_visitor(v)
 133         do
 134                 # TODO
 135         end
 136 end
 137
 138 redef class AAndExpr
 139         # `x and y` is replaced with `if x then y else x`
 140         redef fun accept_transform_visitor(v)
 141         do
 142                 var nif = v.builder.make_if(n_expr, self.mtype)
 143                 nif.n_then.add(n_expr2)
 144                 nif.n_else.add(n_expr.make_var_read)
 145
 146                 replace_with(nif)
 147         end
 148 end
 149
 150 redef class AWhileExpr
 151         redef fun accept_transform_visitor(v)
 152         do
 153                 # TODO
 154         end
 155 end
 156
 157 redef class AForExpr
 158         redef fun accept_transform_visitor(v)
 159         do
 160                 # TODO
 161         end
 162 end
 163
 164 redef class AArrayExpr
 165         # `[x,y]` is replaced with
 166         #
 167         #     var t = new Array[X].with_capacity(2)
 168         #     t.add(x)
 169         #     t.add(y)
 170         #     t
 171         redef fun accept_transform_visitor(v)
 172         do
 173                 var mtype = self.mtype.as(MClassType)
 174                 var nblock = v.builder.make_block
 175
 176                 var meth = v.get_method(self, "with_capacity", mtype.mclass)
 177                 var nnew = v.builder.make_new(mtype, meth, [v.builder.make_int(n_exprs.n_exprs.length)])
 178                 nblock.add nnew
 179
 180                 var madd = v.get_method(self, "push", mtype.mclass)
 181                 for nexpr in self.n_exprs.n_exprs do
 182                         var nadd = v.builder.make_call(nnew.make_var_read, madd, [nexpr])
 183                         nblock.add nadd
 184                 end
 185                 var nres = nnew.make_var_read
 186                 nblock.add nres
 187
 188                 replace_with(nblock)
 189         end
 190 end
 191
 192 redef class ASuperstringExpr
 193         # `"x{y}z"` is replaced with
 194         #
 195         #     var t = new Array[Object].with_capacity(3)
 196         #     t.add("x")
 197         #     t.add(y)
 198         #     t.add("z")
 199         #     t.to_s
 200         redef fun accept_transform_visitor(v)
 201         do
 202                 var nblock = v.builder.make_block
 203
 204                 var arraytype = v.get_class(self, "Array").get_mtype([v.get_class(self, "Object").mclass_type])
 205                 var meth = v.get_method(self, "with_capacity", arraytype.mclass)
 206                 var nnew = v.builder.make_new(arraytype, meth, [v.builder.make_int(n_exprs.length)])
 207                 nblock.add nnew
 208
 209                 var madd = v.get_method(self, "add", arraytype.mclass)
 210                 for nexpr in self.n_exprs do
 211                         var nadd = v.builder.make_call(nnew.make_var_read, madd, [nexpr])
 212                         nblock.add nadd
 213                 end
 214
 215                 var mtos = v.get_method(self, "to_s", arraytype.mclass)
 216                 var ntos = v.builder.make_call(nnew.make_var_read, mtos, null)
 217                 nblock.add ntos
 218
 219                 replace_with(nblock)
 220         end
 221 end
 222
 223 redef class ACrangeExpr
 224         # `[x..y]` is replaced with `new Range[X](x,y)`
 225         redef fun accept_transform_visitor(v)
 226         do
 227                 var mtype = self.mtype.as(MClassType)
 228                 replace_with(v.builder.make_new(mtype, init_callsite.mproperty, [n_expr, n_expr2]))
 229         end
 230 end
 231
 232 redef class AOrangeExpr
 233         # `[x..y[` is replaced with `new Range[X].without_last(x,y)`
 234         redef fun accept_transform_visitor(v)
 235         do
 236                 var mtype = self.mtype.as(MClassType)
 237                 replace_with(v.builder.make_new(mtype, init_callsite.mproperty, [n_expr, n_expr2]))
 238         end
 239 end
 240
 241 redef class AParExpr
 242         # `(x)` is replaced with `x`
 243         redef fun accept_transform_visitor(v)
 244         do
 245                 replace_with(n_expr)
 246         end
 247 end
 248
 249 redef class ASendReassignFormExpr
 250         # `x.foo(y)+=z` is replaced with
 251         #
 252         #     x.foo(y) = x.foo(y) + z
 253         #
 254         # witch is, in reality:
 255         #
 256         #     x."foo="(y, x.foo(y)."+"(z))
 257         redef fun accept_transform_visitor(v)
 258         do
 259                 var nblock = v.builder.make_block
 260                 nblock.add(n_expr)
 261
 262                 var read_args = new Array[AExpr]
 263                 var write_args = new Array[AExpr]
 264                 for a in raw_arguments.as(not null) do
 265                         nblock.add(a)
 266                         read_args.add(a.make_var_read)
 267                         write_args.add(a.make_var_read)
 268                 end
 269
 270                 var nread = v.builder.make_call(n_expr.make_var_read, callsite.mproperty, read_args)
 271
 272                 var nnewvalue = v.builder.make_call(nread, reassign_callsite.mproperty, [n_value])
 273
 274                 write_args.add(nnewvalue)
 275                 var nwrite = v.builder.make_call(n_expr.make_var_read, write_callsite.mproperty, write_args)
 276                 nblock.add(nwrite)
 277
 278                 replace_with(nblock)
 279         end
 280 end
 281
 282 redef class AVarReassignExpr
 283         # `v += z` is replaced with `v = v + z`
 284         redef fun accept_transform_visitor(v)
 285         do
 286                 var variable = self.variable.as(not null)
 287
 288                 var nread = v.builder.make_var_read(variable, read_type.as(not null))
 289
 290                 var nnewvalue = v.builder.make_call(nread, reassign_callsite.mproperty, [n_value])
 291                 var nwrite = v.builder.make_var_assign(variable, nnewvalue)
 292
 293                 replace_with(nwrite)
 294         end
 295 end
 296
 297 redef class AAttrReassignExpr
 298         # `x.a += z` is replaced with `x.a = x.a + z`
 299         redef fun accept_transform_visitor(v)
 300         do
 301                 var nblock = v.builder.make_block
 302                 nblock.add(n_expr)
 303                 var attribute = self.mproperty.as(not null)
 304
 305                 var nread = v.builder.make_attr_read(n_expr.make_var_read, attribute)
 306                 var nnewvalue = v.builder.make_call(nread, reassign_callsite.mproperty, [n_value])
 307                 var nwrite = v.builder.make_attr_assign(n_expr.make_var_read, attribute, nnewvalue)
 308                 nblock.add(nwrite)
 309
 310                 replace_with(nblock)
 311         end
 312 end