src/parser/nit.sablecc3xx

   1
   2 /* This file is part of NIT ( http://www.nitlanguage.org ).
   3  *
   4  * Copyright 2008-2009 Jean Privat <jean@pryen.org>
   5  *
   6  * Licensed under the Apache License, Version 2.0 (the "License");
   7  * you may not use this file except in compliance with the License.
   8  * You may obtain a copy of the License at
   9  *
  10  *     http://www.apache.org/licenses/LICENSE-2.0
  11  *
  12  * Unless required by applicable law or agreed to in writing, software
  13  * distributed under the License is distributed on an "AS IS" BASIS,
  14  * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15  * See the License for the specific language governing permissions and
  16  * limitations under the License.
  17  */
  18
  19 /* This grammar defines the NIT language. */
  20 Package org.nitlanguage.gen;
  21
  22 /*****************************************************************************/
  23 Helpers
  24 /*****************************************************************************/
  25
  26 all = [0 .. 0xFF];
  27 lowercase = ['a' .. 'z'];
  28 uppercase = ['A' .. 'Z'];
  29 digit = ['0' .. '9'];
  30 letter = lowercase | uppercase | digit | '_';
  31
  32 tab = 9;
  33 cr = 13;
  34 lf = 10;
  35 any = [all - [cr + lf]];
  36 eol_helper = cr lf | cr | lf; // This takes care of different platforms
  37
  38 // characers inside strings and super-strings (atomaton powaa)
  39 str_char
  40         = [any - [['"' + '{'] + '\']]
  41         | '\' any
  42         ;
  43 str_body = str_char*;
  44
  45 sstr_char
  46         = [any - [''' + '\']]
  47         | '\' any
  48         ;
  49
  50 sstr_body = sstr_char*;
  51
  52 long_str_char = str_char | cr | lf;
  53
  54 long_str_part
  55         = long_str_char
  56         | '"' long_str_char
  57         | '"' '"' long_str_char
  58         | '{' long_str_char
  59         | '{' '{' long_str_char
  60         ;
  61
  62 long_str_body = long_str_part*;
  63
  64 long_sstr_char = sstr_char | cr | lf;
  65 long_sstr_part
  66         = long_sstr_char
  67         | ''' long_sstr_char
  68         | ''' ''' long_sstr_char
  69         ;
  70
  71 long_sstr_body = long_sstr_part*;
  72
  73
  74 extern_code_char
  75         = [all - ['`' + '\']]
  76         | '\' all
  77         ;
  78 extern_code_body = extern_code_char*;
  79
  80 /*****************************************************************************/
  81 States
  82 /*****************************************************************************/
  83 initial;
  84
  85
  86 /*****************************************************************************/
  87 Tokens
  88 /*****************************************************************************/
  89
  90 blank = (' ' | tab)+;
  91
  92 eol = eol_helper;
  93 comment = '#' any* eol_helper?;
  94
  95 kwmodule = 'package'|'module';
  96 kwimport = 'import';
  97 kwclass = 'class';
  98 kwabstract = 'abstract';
  99 kwinterface = 'interface';
 100 kwenum = 'universal'|'enum';
 101 kwend = 'end';
 102 kwmeth = 'fun';
 103 kwtype = 'type';
 104 kwinit = 'init';
 105 kwredef = 'redef';
 106 kwis = 'is';
 107 kwdo = 'do';
 108 kwreadable = 'readable';
 109 kwwritable = 'writable';
 110 kwvar = 'var';
 111 kwintern = 'intern';
 112 kwextern = 'extern';
 113 kwprotected = 'protected';
 114 kwprivate = 'private';
 115 kwintrude = 'intrude';
 116 kwif = 'if';
 117 kwthen = 'then';
 118 kwelse = 'else';
 119 kwwhile = 'while';
 120 kwloop = 'loop';
 121 kwfor = 'for';
 122 kwin = 'in';
 123 kwand = 'and';
 124 kwor = 'or';
 125 kwnot = 'not';
 126 kwreturn = 'return';
 127 kwcontinue = 'continue';
 128 kwbreak = 'break';
 129 kwabort = 'abort';
 130 kwassert = 'assert';
 131 kwnew = 'new';
 132 kwisa = 'isa';
 133 kwonce = 'once';
 134 kwsuper = 'super';
 135 kwself = 'self';
 136 kwtrue = 'true';
 137 kwfalse = 'false';
 138 kwnull = 'null';
 139 kwas = 'as';
 140 kwnullable = 'nullable';
 141 kwisset = 'isset';
 142 kwlabel = 'label';
 143 kwdebug = '__debug__';
 144
 145 opar = '(';
 146 cpar = ')';
 147 obra = '[';
 148 cbra = ']';
 149 comma = ',';
 150 column = ':';
 151 quad = '::';
 152 assign = '=';
 153 pluseq = '+=';
 154 minuseq = '-=';
 155 dotdotdot = '...';
 156 dotdot = '..';
 157 dot = '.';
 158 plus = '+';
 159 minus = '-';
 160 star = '*';
 161 slash = '/';
 162 percent = '%';
 163 eq = '==';
 164 ne = '!=';
 165 lt = '<';
 166 le = '<=';
 167 ll = '<<';
 168 gt = '>';
 169 ge = '>=';
 170 gg = '>>';
 171 starship = '<=>';
 172 bang='!';
 173
 174 classid = uppercase letter*;
 175 id = lowercase letter*;
 176 attrid = '_' lowercase letter*;
 177
 178 number = digit+;
 179 float = digit* '.' digit+;
 180 string = '"' str_body '"' | '"' '"' '"' long_str_body '"' '"' '"' | ''' ''' ''' long_sstr_body ''' ''' ''';
 181 start_string = '"' str_body '{' | '"' '"' '"' long_str_body '{' '{' '{';
 182 mid_string = '}' str_body '{' | '}' '}' '}' long_str_body '{' '{' '{';
 183 end_string = '}' str_body '"' | '}' '}' '}' long_str_body '"' '"' '"';
 184 char = (''' [[any - '''] - '\'] ''') | (''' '\' any ''');
 185 bad_string = ('"'|'}') str_body | '"' '"' '"' long_str_body | ''' ''' ''' long_sstr_body;
 186 bad_char = ''' '\'? any;
 187
 188 extern_code_segment = '`' '{' extern_code_body '`' '}';
 189
 190 /*****************************************************************************/
 191 Ignored Tokens
 192 /*****************************************************************************/
 193
 194 blank;
 195
 196 /*****************************************************************************/
 197 Productions
 198 /*****************************************************************************/
 199
 200 /* MODULES *******************************************************************/
 201 module
 202         = moduledecl? [imports]:import* [extern_bodies]:extern_code_body* [classdefs]:classdef* implicit_top_class? implicit_main_class? {-> New module(moduledecl, [imports.import], [extern_bodies.extern_code_block], [classdefs.classdef,implicit_top_class.classdef,implicit_main_class.classdef])};
 203
 204 moduledecl
 205         = [doc]:no kwmodule no module_name [n2]:n1 {-> New moduledecl(doc.doc, kwmodule, module_name)};
 206
 207 import
 208         = {std} [doc]:no visibility kwimport no module_name [n2]:n1 {-> New import.std(visibility, kwimport, module_name)}
 209         | {no} [doc]:no visibility kwimport no kwend [n2]:n1 {-> New import.no(visibility, kwimport, kwend)}
 210         ;
 211
 212 implicit_top_class {-> classdef}
 213         = propdefs_toplevel+ {-> New classdef.top([propdefs_toplevel.propdef])};
 214
 215 implicit_main_class {-> classdef?}
 216         = implicit_main_meth {-> New classdef.main([implicit_main_meth.propdef])}
 217         | {null} n {-> Null}
 218         ;
 219 implicit_main_meth {-> propdef}
 220         = [doc]:no stmts {-> New propdef.main_meth(Null, stmts.expr)}
 221         | {n} [doc]:no stmtsn {-> New propdef.main_meth(Null, stmtsn.expr)}
 222         ;
 223
 224 /* CLASSES *******************************************************************/
 225 classdef
 226         = [doc]:no redef visibility classkind no classid formaldefs? extern_code_block? [superclasses]:superclass* propdefs* [n2]:no kwend {-> New classdef.std(doc.doc, redef.kwredef, visibility, classkind, classid, [formaldefs.formaldef], extern_code_block, [superclasses.superclass], [propdefs.propdef], kwend)};
 227 redef {-> kwredef?}
 228         = kwredef? {-> kwredef};
 229 classkind
 230         = {concrete} kwclass
 231         | {abstract} kwabstract kwclass
 232         | {interface} kwinterface
 233         | {enum} kwenum
 234         | {extern} kwextern kwclass?
 235         ;
 236
 237 formaldefs {-> formaldef*}
 238         = obra no formaldef formaldefs_tail* [n2]:no cbra {-> [formaldef, formaldefs_tail.formaldef]};
 239 formaldefs_tail {-> formaldef}
 240         = comma no formaldef {-> formaldef};
 241 formaldef
 242         = classid typing? {-> New formaldef(classid, typing.type)};
 243
 244 superclass {-> superclass}
 245         = {super} no kwsuper [n2]:no type {-> New superclass(kwsuper, type)}
 246         ;
 247
 248 propdefs~toplevel {-> propdef}
 249         = propdef~toplevel n1 {-> propdef~toplevel.propdef}
 250         ;
 251 propdef~toplevel {-> propdef}
 252         = {meth} [doc]:no redef visibility kwmeth methid signature kwdo stmtso kwend? {-> New propdef.concrete_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature, stmtso.expr)}
 253         | {assign_return} [doc]:no redef visibility kwmeth methid signature_withret assign no assign_return {-> New propdef.concrete_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature_withret.signature, assign_return.expr)}
 254 !toplevel| {deferred} [doc]:no redef visibility kwmeth methid signature kwis kwabstract {-> New propdef.deferred_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature)}
 255 !toplevel| {intern} [doc]:no redef visibility kwmeth methid signature kwis kwintern {-> New propdef.intern_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature)}
 256         | {extern} [doc]:no redef visibility kwmeth methid signature kwis kwextern string? extern_calls? extern_code_block? {-> New propdef.extern_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature, string, extern_calls, extern_code_block)}
 257         | {extern_implicit} [doc]:no redef visibility kwmeth methid signature extern_calls? extern_code_block {-> New propdef.extern_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature, Null, extern_calls, extern_code_block)}
 258 !toplevel| {var} [doc]:no readable? writable? redef visibility kwvar attrid typing? {-> New propdef.attr(doc.doc, readable.able, writable.able, redef.kwredef, visibility, kwvar, attrid, Null, typing.type, Null)}
 259 !toplevel| {var2} [doc]:no readable? writable? redef visibility kwvar attrid typing? assign [n2]:no expr {-> New propdef.attr(doc.doc, readable.able, writable.able, redef.kwredef, visibility, kwvar, attrid, Null, typing.type, expr)}
 260 !toplevel| {var3} [doc]:no redef visibility kwvar id typing? writable2? {-> New propdef.attr(doc.doc, Null, writable2.able, redef.kwredef, visibility, kwvar, Null, id, typing.type, Null)}
 261 !toplevel| {var4} [doc]:no redef visibility kwvar id typing? writable2? assign [n2]:no expr {-> New propdef.attr(doc.doc, Null, writable2.able, redef.kwredef, visibility, kwvar, Null, id, typing.type, expr)}
 262 !toplevel| {init} [doc]:no redef visibility kwinit methid? signature kwdo stmtso kwend? {-> New propdef.concrete_init(doc.doc, redef.kwredef, visibility, kwinit, methid, signature, stmtso.expr)}
 263 !toplevel| {type} [doc]:no redef visibility kwtype classid typing {-> New propdef.type(doc.doc, redef.kwredef, visibility, kwtype, classid, typing.type)}
 264 !toplevel| {extern_init} [doc]:no redef visibility kwnew methid? signature kwis kwextern string? extern_calls? extern_code_block? {-> New propdef.extern_init(doc.doc, redef.kwredef, visibility, kwnew, methid, signature, string, extern_calls, extern_code_block)}
 265 !toplevel| {extern_init_implicit} [doc]:no redef visibility kwnew methid? signature string? extern_calls? extern_code_block {-> New propdef.extern_init(doc.doc, redef.kwredef, visibility, kwnew, methid, signature, string, extern_calls, extern_code_block)}
 266         ;
 267 readable {-> able}
 268         = redef kwreadable {-> New able.read(redef.kwredef, kwreadable)}
 269         ;
 270 writable {-> able}
 271         = redef kwwritable {-> New able.write(redef.kwredef, Null, kwwritable)}
 272         ;
 273 writable2 {-> able}
 274         = redef visibility kwwritable {-> New able.write(redef.kwredef, visibility, kwwritable)}
 275         ;
 276
 277 visibility
 278         = {public} {-> New visibility.public()}
 279         | {private} kwprivate no {-> New visibility.private(kwprivate)}
 280         | {protected} kwprotected no {-> New visibility.protected(kwprotected)}
 281         | {intrude} kwintrude no {-> New visibility.intrude(kwintrude)}
 282         ;
 283
 284 methid {-> methid}
 285         = {id} id {-> New methid.id(id)}
 286         | {plus} plus {-> New methid.plus(plus)}
 287         | {minus} minus {-> New methid.minus(minus)}
 288         | {star} star {-> New methid.star(star)}
 289         | {slash} slash {-> New methid.slash(slash)}
 290         | {percent} percent {-> New methid.percent(percent)}
 291         | {eq} eq {-> New methid.eq(eq)}
 292         | {ne} ne {-> New methid.ne(ne)}
 293         | {le} le {-> New methid.le(le)}
 294         | {ge} ge {-> New methid.ge(ge)}
 295         | {lt} lt {-> New methid.lt(lt)}
 296         | {gt} gt {-> New methid.gt(gt)}
 297         | {ll} ll {-> New methid.ll(ll)}
 298         | {gg} gg {-> New methid.gg(gg)}
 299         | {bra} obra cbra {-> New methid.bra(obra, cbra)}
 300         | {starship} starship {-> New methid.starship(starship)}
 301         | {assign} id assign {-> New methid.assign(id, assign)}
 302         | {braassign} obra cbra assign {-> New methid.braassign(obra, cbra, assign)}
 303         ;
 304
 305 signature~withret {-> signature}
 306         = opar no params? cpar typing [no2]:no closure_decls? {-> New signature(opar, [params.param], cpar, typing.type, [closure_decls.closure_decl])}
 307 !withret| {noret} opar no params? cpar [no2]:no closure_decls? {-> New signature(opar, [params.param], cpar, Null, [closure_decls.closure_decl])}
 308         | {nopar} typing no closure_decls? {-> New signature(Null, [], Null, typing.type, [closure_decls.closure_decl])}
 309 !withret| {noparnoret} no closure_decls? {-> New signature(Null, [], Null, Null, [closure_decls.closure_decl])}
 310         ;
 311
 312 signature_noclosures {-> signature}
 313         = opar no params? cpar typing? {-> New signature(opar, [params.param], cpar, typing.type, [])}
 314         | {nopar} typing? {-> New signature(Null, [], Null, typing.type, [])}
 315         ;
 316
 317 params {-> param*}
 318         = param params_tail* [n2]:no {-> [param, params_tail.param] }
 319         ;
 320 params_tail {-> param}
 321         = comma no param {-> param};
 322 param
 323         = {untyped} id {-> New param(id, Null, Null)}
 324         | id typing dotdotdot? {-> New param(id, typing.type, dotdotdot)}
 325         ;
 326
 327 closure_decls {->closure_decl*}
 328         = closure_decl+ {-> [closure_decl]};
 329 closure_decl
 330         = kwbreak? bang id signature_noclosures n {-> New closure_decl(kwbreak, bang, id, signature_noclosures.signature, Null)}
 331         | {optionnal} kwbreak? bang id signature_noclosures kwdo stmtso n {-> New closure_decl(kwbreak, bang, id, signature_noclosures.signature, stmtso.expr)}
 332         | {assign} kwbreak? bang id signature_noclosures assign no assign_continue n {-> New closure_decl(kwbreak, bang, id, signature_noclosures.signature, assign_continue.expr)}
 333         ;
 334
 335 assign_return{-> expr}
 336         = expr_final {-> New expr.return(Null, expr_final.expr)}
 337         ;
 338
 339 extern_calls {-> extern_calls}
 340         = kwimport no extern_call extern_call_tail* {-> New extern_calls( kwimport, [extern_call, extern_call_tail.extern_call] )}
 341         ;
 342 extern_call_tail {-> extern_call}
 343         = comma no extern_call {-> extern_call};
 344 extern_call {-> extern_call}
 345     = {prop} extern_call_prop {-> extern_call_prop.extern_call}
 346     | {cast} extern_call_cast {-> extern_call_cast.extern_call}
 347         | {super} kwsuper {-> New extern_call.super( kwsuper )}
 348     ;
 349 extern_call_prop {-> extern_call}
 350     = {local} methid {-> New extern_call.local_prop( methid )}
 351         | {full} classid quad methid {-> New extern_call.full_prop( classid, quad, methid )}
 352         | {init} classid {-> New extern_call.init_prop( classid )}
 353         ;
 354 extern_call_cast {-> extern_call}
 355     = {as_cast} [from_type]:type kwas [n2]:no opar [n3]:no [to_type]:type [n4]:no cpar {-> New extern_call.cast_as(from_type, kwas, to_type)}
 356         | {as_nullable} type kwas [n2]:no kwnullable {-> New extern_call.as_nullable( type, kwas, kwnullable)}
 357         | {as_not_nullable} type kwas [n2]:no kwnot [n3]:no kwnullable {-> New extern_call.as_not_nullable( type, kwas, kwnot, kwnullable)}
 358         ;
 359
 360 in_language = kwin string;
 361 extern_code_block = in_language? extern_code_segment;
 362 extern_code_body {-> extern_code_block} = no extern_code_block {-> extern_code_block};
 363
 364 /* TYPES *********************************************************************/
 365 type~nobra {-> type}
 366         = {simple} kwnullable? classid {-> New type(kwnullable, classid, [])}
 367 !nobra  | {generic} kwnullable? classid obra no types [n2]:no cbra {-> New type(kwnullable, classid, [types.type])}
 368         ;
 369 types {-> type*}
 370         = type types_tail* {-> [type, types_tail.type]};
 371 types_tail {-> type}
 372         = comma no type {-> type};
 373 typing {-> type}
 374         = column no type {-> type};
 375
 376 /* STATMENTS *****************************************************************/
 377 stmtso~withelse~withend {-> expr?}
 378         = {block} n stmtsnend {-> stmtsnend.expr}
 379         | {emptyblock} n kwend {-> New expr.block([], kwend)}
 380         | {emptyoneline} kwend {-> New expr.block([], kwend)}
 381 !withend| {oneline} stmt~withelse {-> stmt~withelse.expr}
 382         ;
 383 stmts {-> expr}
 384         = stmt stmts_tail* {-> New expr.block([stmt.expr, stmts_tail.expr], Null)};
 385 stmtsn {-> expr}
 386         = stmt stmts_tail* n {-> New expr.block([stmt.expr, stmts_tail.expr], Null)};
 387 stmtsnend {-> expr}
 388         = stmt stmts_tail* n kwend {-> New expr.block([stmt.expr, stmts_tail.expr], kwend)};
 389 stmts_tail {-> expr}
 390         = n stmt {-> stmt.expr};
 391 stmt~withelse {-> expr}
 392         = {vardecl} vardecl~withelse {-> vardecl~withelse.expr}
 393         | {assign} assignment~withelse {-> assignment~withelse.expr}
 394         | {return} kwreturn expr_final~withelse? {-> New expr.return(kwreturn, expr_final~withelse.expr)}
 395         | {break} kwbreak label? expr_final~withelse? {-> New expr.break(kwbreak, label, expr_final~withelse.expr)}
 396         | {abort} kwabort {-> New expr.abort(kwabort)}
 397         | {continue} kwcontinue label? expr_final~withelse? {-> New expr.continue(kwcontinue, label, expr_final~withelse.expr)}
 398         | {do} do~withelse {-> do~withelse.expr}
 399         | {if} if~withelse {-> if~withelse.expr}
 400         | {while} while~withelse {-> while~withelse.expr}
 401         | {loop} loop~withelse {-> loop~withelse.expr}
 402         | {for} for~withelse {-> for~withelse.expr}
 403         | {assert} assert~withelse {-> assert~withelse.expr}
 404         | {call} recv id args_nopar closure_defs~withelse? {-> New expr.call(recv.expr, id, args_nopar.exprs, [closure_defs~withelse.closure_def])}
 405         | {super} qualified? kwsuper args_nopar {-> New expr.super(qualified, kwsuper, args_nopar.exprs)}
 406         | {init} recv kwinit args_nopar {-> New expr.init(recv.expr, kwinit, args_nopar.exprs)}
 407         | {debug_type_is} kwdebug kwtype type column expr_final~withelse {-> New expr.debug_type(kwdebug, kwtype, expr_final~withelse.expr, type) }
 408         ;
 409
 410 label= kwlabel id;
 411
 412 closure_defs~withelse {-> closure_def*}
 413         = {one} closure_def_last~withelse {-> [closure_def_last~withelse.closure_def]}
 414         | closure_def closure_defs~withelse {-> [closure_def, closure_defs~withelse.closure_def]}
 415         ;
 416
 417 closure_def_last~withelse {-> closure_def}
 418         = bang [id]:closure_id idlist? kwdo stmtso_withend label {-> New closure_def(bang, id, [idlist.id], kwdo, stmtso_withend.expr, label)}
 419         | {nolabel} bang [id]:closure_id idlist? kwdo stmtso~withelse {-> New closure_def(bang, id, [idlist.id], kwdo, stmtso~withelse.expr, Null)}
 420         | {assign} bang [id]:closure_id idlist? assign no assign_continue~withelse {-> New closure_def(bang, id, [idlist.id], Null, assign_continue~withelse.expr, Null)}
 421         ;
 422
 423 closure_def {-> closure_def}
 424         = bang [id]:closure_id idlist? kwdo n stmtsn {-> New closure_def(bang, id, [idlist.id], kwdo, stmtsn.expr, Null)}
 425         | {empty} bang [id]:closure_id idlist? kwdo n {-> New closure_def(bang, id, [idlist.id], kwdo, Null, Null)}
 426         ;
 427 closure_id
 428         = {simple} id
 429         | {break} kwbreak
 430         ;
 431
 432 assign_continue~withelse{-> expr}
 433         = expr_final~withelse {-> New expr.continue(Null, Null, expr_final~withelse.expr)}
 434         ;
 435
 436 vardecl~withelse{-> expr}
 437         = kwvar id typing? {-> New expr.vardecl(kwvar, id, typing.type, Null, Null)}
 438         | {assign} kwvar id typing? assign no expr_final~withelse {-> New expr.vardecl(kwvar, id, typing.type, assign, expr_final~withelse.expr)}
 439         ;
 440
 441 assignment~withelse {-> expr}
 442         = {attr} recv attrid assign expr_final~withelse {-> New expr.attr_assign(recv.expr, attrid, assign, expr_final~withelse.expr)}
 443         | {call} recv id args assign expr_final~withelse {-> New expr.call_assign(recv.expr, id, args.exprs, assign,  expr_final~withelse.expr)}
 444         | {bra} expr_atom braargs assign expr_final~withelse {-> New expr.bra_assign(expr_atom.expr, braargs.exprs, assign,  expr_final~withelse.expr)}
 445         | {attr_re} recv attrid assign_op expr_final~withelse {-> New expr.attr_reassign(recv.expr, attrid, assign_op,  expr_final~withelse.expr)}
 446         | {call_re} recv id args assign_op expr_final~withelse {-> New expr.call_reassign(recv.expr, id, args.exprs, assign_op,  expr_final~withelse.expr)}
 447         | {bra_re} expr_atom braargs assign_op expr_final~withelse {-> New expr.bra_reassign(expr_atom.expr, braargs.exprs, assign_op,  expr_final~withelse.expr)}
 448         ;
 449 assign_op
 450         = {plus} pluseq
 451         | {minus} minuseq
 452         ;
 453
 454 do~withelse {-> expr}
 455         = kwdo stmtso_withend label {-> New expr.do(kwdo, stmtso_withend.expr, label)}
 456         | {nolabel} kwdo stmtso~withelse {-> New expr.do(kwdo, stmtso~withelse.expr, Null)}
 457         ;
 458
 459 if~withelse {-> expr}
 460         = {onelineelse} kwif no expr [n2]:no kwthen stmt_withelse kwelse stmtso~withelse {-> New expr.if(kwif, expr, stmt_withelse.expr, stmtso~withelse.expr)}
 461 !withelse       | {oneline} kwif no expr [n2]:no kwthen stmt {-> New expr.if(kwif, expr, stmt.expr, Null)}
 462 !withelse       | {block} kwif no expr [n2]:no kwthen [n3]:n stmtsn elsepartblock {-> New expr.if(kwif, expr, stmtsn.expr, elsepartblock.expr)}
 463 !withelse       | {emptyblock} kwif no expr [n2]:no kwthen [n3]:n? elsepartblock {-> New expr.if(kwif, expr, Null, elsepartblock.expr)}
 464         ;
 465 elsepartblock {-> expr?}
 466         = {else} kwelse stmtso {-> stmtso.expr}
 467         | {empty} kwend {-> New expr.block([], kwend)}
 468         ;
 469
 470 loop~withelse {-> expr}
 471         = kwloop stmtso_withend label {-> New expr.loop(kwloop, stmtso_withend.expr, label)}
 472         | {nolabel} kwloop stmtso~withelse {-> New expr.loop(kwloop, stmtso~withelse.expr, Null)}
 473         ;
 474
 475 while~withelse {-> expr}
 476         = kwwhile no expr [n2]:no kwdo stmtso_withend label {-> New expr.while(kwwhile, expr, kwdo, stmtso_withend.expr, label)}
 477         | {nolabel} kwwhile no expr [n2]:no kwdo stmtso~withelse {-> New expr.while(kwwhile, expr, kwdo, stmtso~withelse.expr, Null)}
 478         ;
 479
 480 for~withelse {-> expr}
 481         = kwfor no [ids]:idlist [n2]:no kwin [n3]:no expr [n4]:no kwdo stmtso_withend label {-> New expr.for(kwfor, [ids.id], expr, kwdo, stmtso_withend.expr, label)}
 482         | {nolabel} kwfor no [ids]:idlist [n2]:no kwin [n3]:no expr [n4]:no kwdo stmtso~withelse {-> New expr.for(kwfor, [ids.id], expr, kwdo, stmtso~withelse.expr, Null)}
 483         ;
 484
 485 assert~withelse {-> expr}
 486         = {else} kwassert assertid? expr_final_withelse kwelse stmtso~withelse {-> New expr.assert(kwassert, assertid.id, expr_final_withelse.expr, stmtso~withelse.expr)}
 487 !withelse| {noelse} kwassert assertid? expr_final {-> New expr.assert(kwassert, assertid.id, expr_final.expr, Null)}
 488         ;
 489 assertid {-> id}
 490         = id column {-> id};
 491
 492 /* EXPRESSIONS ***************************************************************/
 493 expr_final~nopar~withelse~nobra {-> expr}
 494         = expr~nopar~nobra {-> expr~nopar~nobra.expr}
 495         | {closure_call} recv~nobra id args closure_defs~withelse {-> New expr.call(recv~nobra.expr, id, args.exprs, [closure_defs~withelse.closure_def])}
 496 !nobra!nopar    | {closure_bra} expr_atom braargs closure_defs~withelse {-> New expr.bra(expr_atom.expr, braargs.exprs, [closure_defs~withelse.closure_def])}
 497         ;
 498
 499 expr~nopar~nobra {-> expr}
 500         = expr_and~nopar~nobra {-> expr_and~nopar~nobra.expr}
 501         | {ifexpr} kwif [n1]:no expr [n2]:no kwthen [n3]:no [then]:expr [n4]:no kwelse [n5]:no [else]:expr~nopar~nobra {-> New expr.ifexpr(kwif, expr, kwthen, then, kwelse, else.expr)}
 502         ;
 503
 504 expr_and~nopar~nobra {-> expr}
 505         = expr_not~nopar~nobra {-> expr_not~nopar~nobra.expr}
 506         | {:or} expr_and~nopar~nobra :kwor :no expr_not~nopar~nobra
 507         | {:and} expr_and~nopar~nobra :kwand :no expr_not~nopar~nobra
 508         | {:or_else} expr_and~nopar~nobra :kwor :kwelse :no expr_not~nopar~nobra
 509         ;
 510
 511 expr_not~nopar~nobra {-> expr}
 512         = expr_eq~nopar~nobra {-> expr_eq~nopar~nobra.expr}
 513         | {not} kwnot no expr_not~nopar~nobra {-> New expr.not(kwnot, expr_not~nopar~nobra.expr)}
 514         ;
 515
 516 expr_eq~nopar~nobra {-> expr}
 517         = expr_add~nopar~nobra {-> expr_add~nopar~nobra.expr}
 518         | {:eq} expr_add~nopar~nobra :eq :no [expr2]:expr_add~nopar~nobra
 519         | {:ee} expr_add~nopar~nobra :kwis :no [expr2]:expr_add~nopar~nobra
 520         | {:ne} expr_add~nopar~nobra :ne :no [expr2]:expr_add~nopar~nobra
 521         | {:lt} expr_add~nopar~nobra :lt :no [expr2]:expr_add~nopar~nobra
 522         | {:le} expr_add~nopar~nobra :le :no [expr2]:expr_add~nopar~nobra
 523         | {:ll} expr_eq~nopar~nobra :ll :no [expr2]:expr_add~nopar~nobra
 524         | {:gt} expr_add~nopar~nobra :gt :no [expr2]:expr_add~nopar~nobra
 525         | {:ge} expr_add~nopar~nobra :ge :no [expr2]:expr_add~nopar~nobra
 526         | {:gg} expr_eq~nopar~nobra :gg :no [expr2]:expr_add~nopar~nobra
 527         | {:starship} expr_add~nopar~nobra :starship :no [expr2]:expr_add~nopar~nobra
 528         | {:isa} expr_add~nopar~nobra :kwisa :no type~nobra
 529         ;
 530
 531 expr_add~nopar~nobra {-> expr}
 532         =  expr_mul~nopar~nobra {-> expr_mul~nopar~nobra.expr}
 533         | {:plus} expr_add~nopar~nobra :plus :no [expr2]:expr_mul~nopar~nobra
 534         | {:minus} expr_add~nopar~nobra :minus :no [expr2]:expr_mul~nopar~nobra
 535         ;
 536
 537 expr_mul~nopar~nobra {-> expr}
 538         = expr_minus~nopar~nobra {-> expr_minus~nopar~nobra.expr}
 539         | {:star} expr_mul~nopar~nobra :star :no [expr2]:expr_minus~nopar~nobra
 540         | {:slash} expr_mul~nopar~nobra :slash :no [expr2]:expr_minus~nopar~nobra
 541         | {:percent} expr_mul~nopar~nobra :percent :no [expr2]:expr_minus~nopar~nobra
 542         ;
 543
 544 expr_minus~nopar~nobra {-> expr}
 545         = expr_new~nopar~nobra {-> expr_new~nopar~nobra.expr}
 546         | {:uminus} minus :no expr_minus~nopar~nobra
 547         | {:once} kwonce :no expr_minus~nopar~nobra
 548         ;
 549
 550 expr_new~nopar~nobra {-> expr}
 551         = expr_atom~nopar~nobra {-> expr_atom~nopar~nobra.expr}
 552         | {new} kwnew no type~nobra args {-> New expr.new(kwnew, type~nobra.type, Null, args.exprs)}
 553         | {isset_attr} kwisset recv~nopar~nobra attrid {-> New expr.isset_attr(kwisset, recv~nopar~nobra.expr, attrid)}
 554         ;
 555
 556 expr_atom~nopar~nobra {-> expr}
 557         = {attr} recv~nopar~nobra attrid {-> New expr.attr(recv~nopar~nobra.expr, attrid)}
 558         | {call} recv~nopar~nobra id args {-> New expr.call(recv~nopar~nobra.expr, id, args.exprs, [])}
 559         | {super} qualified? kwsuper args {-> New expr.super(qualified, kwsuper, args.exprs)}
 560         | {init} recv~nopar~nobra kwinit args {-> New expr.init(recv~nopar~nobra.expr, kwinit, args.exprs)}
 561 !nobra  | {bra} expr_atom~nopar braargs {-> New expr.bra(expr_atom~nopar.expr, braargs.exprs, [])}
 562         | {new} kwnew no type~nobra dot [n2]:no id args {-> New expr.new(kwnew, type~nobra.type, id, args.exprs)}
 563 // !nopar to unambiguise 'foo[5].bar' between '(foo[5]).bar' and 'foo([5].bar),
 564 !nobra!nopar    | {range} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no cbra {-> New expr.crange(obra, expr, expr2.expr, cbra)}
 565 !nobra!nopar    | {orange} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no [cbra]:obra  {-> New expr.orange(obra, expr, expr2.expr, cbra)}
 566 !nobra!nopar    | {array} braargs {-> New expr.array(braargs.exprs)}
 567         | {:self} kwself
 568         | {:true} kwtrue
 569         | {:false} kwfalse
 570         | {:null} kwnull
 571         | {:int} number
 572         | {:float} float
 573         | {:char} char
 574         | {:string} string
 575         | {superstring} superstring  {-> superstring.expr}
 576 !nopar  | {par} opar expr cpar {-> New expr.par(opar, expr, cpar)}
 577         | {as_cast} expr_atom~nopar~nobra dot no kwas [n2]:no opar [n3]:no type [n4]:no cpar {-> New expr.as_cast(expr_atom~nopar~nobra.expr, kwas, opar, type, cpar)}
 578         | {as_notnull} expr_atom~nopar~nobra dot no kwas [n2]:no opar [n3]:no kwnot [n4]:no kwnull [n5]:no cpar {-> New expr.as_notnull(expr_atom~nopar~nobra.expr, kwas, opar, kwnot, kwnull, cpar)}
 579         ;
 580
 581 superstring {-> expr}
 582         = superstring_start superstring_middle* superstring_end {-> New expr.superstring([superstring_start.expr, superstring_middle.expr, superstring_end.expr])};
 583 superstring_start {-> expr*}
 584         = start_string_p no expr [n2]:no {-> [start_string_p.expr, expr]};
 585 start_string_p {-> expr}
 586         = start_string {-> New expr.start_string(start_string)};
 587 superstring_middle {-> expr*}
 588         = mid_string_p no expr [n2]:no {-> [mid_string_p.expr, expr]};
 589 mid_string_p {-> expr}
 590         = mid_string {-> New expr.mid_string(mid_string)};
 591 superstring_end {-> expr}
 592         = end_string {-> New expr.end_string(end_string)};
 593
 594 /* MISC **********************************************************************/
 595
 596 recv~nopar~nobra {-> expr}
 597         = expr_atom~nopar~nobra dot no {-> expr_atom~nopar~nobra.expr}
 598         | {implicit} {-> New expr.implicit_self()}
 599         ;
 600
 601 args {-> exprs}
 602         = opar no expr_list cpar {-> New exprs.par(opar, [expr_list.expr], cpar) }
 603         | {emptypar} opar no cpar {-> New exprs.par(opar, [], cpar) }
 604         | {empty} {-> New exprs.list([])}
 605         ;
 606 args_nopar {-> exprs}
 607         = opar no expr_list cpar {-> New exprs.par(opar, [expr_list.expr], cpar) }
 608         | {onearg} expr_nopar {-> New exprs.list([expr_nopar.expr])}
 609         | {emptypar} opar no cpar {-> New exprs.par(opar, [], cpar) }
 610         | {empty} {-> New exprs.list([])}
 611         ;
 612 braargs {-> exprs}
 613         = obra no expr_list cbra {-> New exprs.bra(obra, [expr_list.expr], cbra)};
 614 expr_list {-> expr*}
 615         = expr [n2]:no expr_tail* {-> [expr, expr_tail.expr]};
 616 expr_tail {-> expr}
 617         = comma no expr [n2]:no {-> expr};
 618 idlist {-> id*}
 619         = opar idlist_nopar cpar {-> [idlist_nopar.id]}
 620         | {nopar} idlist_nopar {-> [idlist_nopar.id]}
 621         ;
 622 idlist_nopar {-> id*}
 623         = {single} id {-> [id]}
 624         | {more} idlist_nopar no comma [n2]:no id {-> [idlist_nopar.id, id]}
 625         ;
 626
 627 module_name {-> module_name}
 628         = {mod} modquad* id {-> New module_name(Null, [modquad.id], id)}
 629         | {root} quad no modquad* id {-> New module_name(quad, [modquad.id], id)}
 630         ;
 631
 632 qualified
 633         = {cla} modquad* classquad {-> New qualified([modquad.id], classquad.classid)}
 634         | {mod} modquad+ {-> New qualified([modquad.id], Null)}
 635         ;
 636 modquad {-> id}
 637         = id quad no {-> id};
 638 classquad {-> classid}
 639         = classid quad no {-> classid};
 640
 641 n1      = {a} comment | {b} eol;
 642 n {-> doc?}
 643         = {a} n2? comment+ {-> New doc([comment])}
 644         | {b} n2 {-> Null}
 645         ;
 646 no {-> doc?}
 647         = {empty} {-> Null}
 648         | n {-> n.doc}
 649         ;
 650
 651 n2
 652         = {a} n2? comment+ eol+
 653         | {b} eol+
 654         ;
 655
 656 /*****************************************************************************/
 657 Abstract Syntax Tree
 658 /*****************************************************************************/
 659
 660 module  = moduledecl? [imports]:import* [extern_code_blocks]:extern_code_block* [classdefs]:classdef*;
 661
 662 moduledecl
 663         = doc? kwmodule [name]:module_name;
 664
 665 import  = {std} visibility kwimport [name]:module_name
 666         | {no} visibility kwimport kwend
 667         ;
 668
 669 visibility
 670         = {public}
 671         | {private} kwprivate
 672         | {protected} kwprotected
 673         | {intrude} kwintrude
 674         ;
 675
 676 classdef= {std} doc? kwredef? visibility classkind [id]:classid? [formaldefs]:formaldef* extern_code_block? [superclasses]:superclass* [propdefs]:propdef* kwend
 677         | {top} [propdefs]:propdef*
 678         | {main} [propdefs]:propdef*
 679         ;
 680 classkind
 681         = {concrete} kwclass
 682         | {abstract} kwabstract kwclass
 683         | {interface} kwinterface
 684         | {enum} kwenum
 685         | {extern} kwextern kwclass?
 686         ;
 687 formaldef = [id]:classid type?;
 688 superclass = kwsuper type;
 689
 690
 691 propdef = {attr} doc? [readable]:able? [writable]:able? kwredef? visibility kwvar [id]:attrid? [id2]:id? type? expr?
 692         | {meth} doc? kwredef? visibility methid signature
 693         | {deferred_meth} doc? kwredef? visibility kwmeth methid signature
 694         | {intern_meth} doc? kwredef? visibility kwmeth methid signature
 695         | {extern_meth} doc? kwredef? visibility kwmeth methid signature [extern]:string? extern_calls? extern_code_block?
 696         | {concrete_meth} doc? kwredef? visibility kwmeth methid signature [block]:expr?
 697         | {concrete_init} doc? kwredef? visibility kwinit methid? signature [block]:expr?
 698         | {extern_init} doc? kwredef? visibility kwnew methid? signature [extern]:string? extern_calls? extern_code_block?
 699         | {main_meth} kwredef? [block]:expr?
 700         | {type} doc? kwredef? visibility kwtype [id]:classid type
 701         ;
 702
 703 able    = {read} kwredef? kwreadable
 704         | {write} kwredef? visibility? kwwritable
 705         ;
 706
 707 methid = {id} id | {plus} plus | {minus} minus | {star} star | {slash} slash | {percent} percent | {eq} eq | {ne} ne | {le} le | {ge} ge | {lt} lt | {gt} gt |  {ll} ll | {gg} gg | {bra} obra cbra | {starship} starship | {assign} id assign | {braassign} obra cbra assign;
 708
 709 signature = opar? [params]:param* cpar? type? [closure_decls]:closure_decl*;
 710
 711 param   = id type? dotdotdot?
 712         ;
 713
 714 closure_decl = kwbreak? bang id signature expr?
 715         ;
 716
 717 type    = kwnullable? [id]:classid [types]:type*;
 718
 719 label = kwlabel id;
 720
 721 expr    = {block} expr* kwend?
 722         | {vardecl} kwvar id type? assign? expr?
 723         | {return} kwreturn? expr?
 724         | {break} kwbreak label? expr?
 725         | {abort} kwabort
 726         | {continue} kwcontinue? label? expr?
 727         | {do} kwdo [block]:expr? label?
 728         | {if} kwif expr [then]:expr? [else]:expr?
 729         | {ifexpr} kwif expr kwthen [then]:expr kwelse [else]:expr
 730         | {while} kwwhile expr kwdo [block]:expr? label?
 731         | {loop} kwloop [block]:expr? label?
 732         | {for} kwfor [ids]:id* expr kwdo [block]:expr? label?
 733         | {assert} kwassert id? expr [else]:expr?
 734         | {once} kwonce expr
 735         | {send} expr
 736         | {binop} expr [expr2]:expr
 737         | {or} expr [expr2]:expr
 738         | {and} expr [expr2]:expr
 739         | {or_else} expr [expr2]:expr
 740         | {not} kwnot expr
 741         | {eq} expr [expr2]:expr
 742         | {ee} expr [expr2]:expr
 743         | {ne} expr [expr2]:expr
 744         | {lt} expr [expr2]:expr
 745         | {le} expr [expr2]:expr
 746         | {ll} expr [expr2]:expr
 747         | {gt} expr [expr2]:expr
 748         | {ge} expr [expr2]:expr
 749         | {gg} expr [expr2]:expr
 750         | {isa} expr type
 751         | {plus} expr [expr2]:expr
 752         | {minus} expr [expr2]:expr
 753         | {starship} expr [expr2]:expr
 754         | {star} expr [expr2]:expr
 755         | {slash} expr [expr2]:expr
 756         | {percent} expr [expr2]:expr
 757         | {uminus} minus expr
 758         | {new} kwnew type id? [args]:exprs
 759         | {attr} expr [id]:attrid
 760         | {attr_assign} expr [id]:attrid assign [value]:expr
 761         | {attr_reassign} expr [id]:attrid assign_op [value]:expr
 762         | {call} expr id [args]:exprs [closure_defs]:closure_def*
 763         | {call_assign} expr id [args]:exprs assign [value]:expr
 764         | {call_reassign} expr id [args]:exprs assign_op [value]:expr
 765         | {super} qualified? kwsuper [args]:exprs
 766         | {init} expr kwinit [args]:exprs
 767         | {bra} expr [args]:exprs [closure_defs]:closure_def*
 768         | {bra_assign} expr [args]:exprs assign [value]:expr
 769         | {bra_reassign} expr [args]:exprs assign_op [value]:expr
 770         | {closure_call} id [args]:exprs [closure_defs]:closure_def*
 771         | {var} id
 772         | {var_assign} id assign [value]:expr
 773         | {var_reassign} id assign_op [value]:expr
 774         | {range} expr [expr2]:expr
 775         | {crange} obra expr [expr2]:expr cbra
 776         | {orange} obra expr [expr2]:expr [cbra]:obra
 777         | {array} [exprs]:exprs
 778         | {self} kwself
 779         | {implicit_self}
 780         | {true} kwtrue
 781         | {false} kwfalse
 782         | {null} kwnull
 783         | {int} number
 784         | {float} float
 785         | {char} char
 786         | {string} string
 787         | {start_string} [string]:start_string
 788         | {mid_string} [string]:mid_string
 789         | {end_string} [string]:end_string
 790         | {superstring} [exprs]:expr*
 791         | {par} opar expr cpar
 792         | {as_cast} expr kwas opar type cpar
 793         | {as_notnull} expr kwas opar kwnot kwnull cpar
 794         | {isset_attr} kwisset expr [id]:attrid
 795         | {debug_type} kwdebug kwtype expr type
 796         ;
 797 exprs
 798         = {list} [exprs]:expr*
 799         | {par} opar [exprs]:expr* cpar
 800         | {bra} obra [exprs]:expr* cbra
 801         ;
 802 assign_op
 803         = {plus} pluseq
 804         | {minus} minuseq
 805         ;
 806
 807 closure_def
 808         = bang [id]:closure_id [ids]:id* kwdo? expr? label?
 809         ;
 810 closure_id
 811         = {simple} id
 812         | {break} kwbreak
 813         ;
 814
 815 module_name = quad? [path]:id* id;
 816 extern_calls = kwimport [extern_calls]:extern_call*
 817         ;
 818 extern_call =
 819         | {super} kwsuper
 820         | {local_prop} methid
 821         | {full_prop} classid quad? methid
 822         | {init_prop} classid
 823         | {cast_as} [from_type]:type kwas [to_type]:type
 824         | {as_nullable} type kwas kwnullable
 825         | {as_not_nullable} type kwas kwnot kwnullable
 826         ;
 827 in_language = kwin string;
 828 extern_code_block = in_language? extern_code_segment;
 829
 830 qualified = id* classid? ;
 831
 832 doc = comment+;
 833
 834 /*****************************************************************************/
 835