src/nitls.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2012 Jean Privat <jean@pryen.org>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Simple tool to list Nit source files
  18 module nitls
  19
  20 intrude import modelbuilder
  21 import ordered_tree
  22
  23 class ProjTree
  24         super OrderedTree[Object]
  25
  26         var opt_paths = false
  27
  28         redef fun display(o)
  29         do
  30                 if o isa MGroup then
  31                         if opt_paths then
  32                                 return o.filepath.as(not null)
  33                         else
  34                                 return "{o.name} ({o.filepath.to_s})"
  35                         end
  36                 else if o isa ModulePath then
  37                         if opt_paths then
  38                                 return o.filepath
  39                         else
  40                                 return "{o.name} ({o.filepath})"
  41                         end
  42                 else
  43                         abort
  44                 end
  45         end
  46 end
  47
  48 var tc = new ToolContext
  49
  50 var opt_keep = new OptionBool("Ignore errors and files that are not a Nit source file", "-k", "--keep")
  51 var opt_recursive = new OptionBool("Process directories recussively", "-r", "--recursive")
  52 var opt_tree = new OptionBool("List source files in their groups and projects", "-t", "--tree")
  53 var opt_source = new OptionBool("List source files", "-s", "--source")
  54 var opt_project = new OptionBool("List projects paths (default)", "-P", "--project")
  55 var opt_depends = new OptionBool("List dependencies of given modules", "-d", "--depends")
  56 var opt_make = new OptionBool("List dependencies suitable for a rule in a Makefile. Alias for -d, -p and -s", "-M")
  57 var opt_paths = new OptionBool("List only path (instead of name + path)", "-p", "--path")
  58
  59 tc.option_context.add_option(opt_keep, opt_recursive, opt_tree, opt_source, opt_project, opt_depends, opt_paths, opt_make)
  60 tc.tooldescription = "Usage: nitls [OPTION]... <file.nit|directory>...\nLists the projects and/or paths of Nit sources files."
  61 tc.process_options(args)
  62
  63 if opt_make.value then
  64         opt_depends.value = true
  65         opt_paths.value = true
  66         opt_source.value = true
  67 end
  68
  69 var sum = opt_tree.value.to_i + opt_source.value.to_i + opt_project.value.to_i
  70 if sum > 1 then
  71         print "Error: options --tree, --source, and --project are exclusives."
  72         print tc.tooldescription
  73         exit 1
  74 end
  75
  76 var model = new Model
  77 var mb = new ModelBuilder(model, tc)
  78
  79 if opt_depends.value then
  80         if opt_recursive.value then
  81                 print "-M incompatible with -r"
  82                 exit 1
  83         end
  84
  85         mb.parse(tc.option_context.rest)
  86 else
  87         var files
  88         if opt_recursive.value then
  89                 files = new Array[String]
  90                 for d in tc.option_context.rest do
  91                         var pipe = new IProcess("find", d, "-name", "*.nit")
  92                         while not pipe.eof do
  93                                 var l = pipe.read_line
  94                                 if l == "" then break # last line
  95                                 l = l.substring(0,l.length-1) # strip last oef
  96                                 files.add l
  97                         end
  98                         pipe.close
  99                         pipe.wait
 100                         if pipe.status != 0 and not opt_keep.value then exit 1
 101                 end
 102         else
 103                 files = tc.option_context.rest
 104         end
 105
 106         for a in files do
 107                 var mp = mb.identify_file(a)
 108                 if mp == null then
 109                         if not opt_keep.value then tc.check_errors
 110                 end
 111         end
 112 end
 113
 114 if sum == 0 then opt_project.value = true
 115
 116 if opt_tree.value then
 117         var ot = new ProjTree
 118         ot.opt_paths = opt_paths.value
 119         for p in model.mprojects do
 120                 for g in p.mgroups do
 121                         ot.add(g.parent, g)
 122                         for mp in g.module_paths do
 123                                 ot.add(g, mp)
 124                         end
 125                 end
 126         end
 127         ot.sort_with(new CachedAlphaComparator)
 128         ot.write_to(stdout)
 129 end
 130
 131 if opt_source.value then
 132         var list = new Array[String]
 133         for p in model.mprojects do
 134                 for g in p.mgroups do
 135                         for mp in g.module_paths do
 136                                 if opt_paths.value then
 137                                         list.add(mp.filepath)
 138                                 else
 139                                         list.add("{g.full_name}/{mp.name} ({mp.filepath})")
 140                                 end
 141                         end
 142                 end
 143         end
 144         alpha_comparator.sort(list)
 145         for l in list do print l
 146 end
 147
 148 if opt_project.value then
 149         var list = new Array[String]
 150         for p in model.mprojects do
 151                 var path = p.root.filepath.as(not null)
 152                 if opt_paths.value then
 153                         list.add(path)
 154                 else
 155                         list.add("{p.name} ({path})")
 156                 end
 157         end
 158         alpha_comparator.sort(list)
 159         for l in list do print l
 160 end