src/ffi/pkgconfig.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2013 Alexis Laferrière <alexis.laf@xymus.net>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Offers the `PkgconfigPhase` to use the external program "pkg-config" in order
  18 # to discover what options to pass to the C or C++ compiler.
  19 module pkgconfig
  20
  21 import c
  22 private import annotation
  23 private import literal
  24
  25 redef class ToolContext
  26         # Detects the `pkgconfig` annotation on the module declaration only
  27         var pkgconfig_phase: Phase = new PkgconfigPhase(self, [literal_phase])
  28 end
  29
  30 # Detects the `pkgconfig` annotation on the module declaration only
  31 private class PkgconfigPhase
  32         super Phase
  33
  34         redef fun process_annotated_node(nmoduledecl, nat)
  35         do
  36                 # Skip if we are not interested
  37                 if nat.name != "pkgconfig" then return
  38
  39                 # Do some validity checks and print errors if the annotation is used incorrectly
  40                 var modelbuilder = toolcontext.modelbuilder
  41
  42                 if not nmoduledecl isa AModuledecl then
  43                         modelbuilder.error(nat, "Syntax Error: only the declaration of modules may use `pkgconfig`.")
  44                         return
  45                 end
  46
  47                 # retrieve module
  48                 var nmodule = nmoduledecl.parent.as(AModule)
  49                 var mmodule = nmodule.mmodule.as(not null)
  50
  51                 # target pkgs
  52                 var pkgs = new Array[String]
  53
  54                 var args = nat.n_args
  55                 if args.is_empty then
  56                         # use module name
  57                         pkgs.add(mmodule.name)
  58                 else
  59                         for arg in args do
  60                                 var pkg = arg.as_string
  61                                 if pkg == null then
  62                                         modelbuilder.error(nat, "Syntax Error: `pkgconfig` expects its arguments to be the name of the package as String literals.")
  63                                         return
  64                                 end
  65
  66                                 pkgs.add(pkg)
  67                         end
  68                 end
  69
  70                 # check availability of pkg-config
  71                 var proc_which = new ProcessReader("which", "pkg-config")
  72                 proc_which.wait
  73                 var status = proc_which.status
  74                 if status != 0 then
  75                         modelbuilder.error(nat, "Error: program `pkg-config` not found, make sure it is installed.")
  76                         return
  77                 end
  78
  79                 for pkg in pkgs do
  80                         var proc_exist = new Process("pkg-config", "--exists", pkg)
  81                         proc_exist.wait
  82                         status = proc_exist.status
  83                         if status == 1 then
  84                                 modelbuilder.error(nat, "Error: dev package for `{pkg}` unknown by `pkg-config`, install it with `apt-get`, `brew` or similar.")
  85                                 continue
  86                         else if status != 0 then
  87                                 modelbuilder.error(nat, "Error: something went wrong calling `pkg-config`, make sure it is correctly installed.")
  88                                 continue
  89                         end
  90
  91                         mmodule.pkgconfigs.add pkg
  92                 end
  93         end
  94 end