src/phase.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Phases of the processing of nit programs
  16 module phase
  17
  18 import toolcontext
  19 import parser
  20 import poset
  21
  22 redef class ToolContext
  23         # The various registered phases to performs
  24         # The order in the poset is the dependence of phases
  25         #
  26         # While you can directly modify the poset (nodes and edges),
  27         # it is often simpler to use the constructor in `Phase`
  28         var phases = new POSet[Phase]
  29
  30         # --disable-phase
  31         var opt_disable_phase = new OptionArray("Disable a specific phase; use `list` to get the list (debug)", "--disable-phase")
  32
  33         # --sloppy
  34         var opt_sloppy = new OptionBool("Force lazy semantic analysis of the source-code (debug)", "--sloppy")
  35
  36         redef init
  37         do
  38                 super
  39
  40                 option_context.add_option(opt_disable_phase, opt_sloppy)
  41         end
  42
  43         redef fun process_options(args)
  44         do
  45                 super
  46
  47                 for v in opt_disable_phase.value do
  48                         if v == "list" then
  49                                 for p in phases_list do
  50                                         var deps = p.in_hierarchy.direct_greaters
  51                                         if deps.is_empty then
  52                                                 print p
  53                                         else
  54                                                 print "{p} (dep: {deps.join(", ")})"
  55                                         end
  56                                 end
  57                                 exit 0
  58                         end
  59
  60                         var found = false
  61                         for p in phases do
  62                                 if v != p.to_s then continue
  63                                 found = true
  64                                 p.disabled = true
  65                         end
  66                         if not found then fatal_error(null, "Error: no phase named `{v}`. Use `list` to list all phases.")
  67                 end
  68
  69                 if opt_sloppy.value then semantize_is_lazy = true
  70         end
  71
  72         # The list of registered phases in the application order.
  73         var phases_list: Sequence[Phase] is lazy do
  74                 var phases = self.phases.to_a
  75                 self.phases.sort(phases)
  76                 return phases
  77         end
  78
  79         # Is `phase_process_npropdef` not called automatically by `run_phases`?
  80         #
  81         # When set to true, it is the responsibility of the tools
  82         #
  83         # Is false by default.
  84         var semantize_is_lazy = false is writable
  85
  86         # Set of already analyzed modules.
  87         private var phased_modules = new HashSet[AModule]
  88
  89         # List of module to process according to `run_phases`
  90         #
  91         # This allow some new modules to be found and added while analysing the code.
  92         var todo_nmodules: Sequence[AModule]
  93
  94         # Run all registered phases on a set of modules
  95         fun run_phases(nmodules: Collection[AModule])
  96         do
  97                 var time0 = get_time
  98                 self.info("*** SEMANTIC ANALYSIS ***", 1)
  99                 #phases.show_dot
 100
 101                 var phases = phases_list
 102
 103                 for phase in phases do
 104                         self.info(" registered phases: {phase}", 2)
 105                 end
 106
 107                 var todo_nmodules = nmodules.to_a
 108                 self.todo_nmodules = todo_nmodules
 109
 110                 while not todo_nmodules.is_empty do
 111                         var nmodule = todo_nmodules.shift
 112                         if phased_modules.has(nmodule) then continue
 113                         phased_modules.add nmodule
 114
 115                         self.info("Semantic analysis module {nmodule.location.file.filename}", 2)
 116
 117                         var vannot = new AnnotationPhaseVisitor
 118                         vannot.enter_visit(nmodule)
 119
 120                         for phase in phases do
 121                                 if phase.disabled then continue
 122                                 assert phase.toolcontext == self
 123                                 var errcount = self.error_count
 124                                 phase.process_nmodule(nmodule)
 125                                 if errcount != self.error_count then
 126                                         self.check_errors
 127                                 end
 128                                 errcount = self.error_count
 129                                 for nclassdef in nmodule.n_classdefs do
 130                                         assert phase.toolcontext == self
 131                                         phase.process_nclassdef(nclassdef)
 132                                         if not semantize_is_lazy then for npropdef in nclassdef.n_propdefs do
 133                                                 assert phase.toolcontext == self
 134                                                 phase_process_npropdef(phase, npropdef)
 135                                         end
 136                                 end
 137                                 if errcount != self.error_count then
 138                                         self.check_errors
 139                                 end
 140                                 for na in vannot.annotations do
 141                                         var p = na.parent
 142                                         if p isa AAnnotations then p = p.parent
 143                                         assert p != null
 144                                         phase.process_annotated_node(p, na)
 145                                 end
 146                                 if errcount != self.error_count then
 147                                         self.check_errors
 148                                 end
 149                         end
 150                         self.check_errors
 151                 end
 152
 153                 var time1 = get_time
 154                 self.info("*** END SEMANTIC ANALYSIS: {time1-time0} ***", 2)
 155
 156                 self.check_errors
 157         end
 158
 159         # Process the given `phase` on the `npropdef`
 160         # Called by `run_phases`
 161         protected fun phase_process_npropdef(phase: Phase, npropdef: APropdef)
 162         do
 163                 phase.process_npropdef(npropdef)
 164         end
 165
 166         # Run the phase on the given npropdef.
 167         # Does nothing if `semantize_is_lazy` is false.
 168         fun run_phases_on_npropdef(npropdef: APropdef)
 169         do
 170                 if not semantize_is_lazy then return
 171                 if npropdef.is_phased then return
 172                 npropdef.is_phased = true
 173
 174                 #self.info("Semantic analysis of property {npropdef.location.file.filename}", 0)
 175
 176                 var phases = phases_list
 177                 for phase in phases do
 178                         if phase.disabled then continue
 179                         assert phase.toolcontext == self
 180                         phase_process_npropdef(phase, npropdef)
 181                         self.check_errors
 182                 end
 183         end
 184 end
 185
 186 redef class APropdef
 187         # Is the propdef already analyzed by `run_phases_on_npropdef`.
 188         # Unused unless `semantize_is_lazy` is true.
 189         private var is_phased = false
 190 end
 191
 192 # Collect all annotation
 193 private class AnnotationPhaseVisitor
 194         super Visitor
 195
 196         # The collected annotations
 197         var annotations = new Array[AAnnotation]
 198
 199         redef fun visit(n)
 200         do
 201                 n.visit_all(self)
 202                 if n isa AAnnotation then annotations.add n
 203         end
 204 end
 205
 206 # Abstraction of steps in the analysis/processing of Nit programs
 207 # Specific phases should implements one of the `process_*` method
 208 abstract class Phase
 209         # The toolcontext instance attached to the phase
 210         var toolcontext: ToolContext
 211
 212         # The dependence relation of the phase with the other phases
 213         var in_hierarchy: POSetElement[Phase] is noinit
 214
 215         # The explicit dependences, used to initialize `in_importation`
 216         var depends: nullable Collection[Phase]
 217
 218         # Initialize and register a phase to the toolcontext
 219         init
 220         do
 221                 in_hierarchy = toolcontext.phases.add_node(self)
 222                 var depends = self.depends
 223                 if depends != null then
 224                         for d in depends do
 225                                 toolcontext.phases.add_edge(self, d)
 226                         end
 227                 end
 228         end
 229
 230         # By default, the name is the lowercased prefix of the classname
 231         redef fun to_s do return class_name.strip_extension("Phase").to_snake_case
 232
 233         # Is the phase globally disabled?
 234         # A disabled phase is not called automatically called by `ToolContext::run_phases` and cie.
 235         #
 236         # Warning: disabling a phase may cause subsequent phases to work in a degraded way or to fail.
 237         var disabled = false is writable
 238
 239         # Specific actions to execute on the whole tree of a module
 240         # @toimplement
 241         fun process_nmodule(nmodule: AModule) do end
 242
 243         # Specific actions to execute on the tree of a class definition
 244         # Note that the order of the visit is the one of the file
 245         # @toimplement
 246         fun process_nclassdef(nclassdef: AClassdef) do end
 247
 248         # Specific actions to execute on the tree of a property
 249         # Note that the order of the visit is the one of the file
 250         # @toimplement
 251         fun process_npropdef(npropdef: APropdef) do end
 252
 253         # Specific actions to execute on annotated nodes
 254         # Note that the order of the visit is the one of the file
 255         # @toimplement
 256         fun process_annotated_node(node: ANode, nat: AAnnotation) do end
 257 end