lib/standard/file.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2004-2008 Jean Privat <jean@pryen.org>
   4 # Copyright 2008 Floréal Morandat <morandat@lirmm.fr>
   5 # Copyright 2008 Jean-Sébastien Gélinas <calestar@gmail.com>
   6 #
   7 # This file is free software, which comes along with NIT.  This software is
   8 # distributed in the hope that it will be useful, but WITHOUT ANY WARRANTY;
   9 # without  even  the implied warranty of  MERCHANTABILITY or  FITNESS FOR A
  10 # PARTICULAR PURPOSE.  You can modify it is you want,  provided this header
  11 # is kept unaltered, and a notification of the changes is added.
  12 # You  are  allowed  to  redistribute it and sell it, alone or is a part of
  13 # another product.
  14
  15 # File manipulations (create, read, write, etc.)
  16 module file
  17
  18 intrude import stream
  19 intrude import ropes
  20 import string_search
  21 import time
  22
  23 in "C Header" `{
  24         #include <dirent.h>
  25         #include <string.h>
  26         #include <sys/types.h>
  27         #include <sys/stat.h>
  28         #include <unistd.h>
  29         #include <stdio.h>
  30 `}
  31
  32 # File Abstract Stream
  33 abstract class FStream
  34         super IOS
  35         # The path of the file.
  36         var path: nullable String = null
  37
  38         # The FILE *.
  39         private var file: nullable NativeFile = null
  40
  41         # The status of a file. see POSIX stat(2).
  42         fun file_stat: FileStat do return _file.file_stat
  43
  44         # File descriptor of this file
  45         fun fd: Int do return _file.fileno
  46 end
  47
  48 # File input stream
  49 class IFStream
  50         super FStream
  51         super BufferedIStream
  52         super PollableIStream
  53         # Misc
  54
  55         # Open the same file again.
  56         # The original path is reused, therefore the reopened file can be a different file.
  57         fun reopen
  58         do
  59                 if not eof then close
  60                 _file = new NativeFile.io_open_read(path.to_cstring)
  61                 end_reached = false
  62                 _buffer_pos = 0
  63                 _buffer.clear
  64         end
  65
  66         redef fun close
  67         do
  68                 _file.io_close
  69                 _buffer.clear
  70                 end_reached = true
  71         end
  72
  73         redef fun fill_buffer
  74         do
  75                 var nb = _file.io_read(_buffer.items, _buffer.capacity)
  76                 if nb <= 0 then
  77                         end_reached = true
  78                         nb = 0
  79                 end
  80                 _buffer.length = nb
  81                 _buffer_pos = 0
  82         end
  83
  84         # End of file?
  85         redef var end_reached: Bool = false
  86
  87         # Open the file at `path` for reading.
  88         init open(path: String)
  89         do
  90                 self.path = path
  91                 prepare_buffer(10)
  92                 _file = new NativeFile.io_open_read(path.to_cstring)
  93                 assert not _file.address_is_null else
  94                         print "Error: Opening file at '{path}' failed with '{sys.errno.strerror}'"
  95                 end
  96         end
  97
  98 end
  99
 100 # File output stream
 101 class OFStream
 102         super FStream
 103         super OStream
 104
 105         redef fun write(s)
 106         do
 107                 assert _is_writable
 108                 if s isa FlatText then
 109                         write_native(s.to_cstring, s.length)
 110                 else
 111                         for i in s.substrings do write_native(i.to_cstring, i.length)
 112                 end
 113         end
 114
 115         redef fun close
 116         do
 117                 _file.io_close
 118                 _is_writable = false
 119         end
 120
 121         redef var is_writable = false
 122
 123         # Write `len` bytes from `native`.
 124         private fun write_native(native: NativeString, len: Int)
 125         do
 126                 assert _is_writable
 127                 var err = _file.io_write(native, len)
 128                 if err != len then
 129                         # Big problem
 130                         printn("Problem in writing : ", err, " ", len, "\n")
 131                 end
 132         end
 133
 134         # Open the file at `path` for writing.
 135         init open(path: String)
 136         do
 137                 _file = new NativeFile.io_open_write(path.to_cstring)
 138                 assert not _file.address_is_null else
 139                         print "Error: Opening file at '{path}' failed with '{sys.errno.strerror}'"
 140                 end
 141                 self.path = path
 142                 _is_writable = true
 143         end
 144 end
 145
 146 ###############################################################################
 147
 148 # Standard input stream.
 149 class Stdin
 150         super IFStream
 151
 152         init do
 153                 _file = new NativeFile.native_stdin
 154                 path = "/dev/stdin"
 155                 prepare_buffer(1)
 156         end
 157
 158         redef fun poll_in: Bool is extern "file_stdin_poll_in"
 159 end
 160
 161 # Standard output stream.
 162 class Stdout
 163         super OFStream
 164         init do
 165                 _file = new NativeFile.native_stdout
 166                 path = "/dev/stdout"
 167                 _is_writable = true
 168         end
 169 end
 170
 171 # Standard error stream.
 172 class Stderr
 173         super OFStream
 174         init do
 175                 _file = new NativeFile.native_stderr
 176                 path = "/dev/stderr"
 177                 _is_writable = true
 178         end
 179 end
 180
 181 ###############################################################################
 182
 183 redef class Streamable
 184         # Like `write_to` but take care of creating the file
 185         fun write_to_file(filepath: String)
 186         do
 187                 var stream = new OFStream.open(filepath)
 188                 write_to(stream)
 189                 stream.close
 190         end
 191 end
 192
 193 redef class String
 194         # return true if a file with this names exists
 195         fun file_exists: Bool do return to_cstring.file_exists
 196
 197         # The status of a file. see POSIX stat(2).
 198         fun file_stat: FileStat do return to_cstring.file_stat
 199
 200         # The status of a file or of a symlink. see POSIX lstat(2).
 201         fun file_lstat: FileStat do return to_cstring.file_lstat
 202
 203         # Remove a file, return true if success
 204         fun file_delete: Bool do return to_cstring.file_delete
 205
 206         # Copy content of file at `self` to `dest`
 207         fun file_copy_to(dest: String)
 208         do
 209                 var input = new IFStream.open(self)
 210                 var output = new OFStream.open(dest)
 211
 212                 while not input.eof do
 213                         var buffer = input.read(1024)
 214                         output.write buffer
 215                 end
 216
 217                 input.close
 218                 output.close
 219         end
 220
 221         # Remove the trailing extension `ext`.
 222         #
 223         # `ext` usually starts with a dot but could be anything.
 224         #
 225         #     assert "file.txt".strip_extension(".txt")  == "file"
 226         #     assert "file.txt".strip_extension("le.txt")  == "fi"
 227         #     assert "file.txt".strip_extension("xt")  == "file.t"
 228         #
 229         # if `ext` is not present, `self` is returned unmodified.
 230         #
 231         #     assert "file.txt".strip_extension(".tar.gz")  == "file.txt"
 232         fun strip_extension(ext: String): String
 233         do
 234                 if has_suffix(ext) then
 235                         return substring(0, length - ext.length)
 236                 end
 237                 return self
 238         end
 239
 240         # Extract the basename of a path and remove the extension
 241         #
 242         #     assert "/path/to/a_file.ext".basename(".ext")         == "a_file"
 243         #     assert "path/to/a_file.ext".basename(".ext")          == "a_file"
 244         #     assert "path/to".basename(".ext")                     == "to"
 245         #     assert "path/to/".basename(".ext")                    == "to"
 246         #     assert "path".basename("")                        == "path"
 247         #     assert "/path".basename("")                       == "path"
 248         #     assert "/".basename("")                           == "/"
 249         #     assert "".basename("")                            == ""
 250         fun basename(ext: String): String
 251         do
 252                 var l = length - 1 # Index of the last char
 253                 while l > 0 and self.chars[l] == '/' do l -= 1 # remove all trailing `/`
 254                 if l == 0 then return "/"
 255                 var pos = chars.last_index_of_from('/', l)
 256                 var n = self
 257                 if pos >= 0 then
 258                         n = substring(pos+1, l-pos)
 259                 end
 260                 return n.strip_extension(ext)
 261         end
 262
 263         # Extract the dirname of a path
 264         #
 265         #     assert "/path/to/a_file.ext".dirname         == "/path/to"
 266         #     assert "path/to/a_file.ext".dirname          == "path/to"
 267         #     assert "path/to".dirname                     == "path"
 268         #     assert "path/to/".dirname                    == "path"
 269         #     assert "path".dirname                        == "."
 270         #     assert "/path".dirname                       == "/"
 271         #     assert "/".dirname                           == "/"
 272         #     assert "".dirname                            == "."
 273         fun dirname: String
 274         do
 275                 var l = length - 1 # Index of the last char
 276                 while l > 0 and self.chars[l] == '/' do l -= 1 # remove all trailing `/`
 277                 var pos = chars.last_index_of_from('/', l)
 278                 if pos > 0 then
 279                         return substring(0, pos)
 280                 else if pos == 0 then
 281                         return "/"
 282                 else
 283                         return "."
 284                 end
 285         end
 286
 287         # Return the canonicalized absolute pathname (see POSIX function `realpath`)
 288         fun realpath: String do
 289                 var cs = to_cstring.file_realpath
 290                 var res = cs.to_s_with_copy
 291                 # cs.free_malloc # FIXME memory leak
 292                 return res
 293         end
 294
 295         # Simplify a file path by remove useless ".", removing "//", and resolving ".."
 296         # ".." are not resolved if they start the path
 297         # starting "/" is not removed
 298         # trainling "/" is removed
 299         #
 300         # Note that the method only wonrk on the string:
 301         #  * no I/O access is performed
 302         #  * the validity of the path is not checked
 303         #
 304         #     assert "some/./complex/../../path/from/../to/a////file//".simplify_path        ==  "path/to/a/file"
 305         #     assert "../dir/file".simplify_path       ==  "../dir/file"
 306         #     assert "dir/../../".simplify_path        ==  ".."
 307         #     assert "dir/..".simplify_path            ==  "."
 308         #     assert "//absolute//path/".simplify_path ==  "/absolute/path"
 309         #     assert "//absolute//../".simplify_path   ==  "/"
 310         fun simplify_path: String
 311         do
 312                 var a = self.split_with("/")
 313                 var a2 = new Array[String]
 314                 for x in a do
 315                         if x == "." then continue
 316                         if x == "" and not a2.is_empty then continue
 317                         if x == ".." and not a2.is_empty and a2.last != ".." then
 318                                 a2.pop
 319                                 continue
 320                         end
 321                         a2.push(x)
 322                 end
 323                 if a2.is_empty then return "."
 324                 if a2.length == 1 and a2.first == "" then return "/"
 325                 return a2.join("/")
 326         end
 327
 328         # Correctly join two path using the directory separator.
 329         #
 330         # Using a standard "{self}/{path}" does not work in the following cases:
 331         #
 332         # * `self` is empty.
 333         # * `path` ends with `'/'`.
 334         # * `path` starts with `'/'`.
 335         #
 336         # This method ensures that the join is valid.
 337         #
 338         #     assert "hello".join_path("world")   == "hello/world"
 339         #     assert "hel/lo".join_path("wor/ld") == "hel/lo/wor/ld"
 340         #     assert "".join_path("world")        == "world"
 341         #     assert "hello".join_path("/world")  == "/world"
 342         #     assert "hello/".join_path("world")  == "hello/world"
 343         #     assert "hello/".join_path("/world") == "/world"
 344         #
 345         # Note: You may want to use `simplify_path` on the result.
 346         #
 347         # Note: This method works only with POSIX paths.
 348         fun join_path(path: String): String
 349         do
 350                 if path.is_empty then return self
 351                 if self.is_empty then return path
 352                 if path.chars[0] == '/' then return path
 353                 if self.last == '/' then return "{self}{path}"
 354                 return "{self}/{path}"
 355         end
 356
 357         # Convert the path (`self`) to a program name.
 358         #
 359         # Ensure the path (`self`) will be treated as-is by POSIX shells when it is
 360         # used as a program name. In order to do that, prepend `./` if needed.
 361         #
 362         #     assert "foo".to_program_name == "./foo"
 363         #     assert "/foo".to_program_name == "/foo"
 364         #     assert "".to_program_name == "./" # At least, your shell will detect the error.
 365         fun to_program_name: String do
 366                 if self.has_prefix("/") then
 367                         return self
 368                 else
 369                         return "./{self}"
 370                 end
 371         end
 372
 373         # Alias for `join_path`
 374         #
 375         #     assert "hello" / "world"      ==  "hello/world"
 376         #     assert "hel/lo" / "wor/ld"    ==  "hel/lo/wor/ld"
 377         #     assert "" / "world"           ==  "world"
 378         #     assert "/hello" / "/world"    ==  "/world"
 379         #
 380         # This operator is quite useful for chaining changes of path.
 381         # The next one being relative to the previous one.
 382         #
 383         #     var a = "foo"
 384         #     var b = "/bar"
 385         #     var c = "baz/foobar"
 386         #     assert a/b/c == "/bar/baz/foobar"
 387         fun /(path: String): String do return join_path(path)
 388
 389         # Returns the relative path needed to go from `self` to `dest`.
 390         #
 391         #     assert "/foo/bar".relpath("/foo/baz") == "../baz"
 392         #     assert "/foo/bar".relpath("/baz/bar") == "../../baz/bar"
 393         #
 394         # If `self` or `dest` is relative, they are considered relatively to `getcwd`.
 395         #
 396         # In some cases, the result is still independent of the current directory:
 397         #
 398         #     assert "foo/bar".relpath("..") == "../../.."
 399         #
 400         # In other cases, parts of the current directory may be exhibited:
 401         #
 402         #     var p = "../foo/bar".relpath("baz")
 403         #     var c = getcwd.basename("")
 404         #     assert p == "../../{c}/baz"
 405         #
 406         # For path resolution independent of the current directory (eg. for paths in URL),
 407         # or to use an other starting directory than the current directory,
 408         # just force absolute paths:
 409         #
 410         #     var start = "/a/b/c/d"
 411         #     var p2 = (start/"../foo/bar").relpath(start/"baz")
 412         #     assert p2 == "../../d/baz"
 413         #
 414         #
 415         # Neither `self` or `dest` has to be real paths or to exist in directories since
 416         # the resolution is only done with string manipulations and without any access to
 417         # the underlying file system.
 418         #
 419         # If `self` and `dest` are the same directory, the empty string is returned:
 420         #
 421         #     assert "foo".relpath("foo") == ""
 422         #     assert "foo/../bar".relpath("bar") == ""
 423         #
 424         # The empty string and "." designate both the current directory:
 425         #
 426         #     assert "".relpath("foo/bar")  == "foo/bar"
 427         #     assert ".".relpath("foo/bar") == "foo/bar"
 428         #     assert "foo/bar".relpath("")  == "../.."
 429         #     assert "/" + "/".relpath(".") == getcwd
 430         fun relpath(dest: String): String
 431         do
 432                 var cwd = getcwd
 433                 var from = (cwd/self).simplify_path.split("/")
 434                 if from.last.is_empty then from.pop # case for the root directory
 435                 var to = (cwd/dest).simplify_path.split("/")
 436                 if to.last.is_empty then to.pop # case for the root directory
 437
 438                 # Remove common prefixes
 439                 while not from.is_empty and not to.is_empty and from.first == to.first do
 440                         from.shift
 441                         to.shift
 442                 end
 443
 444                 # Result is going up in `from` with ".." then going down following `to`
 445                 var from_len = from.length
 446                 if from_len == 0 then return to.join("/")
 447                 var up = "../"*(from_len-1) + ".."
 448                 if to.is_empty then return up
 449                 var res = up + "/" + to.join("/")
 450                 return res
 451         end
 452
 453         # Create a directory (and all intermediate directories if needed)
 454         fun mkdir
 455         do
 456                 var dirs = self.split_with("/")
 457                 var path = new FlatBuffer
 458                 if dirs.is_empty then return
 459                 if dirs[0].is_empty then
 460                         # it was a starting /
 461                         path.add('/')
 462                 end
 463                 for d in dirs do
 464                         if d.is_empty then continue
 465                         path.append(d)
 466                         path.add('/')
 467                         path.to_s.to_cstring.file_mkdir
 468                 end
 469         end
 470
 471         # Delete a directory and all of its content, return `true` on success
 472         #
 473         # Does not go through symbolic links and may get stuck in a cycle if there
 474         # is a cycle in the filesystem.
 475         fun rmdir: Bool
 476         do
 477                 var ok = true
 478                 for file in self.files do
 479                         var file_path = self.join_path(file)
 480                         var stat = file_path.file_lstat
 481                         if stat.is_dir then
 482                                 ok = file_path.rmdir and ok
 483                         else
 484                                 ok = file_path.file_delete and ok
 485                         end
 486                         stat.free
 487                 end
 488
 489                 # Delete the directory itself
 490                 if ok then to_cstring.rmdir
 491
 492                 return ok
 493         end
 494
 495         # Change the current working directory
 496         #
 497         #     "/etc".chdir
 498         #     assert getcwd == "/etc"
 499         #     "..".chdir
 500         #     assert getcwd == "/"
 501         #
 502         # TODO: errno
 503         fun chdir do to_cstring.file_chdir
 504
 505         # Return right-most extension (without the dot)
 506         #
 507         # Only the last extension is returned.
 508         # There is no special case for combined extensions.
 509         #
 510         #     assert "file.txt".file_extension      == "txt"
 511         #     assert "file.tar.gz".file_extension   == "gz"
 512         #
 513         # For file without extension, `null` is returned.
 514         # Hoever, for trailing dot, `""` is returned.
 515         #
 516         #     assert "file".file_extension          == null
 517         #     assert "file.".file_extension         == ""
 518         #
 519         # The starting dot of hidden files is never considered.
 520         #
 521         #     assert ".file.txt".file_extension     == "txt"
 522         #     assert ".file".file_extension         == null
 523         fun file_extension: nullable String
 524         do
 525                 var last_slash = chars.last_index_of('.')
 526                 if last_slash > 0 then
 527                         return substring( last_slash+1, length )
 528                 else
 529                         return null
 530                 end
 531         end
 532
 533         # returns files contained within the directory represented by self
 534         fun files: Array[String] is extern import Array[String], Array[String].add, NativeString.to_s, String.to_cstring `{
 535                 char *dir_path;
 536                 DIR *dir;
 537
 538                 dir_path = String_to_cstring( recv );
 539                 if ((dir = opendir(dir_path)) == NULL)
 540                 {
 541                         perror( dir_path );
 542                         exit( 1 );
 543                 }
 544                 else
 545                 {
 546                         Array_of_String results;
 547                         String file_name;
 548                         struct dirent *de;
 549
 550                         results = new_Array_of_String();
 551
 552                         while ( ( de = readdir( dir ) ) != NULL )
 553                                 if ( strcmp( de->d_name, ".." ) != 0 &&
 554                                         strcmp( de->d_name, "." ) != 0 )
 555                                 {
 556                                         file_name = NativeString_to_s( strdup( de->d_name ) );
 557                                         Array_of_String_add( results, file_name );
 558                                 }
 559
 560                         closedir( dir );
 561                         return results;
 562                 }
 563         `}
 564 end
 565
 566 redef class NativeString
 567         private fun file_exists: Bool is extern "string_NativeString_NativeString_file_exists_0"
 568         private fun file_stat: FileStat is extern "string_NativeString_NativeString_file_stat_0"
 569         private fun file_lstat: FileStat `{
 570                 struct stat* stat_element;
 571                 int res;
 572                 stat_element = malloc(sizeof(struct stat));
 573                 res = lstat(recv, stat_element);
 574                 if (res == -1) return NULL;
 575                 return stat_element;
 576         `}
 577         private fun file_mkdir: Bool is extern "string_NativeString_NativeString_file_mkdir_0"
 578         private fun rmdir: Bool `{ return rmdir(recv); `}
 579         private fun file_delete: Bool is extern "string_NativeString_NativeString_file_delete_0"
 580         private fun file_chdir is extern "string_NativeString_NativeString_file_chdir_0"
 581         private fun file_realpath: NativeString is extern "file_NativeString_realpath"
 582 end
 583
 584 # This class is system dependent ... must reify the vfs
 585 extern class FileStat `{ struct stat * `}
 586         # Returns the permission bits of file
 587         fun mode: Int is extern "file_FileStat_FileStat_mode_0"
 588         # Returns the last access time
 589         fun atime: Int is extern "file_FileStat_FileStat_atime_0"
 590         # Returns the last status change time
 591         fun ctime: Int is extern "file_FileStat_FileStat_ctime_0"
 592         # Returns the last modification time
 593         fun mtime: Int is extern "file_FileStat_FileStat_mtime_0"
 594         # Returns the size
 595         fun size: Int is extern "file_FileStat_FileStat_size_0"
 596
 597         # Returns true if it is a regular file (not a device file, pipe, sockect, ...)
 598         fun is_reg: Bool `{ return S_ISREG(recv->st_mode); `}
 599         # Returns true if it is a directory
 600         fun is_dir: Bool `{ return S_ISDIR(recv->st_mode); `}
 601         # Returns true if it is a character device
 602         fun is_chr: Bool `{ return S_ISCHR(recv->st_mode); `}
 603         # Returns true if it is a block device
 604         fun is_blk: Bool `{ return S_ISBLK(recv->st_mode); `}
 605         # Returns true if the type is fifo
 606         fun is_fifo: Bool `{ return S_ISFIFO(recv->st_mode); `}
 607         # Returns true if the type is a link
 608         fun is_lnk: Bool `{ return S_ISLNK(recv->st_mode); `}
 609         # Returns true if the type is a socket
 610         fun is_sock: Bool `{ return S_ISSOCK(recv->st_mode); `}
 611 end
 612
 613 # Instance of this class are standard FILE * pointers
 614 private extern class NativeFile `{ FILE* `}
 615         fun io_read(buf: NativeString, len: Int): Int is extern "file_NativeFile_NativeFile_io_read_2"
 616         fun io_write(buf: NativeString, len: Int): Int is extern "file_NativeFile_NativeFile_io_write_2"
 617         fun io_close: Int is extern "file_NativeFile_NativeFile_io_close_0"
 618         fun file_stat: FileStat is extern "file_NativeFile_NativeFile_file_stat_0"
 619         fun fileno: Int `{ return fileno(recv); `}
 620
 621         new io_open_read(path: NativeString) is extern "file_NativeFileCapable_NativeFileCapable_io_open_read_1"
 622         new io_open_write(path: NativeString) is extern "file_NativeFileCapable_NativeFileCapable_io_open_write_1"
 623         new native_stdin is extern "file_NativeFileCapable_NativeFileCapable_native_stdin_0"
 624         new native_stdout is extern "file_NativeFileCapable_NativeFileCapable_native_stdout_0"
 625         new native_stderr is extern "file_NativeFileCapable_NativeFileCapable_native_stderr_0"
 626 end
 627
 628 redef class Sys
 629
 630         # Standard input
 631         var stdin: PollableIStream = new Stdin is protected writable
 632
 633         # Standard output
 634         var stdout: OStream = new Stdout is protected writable
 635
 636         # Standard output for errors
 637         var stderr: OStream = new Stderr is protected writable
 638
 639 end
 640
 641 # Print `objects` on the standard output (`stdout`).
 642 protected fun printn(objects: Object...)
 643 do
 644         sys.stdout.write(objects.to_s)
 645 end
 646
 647 # Print an `object` on the standard output (`stdout`) and add a newline.
 648 protected fun print(object: Object)
 649 do
 650         sys.stdout.write(object.to_s)
 651         sys.stdout.write("\n")
 652 end
 653
 654 # Read a character from the standard input (`stdin`).
 655 protected fun getc: Char
 656 do
 657         return sys.stdin.read_char.ascii
 658 end
 659
 660 # Read a line from the standard input (`stdin`).
 661 protected fun gets: String
 662 do
 663         return sys.stdin.read_line
 664 end
 665
 666 # Return the working (current) directory
 667 protected fun getcwd: String do return file_getcwd.to_s
 668 private fun file_getcwd: NativeString is extern "string_NativeString_NativeString_file_getcwd_0"