lib/standard/math.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2004-2008 Jean Privat <jean@pryen.org>
   4 #
   5 # This file is free software, which comes along with NIT.  This software is
   6 # distributed in the hope that it will be useful, but WITHOUT ANY WARRANTY;
   7 # without  even  the implied warranty of  MERCHANTABILITY or  FITNESS FOR A
   8 # PARTICULAR PURPOSE.  You can modify it is you want,  provided this header
   9 # is kept unaltered, and a notification of the changes is added.
  10 # You  are  allowed  to  redistribute it and sell it, alone or is a part of
  11 # another product.
  12
  13 # Mathematical operations
  14 module math
  15
  16 import kernel
  17 import collection
  18
  19 in "C header" `{
  20 #include <math.h>
  21 `}
  22
  23 redef class Int
  24         # Returns a random `Int` in `[0 .. self[`.
  25         fun rand: Int is extern "kernel_Int_Int_rand_0"
  26
  27         # Returns the result of a binary AND operation on `self` and `i`
  28         #
  29         #    assert 0x10.bin_and(0x01) == 0
  30         fun bin_and(i: Int): Int is extern "kernel_Int_Int_binand_0"
  31
  32         # Returns the result of a binary OR operation on `self` and `i`
  33         #
  34         #    assert 0x10.bin_or(0x01) == 0x11
  35         fun bin_or(i: Int): Int is extern "kernel_Int_Int_binor_0"
  36
  37         # Returns the result of a binary XOR operation on `self` and `i`
  38         #
  39         #    assert 0x101.bin_xor(0x110) == 0x11
  40         fun bin_xor(i: Int): Int is extern "kernel_Int_Int_binxor_0"
  41
  42         # Returns the 1's complement of `self`
  43         #
  44         #    assert 0x2F.bin_not == -48
  45         fun bin_not: Int is extern "kernel_Int_Int_binnot_0"
  46
  47         # Returns the square root of `self`
  48         #
  49         #    assert 16.sqrt == 4
  50         fun sqrt: Int `{ return sqrt(recv); `}
  51
  52         # Returns the greatest common divisor of `self` and `o`
  53         #
  54         #     assert 54.gcd(24)   == 6
  55         #     assert -54.gcd(-24) == 6
  56         #     assert 54.gcd(-24)  == -6
  57         #     assert -54.gcd(24)  == -6
  58         #     assert 12.gcd(6)    == 6
  59         fun gcd(o: Int): Int
  60         do
  61                 if self < 0 then return -(-self).gcd(o)
  62                 if o < 0 then return -(self.gcd(-o))
  63                 if self == 0 or o == self then return o
  64                 if o == 0 then return self
  65                 if self.bin_and(1) == 0 then
  66                         if o.bin_and(1) == 1 then
  67                                 return self.rshift(1).gcd(o)
  68                         else
  69                                 return self.rshift(1).gcd(o.rshift(1)).lshift(1)
  70                         end
  71                 end
  72                 if o.bin_and(1) == 0 then return self.gcd(o.rshift(1))
  73                 if self > o then return (self - o).rshift(1).gcd(o)
  74                 return (o - self).rshift(1).gcd(self)
  75         end
  76
  77         # Is `self` even ?
  78         #
  79         #    assert 12.is_even
  80         fun is_even: Bool do return self % 2 == 0
  81
  82         # Is `self` odd ?
  83         #
  84         #    assert not 13.is_even
  85         fun is_odd: Bool do return not is_even
  86
  87         # Returns the `self` raised to the power of `e`.
  88         #
  89         #    assert 2 ** 3 == 8
  90         fun **(e: Int): Int
  91         do
  92                 return self.to_f.pow(e.to_f).to_i
  93         end
  94
  95         # The factorial of `self` (aka `self!`)
  96         #
  97         # Returns `1 * 2 * 3 * ... * self-1 * self`
  98         #
  99         #    assert 0.factorial == 1  # by convention for an empty product
 100         #    assert 1.factorial == 1
 101         #    assert 4.factorial == 24
 102         #    assert 9.factorial == 362880
 103         fun factorial: Int
 104         do
 105                 assert self >= 0
 106                 var res = 1
 107                 var n = self
 108                 while n > 0 do
 109                         res = res * n
 110                         n -= 1
 111                 end
 112                 return res
 113         end
 114 end
 115
 116 redef class Float
 117         fun sqrt: Float is extern "kernel_Float_Float_sqrt_0"
 118         fun cos: Float is extern "kernel_Float_Float_cos_0"
 119         fun sin: Float is extern "kernel_Float_Float_sin_0"
 120         fun tan: Float is extern "kernel_Float_Float_tan_0"
 121         fun acos: Float is extern "kernel_Float_Float_acos_0"
 122         fun asin: Float is extern "kernel_Float_Float_asin_0"
 123         fun atan: Float is extern "kernel_Float_Float_atan_0"
 124         fun abs: Float `{ return fabs(recv); `}
 125
 126         fun pow(e: Float): Float is extern "kernel_Float_Float_pow_1"
 127         fun log: Float is extern "kernel_Float_Float_log_0"
 128         fun exp: Float is extern "kernel_Float_Float_exp_0"
 129
 130         #     assert 1.1.ceil == 2.0
 131         #     assert 1.9.ceil == 2.0
 132         #     assert 2.0.ceil == 2.0
 133         #     assert (-1.5).ceil == -1.0
 134         fun ceil: Float `{ return ceil(recv); `}
 135
 136         #     assert 1.1.floor == 1.0
 137         #     assert 1.9.floor == 1.0
 138         #     assert 2.0.floor == 2.0
 139         #     assert (-1.5).floor == -2.0
 140         fun floor: Float `{ return floor(recv); `}
 141
 142         # Returns a random `Float` in `[0.0 .. self[`.
 143         fun rand: Float is extern "kernel_Float_Float_rand_0"
 144         fun hypot_with( b : Float ) : Float is extern "hypotf"
 145
 146         fun is_nan: Bool is extern "isnan"
 147
 148         # Is the float an infinite value
 149         # this function returns:
 150         #
 151         #  * 1 if self is positive infinity
 152         #  * -1 if self is negative infinity
 153         #  * 0 otherwise
 154         fun is_inf: Int do
 155                 if is_inf_extern then
 156                         if self < 0.0 then return -1
 157                         return 1
 158                 end
 159                 return 0
 160         end
 161
 162         private fun is_inf_extern: Bool is extern "isinf"
 163 end
 164
 165 redef class Collection[ E ]
 166         # Return a random element form the collection
 167         # There must be at least one element in the collection
 168         fun rand: E
 169         do
 170                 if is_empty then abort
 171                 var rand_index = length.rand
 172
 173                 for e in self do
 174                         if rand_index == 0 then return e
 175                         rand_index -= 1
 176                 end
 177                 abort
 178         end
 179 end
 180
 181 redef class Sys
 182         init
 183         do
 184                 srand
 185         end
 186 end
 187
 188 fun atan2(x: Float, y: Float): Float is extern "kernel_Any_Any_atan2_2"
 189 fun pi: Float is extern "kernel_Any_Any_pi_0"
 190 fun srand_from(x: Int) is extern "kernel_Any_Any_srand_from_1"
 191 fun srand is extern "kernel_Any_Any_srand_0"