lib/java.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2014 Alexis Laferrière <alexis.laf@xymus.net>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Supporting services for the FFI with Java
  18 #
  19 # This modules relies on `Sys::jvm`, `Sys::jni_env` and
  20 # `Sys::create_default_jvm` to get a handle on a JVM. You can adapt the
  21 # behavior of the FFI and services in this module by redefing
  22 # `Sys::create_default_jvm` and supply your own JVM object. You can manage
  23 # multiple java thread by switching the current environment in a redef
  24 # of `Sys::jni_env`, and multiple JVM using `Sys::jvm`.
  25 #
  26 # The module `jvm` gives more control over the JVM instances and wraps
  27 # most of JNI functions. You can use it to further customize the behavior
  28 # of your code.
  29 module java is
  30         c_compiler_option("-I $(JAVA_HOME)/include/")
  31         c_linker_option("-L $(JNI_LIB_PATH) -ljvm")
  32 end
  33
  34 import jvm
  35
  36 redef class Sys
  37         private var jvm_cache: nullable JavaVM = null
  38         private var jni_env_cache: nullable JniEnv = null
  39
  40         # Default Java Virtual Machine to use (will be instanciated using
  41         # `create_default_jvm` if not already set)
  42         fun jvm: JavaVM
  43         do
  44                 if jvm_cache == null then create_default_jvm
  45                 return jvm_cache.as(not null)
  46         end
  47
  48         # Sets the current default Java Virtual Machine (use with `jni_env=`)
  49         fun jvm=(jvm: JavaVM) do jvm_cache = jvm
  50
  51         # Current main `JniEnv`
  52         # FIXME support threaded Java
  53         fun jni_env: JniEnv
  54         do
  55                 if jni_env_cache == null then create_default_jvm
  56                 return jni_env_cache.as(not null)
  57         end
  58
  59         # Sets the current default JNI env (use with `jvm=`)
  60         fun jni_env=(jni_env: JniEnv) do jni_env_cache = jni_env
  61
  62         # Called by `jvm` and `jni_env` to instanciate a Java Virual Machine.
  63         # Used mostly for the FFI with Java.
  64         protected fun create_default_jvm
  65         do
  66                 var builder = new JavaVMBuilder
  67
  68                 # By default, look for Java classes in a jar file the same dir as the executable
  69                 builder.options.add "-Djava.class.path={sys.program_name}.jar"
  70
  71                 var jvm = builder.create_jvm
  72                 assert jvm != null else print "JVM creation failed"
  73
  74                 self.jvm = jvm
  75                 self.jni_env = builder.jni_env.as(not null)
  76         end
  77 end
  78
  79 # A standard Java string `java.lang.String`
  80 #
  81 # Converted to a Nit string using `to_s`, or to a C string with `to_cstring`.
  82 # Created using `String::to_java_string` or `NativeString::to_java_string`.
  83 extern class JavaString in "Java" `{ java.lang.String `}
  84         super JavaObject
  85
  86         redef type SELF: JavaString
  87
  88         # Get the string from Java and copy it to Nit memory
  89         fun to_cstring: NativeString import sys, Sys.jni_env `{
  90                 Sys sys = JavaString_sys(recv);
  91                 JNIEnv *env = Sys_jni_env(sys);
  92
  93                 // Get the data from Java
  94                 const jbyte *java_cstr = (char*)(*env)->GetStringUTFChars(env, recv, NULL);
  95                 jsize len = (*env)->GetStringUTFLength(env, recv);
  96
  97                 // Copy it in control of Nit
  98                 char *nit_cstr = (char*)malloc(len+1);
  99                 memcpy(nit_cstr, java_cstr, len);
 100                 nit_cstr[len] = '\0';
 101
 102                 // Free JNI ref and return
 103                 (*env)->ReleaseStringUTFChars(env, recv, java_cstr);
 104                 return nit_cstr;
 105         `}
 106
 107         redef fun to_s do return to_cstring.to_s
 108 end
 109
 110 redef class NativeString
 111         # Get a Java string from this C string
 112         #
 113         # This instance is only valid until the next execution of Java code.
 114         # You can use `new_local_ref` to keep it longer.
 115         fun to_java_string: JavaString import sys, Sys.jni_env `{
 116                 Sys sys = JavaString_sys(recv);
 117                 JNIEnv *env = Sys_jni_env(sys);
 118                 return (*env)->NewStringUTF(env, recv);
 119         `}
 120 end
 121
 122 redef class String
 123         fun to_java_string: JavaString do return to_cstring.to_java_string
 124 end
 125
 126 redef extern class JavaObject
 127         type SELF: JavaObject
 128
 129         # Returns a global reference to the Java object behind this reference
 130         #
 131         # You must use a global reference when keeping a Java object
 132         # across execution of Java code, per JNI specification.
 133         fun new_global_ref: SELF import sys, Sys.jni_env `{
 134                 Sys sys = JavaObject_sys(recv);
 135                 JNIEnv *env = Sys_jni_env(sys);
 136                 return (*env)->NewGlobalRef(env, recv);
 137         `}
 138
 139         # Delete this global reference
 140         fun delete_global_ref import sys, Sys.jni_env `{
 141                 Sys sys = JavaObject_sys(recv);
 142                 JNIEnv *env = Sys_jni_env(sys);
 143                 (*env)->DeleteGlobalRef(env, recv);
 144         `}
 145 end