src/parser/nit.sablecc3xx

   1
   2 /* This file is part of NIT ( http://www.nitlanguage.org ).
   3  *
   4  * Copyright 2008-2009 Jean Privat <jean@pryen.org>
   5  *
   6  * Licensed under the Apache License, Version 2.0 (the "License");
   7  * you may not use this file except in compliance with the License.
   8  * You may obtain a copy of the License at
   9  *
  10  *     http://www.apache.org/licenses/LICENSE-2.0
  11  *
  12  * Unless required by applicable law or agreed to in writing, software
  13  * distributed under the License is distributed on an "AS IS" BASIS,
  14  * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15  * See the License for the specific language governing permissions and
  16  * limitations under the License.
  17  */
  18
  19 /* This grammar defines the NIT language. */
  20
  21 /*****************************************************************************/
  22 Helpers
  23 /*****************************************************************************/
  24
  25 all = [0 .. 0xFF];
  26 lowercase = ['a' .. 'z'];
  27 uppercase = ['A' .. 'Z'];
  28 digit = ['0' .. '9'];
  29 letter = lowercase | uppercase | digit | '_';
  30
  31 tab = 9;
  32 cr = 13;
  33 lf = 10;
  34 any = [all - [cr + lf]];
  35
  36 // characers inside strings and super-strings (atomaton powaa)
  37 str_char
  38         = [any - [['"' + '{'] + '\']]
  39         | '\' any
  40         ;
  41 str_body = str_char*;
  42
  43 eol_helper = cr lf | cr | lf; // This takes care of different platforms
  44
  45 /*****************************************************************************/
  46 States
  47 /*****************************************************************************/
  48 initial;
  49
  50
  51 /*****************************************************************************/
  52 Tokens
  53 /*****************************************************************************/
  54
  55 blank = (' ' | tab)+;
  56
  57 eol = eol_helper;
  58 comment = '#' any* eol_helper;
  59
  60 kwpackage = 'package';
  61 kwimport = 'import';
  62 kwclass = 'class';
  63 kwabstract = 'abstract';
  64 kwinterface = 'interface';
  65 kwuniversal = 'universal';
  66 kwspecial = 'special';
  67 kwend = 'end';
  68 kwmeth = 'meth';
  69 kwtype = 'type';
  70 kwattr = 'attr';
  71 kwinit = 'init';
  72 kwredef = 'redef';
  73 kwis = 'is';
  74 kwdo = 'do';
  75 kwreadable = 'readable';
  76 kwwritable = 'writable';
  77 kwvar = 'var';
  78 kwintern = 'intern';
  79 kwextern = 'extern';
  80 kwprotected = 'protected';
  81 kwprivate = 'private';
  82 kwintrude = 'intrude';
  83 kwif = 'if';
  84 kwthen = 'then';
  85 kwelse = 'else';
  86 kwwhile = 'while';
  87 kwfor = 'for';
  88 kwin = 'in';
  89 kwand = 'and';
  90 kwor = 'or';
  91 kwnot = 'not';
  92 kwreturn = 'return';
  93 kwcontinue = 'continue';
  94 kwbreak = 'break';
  95 kwabort = 'abort';
  96 kwassert = 'assert';
  97 kwnew = 'new';
  98 kwisa = 'isa';
  99 kwonce = 'once';
 100 kwsuper = 'super';
 101 kwself = 'self';
 102 kwtrue = 'true';
 103 kwfalse = 'false';
 104 kwnull = 'null';
 105 kwas = 'as';
 106 kwwith = 'with';
 107
 108 opar = '(';
 109 cpar = ')';
 110 obra = '[';
 111 cbra = ']';
 112 comma = ',';
 113 column = ':';
 114 quad = '::';
 115 assign = '=';
 116 pluseq = '+=';
 117 minuseq = '-=';
 118 dotdotdot = '...';
 119 dotdot = '..';
 120 dot = '.';
 121 plus = '+';
 122 minus = '-';
 123 star = '*';
 124 slash = '/';
 125 percent = '%';
 126 eq = '==';
 127 ne = '!=';
 128 lt = '<';
 129 le = '<=';
 130 gt = '>';
 131 ge = '>=';
 132 starship = '<=>';
 133
 134 classid = uppercase letter*;
 135 id = lowercase letter*;
 136 attrid = '_' lowercase letter*;
 137
 138 number = digit+;
 139 float = digit* '.' digit+;
 140 char = ''' [any - ''']* ''';
 141 string = '"' str_body '"';
 142 start_string = '"' str_body '{';
 143 mid_string = '}' str_body '{';
 144 end_string = '}' str_body '"';
 145
 146
 147 /*****************************************************************************/
 148 Ignored Tokens
 149 /*****************************************************************************/
 150
 151 blank;
 152
 153 /*****************************************************************************/
 154 Productions
 155 /*****************************************************************************/
 156
 157 /* MODULES *******************************************************************/
 158 module
 159         = packagedecl? [imports]:import* [classdefs]:classdef* implicit_top_class? implicit_main_class? {-> New module(packagedecl, [imports.import],[classdefs.classdef,implicit_top_class.classdef,implicit_main_class.classdef])};
 160
 161 packagedecl
 162         = [doc]:no kwpackage no id [n2]:n1 {-> New packagedecl(doc.doc, kwpackage, id)};
 163
 164 import
 165         = [doc]:no visibility kwimport no id [n2]:n1            {-> New import(visibility, kwimport, id)}
 166         | {no} [doc]:no visibility kwimport no kwend [n2]:n1    {-> New import.no(visibility, kwimport, kwend)}
 167         ;
 168
 169 implicit_top_class {-> classdef}
 170         = tl_propdefs {-> New classdef.top([tl_propdefs.propdef])};
 171
 172 implicit_main_class {-> classdef?}
 173         = implicit_main_meth {-> New classdef.main([implicit_main_meth.propdef])}
 174         | {null} n {-> Null}
 175         ;
 176 implicit_main_meth {-> propdef}
 177         = [doc]:no stmts no {-> New propdef.main_meth(Null, stmts.expr)};
 178
 179 /* CLASSES *******************************************************************/
 180 classdef
 181         = [doc]:no redef visibility classkind no classid formaldefs? [specials]:special* propdefs? [n2]:no kwend {-> New classdef(doc.doc, redef.kwredef, visibility, classkind, classid, [formaldefs.formaldef], [specials.superclass], [propdefs.propdef])};
 182 redef {-> kwredef?}
 183         = kwredef? {-> kwredef};
 184 classkind
 185         = {concrete} kwclass
 186         | {abstract} kwabstract kwclass
 187         | {interface} kwinterface
 188         | {universal} kwuniversal
 189         ;
 190
 191 formaldefs {-> formaldef*}
 192         = obra no formaldef formaldefs_tail* [n2]:no cbra {-> [formaldef, formaldefs_tail.formaldef]};
 193 formaldefs_tail {-> formaldef}
 194         = comma no formaldef {-> formaldef};
 195 formaldef
 196         = classid typing? {-> New formaldef(classid, typing.type)};
 197
 198 special {-> superclass}
 199         = no kwspecial [n2]:no type {-> New superclass(kwspecial, type)};
 200
 201 propdefs {-> propdef*}
 202         = propdef n1 propdefs_tail* {-> [propdef, propdefs_tail.propdef]};
 203 propdefs_tail {-> propdef}
 204         = propdef n1 {-> propdef};
 205 propdef
 206         = {attr} [doc]:no readable writable redef visibility kwattr attrid typing? {-> New propdef.attr(doc.doc, readable.able, writable.able, redef.kwredef, visibility, kwattr, attrid, typing.type, Null)}
 207         | {attr2} [doc]:no readable writable redef visibility kwattr attrid typing? assign [n2]:no expr {-> New propdef.attr(doc.doc, readable.able, writable.able, redef.kwredef, visibility, kwattr, attrid, typing.type, expr)}
 208         | {deferred} [doc]:no redef visibility kwmeth methid signature kwis kwabstract {-> New propdef.deferred_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature)}
 209         | {intern} [doc]:no redef visibility kwmeth methid signature kwis kwintern {-> New propdef.intern_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature)}
 210         | {extern} [doc]:no redef visibility kwmeth methid signature kwis kwextern string? {-> New propdef.extern_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature, string)}
 211         | {meth} [doc]:no redef visibility kwmeth methid signature kwdo stmtso kwend? {-> New propdef.concrete_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature, stmtso.expr)}
 212         | {init} [doc]:no redef visibility kwinit methid? signature kwdo stmtso kwend? {-> New propdef.concrete_init(doc.doc, redef.kwredef, visibility, kwinit, methid, signature, stmtso.expr)}
 213         | {type} [doc]:no redef visibility kwtype classid typing {-> New propdef.type(doc.doc, redef.kwredef, visibility, kwtype, classid, typing.type)}
 214         ;
 215 readable {-> able?}
 216         = redef kwreadable {-> New able.read(redef.kwredef, kwreadable)}
 217         | {empty} {-> Null}
 218         ;
 219 writable {-> able?}
 220         = redef kwwritable {-> New able.write(redef.kwredef, kwwritable)}
 221         | {empty} {-> Null}
 222         ;
 223
 224 tl_propdefs {-> propdef*}
 225         = tl_propdef n1 tl_propdefs_tail* {-> [tl_propdef.propdef, tl_propdefs_tail.propdef]};
 226 tl_propdefs_tail {-> propdef}
 227         = tl_propdef n1 {-> tl_propdef.propdef};
 228 tl_propdef {-> propdef}
 229         = {extern} [doc]:no redef visibility kwmeth methid signature kwis kwextern string? {-> New propdef.extern_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature, string)}
 230         | {meth} [doc]:no redef visibility kwmeth methid signature kwdo stmtso {-> New propdef.concrete_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature, stmtso.expr)}
 231         ;
 232
 233 visibility
 234         = {public} {-> New visibility.public()}
 235         | {private} kwprivate no {-> New visibility.private(kwprivate)}
 236         | {protected} kwprotected no {-> New visibility.protected(kwprotected)}
 237         | {intrude} kwintrude no {-> New visibility.intrude(kwintrude)}
 238         ;
 239
 240 methid
 241         = {id} id
 242         | {plus} plus
 243         | {minus} minus
 244         | {star} star
 245         | {slash} slash
 246         | {percent} percent
 247         | {eq} eq
 248         | {ne} ne
 249         | {le} le
 250         | {ge} ge
 251         | {lt} lt
 252         | {gt} gt
 253         | {bra} obra cbra
 254         | {starship} starship
 255         | {assign} id assign
 256         | {braassign} obra cbra assign
 257         ;
 258
 259 signature
 260         = params? typing? closure_decls {-> New signature([params.param], typing.type, [closure_decls.closure_decl])}
 261         | {noclosures} params? typing? no {-> New signature([params.param], typing.type, [])}
 262         ;
 263
 264 signature_noclosures {-> signature}
 265         = params? typing? {-> New signature([params.param], typing.type, [])};
 266
 267 params {-> param*}
 268         = opar no param params_tail* [n2]:no cpar {-> [param, params_tail.param]}
 269         | {empty} opar no cpar {-> []}
 270         ;
 271 params_tail {-> param}
 272         = comma no param {-> param};
 273 param
 274         = {untyped} id {-> New param(id, Null, Null)}
 275         | id typing dotdotdot? {-> New param(id, typing.type, dotdotdot)}
 276         ;
 277
 278 closure_decls {->closure_decl*}
 279         = no closure_decl+ {-> [closure_decl]};
 280 closure_decl
 281         = kwwith kwbreak? [no2]:no id signature_noclosures n {-> New closure_decl(kwwith, kwbreak, id, signature_noclosures.signature, Null)}
 282         | {optionnal} kwwith kwbreak? [no2]:no id signature_noclosures kwdo stmtso n {-> New closure_decl(kwwith, kwbreak, id, signature_noclosures.signature, stmtso.expr)}
 283         ;
 284
 285 /* TYPES *********************************************************************/
 286 type~nopar~nobra {-> type}
 287         = {simple} classid {-> New type(classid, [])}
 288 !nobra  | {generic} classid obra no types [n2]:no cbra {-> New type(classid, [types.type])}
 289         ;
 290 types {-> type*}
 291         = type types_tail* {-> [type, types_tail.type]};
 292 types_tail {-> type}
 293         = comma no type {-> type};
 294 typing {-> type}
 295         = column no type {-> type};
 296
 297 /* STATMENTS *****************************************************************/
 298 stmtso~withelse {-> expr?}
 299         = {oneline} stmt~withelse {-> stmt~withelse.expr}
 300         | {block} n stmts [n2]:n kwend {-> stmts.expr}
 301         | {emptyblock} n kwend {-> New expr.block([])}
 302         | {emptyoneline} kwend {-> New expr.block([])}
 303         ;
 304 stmts {-> expr}
 305         = stmt stmts_tail* {-> New expr.block([stmt.expr, stmts_tail.expr])};
 306 stmts_tail {-> expr}
 307         = n stmt {-> stmt.expr};
 308 stmt~withelse {-> expr}
 309         = {vardecl} vardecl~withelse {-> vardecl~withelse.expr}
 310         | {assign} assignment~withelse {-> assignment~withelse.expr}
 311         | {return} kwreturn expr_final~withelse? {-> New expr.return(kwreturn, expr_final~withelse.expr)}
 312         | {break} kwbreak expr_final~withelse? {-> New expr.break(kwbreak, expr_final~withelse.expr)}
 313         | {abort} kwabort {-> New expr.abort(kwabort)}
 314         | {continue} kwcontinue expr_final~withelse? {-> New expr.continue(kwcontinue, expr_final~withelse.expr)}
 315         | {do} do~withelse {-> do~withelse.expr}
 316         | {if} if~withelse {-> if~withelse.expr}
 317         | {while} while~withelse {-> while~withelse.expr}
 318         | {for} for~withelse {-> for~withelse.expr}
 319         | {assert} assert~withelse {-> assert~withelse.expr}
 320 //      | {expr} expr {-> expr.expr}
 321         | {call} recv id args_nopar closure_defs~withelse? {-> New expr.call(recv.expr, id, [args_nopar.expr], [closure_defs~withelse.closure_def])}
 322         | {super} qualified? kwsuper args_nopar {-> New expr.super(qualified, kwsuper, [args_nopar.expr])}
 323         | {init} recv kwinit args_nopar {-> New expr.init(recv.expr, kwinit, [args_nopar.expr])}
 324         ;
 325
 326 closure_defs~withelse {-> closure_def*}
 327         = {one} closure_def_last~withelse {-> [closure_def_last~withelse.closure_def]}
 328         | closure_def closure_defs~withelse {-> [closure_def, closure_defs~withelse.closure_def]}
 329         ;
 330
 331 closure_def_last~withelse {-> closure_def}
 332         = kwwith idlist? kwdo stmtso~withelse {-> New closure_def(kwwith, [idlist.id], kwdo, stmtso~withelse.expr)}
 333         ;
 334
 335 closure_def {-> closure_def}
 336         = kwwith idlist? kwdo n stmts [n2]:n {-> New closure_def(kwwith, [idlist.id], kwdo, stmts.expr)}
 337         | {empty} kwwith idlist? kwdo n {-> New closure_def(kwwith, [idlist.id], kwdo, Null)}
 338         ;
 339
 340 vardecl~withelse{-> expr}
 341         = kwvar id typing? {-> New expr.vardecl(kwvar, id, typing.type, Null, Null)}
 342         | {assign} kwvar id typing? assign no expr_final~withelse {-> New expr.vardecl(kwvar, id, typing.type, assign, expr_final~withelse.expr)}
 343         ;
 344
 345 assignment~withelse {-> expr}
 346         = {attr} recv attrid assign expr_final~withelse {-> New expr.attr_assign(recv.expr, attrid, assign, expr_final~withelse.expr)}
 347         | {call} recv id args assign expr_final~withelse {-> New expr.call_assign(recv.expr, id, [args.expr], assign,  expr_final~withelse.expr)}
 348         | {bra} expr_atom braargs assign expr_final~withelse {-> New expr.bra_assign(expr_atom.expr, [braargs.expr], assign,  expr_final~withelse.expr)}
 349         | {attr_re} recv attrid assign_op expr_final~withelse {-> New expr.attr_reassign(recv.expr, attrid, assign_op,  expr_final~withelse.expr)}
 350         | {call_re} recv id args assign_op expr_final~withelse {-> New expr.call_reassign(recv.expr, id, [args.expr], assign_op,  expr_final~withelse.expr)}
 351         | {bra_re} expr_atom braargs assign_op expr_final~withelse {-> New expr.bra_reassign(expr_atom.expr, [braargs.expr], assign_op,  expr_final~withelse.expr)}
 352         ;
 353 assign_op
 354         = {plus} pluseq
 355         | {minus} minuseq
 356         ;
 357
 358 do~withelse {-> expr}
 359         = kwdo stmtso~withelse {-> New expr.do(kwdo, stmtso~withelse.expr)}
 360         ;
 361
 362 if~withelse {-> expr}
 363         = {onelineelse} kwif no expr [n2]:no kwthen stmt_withelse kwelse stmtso~withelse {-> New expr.if(kwif, expr, stmt_withelse.expr, stmtso~withelse.expr)}
 364 !withelse       | {oneline} kwif no expr [n2]:no kwthen stmt {-> New expr.if(kwif, expr, stmt.expr, Null)}
 365 !withelse       | {block} kwif no expr [n2]:no kwthen [n3]:n stmts [n4]:n elsepartblock {-> New expr.if(kwif, expr, stmts.expr, elsepartblock.expr)}
 366 !withelse       | {emptyblock} kwif no expr [n2]:no kwthen [n3]:n? elsepartblock {-> New expr.if(kwif, expr, Null, elsepartblock.expr)}
 367         ;
 368 elsepartblock {-> expr?}
 369         = {else} kwelse stmtso {-> stmtso.expr}
 370         | {empty} kwend {-> Null}
 371         ;
 372
 373 while~withelse {-> expr}
 374         = kwwhile no expr [n2]:no kwdo stmtso~withelse {-> New expr.while(kwwhile, expr, kwdo, stmtso~withelse.expr)};
 375
 376 for~withelse {-> expr}
 377         = for_vardecl [n4]:no kwdo stmtso~withelse {-> New expr.for(for_vardecl.expr, kwdo, stmtso~withelse.expr)};
 378 for_vardecl {-> expr}
 379         = kwfor no id [n2]:no kwin [n3]:no expr {-> New expr.for_vardecl(kwfor, id, expr)};
 380
 381 assert~withelse {-> expr}
 382         = kwassert assertid? expr_final~withelse {-> New expr.assert(kwassert, assertid.id, expr_final~withelse.expr)};
 383 assertid {-> id}
 384         = id column {-> id};
 385
 386 /* EXPRESSIONS ***************************************************************/
 387 expr_final~nopar~withelse~nobra {-> expr}
 388         = expr~nopar~nobra {-> expr~nopar~nobra.expr}
 389         | {closure_call} recv~nobra id args closure_defs~withelse {-> New expr.call(recv~nobra.expr, id, [args.expr], [closure_defs~withelse.closure_def])}
 390 !nobra!nopar    | {closure_bra} expr_atom braargs closure_defs~withelse {-> New expr.bra(expr_atom.expr, [braargs.expr], [closure_defs~withelse.closure_def])}
 391         ;
 392
 393 expr~nopar~nobra {-> expr}
 394         = expr_and~nopar~nobra {-> expr_and~nopar~nobra.expr}
 395         | {ifexpr} kwif [n1]:no expr [n2]:no kwthen [n3]:no [then]:expr [n4]:no kwelse [n5]:no [else]:expr~nopar~nobra {-> New expr.ifexpr(kwif, expr, kwthen, then, kwelse, else.expr)}
 396         ;
 397
 398 expr_and~nopar~nobra {-> expr}
 399         = expr_not~nopar~nobra {-> expr_not~nopar~nobra.expr}
 400         | {or} expr_and~nopar~nobra kwor no expr_not~nopar~nobra {-> New expr.or(expr_and~nopar~nobra.expr, expr_not~nopar~nobra.expr)}
 401         | {and} expr_and~nopar~nobra kwand no expr_not~nopar~nobra {-> New expr.and(expr_and~nopar~nobra.expr, expr_not~nopar~nobra.expr)}
 402         ;
 403
 404 expr_not~nopar~nobra {-> expr}
 405         = expr_eq~nopar~nobra {-> expr_eq~nopar~nobra.expr}
 406         | {not} kwnot no expr_not~nopar~nobra {-> New expr.not(kwnot, expr_not~nopar~nobra.expr)}
 407         ;
 408
 409 expr_eq~nopar~nobra {-> expr}
 410         = expr_add~nopar~nobra {-> expr_add~nopar~nobra.expr}
 411         | {eq} expr_add~nopar~nobra eq no [expr2]:expr_add~nopar~nobra {-> New expr.eq(expr_add~nopar~nobra.expr, expr2.expr)}
 412         | {ee} expr_add~nopar~nobra kwis no [expr2]:expr_add~nopar~nobra {-> New expr.ee(expr_add~nopar~nobra.expr, expr2.expr)}
 413         | {ne} expr_add~nopar~nobra ne no [expr2]:expr_add~nopar~nobra {-> New expr.ne(expr_add~nopar~nobra.expr, expr2.expr)}
 414         | {lt} expr_add~nopar~nobra lt no [expr2]:expr_add~nopar~nobra {-> New expr.lt(expr_add~nopar~nobra.expr, expr2.expr)}
 415         | {le} expr_add~nopar~nobra le no [expr2]:expr_add~nopar~nobra {-> New expr.le(expr_add~nopar~nobra.expr, expr2.expr)}
 416         | {gt} expr_add~nopar~nobra gt no [expr2]:expr_add~nopar~nobra {-> New expr.gt(expr_add~nopar~nobra.expr, expr2.expr)}
 417         | {ge} expr_add~nopar~nobra ge no [expr2]:expr_add~nopar~nobra {-> New expr.ge(expr_add~nopar~nobra.expr, expr2.expr)}
 418         | {starship} expr_add~nopar~nobra starship no [expr2]:expr_add~nopar~nobra {-> New expr.starship(expr_add~nopar~nobra.expr, expr2.expr)}
 419         | {isa} expr_add~nopar~nobra kwisa no type~nopar~nobra {-> New expr.isa(expr_add~nopar~nobra.expr, type~nopar~nobra.type)}
 420         ;
 421
 422 expr_add~nopar~nobra {-> expr}
 423         =  expr_mul~nopar~nobra {-> expr_mul~nopar~nobra.expr}
 424         | {plus} expr_add~nopar~nobra plus no [expr2]:expr_mul~nopar~nobra {-> New expr.plus(expr_add~nopar~nobra.expr, expr2.expr)}
 425         | {minus} expr_add~nopar~nobra minus no [expr2]:expr_mul~nopar~nobra {-> New expr.minus(expr_add~nopar~nobra.expr, expr2.expr)}
 426         ;
 427
 428 expr_mul~nopar~nobra {-> expr}
 429         = expr_minus~nopar~nobra {-> expr_minus~nopar~nobra.expr}
 430         | {star} expr_mul~nopar~nobra star no [expr2]:expr_minus~nopar~nobra {-> New expr.star(expr_mul~nopar~nobra.expr, expr2.expr)}
 431         | {slash} expr_mul~nopar~nobra slash no [expr2]:expr_minus~nopar~nobra {-> New expr.slash(expr_mul~nopar~nobra.expr, expr2.expr)}
 432         | {percent} expr_mul~nopar~nobra percent no [expr2]:expr_minus~nopar~nobra {-> New expr.percent(expr_mul~nopar~nobra.expr, expr2.expr)}
 433         ;
 434
 435 expr_minus~nopar~nobra {-> expr}
 436         = expr_new~nopar~nobra {-> expr_new~nopar~nobra.expr}
 437         | {minus} minus no expr_minus~nopar~nobra {-> New expr.uminus(minus, expr_minus~nopar~nobra.expr)}
 438         | {once} kwonce no expr_minus~nopar~nobra {-> New expr.once(kwonce, expr_minus~nopar~nobra.expr)}
 439         ;
 440
 441 expr_new~nopar~nobra {-> expr}
 442         = expr_atom~nopar~nobra {-> expr_atom~nopar~nobra.expr}
 443         | {new} kwnew no type~nopar~nobra args {-> New expr.new(kwnew, type~nopar~nobra.type, Null, [args.expr])}
 444         ;
 445
 446 expr_atom~nopar~nobra {-> expr}
 447         = {attr} recv~nopar~nobra attrid {-> New expr.attr(recv~nopar~nobra.expr, attrid)}
 448         | {call} recv~nopar~nobra id args {-> New expr.call(recv~nopar~nobra.expr, id, [args.expr], [])}
 449         | {super} qualified? kwsuper args {-> New expr.super(qualified, kwsuper, [args.expr])}
 450         | {init} recv~nopar~nobra kwinit args {-> New expr.init(recv~nopar~nobra.expr, kwinit, [args.expr])}
 451 !nobra!nopar    | {bra} expr_atom braargs {-> New expr.bra(expr_atom.expr, [braargs.expr], [])}
 452         | {new} kwnew no type~nopar~nobra dot [n2]:no id args {-> New expr.new(kwnew, type~nopar~nobra.type, id, [args.expr])}
 453 !nobra!nopar    | {range} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no cbra {-> New expr.crange(expr, expr2.expr)}
 454 !nobra!nopar    | {orange} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no [cbra]:obra  {-> New expr.orange(expr, expr2.expr)}
 455 !nobra!nopar    | {array} braargs {-> New expr.array([braargs.expr])}
 456         | {self} kwself {-> New expr.self(kwself)}
 457         | {true} kwtrue {-> New expr.true(kwtrue)}
 458         | {false} kwfalse {-> New expr.false(kwfalse)}
 459         | {null} kwnull {-> New expr.null(kwnull)}
 460         | {int} number  {-> New expr.int(number)}
 461         | {float} float  {-> New expr.float(float)}
 462         | {char} char  {-> New expr.char(char)}
 463         | {string} string  {-> New expr.string(string)}
 464         | {superstring} superstring  {-> superstring.expr}
 465 !nopar  | {par} opar expr cpar {-> expr}
 466         | {as_cast} expr_atom~nopar~nobra dot no kwas [n2]:no opar [n3]:no type [n4]:no cpar {-> New expr.as_cast(expr_atom~nopar~nobra.expr, kwas, type)}
 467         ;
 468
 469 superstring {-> expr}
 470         = superstring_start superstring_middle* superstring_end {-> New expr.superstring([superstring_start.expr, superstring_middle.expr, superstring_end.expr])};
 471 superstring_start {-> expr*}
 472         = start_string_p no expr [n2]:no {-> [start_string_p.expr, expr]};
 473 start_string_p {-> expr}
 474         = start_string {-> New expr.start_string(start_string)};
 475 superstring_middle {-> expr*}
 476         = mid_string_p no expr [n2]:no {-> [mid_string_p.expr, expr]};
 477 mid_string_p {-> expr}
 478         = mid_string {-> New expr.mid_string(mid_string)};
 479 superstring_end {-> expr}
 480         = end_string {-> New expr.end_string(end_string)};
 481
 482 /* MISC **********************************************************************/
 483
 484 recv~nopar~nobra {-> expr}
 485         = expr_atom~nopar~nobra dot no {-> expr_atom~nopar~nobra.expr}
 486         | {implicit} {-> New expr.implicit_self()}
 487         ;
 488
 489 args {-> expr*}
 490         = opar no expr [n2]:no args_tail* cpar {-> [expr, args_tail.expr]}
 491         | {emptypar} opar no cpar {-> []}
 492         | {empty} {-> []}
 493         ;
 494 args_nopar {-> expr*}
 495         = opar no expr [n2]:no args_tail* cpar {-> [expr, args_tail.expr]}
 496         | {onearg} expr_nopar {-> [expr_nopar.expr]}
 497         | {emptypar} opar no cpar {-> []}
 498         | {empty} {-> []}
 499         ;
 500 braargs {-> expr*}
 501         = obra no expr [n2]:no args_tail* cbra {-> [expr, args_tail.expr]};
 502 args_tail {-> expr}
 503         = comma no expr [n2]:no {-> expr};
 504 idlist {-> id*}
 505         = {single} id {-> [id]}
 506         | {more} idlist no comma [n2]:no id {-> [idlist.id, id]}
 507         ;
 508
 509 qualified
 510         = {cla} modquad* classquad {-> New qualified([modquad.id], classquad.classid)}
 511         | {mod} modquad+ {-> New qualified([modquad.id], Null)}
 512         ;
 513 modquad {-> id}
 514         = id quad no {-> id};
 515 classquad {-> classid}
 516         = classid quad no {-> classid};
 517
 518 n1      = {a} comment | {b} eol;
 519 n {-> doc?}
 520         = {a} n2? comment+ {-> New doc([comment])}
 521         | {b} n2 {-> Null}
 522         ;
 523 no {-> doc?}
 524         = {empty} {-> Null}
 525         | n {-> n.doc}
 526         ;
 527
 528 n2
 529         = {a} n2? comment+ eol+
 530         | {b} eol+
 531         ;
 532
 533 /*****************************************************************************/
 534 Abstract Syntax Tree
 535 /*****************************************************************************/
 536
 537 module  = packagedecl? [imports]:import* [classdefs]:classdef*;
 538
 539 packagedecl
 540         = doc? kwpackage id;
 541
 542 import  =  visibility kwimport id
 543         | {no} visibility kwimport kwend
 544         ;
 545
 546 visibility
 547         = {public}
 548         | {private} kwprivate
 549         | {protected} kwprotected
 550         | {intrude} kwintrude
 551         ;
 552
 553 classdef = doc? kwredef? visibility classkind [id]:classid? [formaldefs]:formaldef* [superclasses]:superclass* [propdefs]:propdef*
 554         | {top} [propdefs]:propdef*
 555         | {main} [propdefs]:propdef*
 556         ;
 557 classkind
 558         = {concrete} kwclass
 559         | {abstract} kwabstract kwclass
 560         | {interface} kwinterface
 561         | {universal} kwuniversal
 562         ;
 563 formaldef = [id]:classid type?;
 564 superclass = kwspecial type;
 565
 566
 567 propdef = {attr} doc? [readable]:able? [writable]:able? kwredef? visibility kwattr [id]:attrid type? expr?
 568         | {meth} doc? kwredef? visibility methid signature
 569         | {deferred_meth} doc? kwredef? visibility kwmeth methid signature
 570         | {intern_meth} doc? kwredef? visibility kwmeth methid signature
 571         | {extern_meth} doc? kwredef? visibility kwmeth methid signature [extern]:string?
 572         | {concrete_meth} doc? kwredef? visibility kwmeth methid signature [block]:expr?
 573         | {concrete_init} doc? kwredef? visibility kwinit methid? signature [block]:expr?
 574         | {main_meth} kwredef? [block]:expr?
 575         | {type} doc? kwredef? visibility kwtype [id]:classid type
 576         ;
 577
 578 able    = {read} kwredef? kwreadable
 579         | {write} kwredef? kwwritable
 580         ;
 581
 582 methid = {id} id | {plus} plus | {minus} minus | {star} star | {slash} slash | {percent} percent | {eq} eq | {ne} ne | {le} le | {ge} ge | {lt} lt | {gt} gt | {bra} obra cbra | {starship} starship | {assign} id assign | {braassign} obra cbra assign;
 583
 584 signature = [params]:param* type? [closure_decls]:closure_decl*;
 585
 586 param   = id type? dotdotdot?
 587         ;
 588
 589 closure_decl = kwwith kwbreak? id signature expr?
 590         ;
 591
 592 type    = [id]:classid [types]:type*;
 593
 594 expr    = {block} expr*
 595         | {vardecl} kwvar id type? assign? expr?
 596         | {return} kwreturn expr?
 597         | {break} kwbreak expr?
 598         | {abort} kwabort
 599         | {continue} kwcontinue expr?
 600         | {do} kwdo [block]:expr?
 601         | {if} kwif expr [then]:expr? [else]:expr?
 602         | {ifexpr} kwif expr kwthen [then]:expr kwelse [else]:expr
 603         | {while} kwwhile expr kwdo [block]:expr?
 604         | {for} [vardecl]:expr kwdo [block]:expr?
 605         | {for_vardecl} kwfor id expr
 606         | {assert} kwassert id? expr
 607         | {once} kwonce expr
 608         | {send} expr
 609         | {binop} expr [expr2]:expr
 610         | {or} expr [expr2]:expr
 611         | {and} expr [expr2]:expr
 612         | {not} kwnot expr
 613         | {eq} expr [expr2]:expr
 614         | {ee} expr [expr2]:expr
 615         | {ne} expr [expr2]:expr
 616         | {lt} expr [expr2]:expr
 617         | {le} expr [expr2]:expr
 618         | {gt} expr [expr2]:expr
 619         | {ge} expr [expr2]:expr
 620         | {isa} expr type
 621         | {plus} expr [expr2]:expr
 622         | {minus} expr [expr2]:expr
 623         | {starship} expr [expr2]:expr
 624         | {star} expr [expr2]:expr
 625         | {slash} expr [expr2]:expr
 626         | {percent} expr [expr2]:expr
 627         | {uminus} minus expr
 628         | {new} kwnew type id? [args]:expr*
 629         | {attr} expr [id]:attrid
 630         | {attr_assign} expr [id]:attrid assign [value]:expr
 631         | {attr_reassign} expr [id]:attrid assign_op [value]:expr
 632         | {call} expr id [args]:expr* [closure_defs]:closure_def*
 633         | {call_assign} expr id [args]:expr* assign [value]:expr
 634         | {call_reassign} expr id [args]:expr* assign_op [value]:expr
 635         | {super} qualified? kwsuper [args]:expr*
 636         | {init} expr kwinit [args]:expr*
 637         | {bra} expr [args]:expr* [closure_defs]:closure_def*
 638         | {bra_assign} expr [args]:expr* assign [value]:expr
 639         | {bra_reassign} expr [args]:expr* assign_op [value]:expr
 640         | {var} id
 641         | {var_assign} id assign [value]:expr
 642         | {var_reassign} id assign_op [value]:expr
 643         | {range} expr [expr2]:expr
 644         | {crange} expr [expr2]:expr
 645         | {orange} expr [expr2]:expr
 646         | {array} [exprs]:expr*
 647         | {self} kwself
 648         | {implicit_self}
 649         | {true} kwtrue
 650         | {false} kwfalse
 651         | {null} kwnull
 652         | {int} number
 653         | {float} float
 654         | {char} char
 655         | {string} string
 656         | {start_string} [string]:start_string
 657         | {mid_string} [string]:mid_string
 658         | {end_string} [string]:end_string
 659         | {superstring} [exprs]:expr*
 660         | {par} expr
 661         | {as_cast} expr kwas type
 662         ;
 663 assign_op
 664         = {plus} pluseq
 665         | {minus} minuseq
 666         ;
 667
 668 closure_def
 669         = kwwith id* kwdo expr?
 670         ;
 671
 672 qualified = id* classid? ;
 673
 674 doc = comment+;
 675
 676 /*****************************************************************************/
 677