src/model/mmodule.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2012 Jean Privat <jean@pryen.org>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # modules and module hierarchies in the metamodel
  18 module mmodule
  19
  20 import location
  21 import mproject
  22 private import more_collections
  23
  24 # The container class of a Nit object-oriented model.
  25 # A model knows modules, classes and properties and can retrieve them.
  26 redef class Model
  27         # All known modules
  28         var mmodules = new Array[MModule]
  29
  30         # Full module importation hierarchy including private or nested links.
  31         var mmodule_importation_hierarchy = new POSet[MModule]
  32
  33         # Collections of modules grouped by their short names
  34         private var mmodules_by_name = new MultiHashMap[String, MModule]
  35
  36         # Return all module named `name`
  37         # If such a module does not exist, null is returned (instead of an empty array)
  38         #
  39         # Visibility or modules are not considered
  40         fun get_mmodules_by_name(name: String): nullable Array[MModule]
  41         do
  42                 if mmodules_by_name.has_key(name) then
  43                         return mmodules_by_name[name]
  44                 else
  45                         return null
  46                 end
  47         end
  48 end
  49
  50 redef class MGroup
  51         # The loaded modules of this group
  52         var mmodules = new Array[MModule]
  53
  54         # The default module of a group (if any, and if loaded)
  55         #
  56         # The default module of a group is the one that has the same name.
  57         # Return `null` if the group has no default module or if the default
  58         # module is not loaded.
  59         var default_mmodule: nullable MModule = null
  60
  61         redef fun mdoc_or_fallback
  62         do
  63                 if mdoc != null then return mdoc
  64                 if default_mmodule == null then return null
  65                 return default_mmodule.mdoc_or_fallback
  66         end
  67 end
  68
  69 # A Nit module is usually associated with a Nit source file.
  70 class MModule
  71         super MConcern
  72
  73         # The model considered
  74         redef var model: Model
  75
  76         # The group of module in the project if any
  77         var mgroup: nullable MGroup
  78
  79         # The short name of the module
  80         redef var name: String
  81
  82         # The origin of the definition
  83         var location: Location
  84
  85         # Alias for `name`
  86         redef fun to_s do return self.name
  87
  88         # The view of the module in the `model.mmodule_importation_hierarchy`
  89         var in_importation: POSetElement[MModule] is noinit
  90
  91         # The canonical name of the module.
  92         #
  93         # It is usually the `name` prefixed by the project's name.
  94         # Example: `"project::name"`
  95         #
  96         # If both names are the same (of if the module is project-less), then
  97         # the short-name is used alone.
  98         redef var full_name is lazy do
  99                 var mgroup = self.mgroup
 100                 if mgroup == null or mgroup.mproject.name == self.name then
 101                         return self.name
 102                 else
 103                         return "{mgroup.mproject.name}::{self.name}"
 104                 end
 105         end
 106
 107         # Create a new empty module and register it to a model
 108         init
 109         do
 110                 model.mmodules_by_name.add_one(name, self)
 111                 model.mmodules.add(self)
 112                 if mgroup != null then
 113                         mgroup.mmodules.add(self)
 114                         if mgroup.name == name then
 115                                 assert mgroup.default_mmodule == null
 116                                 mgroup.default_mmodule = self
 117                         end
 118                         # placebo for old module nesting hierarchy
 119                         var direct_owner = mgroup.default_mmodule
 120                         if direct_owner == self then
 121                                 # The potential owner is the default_mmodule of the parent group
 122                                 if mgroup.parent != null then direct_owner = mgroup.parent.default_mmodule
 123                         end
 124                 end
 125                 self.in_importation = model.mmodule_importation_hierarchy.add_node(self)
 126         end
 127
 128         # Register the imported modules (ie "import some_module")
 129         # This function can only invoked once by mmodule.
 130         # The visibility must be set with `set_visibility_for`.
 131         fun set_imported_mmodules(imported_mmodules: Array[MModule])
 132         do
 133                 assert unique_invocation: self.in_importation.direct_greaters.is_empty
 134                 for m in imported_mmodules do
 135                         self.model.mmodule_importation_hierarchy.add_edge(self, m)
 136                 end
 137         end
 138
 139         private var intrude_mmodules = new HashSet[MModule]
 140         private var public_mmodules = new HashSet[MModule]
 141         private var private_mmodules = new HashSet[MModule]
 142
 143         # Return the visibility level of an imported module `m`
 144         fun visibility_for(m: MModule): MVisibility
 145         do
 146                 if m == self then return intrude_visibility
 147                 if self.intrude_mmodules.has(m) then return intrude_visibility
 148                 if self.public_mmodules.has(m) then return public_visibility
 149                 if self.private_mmodules.has(m) then return private_visibility
 150                 return none_visibility
 151         end
 152
 153         # Set the visibility of an imported module
 154         # REQUIRE: the visibility of the modules imported by `m` are already set for `m`
 155         fun set_visibility_for(m: MModule, v: MVisibility)
 156         do
 157                 if v == intrude_visibility then
 158                         self.intrude_mmodules.add(m)
 159                         self.intrude_mmodules.add_all(m.intrude_mmodules)
 160                         self.public_mmodules.add_all(m.public_mmodules)
 161                         self.private_mmodules.add_all(m.private_mmodules)
 162                 else if v == public_visibility then
 163                         self.public_mmodules.add(m)
 164                         self.public_mmodules.add_all(m.intrude_mmodules)
 165                         self.public_mmodules.add_all(m.public_mmodules)
 166                 else if v == private_visibility then
 167                         self.private_mmodules.add(m)
 168                         self.private_mmodules.add_all(m.intrude_mmodules)
 169                         self.private_mmodules.add_all(m.public_mmodules)
 170                 else
 171                         print "{self} visibility for {m} = {v}"
 172                         abort # invalid visibility
 173                 end
 174         end
 175
 176         # Return true if a class or a property introduced in `intro_mmodule` with a visibility of `visibility` is visible in self.
 177         fun is_visible(intro_mmodule: MModule, visibility: MVisibility): Bool
 178         do
 179                 var v = visibility_for(intro_mmodule)
 180                 if v == intrude_visibility then
 181                         return visibility >= private_visibility
 182                 else if v == public_visibility then
 183                         return visibility > private_visibility
 184                 else if v == private_visibility then
 185                         return visibility > private_visibility
 186                 else if v == none_visibility then
 187                         return false
 188                 else
 189                         abort
 190                 end
 191         end
 192
 193         # Is `self` created for internal purpose?
 194         # Fictive modules are instantiated internally but they should not be
 195         # exposed to the final user.
 196         var is_fictive: Bool = false is writable
 197
 198         redef fun parent_concern do return mgroup
 199 end