lib/glesv2/glesv2.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2014 Alexis Laferrière <alexis.laf@xymus.net>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # OpenGL graphics rendering library for embedded systems, version 2.0
  18 #
  19 # This is a low-level wrapper, it can be useful for developers already familiar
  20 # with the C API of OpenGL. Most developers will prefer to use higher level
  21 # wrappers such as `mnit` and `gammit`.
  22 #
  23 # Defines the annotations `glsl_vertex_shader` and `glsl_fragment_shader`
  24 # applicable on string literals to check shader code using `glslangValidator`.
  25 # The tool must be in PATH. It can be downloaded from
  26 # https://www.khronos.org/opengles/sdk/tools/Reference-Compiler/
  27 #
  28 # Most services of this module are a direct wrapper of the underlying
  29 # C library. If a method or class is not documented in Nit, refer to
  30 # the official documentation by the Khronos Group at:
  31 # http://www.khronos.org/opengles/sdk/docs/man/
  32 module glesv2 is
  33         pkgconfig
  34         new_annotation glsl_vertex_shader
  35         new_annotation glsl_fragment_shader
  36         ldflags("-lGLESv2")@android
  37 end
  38
  39 import android::aware
  40 intrude import c
  41
  42 in "C Header" `{
  43         #include <GLES2/gl2.h>
  44 `}
  45
  46 # OpenGL ES program to which we attach shaders
  47 extern class GLProgram `{GLuint`}
  48         # Create a new program
  49         #
  50         # The newly created instance should be checked using `is_ok`.
  51         new `{ return glCreateProgram(); `}
  52
  53         # Is this a valid program?
  54         fun is_ok: Bool `{ return glIsProgram(self); `}
  55
  56         # Attach a `shader` to this program
  57         fun attach_shader(shader: GLShader) `{ glAttachShader(self, shader); `}
  58
  59         # Set the location for the attribute by `name`
  60         fun bind_attrib_location(index: Int, name: String) import String.to_cstring `{
  61                 GLchar *c_name = String_to_cstring(name);
  62                 glBindAttribLocation(self, index, c_name);
  63         `}
  64
  65         # Get the location of the attribute by `name`
  66         #
  67         # Returns `-1` if there is no active attribute named `name`.
  68         fun attrib_location(name: String): Int import String.to_cstring `{
  69                 GLchar *c_name = String_to_cstring(name);
  70                 return glGetAttribLocation(self, c_name);
  71         `}
  72
  73         # Get the location of the uniform by `name`
  74         #
  75         # Returns `-1` if there is no active uniform named `name`.
  76         fun uniform_location(name: String): Int import String.to_cstring `{
  77                 GLchar *c_name = String_to_cstring(name);
  78                 return glGetUniformLocation(self, c_name);
  79         `}
  80
  81         # Query information on this program
  82         fun query(pname: Int): Int `{
  83                 int val;
  84                 glGetProgramiv(self, pname, &val);
  85                 return val;
  86         `}
  87
  88         # Try to link this program
  89         #
  90         # Check result using `in_linked` and `info_log`.
  91         fun link `{ glLinkProgram(self); `}
  92
  93         # Is this program linked?
  94         fun is_linked: Bool do return query(0x8B82) != 0
  95
  96         # Use this program for the following operations
  97         fun use `{ glUseProgram(self); `}
  98
  99         # Delete this program
 100         fun delete `{ glDeleteProgram(self); `}
 101
 102         # Has this program been deleted?
 103         fun is_deleted: Bool do return query(0x8B80) != 0
 104
 105         # Validate whether this program can be executed in the current OpenGL state
 106         #
 107         # Check results using `is_validated` and `info_log`.
 108         fun validate `{ glValidateProgram(self); `}
 109
 110         # Boolean result of `validate`, must be called after `validate`
 111         fun is_validated: Bool do return query(0x8B83) != 0
 112
 113         # Retrieve the information log of this program
 114         #
 115         # Useful with `link` and `validate`
 116         fun info_log: String import NativeString.to_s `{
 117                 int size;
 118                 glGetProgramiv(self, GL_INFO_LOG_LENGTH, &size);
 119                 GLchar *msg = malloc(size);
 120                 glGetProgramInfoLog(self, size, NULL, msg);
 121                 return NativeString_to_s(msg);
 122         `}
 123
 124         # Number of active uniform in this program
 125         #
 126         # This should be the number of uniforms declared in all shader, except
 127         # unused uniforms which may have been optimized out.
 128         fun n_active_uniforms: Int do return query(0x8B86)
 129
 130         # Length of the longest uniform name in this program, including `\n`
 131         fun active_uniform_max_length: Int do return query(0x8B87)
 132
 133         # Number of active attributes in this program
 134         #
 135         # This should be the number of uniforms declared in all shader, except
 136         # unused uniforms which may have been optimized out.
 137         fun n_active_attributes: Int do return query(0x8B89)
 138
 139         # Length of the longest uniform name in this program, including `\n`
 140         fun active_attribute_max_length: Int do return query(0x8B8A)
 141
 142         # Number of shaders attached to this program
 143         fun n_attached_shaders: Int do return query(0x8B85)
 144
 145         # Name of the active attribute at `index`
 146         fun active_attrib_name(index: Int): String
 147         do
 148                 var max_size = active_attribute_max_length
 149                 return active_attrib_name_native(index, max_size).to_s
 150         end
 151         private fun active_attrib_name_native(index, max_size: Int): NativeString `{
 152                 // We get more values than we need, for compatibility. At least the
 153                 // NVidia driver tries to fill them even if NULL.
 154
 155                 char *name = malloc(max_size);
 156                 int size;
 157                 GLenum type;
 158                 glGetActiveAttrib(self, index, max_size, NULL, &size, &type, name);
 159                 return name;
 160         `}
 161
 162         # Size of the active attribute at `index`
 163         fun active_attrib_size(index: Int): Int `{
 164                 int size;
 165                 GLenum type;
 166                 glGetActiveAttrib(self, index, 0, NULL, &size, &type, NULL);
 167                 return size;
 168         `}
 169
 170         # Type of the active attribute at `index`
 171         #
 172         # May only be float related data types (single float, vectors and matrix).
 173         fun active_attrib_type(index: Int): GLFloatDataType `{
 174                 int size;
 175                 GLenum type;
 176                 glGetActiveAttrib(self, index, 0, NULL, &size, &type, NULL);
 177                 return type;
 178         `}
 179
 180         # Name of the active uniform at `index`
 181         fun active_uniform_name(index: Int): String
 182         do
 183                 var max_size = active_attribute_max_length
 184                 return active_uniform_name_native(index, max_size).to_s
 185         end
 186         private fun active_uniform_name_native(index, max_size: Int): NativeString `{
 187                 char *name = malloc(max_size);
 188                 int size;
 189                 GLenum type;
 190                 glGetActiveUniform(self, index, max_size, NULL, &size, &type, name);
 191                 return name;
 192         `}
 193
 194         # Size of the active uniform at `index`
 195         fun active_uniform_size(index: Int): Int `{
 196                 int size;
 197                 GLenum type;
 198                 glGetActiveUniform(self, index, 0, NULL, &size, &type, NULL);
 199                 return size;
 200         `}
 201
 202         # Type of the active uniform at `index`
 203         #
 204         # May be any data type supported by OpenGL ES 2.0 shaders.
 205         fun active_uniform_type(index: Int): GLDataType `{
 206                 int size;
 207                 GLenum type = 0;
 208                 glGetActiveUniform(self, index, 0, NULL, &size, &type, NULL);
 209                 return type;
 210         `}
 211 end
 212
 213 # Abstract OpenGL ES shader object, implemented by `GLFragmentShader` and `GLVertexShader`
 214 extern class GLShader `{GLuint`}
 215         # Set the source of the shader
 216         fun source=(code: NativeString) `{
 217                 glShaderSource(self, 1, (GLchar const **)&code, NULL);
 218         `}
 219
 220         # Source of the shader, if available
 221         #
 222         # Returns `null` if the source is not available, usually when the shader
 223         # was created from a binary file.
 224         fun source: nullable String
 225         do
 226                 var size = query(0x8B88)
 227                 if size == 0 then return null
 228                 return source_native(size).to_s
 229         end
 230
 231         private fun source_native(size: Int): NativeString `{
 232                 GLchar *code = malloc(size);
 233                 glGetShaderSource(self, size, NULL, code);
 234                 return code;
 235         `}
 236
 237         # Query information on this shader
 238         protected fun query(pname: Int): Int `{
 239                 int val;
 240                 glGetShaderiv(self, pname, &val);
 241                 return val;
 242         `}
 243
 244         # Try to compile `source` into a binary GPU program
 245         #
 246         # Check the result using `is_compiled` and `info_log`
 247         fun compile `{ glCompileShader(self); `}
 248
 249         # Has this shader been compiled?
 250         fun is_compiled: Bool do return query(0x8B81) != 0
 251
 252         # Delete this shader
 253         fun delete `{ glDeleteShader(self); `}
 254
 255         # Has this shader been deleted?
 256         fun is_deleted: Bool do return query(0x8B80) != 0
 257
 258         # Is this a valid shader?
 259         fun is_ok: Bool `{ return glIsShader(self); `}
 260
 261         # Retrieve the information log of this shader
 262         #
 263         # Useful with `link` and `validate`
 264         fun info_log: String import NativeString.to_s `{
 265                 int size;
 266                 glGetShaderiv(self, GL_INFO_LOG_LENGTH, &size);
 267                 GLchar *msg = malloc(size);
 268                 glGetShaderInfoLog(self, size, NULL, msg);
 269                 return NativeString_to_s(msg);
 270         `}
 271 end
 272
 273 # An OpenGL ES 2.0 fragment shader
 274 extern class GLFragmentShader
 275         super GLShader
 276
 277         # Create a new fragment shader
 278         #
 279         # The newly created instance should be checked using `is_ok`.
 280         new `{ return glCreateShader(GL_FRAGMENT_SHADER); `}
 281 end
 282
 283 # An OpenGL ES 2.0 vertex shader
 284 extern class GLVertexShader
 285         super GLShader
 286
 287         # Create a new fragment shader
 288         #
 289         # The newly created instance should be checked using `is_ok`.
 290         new `{ return glCreateShader(GL_VERTEX_SHADER); `}
 291 end
 292
 293 # An array of `Float` associated to a program variable
 294 class VertexArray
 295         var index: Int
 296
 297         # Number of data per vertex
 298         var count: Int
 299
 300         protected var glfloat_array: NativeGLfloatArray
 301
 302         init(index, count: Int, array: Array[Float])
 303         do
 304                 self.index = index
 305                 self.count = count
 306                 self.glfloat_array = new NativeGLfloatArray(array.length)
 307                 for k in [0..array.length[ do
 308                         glfloat_array[k] = array[k]
 309                 end
 310         end
 311
 312         fun attrib_pointer do attrib_pointer_intern(index, count, glfloat_array)
 313         private fun attrib_pointer_intern(index, count: Int, array: NativeGLfloatArray) `{
 314                 glVertexAttribPointer(index, count, GL_FLOAT, GL_FALSE, 0, array);
 315         `}
 316
 317         fun enable do enable_intern(index)
 318         private fun enable_intern(index: Int) `{ glEnableVertexAttribArray(index); `}
 319
 320         fun draw_arrays_triangles do draw_arrays_triangles_intern(index, count)
 321         private fun draw_arrays_triangles_intern(index, count: Int) `{
 322                 glDrawArrays(GL_TRIANGLES, index, count);
 323         `}
 324 end
 325
 326 # Low level array of `Float`
 327 class GLfloatArray
 328         super CArray[Float]
 329         redef type NATIVE: NativeGLfloatArray
 330
 331         init do native_array = new NativeGLfloatArray(length)
 332
 333         # Create with the content of `array`
 334         new from(array: Array[Float])
 335         do
 336                 var arr = new GLfloatArray(array.length)
 337                 arr.fill_from array
 338                 return arr
 339         end
 340
 341         # Fill with the content of `array`
 342         fun fill_from(array: Array[Float])
 343         do
 344                 assert length >= array.length
 345                 for k in [0..array.length[ do
 346                         self[k] = array[k]
 347                 end
 348         end
 349 end
 350
 351 # An array of `GLfloat` in C (`GLfloat*`)
 352 extern class NativeGLfloatArray `{ GLfloat* `}
 353         super NativeCArray
 354         redef type E: Float
 355
 356         new(size: Int) `{ return calloc(size, sizeof(GLfloat)); `}
 357
 358         redef fun [](index) `{ return self[index]; `}
 359         redef fun []=(index, val) `{ self[index] = val; `}
 360
 361         redef fun +(offset) `{ return self + offset; `}
 362 end
 363
 364 # General type for OpenGL enumerations
 365 extern class GLEnum `{ GLenum `}
 366
 367         redef fun hash `{ return self; `}
 368
 369         redef fun ==(o) do return o != null and is_same_type(o) and o.hash == self.hash
 370 end
 371
 372 # An OpenGL ES 2.0 error code
 373 extern class GLError
 374         super GLEnum
 375
 376         # Is there no error?
 377         fun is_ok: Bool do return is_no_error
 378
 379         # Is this not an error?
 380         fun is_no_error: Bool `{ return self == GL_NO_ERROR; `}
 381
 382         fun is_invalid_enum: Bool `{ return self == GL_INVALID_ENUM; `}
 383         fun is_invalid_value: Bool `{ return self == GL_INVALID_VALUE; `}
 384         fun is_invalid_operation: Bool `{ return self == GL_INVALID_OPERATION; `}
 385         fun is_invalid_framebuffer_operation: Bool `{ return self == GL_INVALID_FRAMEBUFFER_OPERATION; `}
 386         fun is_out_of_memory: Bool `{ return self == GL_OUT_OF_MEMORY; `}
 387
 388         redef fun to_s
 389         do
 390                 if is_no_error then return "No error"
 391                 if is_invalid_enum then return "Invalid enum"
 392                 if is_invalid_value then return "Invalid value"
 393                 if is_invalid_operation then return "Invalid operation"
 394                 if is_invalid_framebuffer_operation then return "invalid framebuffer operation"
 395                 if is_out_of_memory then return "Out of memory"
 396                 return "Truely unknown error"
 397         end
 398 end
 399
 400 fun assert_no_gl_error
 401 do
 402         var error = gl.error
 403         if not error.is_ok then
 404                 print "GL error: {error}"
 405                 abort
 406         end
 407 end
 408
 409 # Does `name` corresponds to a texture?
 410 fun glIsTexture(name: Int): Bool `{ return glIsTexture(name); `}
 411
 412 # Bind the named `texture` to a `target`
 413 fun glBindTexture(target: GLTextureTarget, texture: Int) `{ glBindTexture(target, texture); `}
 414
 415 # Set pixel storage modes
 416 fun glPixelStorei(parameter: GLPack, val: Int) `{ glPixelStorei(parameter, val); `}
 417
 418 # Symbolic name of the parameter to be set with `glPixelStorei`
 419 extern class GLPack
 420         super GLEnum
 421 end
 422
 423 # Parameter to specify the alignment requirements for the start of each pixel row in memory
 424 fun gl_PACK_ALIGNEMENT: GLPack `{ return GL_PACK_ALIGNMENT; `}
 425
 426 # Parameter to specify the alignment requirements for the start of each pixel row in memory
 427 fun gl_UNPACK_ALIGNEMENT: GLPack `{ return GL_UNPACK_ALIGNMENT; `}
 428
 429 # TODO GL_PACK_ROW_LENGTH, GL_PACK_IMAGE_HEIGHT, GL_PACK_SKIP_PIXELS, GL_PACK_SKIP_ROWS, GL_PACK_SKIP_IMAGES
 430 # GL_UNPACK_ROW_LENGTH, GL_UNPACK_IMAGE_HEIGHT, GL_UNPACK_SKIP_PIXELS, GL_UNPACK_SKIP_ROWS, GL_UNPACK_SKIP_IMAGES
 431
 432 # Specify a two-dimensional texture image
 433 fun glTexImage2D(target: GLTextureTarget, level, internalformat, width, height, border: Int,
 434                  format: GLPixelFormat, typ: GLPixelType, data: NativeCByteArray) `{
 435         glTexImage2D(target, level, internalformat, width, height, border, format, typ, data);
 436 `}
 437
 438 # Texture minifying and magnifying function
 439 extern class GLTextureFilter
 440         super GLEnum
 441 end
 442
 443 fun gl_NEAREST: GLTextureFilter `{ return GL_NEAREST; `}
 444 fun gl_LINEAR: GLTextureFilter `{ return GL_LINEAR; `}
 445 fun gl_NEAREST_MIPMAP_NEAREST: GLTextureFilter `{ return GL_NEAREST_MIPMAP_NEAREST; `}
 446 fun gl_LINEAR_MIPMAP_NEAREST: GLTextureFilter `{ return GL_LINEAR_MIPMAP_NEAREST; `}
 447 fun gl_NEAREST_MIPMAP_NINEAR: GLTextureFilter `{ return GL_NEAREST_MIPMAP_LINEAR; `}
 448 fun gl_LINEAR_MIPMAP_LINEAR: GLTextureFilter `{ return GL_LINEAR_MIPMAP_LINEAR; `}
 449
 450 # Wrap parameter of a texture
 451 #
 452 # Used by: `tex_parameter_wrap_*`
 453 extern class GLTextureWrap
 454         super GLEnum
 455
 456         new clamp_to_edge `{ return GL_CLAMP_TO_EDGE; `}
 457         new mirrored_repeat `{ return GL_MIRRORED_REPEAT; `}
 458         new repeat `{ return GL_REPEAT; `}
 459 end
 460
 461 # Target texture
 462 extern class GLTextureTarget
 463         super GLEnum
 464 end
 465
 466 # Two-dimensional texture
 467 fun gl_TEXTURE_2D: GLTextureTarget `{ return GL_TEXTURE_2D; `}
 468
 469 # Cube map texture
 470 fun gl_TEXTURE_CUBE_MAP: GLTextureTarget `{ return GL_TEXTURE_CUBE_MAP; `}
 471
 472 # TODO GL_TEXTURE_CUBE_MAP_POSITIVE_X, GL_TEXTURE_CUBE_MAP_NEGATIVE_X, GL_TEXTURE_CUBE_MAP_POSITIVE_Y,
 473 # GL_TEXTURE_CUBE_MAP_NEGATIVE_Y, GL_TEXTURE_CUBE_MAP_POSITIVE_Z, GL_TEXTURE_CUBE_MAP_NEGATIVE_Z
 474
 475 # A server-side capability
 476 class GLCap
 477
 478         # TODO private init
 479
 480         # Internal OpenGL integer for this capability
 481         private var val: Int
 482
 483         # Enable this server-side capability
 484         fun enable do enable_native(val)
 485         private fun enable_native(cap: Int) `{ glEnable(cap); `}
 486
 487         # Disable this server-side capability
 488         fun disable do disable_native(val)
 489         private fun disable_native(cap: Int) `{ glDisable(cap); `}
 490
 491         redef fun hash do return val
 492         redef fun ==(o) do return o != null and is_same_type(o) and o.hash == self.hash
 493 end
 494
 495 # Attach a renderbuffer object to a framebuffer object
 496 fun glFramebufferRenderbuffer(target: GLFramebufferTarget, attachment: GLAttachment,
 497                               renderbuffertarget: GLRenderbufferTarget, renderbuffer: Int) `{
 498         glFramebufferRenderbuffer(target, attachment, renderbuffertarget, renderbuffer);
 499 `}
 500
 501 # Establish data storage, `format` and dimensions of the `target` renderbuffer object's image
 502 fun glRenderbufferStorage(target: GLRenderbufferTarget, format: GLRenderbufferFormat, width, height: Int) `{
 503         glRenderbufferStorage(GL_RENDERBUFFER, format, width, height);
 504 `}
 505
 506 # Format for a renderbuffer
 507 extern class GLRenderbufferFormat
 508         super GLEnum
 509 end
 510
 511 # 4 red, 4 green, 4 blue, 4 alpha bits format
 512 fun gl_RGBA4: GLRenderbufferFormat `{ return GL_RGBA4; `}
 513
 514 # 5 red, 6 green, 5 blue bits format
 515 fun gl_RGB565: GLRenderbufferFormat `{ return GL_RGB565; `}
 516
 517 # 5 red, 5 green, 5 blue, 1 alpha bits format
 518 fun gl_RGB_A1: GLRenderbufferFormat `{ return GL_RGB5_A1; `}
 519
 520 # 16 depth bits format
 521 fun gl_DEPTH_COMPNENT16: GLRenderbufferFormat `{ return GL_DEPTH_COMPONENT16; `}
 522
 523 # 8 stencil bits format
 524 fun gl_STENCIL_INDEX8: GLRenderbufferFormat `{ return GL_STENCIL_INDEX8; `}
 525
 526 # Renderbuffer attachment point to a framebuffer
 527 extern class GLAttachment
 528         super GLEnum
 529 end
 530
 531 # First color attachment point
 532 fun gl_COLOR_ATTACHMENT0: GLAttachment `{ return GL_COLOR_ATTACHMENT0; `}
 533
 534 # Depth attachment point
 535 fun gl_DEPTH_ATTACHMENT: GLAttachment `{ return GL_DEPTH_ATTACHMENT; `}
 536
 537 # Stencil attachment
 538 fun gl_STENCIL_ATTACHMENT: GLAttachment `{ return GL_STENCIL_ATTACHMENT; `}
 539
 540 redef class Sys
 541         private var gles = new GLES is lazy
 542 end
 543
 544 # Entry points to OpenGL ES 2.0 services
 545 fun gl: GLES do return sys.gles
 546
 547 # OpenGL ES 2.0 services
 548 class GLES
 549
 550         # Clear the color buffer to `red`, `green`, `blue` and `alpha`
 551         fun clear_color(red, green, blue, alpha: Float) `{
 552                 glClearColor(red, green, blue, alpha);
 553         `}
 554
 555         # Set the viewport
 556         fun viewport(x, y, width, height: Int) `{ glViewport(x, y, width, height); `}
 557
 558         # Specify mapping of depth values from normalized device coordinates to window coordinates
 559         #
 560         # Default at `gl_depth_range(0.0, 1.0)`
 561         fun depth_range(near, far: Float) `{ glDepthRangef(near, far); `}
 562
 563         # Define front- and back-facing polygons
 564         #
 565         # Front-facing polygons are clockwise if `value`, counter-clockwise otherwise.
 566         fun front_face=(value: Bool) `{ glFrontFace(value? GL_CW: GL_CCW); `}
 567
 568         # Specify whether front- or back-facing polygons can be culled, default is `back` only
 569         #
 570         # One or both of `front` or `back` must be `true`. If you want to deactivate culling
 571         # use `(new GLCap.cull_face).disable`.
 572         #
 573         # Require: `front or back`
 574         fun cull_face(front, back: Bool)
 575         do
 576                 assert not (front or back)
 577                 cull_face_native(front, back)
 578         end
 579
 580         private fun cull_face_native(front, back: Bool) `{
 581                 glCullFace(front? back? GL_FRONT_AND_BACK: GL_BACK: GL_FRONT);
 582         `}
 583
 584         # Clear the `buffer`
 585         fun clear(buffer: GLBuffer) `{ glClear(buffer); `}
 586
 587         # Last error from OpenGL ES 2.0
 588         fun error: GLError `{ return glGetError(); `}
 589
 590         # Query the boolean value at `key`
 591         private fun get_bool(key: Int): Bool `{
 592                 GLboolean val;
 593                 glGetBooleanv(key, &val);
 594                 return val == GL_TRUE;
 595         `}
 596
 597         # Query the floating point value at `key`
 598         private fun get_float(key: Int): Float `{
 599                 GLfloat val;
 600                 glGetFloatv(key, &val);
 601                 return val;
 602         `}
 603
 604         # Query the integer value at `key`
 605         private fun get_int(key: Int): Int `{
 606                 GLint val;
 607                 glGetIntegerv(key, &val);
 608                 return val;
 609         `}
 610
 611         # Does this driver support shader compilation?
 612         #
 613         # Should always return `true` in OpenGL ES 2.0 and 3.0.
 614         fun shader_compiler: Bool do return get_bool(0x8DFA)
 615
 616         # Enable or disable writing into the depth buffer
 617         fun depth_mask(value: Bool) `{ glDepthMask(value); `}
 618
 619         # Set the scale and units used to calculate depth values
 620         fun polygon_offset(factor, units: Float) `{ glPolygonOffset(factor, units); `}
 621
 622         # Specify the width of rasterized lines
 623         fun line_width(width: Float) `{ glLineWidth(width); `}
 624
 625         # Set the pixel arithmetic for the blending operations
 626         #
 627         # Defaultvalues before assignation:
 628         # * `src_factor`: `GLBlendFactor::one`
 629         # * `dst_factor`: `GLBlendFactor::zero`
 630         fun blend_func(src_factor, dst_factor: GLBlendFactor) `{
 631                 glBlendFunc(src_factor, dst_factor);
 632         `}
 633
 634         # Specify the value used for depth buffer comparisons
 635         #
 636         # Default value is `GLDepthFunc::less`
 637         #
 638         # Foreign: glDepthFunc
 639         fun depth_func(func: GLDepthFunc) `{ glDepthFunc(func); `}
 640
 641         # Copy a block of pixels from the framebuffer of `fomat` and `typ` at `data`
 642         #
 643         # Foreign: glReadPixel
 644         fun read_pixels(x, y, width, height: Int, format: GLPixelFormat, typ: GLPixelType, data: Pointer) `{
 645                 glReadPixels(x, y, width, height, format, typ, data);
 646         `}
 647
 648         # Set the texture minifying function
 649         #
 650         # Foreign: glTexParameter with GL_TEXTURE_MIN_FILTER
 651         fun tex_parameter_min_filter(target: GLTextureTarget, value: GLTextureFilter) `{
 652                 glTexParameteri(target, GL_TEXTURE_MIN_FILTER, value);
 653         `}
 654
 655         # Set the texture magnification function
 656         #
 657         # Foreign: glTexParameter with GL_TEXTURE_MAG_FILTER
 658         fun tex_parameter_mag_filter(target: GLTextureTarget, value: GLTextureFilter) `{
 659                 glTexParameteri(target, GL_TEXTURE_MAG_FILTER, value);
 660         `}
 661
 662         # Set the texture wrap parameter for coordinates _s_
 663         #
 664         # Foreign: glTexParameter with GL_TEXTURE_WRAP_S
 665         fun tex_parameter_wrap_s(target: GLTextureTarget, value: GLTextureWrap) `{
 666                 glTexParameteri(target, GL_TEXTURE_WRAP_S, value);
 667         `}
 668
 669         # Set the texture wrap parameter for coordinates _t_
 670         #
 671         # Foreign: glTexParameter with GL_TEXTURE_WRAP_T
 672         fun tex_parameter_wrap_t(target: GLTextureTarget, value: GLTextureWrap) `{
 673                 glTexParameteri(target, GL_TEXTURE_WRAP_T, value);
 674         `}
 675
 676         # Render primitives from array data
 677         #
 678         # Foreign: glDrawArrays
 679         fun draw_arrays(mode: GLDrawMode, from, count: Int) `{ glDrawArrays(mode, from, count); `}
 680
 681         # OpenGL server-side capabilities
 682         var capabilities = new GLCapabilities is lazy
 683 end
 684
 685 # Bind `framebuffer` to a framebuffer target
 686 #
 687 # In OpenGL ES 2.0, `target` must be `gl_FRAMEBUFFER`.
 688 fun glBindFramebuffer(target: GLFramebufferTarget, framebuffer: Int) `{
 689         glBindFramebuffer(target, framebuffer);
 690 `}
 691
 692 # Target of `glBindFramebuffer`
 693 extern class GLFramebufferTarget
 694         super GLEnum
 695 end
 696
 697 # Target both reading and writing on the framebuffer with `glBindFramebuffer`
 698 fun gl_FRAMEBUFFER: GLFramebufferTarget `{ return GL_FRAMEBUFFER; `}
 699
 700 # Bind `renderbuffer` to a renderbuffer target
 701 #
 702 # In OpenGL ES 2.0, `target` must be `gl_RENDERBUFFER`.
 703 fun glBindRenderbuffer(target: GLRenderbufferTarget, renderbuffer: Int) `{
 704         glBindRenderbuffer(target, renderbuffer);
 705 `}
 706
 707 # Target of `glBindRenderbuffer`
 708 extern class GLRenderbufferTarget
 709         super GLEnum
 710 end
 711
 712 # Target a renderbuffer with `glBindRenderbuffer`
 713 fun gl_RENDERBUFFER: GLRenderbufferTarget `{ return GL_RENDERBUFFER; `}
 714
 715 # Specify implementation specific hints
 716 fun glHint(target: GLHintTarget, mode: GLHintMode) `{
 717         glHint(target, mode);
 718 `}
 719
 720 # Generate and fill set of mipmaps for the texture object `target`
 721 fun glGenerateMipmap(target: GLTextureTarget) `{ glGenerateMipmap(target); `}
 722
 723 # Bind the named `buffer` object
 724 fun glBindBuffer(target: GLArrayBuffer, buffer: Int) `{ glBindBuffer(target, buffer); `}
 725
 726 # Target to which bind the buffer with `glBindBuffer`
 727 extern class GLArrayBuffer
 728         super GLEnum
 729 end
 730
 731 # Array buffer target
 732 fun gl_ARRAY_BUFFER: GLArrayBuffer `{ return GL_ARRAY_BUFFER; `}
 733
 734 # Element array buffer
 735 fun gl_ELEMENT_ARRAY_BUFFER: GLArrayBuffer `{ return GL_ELEMENT_ARRAY_BUFFER; `}
 736
 737 # Completeness status of a framebuffer object
 738 fun glCheckFramebufferStatus(target: GLFramebufferTarget): GLFramebufferStatus `{
 739         return glCheckFramebufferStatus(target);
 740 `}
 741
 742 # Return value of `glCheckFramebufferStatus`
 743 extern class GLFramebufferStatus
 744         super GLEnum
 745
 746         redef fun to_s
 747         do
 748                 if self == gl_FRAMEBUFFER_COMPLETE then return "complete"
 749                 if self == gl_FRAMEBUFFER_INCOMPLETE_ATTACHMENT then return "incomplete attachment"
 750                 if self == gl_FRAMEBUFFER_INCOMPLETE_DIMENSIONS then return "incomplete dimension"
 751                 if self == gl_FRAMEBUFFER_INCOMPLETE_MISSING_ATTACHMENT then return "incomplete missing attachment"
 752                 if self == gl_FRAMEBUFFER_UNSUPPORTED then return "unsupported"
 753                 return "unknown"
 754         end
 755 end
 756
 757 # The framebuffer is complete
 758 fun gl_FRAMEBUFFER_COMPLETE: GLFramebufferStatus `{
 759         return GL_FRAMEBUFFER_COMPLETE;
 760 `}
 761
 762 # Not all framebuffer attachment points are framebuffer attachment complete
 763 fun gl_FRAMEBUFFER_INCOMPLETE_ATTACHMENT: GLFramebufferStatus `{
 764         return GL_FRAMEBUFFER_INCOMPLETE_ATTACHMENT;
 765 `}
 766
 767 # Not all attached images have the same width and height
 768 fun gl_FRAMEBUFFER_INCOMPLETE_DIMENSIONS: GLFramebufferStatus `{
 769         return GL_FRAMEBUFFER_INCOMPLETE_DIMENSIONS;
 770 `}
 771
 772 # No images are attached to the framebuffer
 773 fun gl_FRAMEBUFFER_INCOMPLETE_MISSING_ATTACHMENT: GLFramebufferStatus `{
 774         return GL_FRAMEBUFFER_INCOMPLETE_MISSING_ATTACHMENT;
 775 `}
 776
 777 # The combination of internal formats of the attached images violates an implementation-dependent set of restrictions
 778 fun gl_FRAMEBUFFER_UNSUPPORTED: GLFramebufferStatus `{
 779         return GL_FRAMEBUFFER_UNSUPPORTED;
 780 `}
 781
 782 # Hint target for `glHint`
 783 extern class GLHintTarget
 784         super GLEnum
 785 end
 786
 787 # Indicates the quality of filtering when generating mipmap images
 788 fun gl_GENERATE_MIPMAP_HINT: GLHintTarget `{ return GL_GENERATE_MIPMAP_HINT; `}
 789
 790 # Hint mode for `glHint`
 791 extern class GLHintMode
 792         super GLEnum
 793 end
 794
 795 # The most efficient option should be chosen
 796 fun gl_FASTEST: GLHintMode `{ return GL_FASTEST; `}
 797
 798 # The most correct, or highest quality, option should be chosen
 799 fun gl_NICEST: GLHintMode `{ return GL_NICEST; `}
 800
 801 # No preference
 802 fun gl_DONT_CARE: GLHintMode `{ return GL_DONT_CARE; `}
 803
 804 # Attach a level of a texture object as a logical buffer to the currently bound framebuffer object
 805 fun glFramebufferTexture2D(target: GLFramebufferTarget, attachment: GLAttachment,
 806                            texture_target: GLTextureTarget,  texture, level: Int) `{
 807         glFramebufferTexture2D(target, attachment, texture_target, texture, level);
 808 `}
 809
 810 # Entry point to OpenGL server-side capabilities
 811 class GLCapabilities
 812
 813         # GL capability: blend the computed fragment color values
 814         #
 815         # Foreign: GL_BLEND
 816         var blend: GLCap is lazy do return new GLCap(0x0BE2)
 817
 818         # GL capability: cull polygons based of their winding in window coordinates
 819         #
 820         # Foreign: GL_CULL_FACE
 821         var cull_face: GLCap is lazy do return new GLCap(0x0B44)
 822
 823         # GL capability: do depth comparisons and update the depth buffer
 824         #
 825         # Foreign: GL_DEPTH_TEST
 826         var depth_test: GLCap is lazy do return new GLCap(0x0B71)
 827
 828         # GL capability: dither color components or indices before they are written to the color buffer
 829         #
 830         # Foreign: GL_DITHER
 831         var dither: GLCap is lazy do return new GLCap(0x0BE2)
 832
 833         # GL capability: add an offset to depth values of a polygon fragment before depth test
 834         #
 835         # Foreign: GL_POLYGON_OFFSET_FILL
 836         var polygon_offset_fill: GLCap is lazy do return new GLCap(0x8037)
 837
 838         # GL capability: compute a temporary coverage value where each bit is determined by the alpha value at the corresponding location
 839         #
 840         # Foreign: GL_SAMPLE_ALPHA_TO_COVERAGE
 841         var sample_alpha_to_coverage: GLCap is lazy do return new GLCap(0x809E)
 842
 843         # GL capability: AND the fragment coverage with the temporary coverage value
 844         #
 845         # Foreign: GL_SAMPLE_COVERAGE
 846         var sample_coverage: GLCap is lazy do return new GLCap(0x80A0)
 847
 848         # GL capability: discard fragments that are outside the scissor rectangle
 849         #
 850         # Foreign: GL_SCISSOR_TEST
 851         var scissor_test: GLCap is lazy do return new GLCap(0x0C11)
 852
 853         # GL capability: do stencil testing and update the stencil buffer
 854         #
 855         # Foreign: GL_STENCIL_TEST
 856         var stencil_test: GLCap is lazy do return new GLCap(0x0B90)
 857 end
 858
 859 # Float related data types of OpenGL ES 2.0 shaders
 860 #
 861 # Only data types supported by shader attributes, as seen with
 862 # `GLProgram::active_attrib_type`.
 863 extern class GLFloatDataType
 864         super GLEnum
 865
 866         fun is_float: Bool `{ return self == GL_FLOAT; `}
 867         fun is_float_vec2: Bool `{ return self == GL_FLOAT_VEC2; `}
 868         fun is_float_vec3: Bool `{ return self == GL_FLOAT_VEC3; `}
 869         fun is_float_vec4: Bool `{ return self == GL_FLOAT_VEC4; `}
 870         fun is_float_mat2: Bool `{ return self == GL_FLOAT_MAT2; `}
 871         fun is_float_mat3: Bool `{ return self == GL_FLOAT_MAT3; `}
 872         fun is_float_mat4: Bool `{ return self == GL_FLOAT_MAT4; `}
 873
 874         # Instances of `GLFloatDataType` can be equal to instances of `GLDataType`
 875         redef fun ==(o)
 876         do
 877                 return o != null and o isa GLFloatDataType and o.hash == self.hash
 878         end
 879 end
 880
 881 # All data types of OpenGL ES 2.0 shaders
 882 #
 883 # These types can be used by shader uniforms, as seen with
 884 # `GLProgram::active_uniform_type`.
 885 extern class GLDataType
 886         super GLFloatDataType
 887
 888         fun is_int: Bool `{ return self == GL_INT; `}
 889         fun is_int_vec2: Bool `{ return self == GL_INT_VEC2; `}
 890         fun is_int_vec3: Bool `{ return self == GL_INT_VEC3; `}
 891         fun is_int_vec4: Bool `{ return self == GL_INT_VEC4; `}
 892         fun is_bool: Bool `{ return self == GL_BOOL; `}
 893         fun is_bool_vec2: Bool `{ return self == GL_BOOL_VEC2; `}
 894         fun is_bool_vec3: Bool `{ return self == GL_BOOL_VEC3; `}
 895         fun is_bool_vec4: Bool `{ return self == GL_BOOL_VEC4; `}
 896         fun is_sampler_2d: Bool `{ return self == GL_SAMPLER_2D; `}
 897         fun is_sampler_cube: Bool `{ return self == GL_SAMPLER_CUBE; `}
 898 end
 899
 900 # Kind of primitives to render with `GLES::draw_arrays`
 901 extern class GLDrawMode
 902         super GLEnum
 903
 904         new points `{ return GL_POINTS; `}
 905         new line_strip `{ return GL_LINE_STRIP; `}
 906         new line_loop `{ return GL_LINE_LOOP; `}
 907         new lines `{ return GL_LINES; `}
 908         new triangle_strip `{ return GL_TRIANGLE_STRIP; `}
 909         new triangle_fan `{ return GL_TRIANGLE_FAN; `}
 910         new triangles `{ return GL_TRIANGLES; `}
 911 end
 912
 913 # Pixel arithmetic for blending operations
 914 #
 915 # Used by `GLES::blend_func`
 916 extern class GLBlendFactor
 917         super GLEnum
 918
 919         new zero `{ return GL_ZERO; `}
 920         new one `{ return GL_ONE; `}
 921         new src_color `{ return GL_SRC_COLOR; `}
 922         new one_minus_src_color `{ return GL_ONE_MINUS_SRC_COLOR; `}
 923         new dst_color `{ return GL_DST_COLOR; `}
 924         new one_minus_dst_color `{ return GL_ONE_MINUS_DST_COLOR; `}
 925         new src_alpha `{ return GL_SRC_ALPHA; `}
 926         new one_minus_src_alpha `{ return GL_ONE_MINUS_SRC_ALPHA; `}
 927         new dst_alpha `{ return GL_DST_ALPHA; `}
 928         new one_minus_dst_alpha `{ return GL_ONE_MINUS_DST_ALPHA; `}
 929         new constant_color `{ return GL_CONSTANT_COLOR; `}
 930         new one_minus_constant_color `{ return GL_ONE_MINUS_CONSTANT_COLOR; `}
 931         new constant_alpha `{ return GL_CONSTANT_ALPHA; `}
 932         new one_minus_constant_alpha `{ return GL_ONE_MINUS_CONSTANT_ALPHA; `}
 933
 934         # Used for destination only
 935         new src_alpha_saturate `{ return GL_SRC_ALPHA_SATURATE; `}
 936 end
 937
 938 # Condition under which a pixel will be drawn
 939 #
 940 # Used by `GLES::depth_func`
 941 extern class GLDepthFunc
 942         super GLEnum
 943
 944          new never `{ return GL_NEVER; `}
 945          new less `{ return GL_LESS; `}
 946          new equal `{ return GL_EQUAL; `}
 947          new lequal `{ return GL_LEQUAL; `}
 948          new greater `{ return GL_GREATER; `}
 949          new not_equal `{ return GL_NOTEQUAL; `}
 950          new gequal `{ return GL_GEQUAL; `}
 951          new always `{ return GL_ALWAYS; `}
 952 end
 953
 954 # Format of pixel data
 955 #
 956 # Used by `GLES::read_pixels`
 957 extern class GLPixelFormat
 958         super GLEnum
 959
 960         new alpha `{ return GL_ALPHA; `}
 961         new rgb `{ return GL_RGB; `}
 962         new rgba `{ return GL_RGBA; `}
 963 end
 964
 965 # Data type of pixel data
 966 #
 967 # Used by `GLES::read_pixels`
 968 extern class GLPixelType
 969         super GLEnum
 970
 971         new unsigned_byte `{ return GL_UNSIGNED_BYTE; `}
 972         new unsigned_short_5_6_5 `{ return GL_UNSIGNED_SHORT_5_6_5; `}
 973         new unsigned_short_4_4_4_4 `{ return GL_UNSIGNED_SHORT_4_4_4_4; `}
 974         new unsigned_short_5_5_5_1 `{ return GL_UNSIGNED_SHORT_5_5_5_1; `}
 975 end
 976
 977 # Set of buffers as a bitwise OR mask, used by `GLES::clear`
 978 #
 979 # ~~~
 980 # var buffers = (new GLBuffer).color.depth
 981 # gl.clear buffers
 982 # ~~~
 983 extern class GLBuffer `{ GLbitfield `}
 984         # Get an empty set of buffers
 985         new `{ return 0; `}
 986
 987         # Add the color buffer to the returned buffer set
 988         fun color: GLBuffer `{ return self | GL_COLOR_BUFFER_BIT; `}
 989
 990         # Add the depth buffer to the returned buffer set
 991         fun depth: GLBuffer `{ return self | GL_DEPTH_BUFFER_BIT; `}
 992
 993         # Add the stencil buffer to the returned buffer set
 994         fun stencil: GLBuffer `{ return self | GL_STENCIL_BUFFER_BIT; `}
 995 end