src/nitweb.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 # http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Runs a webserver based on nitcorn that render things from model.
  16 module nitweb
  17
  18 import frontend
  19 import web
  20
  21 redef class ToolContext
  22
  23         # Host name to bind on.
  24         var opt_host = new OptionString("Host to bind the server on", "--host")
  25
  26         # Port number to bind on.
  27         var opt_port = new OptionInt("Port number to use", 3000, "--port")
  28
  29         # Web rendering phase.
  30         var webphase: Phase = new NitwebPhase(self, null)
  31
  32         init do
  33                 super
  34                 option_context.add_option(opt_host, opt_port)
  35         end
  36 end
  37
  38 # Phase that builds the model and wait for http request to serve pages.
  39 private class NitwebPhase
  40         super Phase
  41         redef fun process_mainmodule(mainmodule, mmodules)
  42         do
  43                 var model = mainmodule.model
  44                 var modelbuilder = toolcontext.modelbuilder
  45
  46                 # Build catalog
  47                 var catalog = new Catalog(modelbuilder)
  48                 for mpackage in model.mpackages do
  49                         catalog.deps.add_node(mpackage)
  50                         for mgroup in mpackage.mgroups do
  51                                 for mmodule in mgroup.mmodules do
  52                                         for imported in mmodule.in_importation.direct_greaters do
  53                                                 var ip = imported.mpackage
  54                                                 if ip == null or ip == mpackage then continue
  55                                                 catalog.deps.add_edge(mpackage, ip)
  56                                         end
  57                                 end
  58                         end
  59                         catalog.git_info(mpackage)
  60                         catalog.package_page(mpackage)
  61                 end
  62
  63                 # Run the server
  64                 var host = toolcontext.opt_host.value or else "localhost"
  65                 var port = toolcontext.opt_port.value
  66
  67                 var app = new App
  68
  69                 app.use("/api", new APIRouter(model, modelbuilder, mainmodule, catalog))
  70                 app.use("/doc/:namespace", new DocAction(model, mainmodule, modelbuilder))
  71                 app.use("/*", new StaticHandler(toolcontext.share_dir / "nitweb", "index.html"))
  72
  73                 app.listen(host, port.to_i)
  74         end
  75 end
  76
  77 # Group all api handlers in one router.
  78 class APIRouter
  79         super Router
  80
  81         # Model to pass to handlers.
  82         var model: Model
  83
  84         # ModelBuilder to pass to handlers.
  85         var modelbuilder: ModelBuilder
  86
  87         # Mainmodule to pass to handlers.
  88         var mainmodule: MModule
  89
  90         # Catalog to pass to handlers.
  91         var catalog: Catalog
  92
  93         init do
  94                 use("/catalog", new APICatalogRouter(model, mainmodule, catalog))
  95                 use("/list", new APIList(model, mainmodule))
  96                 use("/search", new APISearch(model, mainmodule))
  97                 use("/random", new APIRandom(model, mainmodule))
  98                 use("/entity/:id", new APIEntity(model, mainmodule))
  99                 use("/code/:id", new APIEntityCode(model, mainmodule, modelbuilder))
 100                 use("/uml/:id", new APIEntityUML(model, mainmodule))
 101         end
 102 end
 103
 104 # build toolcontext
 105 var toolcontext = new ToolContext
 106 var tpl = new Template
 107 tpl.add "Usage: nitweb [OPTION]... <file.nit>...\n"
 108 tpl.add "Run a webserver based on nitcorn that serve pages about model."
 109 toolcontext.tooldescription = tpl.write_to_string
 110
 111 # process options
 112 toolcontext.process_options(args)
 113 var arguments = toolcontext.option_context.rest
 114
 115 # build model
 116 var model = new Model
 117 var mbuilder = new ModelBuilder(model, toolcontext)
 118 var mmodules = mbuilder.parse_full(arguments)
 119
 120 # process
 121 if mmodules.is_empty then return
 122 mbuilder.run_phases
 123 toolcontext.run_global_phases(mmodules)