src/ni_nitdoc.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2008 Jean Privat <jean@pryen.org>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 # http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 module ni_nitdoc
  18
  19 import model_utils
  20 import abstract_compiler
  21
  22 # The NitdocContext contains all the knowledge used for doc generation
  23 class NitdocContext
  24         super ToolContext
  25
  26         private var model: Model
  27         private var mbuilder: ModelBuilder
  28         private var mainmodule: MModule
  29         private var class_hierarchy: POSet[MClass]
  30         private var arguments: Array[String]
  31         private var output_dir: nullable String
  32         private var dot_dir: nullable String
  33         private var share_dir: nullable String
  34         private var source: nullable String
  35         private var min_visibility: MVisibility
  36
  37         private var opt_dir = new OptionString("Directory where doc is generated", "-d", "--dir")
  38         private var opt_source = new OptionString("What link for source (%f for filename, %l for first line, %L for last line)", "--source")
  39         private var opt_sharedir = new OptionString("Directory containing the nitdoc files", "--sharedir")
  40         private var opt_nodot = new OptionBool("Do not generate graphes with graphiviz", "--no-dot")
  41         private var opt_private: OptionBool = new OptionBool("Generate the private API", "--private")
  42
  43         private var opt_custom_title: OptionString = new OptionString("Title displayed in the top of the Overview page and as suffix of all page names", "--custom-title")
  44         private var opt_custom_menu_items: OptionString = new OptionString("Items displayed in menu before the 'Overview' item (Each item must be enclosed in 'li' tags)", "--custom-menu-items")
  45         private var opt_custom_overview_text: OptionString = new OptionString("Text displayed as introduction of Overview page before the modules list", "--custom-overview-text")
  46         private var opt_custom_footer_text: OptionString = new OptionString("Text displayed as footer of all pages", "--custom-footer-text")
  47
  48         init do
  49                 super
  50                 self.arguments = option_context.rest
  51                 option_context.options.clear
  52                 option_context.add_option(opt_dir)
  53                 option_context.add_option(opt_source)
  54                 option_context.add_option(opt_sharedir)
  55                 option_context.add_option(opt_nodot)
  56                 option_context.add_option(opt_private)
  57                 option_context.add_option(opt_custom_title)
  58                 option_context.add_option(opt_custom_footer_text)
  59                 option_context.add_option(opt_custom_overview_text)
  60                 option_context.add_option(opt_custom_menu_items)
  61                 process_options
  62
  63                 if arguments.length < 1 then
  64                         option_context.usage
  65                         exit(1)
  66                 end
  67
  68                 model = new Model
  69                 mbuilder = new ModelBuilder(model, self)
  70                 # Here we load an process all modules passed on the command line
  71                 var mmodules = mbuilder.parse_and_build(arguments)
  72                 mbuilder.full_propdef_semantic_analysis
  73                 if mmodules.is_empty then return
  74
  75                 if mmodules.length == 1 then
  76                         mainmodule = mmodules.first
  77                 else
  78                         # We need a main module, so we build it by importing all modules
  79                         mainmodule = new MModule(model, null, "<main>", new Location(null, 0, 0, 0, 0))
  80                         mainmodule.set_imported_mmodules(mmodules)
  81                 end
  82                 self.class_hierarchy = mainmodule.flatten_mclass_hierarchy
  83         end
  84
  85         redef fun process_options do
  86                 super
  87                 if not opt_dir.value is null then
  88                         output_dir = opt_dir.value
  89                 else
  90                         output_dir = "doc"
  91                 end
  92                 if not opt_sharedir.value is null then
  93                         share_dir = opt_sharedir.value
  94                 else
  95                         var dir = "NIT_DIR".environ
  96                         if dir.is_empty then
  97                                 dir = "{sys.program_name.dirname}/../share/nitdoc"
  98                         else
  99                                 dir = "{dir}/share/nitdoc"
 100                         end
 101                         share_dir = dir
 102                         if share_dir is null then
 103                                 print "Error: Cannot locate nitdoc share files. Uses --sharedir or envvar NIT_DIR"
 104                                 abort
 105                         end
 106                         dir = "{share_dir.to_s}/scripts/js-facilities.js"
 107                         if share_dir is null then
 108                                 print "Error: Invalid nitdoc share files. Check --sharedir or envvar NIT_DIR"
 109                                 abort
 110                         end
 111
 112                         if opt_private.value then
 113                                 min_visibility = none_visibility
 114                         else
 115                                 min_visibility = protected_visibility
 116                         end
 117                 end
 118                 source = opt_source.value
 119         end
 120
 121         fun generate_nitdoc do
 122                 # Create destination dir if it's necessary
 123                 if not output_dir.file_exists then output_dir.mkdir
 124                 sys.system("cp -r {share_dir.to_s}/* {output_dir.to_s}/")
 125                 self.dot_dir = null
 126                 if not opt_nodot.value then self.dot_dir = output_dir.to_s
 127                 overview
 128                 fullindex
 129                 modules
 130                 classes
 131                 quicksearch_list
 132         end
 133
 134         private fun overview do
 135                 var overviewpage = new NitdocOverview(self, dot_dir)
 136                 overviewpage.save("{output_dir.to_s}/index.html")
 137         end
 138
 139         private fun fullindex do
 140                 var fullindex = new NitdocFullindex(self)
 141                 fullindex.save("{output_dir.to_s}/full-index.html")
 142         end
 143
 144         private fun modules do
 145                 for mmodule in model.mmodules do
 146                         if mmodule.name == "<main>" then continue
 147                         var modulepage = new NitdocModule(mmodule, self, dot_dir)
 148                         modulepage.save("{output_dir.to_s}/{mmodule.url}")
 149                 end
 150         end
 151
 152         private fun classes do
 153                 for mclass in mbuilder.model.mclasses do
 154                         var classpage = new NitdocClass(mclass, self, dot_dir, source)
 155                         classpage.save("{output_dir.to_s}/{mclass.url}")
 156                 end
 157         end
 158
 159         private fun quicksearch_list do
 160                 var file = new OFStream.open("{output_dir.to_s}/quicksearch-list.js")
 161                 var content = new Buffer
 162                 content.append("var entries = \{ ")
 163
 164                 for mmodule in model.mmodules do
 165                         content.append("\"{mmodule.name}\": [")
 166                         content.append("\{txt: \"{mmodule.name}\", url:\"{mmodule.url}\" \},")
 167                         content.append("],")
 168                 end
 169                 for mclass in model.mclasses do
 170                         if mclass.visibility < min_visibility then continue
 171                         content.append("\"{mclass.name}\": [")
 172                         content.append("\{txt: \"{mclass.name}\", url:\"{mclass.url}\" \},")
 173                         content.append("],")
 174                 end
 175                 var name2mprops = new HashMap[String, Set[MPropDef]]
 176                 for mproperty in model.mproperties do
 177                         if mproperty.visibility < min_visibility then continue
 178                         if mproperty isa MAttribute then continue
 179                         if not name2mprops.has_key(mproperty.name) then name2mprops[mproperty.name] = new HashSet[MPropDef]
 180                         name2mprops[mproperty.name].add_all(mproperty.mpropdefs)
 181                 end
 182                 for mproperty, mpropdefs in name2mprops do
 183                         content.append("\"{mproperty}\": [")
 184                         for mpropdef in mpropdefs do
 185                                 content.append("\{txt: \"{mpropdef.full_name}\", url:\"{mpropdef.url}\" \},")
 186                         end
 187                         content.append("],")
 188                 end
 189
 190                 content.append(" \};")
 191                 file.write(content.to_s)
 192                 file.close
 193         end
 194
 195 end
 196
 197 # Nitdoc base page
 198 abstract class NitdocPage
 199         super Buffer
 200
 201         var dot_dir: nullable String
 202         var source: nullable String
 203         var ctx: NitdocContext
 204
 205         init(ctx: NitdocContext) do
 206                 super
 207                 self.ctx = ctx
 208         end
 209
 210         protected fun head do
 211                 append("<meta charset='utf-8'/>")
 212                 append("<script type='text/javascript' src='scripts/jquery-1.7.1.min.js'></script>")
 213                 append("<script type='text/javascript' src='quicksearch-list.js'></script>")
 214                 append("<script type='text/javascript' src='scripts/js-facilities.js'></script>")
 215                 append("<link rel='stylesheet' href='styles/main.css' type='text/css' media='screen'/>")
 216                 var title = ""
 217                 if ctx.opt_custom_title.value != null then
 218                         title = " | {ctx.opt_custom_title.value.to_s}"
 219                 end
 220                 append("<title>{self.title}{title}</title>")
 221         end
 222
 223         protected fun menu do
 224                 if ctx.opt_custom_menu_items.value != null then
 225                         append(ctx.opt_custom_menu_items.value.to_s)
 226                 end
 227         end
 228
 229         protected fun title: String is abstract
 230
 231         protected fun header do
 232                 append("<header>")
 233                 append("<nav class='main'>")
 234                 append("<ul>")
 235                 menu
 236                 append("<li id='liGitHub'>")
 237                 append("<a class='btn' id='logGitHub'>")
 238                 append("<img id='imgGitHub' src='resources/icons/github-icon.png' alt='GitHub'/>")
 239                 append("</a>")
 240                 append("<div class='popover bottom'>")
 241                 append("<div class='arrow'>&nbsp;</div>")
 242                 append("<div class='githubTitle'>")
 243                 append("<h3>Github Sign In</h3>")
 244                 append("</div>")
 245                 append("<div>")
 246                 append("<label id='lbloginGit'>Username</label>")
 247                 append("<input id='loginGit' name='login' type='text'/>")
 248                 append("<label id='logginMessage'>Hello ")
 249                 append("<a id='githubAccount'><strong id='nickName'></strong></a>")
 250                 append("</label>")
 251                 append("</div>")
 252                 append("<div>")
 253                 append("<label id='lbpasswordGit'>Password</label>")
 254                 append("<input id='passwordGit' name='password' type='password'/>")
 255                 append("<div id='listBranches'>")
 256                 append("<label id='lbBranches'>Branch</label>")
 257                 append("<select class='dropdown' id='dropBranches' name='dropBranches' tabindex='1'></select>")
 258                 append("</div>")
 259                 append("</div>")
 260                 append("<div>")
 261                 append("<label id='lbrepositoryGit'>Repository</label>")
 262                 append("<input id='repositoryGit' name='repository' type='text'/>")
 263                 append("</div>")
 264                 append("<div>")
 265                 append("<label id='lbbranchGit'>Branch</label>")
 266                 append("<input id='branchGit' name='branch' type='text'/>")
 267                 append("</div>")
 268                 append("<div>")
 269                 append("<a id='signIn'>Sign In</a>")
 270                 append("</div>")
 271                 append("</div>")
 272                 append("</li>")
 273                 append("</ul>")
 274                 append("</nav>")
 275                 append("</header>")
 276         end
 277
 278         protected fun content is abstract
 279
 280         protected fun footer do
 281                 if ctx.opt_custom_footer_text.value != null then
 282                         append("<footer>{ctx.opt_custom_footer_text.value.to_s}</footer>")
 283                 end
 284         end
 285
 286         # Generate a clickable graphviz image using a dot content
 287         protected fun generate_dot(dot: String, name: String, alt: String) do
 288                 var output_dir = dot_dir
 289                 if output_dir == null then return
 290                 var file = new OFStream.open("{output_dir}/{name}.dot")
 291                 file.write(dot)
 292                 file.close
 293                 sys.system("\{ test -f {output_dir}/{name}.png && test -f {output_dir}/{name}.s.dot && diff {output_dir}/{name}.dot {output_dir}/{name}.s.dot >/dev/null 2>&1 ; \} || \{ cp {output_dir}/{name}.dot {output_dir}/{name}.s.dot && dot -Tpng -o{output_dir}/{name}.png -Tcmapx -o{output_dir}/{name}.map {output_dir}/{name}.s.dot ; \}")
 294                 append("<article class='graph'>")
 295                 append("<img src='{name}.png' usemap='#{name}' style='margin:auto' alt='{alt}'/>")
 296                 append("</article>")
 297                 var fmap = new IFStream.open("{output_dir}/{name}.map")
 298                 append(fmap.read_all)
 299                 fmap.close
 300         end
 301
 302         # Add a (source) link for a given location
 303         protected fun show_source(l: Location): String
 304         do
 305                 if source == null then
 306                         return "({l.file.filename.simplify_path})"
 307                 else
 308                         # THIS IS JUST UGLY ! (but there is no replace yet)
 309                         var x = source.split_with("%f")
 310                         source = x.join(l.file.filename.simplify_path)
 311                         x = source.split_with("%l")
 312                         source = x.join(l.line_start.to_s)
 313                         x = source.split_with("%L")
 314                         source = x.join(l.line_end.to_s)
 315                         return " (<a href=\"{source.to_s}\">source</a>)"
 316                 end
 317         end
 318
 319         # Render the page as a html string
 320         fun render: String do
 321                 append("<!DOCTYPE html>")
 322                 append("<head>")
 323                 head
 324                 append("</head>")
 325                 append("<body>")
 326                 header
 327                 append("<div class='page'>")
 328                 content
 329                 append("</div>")
 330                 footer
 331                 append("</body>")
 332                 return to_s
 333         end
 334
 335         # Save html page in the specified file
 336         fun save(file: String) do
 337                 var out = new OFStream.open(file)
 338                 out.write(render)
 339                 out.close
 340         end
 341 end
 342
 343 # The overview page
 344 class NitdocOverview
 345         super NitdocPage
 346         private var mbuilder: ModelBuilder
 347         private var mmodules = new Array[MModule]
 348
 349         init(ctx: NitdocContext, dot_dir: nullable String) do
 350                 super(ctx)
 351                 self.mbuilder = ctx.mbuilder
 352                 self.dot_dir = dot_dir
 353                 # get modules
 354                 var mmodules = new HashSet[MModule]
 355                 for mmodule in mbuilder.model.mmodules do
 356                         if mmodule.name == "<main>" then continue
 357                         var owner = mmodule.public_owner
 358                         if owner != null then
 359                                 mmodules.add(owner)
 360                         else
 361                                 mmodules.add(mmodule)
 362                         end
 363                 end
 364                 # sort modules
 365                 var sorter = new ComparableSorter[MModule]
 366                 self.mmodules.add_all(mmodules)
 367                 sorter.sort(self.mmodules)
 368         end
 369
 370         redef fun title do return "Overview"
 371
 372         redef fun menu do
 373                 super
 374                 append("<li class='current'>Overview</li>")
 375                 append("<li><a href='full-index.html'>Full Index</a></li>")
 376         end
 377
 378         redef fun content do
 379                 append("<div class='content fullpage'>")
 380                 var title = "Overview"
 381                 if ctx.opt_custom_title.value != null then
 382                         title = ctx.opt_custom_title.value.to_s
 383                 end
 384                 append("<h1>{title}</h1>")
 385                 var text = ""
 386                 if ctx.opt_custom_overview_text.value != null then
 387                         text = ctx.opt_custom_overview_text.value.to_s
 388                 end
 389                 append("<article class='overview'>{text}</article>")
 390                 append("<article class='overview'>")
 391                 # module list
 392                 append("<h2>Modules</h2>")
 393                 append("<ul>")
 394                 for mmodule in mmodules do
 395                         if mbuilder.mmodule2nmodule.has_key(mmodule) then
 396                                 var amodule = mbuilder.mmodule2nmodule[mmodule]
 397                                 append("<li>")
 398                                 mmodule.html_link(self)
 399                                 append("&nbsp;{amodule.short_comment}</li>")
 400                         end
 401                 end
 402                 append("</ul>")
 403                 # module graph
 404                 process_generate_dot
 405                 append("</article>")
 406                 append("</div>")
 407         end
 408
 409         private fun process_generate_dot do
 410                 # build poset with public owners
 411                 var poset = new POSet[MModule]
 412                 for mmodule in mmodules do
 413                         poset.add_node(mmodule)
 414                         for omodule in mmodules do
 415                                 if mmodule == omodule then continue
 416                                 if mmodule.in_importation < omodule then
 417                                         poset.add_node(omodule)
 418                                         poset.add_edge(mmodule, omodule)
 419                                 end
 420                         end
 421                 end
 422                 # build graph
 423                 var op = new Buffer
 424                 op.append("digraph dep \{ rankdir=BT; node[shape=none,margin=0,width=0,height=0,fontsize=10]; edge[dir=none,color=gray]; ranksep=0.2; nodesep=0.1;\n")
 425                 for mmodule in poset do
 426                         op.append("\"{mmodule.name}\"[URL=\"{mmodule.url}\"];\n")
 427                         for omodule in poset[mmodule].direct_greaters do
 428                                 op.append("\"{mmodule.name}\"->\"{omodule.name}\";\n")
 429                         end
 430                 end
 431                 op.append("\}\n")
 432                 generate_dot(op.to_s, "dep", "Modules hierarchy")
 433         end
 434 end
 435
 436 # The full index page
 437 class NitdocFullindex
 438         super NitdocPage
 439
 440         init(ctx: NitdocContext) do
 441                 super(ctx)
 442                 self.dot_dir = null
 443         end
 444
 445         redef fun title do return "Full Index"
 446
 447         redef fun menu do
 448                 super
 449                 append("<li><a href='index.html'>Overview</a></li>")
 450                 append("<li class='current'>Full Index</li>")
 451         end
 452
 453         redef fun content do
 454                 append("<div class='content fullpage'>")
 455                 append("<h1>Full Index</h1>")
 456                 module_column
 457                 classes_column
 458                 properties_column
 459                 append("</div>")
 460         end
 461
 462         # Add to content modules column
 463         private fun module_column do
 464                 var sorted = ctx.mbuilder.model.mmodule_importation_hierarchy.to_a
 465                 var sorter = new ComparableSorter[MModule]
 466                 sorter.sort(sorted)
 467                 append("<article class='modules filterable'>")
 468                 append("<h2>Modules</h2>")
 469                 append("<ul>")
 470                 for mmodule in sorted do
 471                         append("<li>")
 472                         mmodule.html_link(self)
 473                         append("</li>")
 474                 end
 475                 append("</ul>")
 476                 append("</article>")
 477         end
 478
 479         # Add to content classes modules
 480         private fun classes_column do
 481                 var sorted = ctx.mbuilder.model.mclasses
 482                 var sorter = new ComparableSorter[MClass]
 483                 sorter.sort(sorted)
 484                 append("<article class='modules filterable'>")
 485                 append("<h2>Classes</h2>")
 486                 append("<ul>")
 487                 for mclass in sorted do
 488                         if mclass.visibility < ctx.min_visibility then continue
 489                         append("<li>")
 490                         mclass.html_link(self)
 491                         append("</li>")
 492                 end
 493                 append("</ul>")
 494                 append("</article>")
 495         end
 496
 497         # Insert the properties column of fullindex page
 498         private fun properties_column do
 499                 var sorted = ctx.mbuilder.model.mproperties
 500                 var sorter = new ComparableSorter[MProperty]
 501                 sorter.sort(sorted)
 502                 append("<article class='modules filterable'>")
 503                 append("<h2>Properties</h2>")
 504                 append("<ul>")
 505                 for mproperty in sorted do
 506                         if mproperty.visibility < ctx.min_visibility then continue
 507                         if mproperty isa MAttribute then continue
 508                         append("<li>")
 509                         mproperty.intro.html_link(self)
 510                         append(" (")
 511                         mproperty.intro.mclassdef.mclass.html_link(self)
 512                         append(")</li>")
 513                 end
 514                 append("</ul>")
 515                 append("</article>")
 516         end
 517
 518 end
 519
 520 # A module page
 521 class NitdocModule
 522         super NitdocPage
 523
 524         private var mmodule: MModule
 525         private var mbuilder: ModelBuilder
 526
 527         init(mmodule: MModule, ctx: NitdocContext, dot_dir: nullable String) do
 528                 super(ctx)
 529                 self.mmodule = mmodule
 530                 self.mbuilder = ctx.mbuilder
 531                 self.dot_dir = dot_dir
 532         end
 533
 534         redef fun title do
 535                 if mbuilder.mmodule2nmodule.has_key(mmodule) then
 536                         var nmodule = mbuilder.mmodule2nmodule[mmodule]
 537                         return "{mmodule.name} module | {nmodule.short_comment}"
 538                 else
 539                         return "{mmodule.name} module"
 540                 end
 541         end
 542
 543         redef fun menu do
 544                 super
 545                 append("<li><a href='index.html'>Overview</a></li>")
 546                 append("<li class='current'>{mmodule.name}</li>")
 547                 append("<li><a href='full-index.html'>Full Index</a></li>")
 548         end
 549
 550         redef fun content do
 551                 sidebar
 552                 append("<div class='content'>")
 553                 append("<h1>{mmodule.name}</h1>")
 554                 append("<div class='subtitle info'>")
 555                 mmodule.html_signature(self)
 556                 append("</div>")
 557                 mmodule.html_full_comment(self)
 558                 process_generate_dot
 559                 classes
 560                 properties
 561                 append("</div>")
 562         end
 563
 564         private fun process_generate_dot do
 565                 # build poset with public owners
 566                 var poset = new POSet[MModule]
 567                 for mmodule in self.mmodule.in_importation.poset do
 568                         if mmodule.name == "<main>" then continue
 569                         if mmodule.public_owner != null then continue
 570                         if not mmodule.in_importation < self.mmodule and not self.mmodule.in_importation < mmodule and mmodule != self.mmodule then continue
 571                         poset.add_node(mmodule)
 572                         for omodule in mmodule.in_importation.poset do
 573                                 if mmodule == omodule then continue
 574                                 if omodule.name == "<main>" then continue
 575                                 if omodule.public_owner != null then continue
 576                                 if mmodule.in_importation < omodule then
 577                                         poset.add_node(omodule)
 578                                         poset.add_edge(mmodule, omodule)
 579                                 end
 580                         end
 581                 end
 582                 # build graph
 583                 var op = new Buffer
 584                 var name = "dep_{mmodule.name}"
 585                 op.append("digraph {name} \{ rankdir=BT; node[shape=none,margin=0,width=0,height=0,fontsize=10]; edge[dir=none,color=gray]; ranksep=0.2; nodesep=0.1;\n")
 586                 for mmodule in poset do
 587                         if mmodule == self.mmodule then
 588                                 op.append("\"{mmodule.name}\"[shape=box,margin=0.03];\n")
 589                         else
 590                                 op.append("\"{mmodule.name}\"[URL=\"{mmodule.url}\"];\n")
 591                         end
 592                         for omodule in poset[mmodule].direct_greaters do
 593                                 op.append("\"{mmodule.name}\"->\"{omodule.name}\";\n")
 594                         end
 595                 end
 596                 op.append("\}\n")
 597                 generate_dot(op.to_s, name, "Dependency graph for module {mmodule.name}")
 598         end
 599
 600         private fun sidebar do
 601                 append("<div class='menu'>")
 602                 append("<nav>")
 603                 append("<h3>Module Hierarchy</h3>")
 604                 var dependencies = new Array[MModule]
 605                 for dep in mmodule.in_importation.greaters do
 606                         if dep == mmodule or dep.public_owner != null then continue
 607                         dependencies.add(dep)
 608                 end
 609                 if dependencies.length > 0 then
 610                         append("<h4>All dependencies</h4>")
 611                         display_module_list(dependencies)
 612                 end
 613                 var clients = new Array[MModule]
 614                 for dep in mmodule.in_importation.smallers do
 615                         if dep == mmodule or dep.public_owner != null then continue
 616                         clients.add(dep)
 617                 end
 618                 if clients.length > 0 then
 619                         append("<h4>All clients</h4>")
 620                         display_module_list(clients)
 621                 end
 622                 append("</nav>")
 623                 if ctx.min_visibility < protected_visibility then
 624                         if mmodule.in_nesting.direct_greaters.length > 0 then
 625                                 append("<nav>")
 626                                 append("<h3>Nested Modules</h3>")
 627                                 display_module_list(mmodule.in_nesting.direct_greaters.to_a)
 628                                 append("</nav>")
 629                         end
 630                 end
 631                 append("</div>")
 632         end
 633
 634         private fun display_module_list(list: Array[MModule]) do
 635                 append("<ul>")
 636                 var sorter = new ComparableSorter[MModule]
 637                 sorter.sort(list)
 638                 for m in list do
 639                         append("<li>")
 640                         m.html_link(self)
 641                         append("</li>")
 642                 end
 643                 append("</ul>")
 644         end
 645
 646         # display the class column
 647         private fun classes do
 648                 var intro_mclasses = mmodule.intro_mclasses
 649                 var redef_mclasses = mmodule.redef_mclasses
 650                 var all_mclasses = new HashSet[MClass]
 651                 for m in mmodule.in_nesting.greaters do
 652                         all_mclasses.add_all(m.intro_mclasses)
 653                         all_mclasses.add_all(m.redef_mclasses)
 654                 end
 655                 all_mclasses.add_all(intro_mclasses)
 656                 all_mclasses.add_all(redef_mclasses)
 657
 658                 var sorted = new Array[MClass]
 659                 sorted.add_all(all_mclasses)
 660                 var sorter = new ComparableSorter[MClass]
 661                 sorter.sort(sorted)
 662                 append("<div class='module'>")
 663                 append("<article class='classes filterable'>")
 664                 append("<h2>Classes</h2>")
 665                 append("<ul>")
 666                 for c in sorted do
 667                         if c.visibility < ctx.min_visibility then continue
 668                         if redef_mclasses.has(c) and c.intro_mmodule.public_owner != mmodule then
 669                                 append("<li class='redef'>")
 670                                 append("<span title='refined in this module'>R </span>")
 671                         else
 672                                 append("<li class='intro'>")
 673                                 append("<span title='introduced in this module'>I </span>")
 674                         end
 675                         c.html_link(self)
 676                         append("</li>")
 677                 end
 678                 append("</ul>")
 679                 append("</article>")
 680                 append("</div>")
 681         end
 682
 683         # display the property column
 684         private fun properties do
 685                 # get properties
 686                 var mpropdefs = new HashSet[MPropDef]
 687                 for m in mmodule.in_nesting.greaters do
 688                         for c in m.mclassdefs do mpropdefs.add_all(c.mpropdefs)
 689                 end
 690                 for c in mmodule.mclassdefs do mpropdefs.add_all(c.mpropdefs)
 691                 var sorted = mpropdefs.to_a
 692                 var sorter = new ComparableSorter[MPropDef]
 693                 sorter.sort(sorted)
 694                 # display properties in one column
 695                 append("<article class='properties filterable'>")
 696                 append("<h2>Properties</h2>")
 697                 append("<ul>")
 698                 for mprop in sorted do
 699                         if mprop isa MAttributeDef then continue
 700                         if mprop.mproperty.visibility < ctx.min_visibility then continue
 701                         mprop.html_list_item(self)
 702                 end
 703                 append("</ul>")
 704                 append("</article>")
 705         end
 706 end
 707
 708 # A class page
 709 class NitdocClass
 710         super NitdocPage
 711
 712         private var mclass: MClass
 713         private var vtypes = new HashSet[MVirtualTypeDef]
 714         private var consts = new HashSet[MMethodDef]
 715         private var meths = new HashSet[MMethodDef]
 716         private var inherited = new HashSet[MPropDef]
 717
 718         init(mclass: MClass, ctx: NitdocContext, dot_dir: nullable String, source: nullable String) do
 719                 super(ctx)
 720                 self.mclass = mclass
 721                 self.dot_dir = dot_dir
 722                 self.source = source
 723                 # load properties
 724                 for mclassdef in mclass.mclassdefs do
 725                         for mpropdef in mclassdef.mpropdefs do
 726                                 if mpropdef.mproperty.visibility < ctx.min_visibility then continue
 727                                 if mpropdef isa MVirtualTypeDef then vtypes.add(mpropdef)
 728                                 if mpropdef isa MMethodDef then
 729                                         if mpropdef.mproperty.is_init then
 730                                                 consts.add(mpropdef)
 731                                         else
 732                                                 meths.add(mpropdef)
 733                                         end
 734                                 end
 735                         end
 736                 end
 737                 # get inherited properties
 738                 for mprop in mclass.inherited_mproperties do
 739                         var mpropdef = mprop.intro
 740                         if mprop.visibility < ctx.min_visibility then continue
 741                         if mpropdef isa MVirtualTypeDef then vtypes.add(mpropdef)
 742                         if mpropdef isa MMethodDef then
 743                                 if mpropdef.mproperty.is_init then
 744                                         consts.add(mpropdef)
 745                                 else
 746                                         meths.add(mpropdef)
 747                                 end
 748                         end
 749                         inherited.add(mpropdef)
 750                 end
 751         end
 752
 753         redef fun title do
 754                 var nclass = ctx.mbuilder.mclassdef2nclassdef[mclass.intro]
 755                 if nclass isa AStdClassdef then
 756                         return "{mclass.name} class | {nclass.short_comment}"
 757                 else
 758                         return "{mclass.name} class"
 759                 end
 760         end
 761
 762         redef fun menu do
 763                 super
 764                 append("<li><a href='index.html'>Overview</a></li>")
 765                 var public_owner = mclass.public_owner
 766                 if public_owner is null then
 767                         append("<li>")
 768                         mclass.intro_mmodule.html_link(self)
 769                         append("</li>")
 770                 else
 771                         append("<li>")
 772                         public_owner.html_link(self)
 773                         append("</li>")
 774                 end
 775                 append("<li class='current'>{mclass.name}</li>")
 776                 append("<li><a href='full-index.html'>Full Index</a></li>")
 777         end
 778
 779         redef fun content do
 780                 append("<div class='menu'>")
 781                 properties_column
 782                 inheritance_column
 783                 append("</div>")
 784                 append("<div class='content'>")
 785                 class_doc
 786                 append("</div>")
 787         end
 788
 789         private fun properties_column do
 790                 var sorter = new ComparableSorter[MPropDef]
 791                 append("<nav class='properties filterable'>")
 792                 append("<h3>Properties</h3>")
 793                 # virtual types
 794                 if vtypes.length > 0 then
 795                         var vts = new Array[MVirtualTypeDef]
 796                         vts.add_all(vtypes)
 797                         sorter.sort(vts)
 798                         append("<h4>Virtual Types</h4>")
 799                         append("<ul>")
 800                         for mprop in vts do
 801                                 mprop.html_sidebar_item(self)
 802                         end
 803                         append("</ul>")
 804                 end
 805                 # constructors
 806                 if consts.length > 0 then
 807                         var cts = new Array[MMethodDef]
 808                         cts.add_all(consts)
 809                         sorter.sort(cts)
 810                         append("<h4>Constructors</h4>")
 811                         append("<ul>")
 812                         for mprop in cts do
 813                                 if mprop.mproperty.name == "init" and mprop.mclassdef.mclass != mclass then continue
 814                                 mprop.html_sidebar_item(self)
 815                         end
 816                         append("</ul>")
 817                 end
 818                 # methods
 819                 if meths.length > 0 then
 820                         var mts = new Array[MMethodDef]
 821                         mts.add_all(meths)
 822                         sorter.sort(mts)
 823                         append("<h4>Methods</h4>")
 824                         append("<ul>")
 825                         for mprop in mts do
 826                                 if mclass.name != "Object" and mprop.mproperty.intro_mclassdef.mclass.name == "Object" and mprop.mproperty.visibility <= protected_visibility then continue
 827                                 mprop.html_sidebar_item(self)
 828                         end
 829                         append("</ul>")
 830                 end
 831                 append("</nav>")
 832         end
 833
 834         private fun inheritance_column do
 835                 var sorted = new Array[MClass]
 836                 var sorterp = new ComparableSorter[MClass]
 837                 append("<nav>")
 838                 append("<h3>Inheritance</h3>")
 839                 var greaters = mclass.in_hierarchy(ctx.mainmodule).greaters.to_a
 840                 if greaters.length > 1 then
 841                         ctx.mainmodule.linearize_mclasses(greaters)
 842                         append("<h4>Superclasses</h4>")
 843                         append("<ul>")
 844                         for sup in greaters do
 845                                 if sup == mclass then continue
 846                                 append("<li>")
 847                                 sup.html_link(self)
 848                                 append("</li>")
 849                         end
 850                         append("</ul>")
 851                 end
 852                 var smallers = mclass.in_hierarchy(ctx.mainmodule).smallers.to_a
 853                 var direct_smallers = mclass.in_hierarchy(ctx.mainmodule).direct_smallers.to_a
 854                 if smallers.length <= 1 then
 855                         append("<h4>No Known Subclasses</h4>")
 856                 else if smallers.length <= 100 then
 857                         ctx.mainmodule.linearize_mclasses(smallers)
 858                         append("<h4>Subclasses</h4>")
 859                         append("<ul>")
 860                         for sub in smallers do
 861                                 if sub == mclass then continue
 862                                 append("<li>")
 863                                 sub.html_link(self)
 864                                 append("</li>")
 865                         end
 866                         append("</ul>")
 867                 else if direct_smallers.length <= 100 then
 868                         ctx.mainmodule.linearize_mclasses(direct_smallers)
 869                         append("<h4>Direct Subclasses Only</h4>")
 870                         append("<ul>")
 871                         for sub in direct_smallers do
 872                                 if sub == mclass then continue
 873                                 append("<li>")
 874                                 sub.html_link(self)
 875                                 append("</li>")
 876                         end
 877                         append("</ul>")
 878                 else
 879                         append("<h4>Too much Subclasses to list</h4>")
 880                 end
 881                 append("</nav>")
 882         end
 883
 884         private fun class_doc do
 885                 # title
 886                 append("<h1>{mclass.signature}</h1>")
 887                 append("<div class='subtitle info'>")
 888                 mclass.html_full_signature(self)
 889                 append("</div>")
 890                 # comment
 891                 var nclass = ctx.mbuilder.mclassdef2nclassdef[mclass.intro]
 892                 append("<div style=\"float: right;\"><a id=\"lblDiffCommit\"></a></div>")
 893                 append("<section class='description'>")
 894                 if nclass isa AStdClassdef and not nclass.full_comment.is_empty then append("<pre class=\"text_label\" title=\"122\" name=\"\" tag=\"{mclass.mclassdefs.first.location.to_s}\" type=\"2\">{nclass.full_comment}</pre><textarea id=\"fileContent\" class=\"edit\" cols=\"76\" rows=\"1\" style=\"display: none;\"></textarea><a id=\"cancelBtn\" style=\"display: none;\">Cancel</a><a id=\"commitBtn\" style=\"display: none;\">Commit</a><pre id=\"preSave\" class=\"text_label\" type=\"2\"></pre>")
 895                 process_generate_dot
 896                 append("</section>")
 897                 # concerns
 898                 var concern2meths = new ArrayMap[MModule, Array[MMethodDef]]
 899                 var sorted_meths = new Array[MMethodDef]
 900                 var sorted = new Array[MModule]
 901                 sorted_meths.add_all(meths)
 902                 ctx.mainmodule.linearize_mpropdefs(sorted_meths)
 903                 for meth in meths do
 904                         if inherited.has(meth) then continue
 905                         var mmodule = meth.mclassdef.mmodule
 906                         if not concern2meths.has_key(mmodule) then
 907                                 sorted.add(mmodule)
 908                                 concern2meths[mmodule] = new Array[MMethodDef]
 909                         end
 910                         concern2meths[mmodule].add(meth)
 911                 end
 912                 var sections = new ArrayMap[MModule, Array[MModule]]
 913                 for mmodule in concern2meths.keys do
 914                         var owner = mmodule.public_owner
 915                         if owner == null then owner = mmodule
 916                         if not sections.has_key(owner) then sections[owner] = new Array[MModule]
 917                         if owner != mmodule then sections[owner].add(mmodule)
 918                 end
 919                 append("<section class='concerns'>")
 920                 append("<h2 class='section-header'>Concerns</h2>")
 921                 append("<ul>")
 922                 for owner, mmodules in sections do
 923                         var nowner = ctx.mbuilder.mmodule2nmodule[owner]
 924                         append("<li>")
 925                         if nowner.short_comment.is_empty then
 926                                 append("<a href=\"#{owner.anchor}\">{owner.name}</a>")
 927                         else
 928                                 append("<a href=\"#{owner.anchor}\">{owner.name}</a>: {nowner.short_comment}")
 929                         end
 930                         if not mmodules.is_empty then
 931                                 append("<ul>")
 932                                 for mmodule in mmodules do
 933                                         var nmodule = ctx.mbuilder.mmodule2nmodule[mmodule]
 934                                         if nmodule.short_comment.is_empty then
 935                                                 append("<li><a href=\"#{mmodule.anchor}\">{mmodule.name}</a></li>")
 936                                         else
 937                                                 append("<li><a href=\"#{mmodule.anchor}\">{mmodule.name}</a>: {nmodule.short_comment}</li>")
 938                                         end
 939                                 end
 940                                 append("</ul>")
 941                         end
 942                         append("</li>")
 943                 end
 944                 append("</ul>")
 945                 append("</section>")
 946                 # properties
 947                 var prop_sorter = new ComparableSorter[MPropDef]
 948                 var sorterprop = new ComparableSorter[MProperty]
 949                 var sorterc = new ComparableSorter[MClass]
 950                 var lmmodule = new List[MModule]
 951                 # virtual and formal types
 952                 var local_vtypes = new Array[MVirtualTypeDef]
 953                 for vt in vtypes do if not inherited.has(vt) then local_vtypes.add(vt)
 954                 if local_vtypes.length > 0 or mclass.arity > 0 then
 955                         append("<section class='types'>")
 956                         append("<h2>Formal and Virtual Types</h2>")
 957                         # formal types
 958                         if mclass.arity > 0 and nclass isa AStdClassdef then
 959                                 for ft, bound in mclass.parameter_types do
 960                                         append("<article id='FT_{ft}'>")
 961                                         append("<h3 class='signature'>{ft}: ")
 962                                         bound.html_link(self)
 963                                         append("</h3>")
 964                                         append("<div class=\"info\">formal generic type</div>")
 965                                         append("</article>")
 966                                 end
 967                         end
 968                         # virtual types
 969                         prop_sorter.sort(local_vtypes)
 970                         for prop in local_vtypes do prop.html_full_desc(self)
 971                         append("</section>")
 972                 end
 973                 # constructors
 974                 var local_consts = new Array[MMethodDef]
 975                 for const in consts do if not inherited.has(const) then local_consts.add(const)
 976                 prop_sorter.sort(local_consts)
 977                 if local_consts.length > 0 then
 978                         append("<section class='constructors'>")
 979                         append("<h2 class='section-header'>Constructors</h2>")
 980                         for prop in local_consts do prop.html_full_desc(self)
 981                         append("</section>")
 982                 end
 983                 # methods
 984                 if not concern2meths.is_empty then
 985                         append("<section class='methods'>")
 986                         append("<h2 class='section-header'>Methods</h2>")
 987                         for owner, mmodules in sections do
 988                                 append("<a id=\"{owner.anchor}\"></a>")
 989                                 if owner != mclass.intro_mmodule and owner != mclass.public_owner then
 990                                         var nowner = ctx.mbuilder.mmodule2nmodule[owner]
 991                                         append("<h3 class=\"concern-toplevel\">Methods refined in ")
 992                                         owner.html_link(self)
 993                                         append("</h3>")
 994                                         append("<p class=\"concern-doc\">")
 995                                         owner.html_link(self)
 996                                         if not nowner.short_comment.is_empty then
 997                                                 append(": {nowner.short_comment}")
 998                                         end
 999                                         append("</p>")
1000                                 end
1001                                 if concern2meths.has_key(owner) then
1002                                         var mmethods = concern2meths[owner]
1003                                         prop_sorter.sort(mmethods)
1004                                         for prop in mmethods do prop.html_full_desc(self)
1005                                 end
1006                                 for mmodule in mmodules do
1007                                         append("<a id=\"{mmodule.anchor}\"></a>")
1008                                         var nmodule = ctx.mbuilder.mmodule2nmodule[mmodule]
1009                                         if mmodule != mclass.intro_mmodule and mmodule != mclass.public_owner then
1010                                                 append("<p class=\"concern-doc\">")
1011                                                 mmodule.html_link(self)
1012                                                 if not nmodule.short_comment.is_empty then
1013                                                         append(": {nmodule.short_comment}")
1014                                                 end
1015                                                 append("</p>")
1016                                         end
1017                                         var mmethods = concern2meths[mmodule]
1018                                         prop_sorter.sort(mmethods)
1019                                         for prop in mmethods do prop.html_full_desc(self)
1020                                 end
1021                         end
1022                 end
1023                 # inherited properties
1024                 if inherited.length > 0 then
1025                         var sorted_inherited = new Array[MPropDef]
1026                         sorted_inherited.add_all(inherited)
1027                         ctx.mainmodule.linearize_mpropdefs(sorted_inherited)
1028                         var classes = new ArrayMap[MClass, Array[MPropDef]]
1029                         for mmethod in sorted_inherited.reversed do
1030                                 var mclass = mmethod.mclassdef.mclass
1031                                 if not classes.has_key(mclass) then classes[mclass] = new Array[MPropDef]
1032                                 classes[mclass].add(mmethod)
1033                         end
1034                         append("<h3>Inherited Properties</h3>")
1035                         for c, mmethods in classes do
1036                                 prop_sorter.sort(mmethods)
1037                                 append("<p>Defined in ")
1038                                 c.html_link(self)
1039                                 append("}: ")
1040                                 for i in [0..mmethods.length[ do
1041                                         var mmethod = mmethods[i]
1042                                         mmethod.html_link(self)
1043                                         if i <= mmethods.length - 1 then append(", ")
1044                                 end
1045                                 append("</p>")
1046                         end
1047                 end
1048                 append("</section>")
1049         end
1050
1051         private fun process_generate_dot do
1052                 var pe = ctx.class_hierarchy[mclass]
1053                 var cla = new HashSet[MClass]
1054                 var sm = new HashSet[MClass]
1055                 var sm2 = new HashSet[MClass]
1056                 sm.add(mclass)
1057                 while cla.length + sm.length < 10 and sm.length > 0 do
1058                         cla.add_all(sm)
1059                         sm2.clear
1060                         for x in sm do
1061                                 sm2.add_all(pe.poset[x].direct_smallers)
1062                         end
1063                         var t = sm
1064                         sm = sm2
1065                         sm2 = t
1066                 end
1067                 cla.add_all(pe.greaters)
1068
1069                 var op = new Buffer
1070                 var name = "dep_{mclass.name}"
1071                 op.append("digraph {name} \{ rankdir=BT; node[shape=none,margin=0,width=0,height=0,fontsize=10]; edge[dir=none,color=gray]; ranksep=0.2; nodesep=0.1;\n")
1072                 for c in cla do
1073                         if c == mclass then
1074                                 op.append("\"{c.name}\"[shape=box,margin=0.03];\n")
1075                         else
1076                                 op.append("\"{c.name}\"[URL=\"{c.url}\"];\n")
1077                         end
1078                         for c2 in pe.poset[c].direct_greaters do
1079                                 if not cla.has(c2) then continue
1080                                 op.append("\"{c.name}\"->\"{c2.name}\";\n")
1081                         end
1082                         if not pe.poset[c].direct_smallers.is_empty then
1083                                 var others = true
1084                                 for c2 in pe.poset[c].direct_smallers do
1085                                         if cla.has(c2) then others = false
1086                                 end
1087                                 if others then
1088                                         op.append("\"{c.name}...\"[label=\"\"];\n")
1089                                         op.append("\"{c.name}...\"->\"{c.name}\"[style=dotted];\n")
1090                                 end
1091                         end
1092                 end
1093                 op.append("\}\n")
1094                 generate_dot(op.to_s, name, "Dependency graph for class {mclass.name}")
1095         end
1096 end
1097
1098 #
1099 # Model redefs
1100 #
1101
1102 redef class MModule
1103         super Comparable
1104         redef type OTHER: MModule
1105         redef fun <(other: OTHER): Bool do return self.name < other.name
1106
1107         # URL to nitdoc page
1108         fun url: String do
1109                 var res = new Buffer
1110                 res.append("module_")
1111                 var mowner = public_owner
1112                 if mowner != null then
1113                         res.append("{public_owner.name}_")
1114                 end
1115                 res.append("{self.name}.html")
1116                 return res.to_s
1117         end
1118
1119         # html anchor id to the module in a nitdoc page
1120         fun anchor: String do
1121                 var res = new Buffer
1122                 res.append("MOD_")
1123                 var mowner = public_owner
1124                 if mowner != null then
1125                         res.append("{public_owner.name}_")
1126                 end
1127                 res.append(self.name)
1128                 return res.to_s
1129         end
1130
1131         # Return a link (html a tag) to the nitdoc module page
1132         fun html_link(page: NitdocPage) do
1133                 if page.ctx.mbuilder.mmodule2nmodule.has_key(self) then
1134                         page.append("<a href='{url}' title='{page.ctx.mbuilder.mmodule2nmodule[self].short_comment}'>{name}</a>")
1135                 else
1136                         page.append("<a href='{url}'>{name}</a>")
1137                 end
1138         end
1139
1140         # Return the module signature decorated with html
1141         fun html_signature(page: NitdocPage) do
1142                 page.append("<span>module ")
1143                 html_full_namespace(page)
1144                 page.append("</span>")
1145         end
1146
1147         # Return the module full namespace decorated with html
1148         fun html_full_namespace(page: NitdocPage) do
1149                 page.append("<span>")
1150                 var mowner = public_owner
1151                 if mowner != null then
1152                         public_owner.html_namespace(page)
1153                         page.append("::")
1154                 end
1155                 html_link(page)
1156                 page.append("</span>")
1157         end
1158
1159         # Return the module full namespace decorated with html
1160         fun html_namespace(page: NitdocPage) do
1161                 page.append("<span>")
1162                 var mowner = public_owner
1163                 if mowner != null then
1164                         public_owner.html_namespace(page)
1165                 else
1166                         html_link(page)
1167                 end
1168                 page.append("</span>")
1169         end
1170
1171         # Return the full comment of the module decorated with html
1172         fun html_full_comment(page: NitdocPage) do
1173                 if page.ctx.mbuilder.mmodule2nmodule.has_key(self) then
1174                         page.append("<div id='description'>")
1175                         page.append("<pre class='text_label'>{page.ctx.mbuilder.mmodule2nmodule[self].full_comment}</pre>")
1176                         page.append("<textarea class='edit' rows='1' cols='76' id='fileContent'></textarea>")
1177                         page.append("<a id='cancelBtn'>Cancel</a>")
1178                         page.append("<a id='commitBtn'>Commit</a>")
1179                         page.append("<pre class='text_label' id='preSave' type='2'></pre>")
1180                         page.append("</div>")
1181                 end
1182         end
1183 end
1184
1185 redef class MClass
1186         super Comparable
1187         redef type OTHER: MClass
1188         redef fun <(other: OTHER): Bool do return self.name < other.name
1189
1190         # Return the module signature decorated with html
1191         fun html_full_signature(page: NitdocPage) do
1192                 if visibility < public_visibility then page.append("{visibility.to_s} ")
1193                 page.append("{kind} ")
1194                 html_namespace(page)
1195         end
1196
1197         # name with formal parameter
1198         # Foo[A, B]
1199         private fun signature: String do
1200                 if arity > 0 then
1201                         return "{name}[{intro.parameter_names.join(", ")}]"
1202                 else
1203                         return name
1204                 end
1205         end
1206
1207         # Return a link (html a tag) to the nitdoc class page
1208         fun html_link(page: NitdocPage) do
1209                 page.append("<a href='{url}'")
1210                 if page.ctx.mbuilder.mclassdef2nclassdef.has_key(intro) then
1211                         var nclass = page.ctx.mbuilder.mclassdef2nclassdef[intro]
1212                         if nclass isa AStdClassdef then
1213                                 page.append(" title=\"{nclass.short_comment}\"")
1214                         end
1215                 end
1216                 page.append(">{signature}</a>")
1217         end
1218
1219         # Return the class namespace decorated with html
1220         fun html_namespace(page: NitdocPage) do
1221                 intro_mmodule.html_namespace(page)
1222                 page.append("::<span>")
1223                 html_link(page)
1224                 page.append("</span>")
1225         end
1226
1227         fun url: String do
1228                 return "class_{public_owner}_{c_name}.html"
1229         end
1230
1231         # Escape name for html output
1232         redef fun name do return super.html_escape
1233 end
1234
1235 redef class MProperty
1236         super Comparable
1237         redef type OTHER: MProperty
1238         redef fun <(other: OTHER): Bool do return self.name < other.name
1239
1240         # Return the property namespace decorated with html
1241         fun html_namespace(page: NitdocPage) do
1242                 intro_mclassdef.mclass.html_namespace(page)
1243                 page.append("::<span>")
1244                 intro.html_link(page)
1245                 page.append("</span>")
1246         end
1247
1248         # Escape name for html output
1249         redef fun name do return super.html_escape
1250 end
1251
1252 redef class MType
1253         fun html_link(page: NitdocPage) is abstract
1254 end
1255
1256 redef class MClassType
1257         redef fun html_link(page) do mclass.html_link(page)
1258 end
1259
1260 redef class MNullableType
1261         redef fun html_link(page) do
1262                 page.append("nullable ")
1263                 mtype.html_link(page)
1264         end
1265 end
1266
1267 redef class MGenericType
1268         redef fun html_link(page) do
1269                 page.append("<a href='{mclass.url}'>{mclass.name}</a>[")
1270                 for i in [0..arguments.length[ do
1271                         arguments[i].html_link(page)
1272                         if i < arguments.length - 1 then page.append(", ")
1273                 end
1274                 page.append("]")
1275         end
1276 end
1277
1278 redef class MParameterType
1279         redef fun html_link(page) do
1280                 var name = mclass.intro.parameter_names[rank]
1281                 page.append("<a href='{mclass.url}#FT_{name}' title='formal type'>{name}</a>")
1282         end
1283 end
1284
1285 redef class MVirtualType
1286         redef fun html_link(page) do mproperty.intro.html_link(page)
1287 end
1288
1289 redef class MClassDef
1290         # Return the classdef namespace decorated with html
1291         fun html_namespace(page: NitdocPage) do
1292                 mmodule.html_full_namespace(page)
1293                 page.append("::<span>")
1294                 mclass.html_link(page)
1295                 page.append("</span>")
1296         end
1297 end
1298
1299 redef class MPropDef
1300         super Comparable
1301         redef type OTHER: MPropDef
1302         redef fun <(other: OTHER): Bool do return self.mproperty.name < other.mproperty.name
1303
1304         fun url: String do return "{mclassdef.mclass.url}#{anchor}"
1305         fun anchor: String do return "PROP_{mclassdef.mclass.public_owner.name}_{c_name}"
1306
1307         # Return a link (html a tag) to the nitdoc class page
1308         fun html_link(page: NitdocPage) do
1309                 if page.ctx.mbuilder.mpropdef2npropdef.has_key(self) then
1310                         var nprop = page.ctx.mbuilder.mpropdef2npropdef[self]
1311                         page.append("<a href=\"{url}\" title=\"{nprop.short_comment}\">{mproperty.name}</a>")
1312                 else
1313                         page.append("<a href=\"{url}\">{mproperty.name}</a>")
1314                 end
1315         end
1316
1317         # Return a list item for the mpropdef
1318         private fun html_list_item(page: NitdocPage) do
1319                 if is_intro then
1320                         page.append("<li class='intro'>")
1321                         page.append("<span title='introduction'>I</span>&nbsp;")
1322                 else
1323                         page.append("<li class='redef'>")
1324                         page.append("<span title='redefinition'>R</span>&nbsp;")
1325                 end
1326                 html_link(page)
1327                 page.append("(")
1328                 mclassdef.mclass.html_link(page)
1329                 page.append(")")
1330                 page.append("</li>")
1331         end
1332
1333         # Return a list item for the mpropdef
1334         private fun html_sidebar_item(page: NitdocClass) do
1335                 if is_intro and mclassdef.mclass == page.mclass then
1336                         page.append("<li class='intro'>")
1337                         page.append("<span title='Introduced'>I</span>")
1338                 else if is_intro and mclassdef.mclass != page.mclass then
1339                         page.append("<li class='inherit'>")
1340                         page.append("<span title='Inherited'>H</span>")
1341                 else
1342                         page.append("<li class='redef'>")
1343                         page.append("<span title='Redefined'>R</span>")
1344                 end
1345                 html_link(page)
1346                 page.append("</li>")
1347         end
1348
1349         private fun html_full_desc(page: NitdocClass) is abstract
1350         private fun html_info(page: NitdocClass) is abstract
1351
1352         fun full_name: String do
1353                 return "{mclassdef.mclass.public_owner.name}::{mclassdef.mclass.name}::{mproperty.name}"
1354         end
1355
1356         private fun html_inheritance(page: NitdocClass) do
1357                 # definitions block
1358                 page.append("<p class='info'>")
1359                 page.ctx.mainmodule.linearize_mpropdefs(mproperty.mpropdefs)
1360                 var previous_defs = new Array[MPropDef]
1361                 var next_defs = new Array[MPropDef]
1362                 var self_passed = false
1363                 for def in mproperty.mpropdefs do
1364                         if def == self then
1365                                 self_passed = true
1366                                 continue
1367                         end
1368                         if not self_passed then
1369                                 if def.mclassdef.mclass.in_hierarchy(page.ctx.mainmodule) < page.mclass then continue
1370                                 if def.is_intro then continue
1371                                 previous_defs.add(def)
1372                         else
1373                                 if page.mclass.in_hierarchy(page.ctx.mainmodule) < def.mclassdef.mclass then continue
1374                                 next_defs.add(def)
1375                         end
1376                 end
1377                 page.append("defined by ")
1378                 mclassdef.mmodule.html_full_namespace(page)
1379                 if page.ctx.mbuilder.mpropdef2npropdef.has_key(self) then
1380                         page.append(" {page.show_source(page.ctx.mbuilder.mpropdef2npropdef[self].location)}")
1381                 end
1382                 if not is_intro then
1383                         page.append(", introduced by ")
1384                         mproperty.intro.mclassdef.mclass.html_link(page)
1385                         if page.ctx.mbuilder.mpropdef2npropdef.has_key(self) then
1386                                 page.append(" {page.show_source(page.ctx.mbuilder.mpropdef2npropdef[self].location)}")
1387                         end
1388                 end
1389                 if not previous_defs.is_empty then
1390                         page.append(", inherited from ")
1391                         for i in [0..previous_defs.length[ do
1392                                 var def = previous_defs[i]
1393                                 def.mclassdef.mclass.html_link(page)
1394                                 if page.ctx.mbuilder.mpropdef2npropdef.has_key(def) then
1395                                         page.append(" {page.show_source(page.ctx.mbuilder.mpropdef2npropdef[def].location)}")
1396                                 end
1397
1398                                 if i < previous_defs.length - 1 then page.append(", ")
1399                         end
1400                 end
1401                 if not next_defs.is_empty then
1402                         page.append(", redefined by ")
1403                         for i in [0..next_defs.length[ do
1404                                 var def = next_defs[i]
1405                                 def.mclassdef.mclass.html_link(page)
1406                                 if page.ctx.mbuilder.mpropdef2npropdef.has_key(def) then
1407                                         page.append(" {page.show_source(page.ctx.mbuilder.mpropdef2npropdef[def].location)}")
1408                                 end
1409                                 if i < next_defs.length - 1 then page.append(", ")
1410                         end
1411                 end
1412                 page.append(".</p>")
1413         end
1414
1415         private fun html_comment(page: NitdocClass) do
1416                 if not page.ctx.mbuilder.mpropdef2npropdef.has_key(self) then return
1417                 var nprop = page.ctx.mbuilder.mpropdef2npropdef[self]
1418                 page.append("<div class='description'>")
1419                 if not is_intro then
1420                         var intro_nprop = page.ctx.mbuilder.mpropdef2npropdef[mproperty.intro]
1421                         page.append("<p>from ")
1422                         mproperty.html_namespace(page)
1423                         page.append("</p>")
1424                         if intro_nprop.full_comment == "" then
1425                                 page.append("<a class=\"newComment\" title=\"32\" tag=\"\">New Comment</a>")
1426                         else
1427                                 page.append("<pre class=\"text_label\" title=\"\" name=\"\" tag=\"\" type=\"1\">{intro_nprop.full_comment}</pre>")
1428                         end
1429                         page.append("<p>from ")
1430                         mclassdef.html_namespace(page)
1431                         page.append("</p>")
1432                 end
1433                 if nprop.full_comment == "" then
1434                         page.append("<a class=\"newComment\" title=\"32\" tag=\"\">New Comment</a>")
1435                 else
1436                         page.append("<pre class=\"text_label\" title=\"\" name=\"\" tag=\"\" type=\"1\">{nprop.full_comment}</pre>")
1437                 end
1438                 page.append("<textarea id=\"fileContent\" class=\"edit\" cols=\"76\" rows=\"1\" style=\"display: none;\"></textarea><a id=\"cancelBtn\" style=\"display: none;\">Cancel</a><a id=\"commitBtn\" style=\"display: none;\">Commit</a><pre id=\"preSave\" class=\"text_label\" type=\"2\"></pre>")
1439                 html_inheritance(page)
1440                 page.append("</div>")
1441         end
1442 end
1443
1444 redef class MMethodDef
1445         redef fun html_full_desc(page) do
1446                 if not page.ctx.mbuilder.mpropdef2npropdef.has_key(self) then return
1447                 var nprop = page.ctx.mbuilder.mpropdef2npropdef[self]
1448                 var classes = new Array[String]
1449                 var is_redef = mproperty.intro_mclassdef.mclass != page.mclass
1450                 if mproperty.is_init then
1451                         classes.add("init")
1452                 else
1453                         classes.add("fun")
1454                 end
1455                 if is_redef then classes.add("redef")
1456                 classes.add(mproperty.visibility.to_s)
1457                 page.append("<article class='{classes.join(" ")}' id='{anchor}'>")
1458                 if nprop isa AAttrPropdef then
1459                         if nprop.mreadpropdef == self then
1460                                 page.append("<h3 class='signature'>{mproperty.name}: ")
1461                                 nprop.html_signature(page)
1462                                 page.append("</h3>")
1463                         else
1464                                 page.append("<h3 class='signature'>{mproperty.name}(value: ")
1465                                 nprop.html_signature(page)
1466                                 page.append(")</h3>")
1467                         end
1468                 else
1469                         var intro_nprop = page.ctx.mbuilder.mpropdef2npropdef[mproperty.intro]
1470                         page.append("<h3 class='signature'>{mproperty.name}")
1471                         intro_nprop.html_signature(page)
1472                         page.append("</h3>")
1473                 end
1474                 html_info(page)
1475                 html_comment(page)
1476                 page.append("</article>")
1477         end
1478
1479         redef fun html_info(page) do
1480                 page.append("<div class='info'>")
1481                 if mproperty.visibility < public_visibility then page.append("{mproperty.visibility.to_s} ")
1482                 if mproperty.intro_mclassdef.mclass != page.mclass then page.append("redef ")
1483                 page.append("fun ")
1484                 mproperty.html_namespace(page)
1485                 page.append("</div>")
1486                 page.append("<div style=\"float: right;\"><a id=\"lblDiffCommit\"></a></div>")
1487         end
1488 end
1489
1490 redef class MVirtualTypeDef
1491         redef fun html_full_desc(page) do
1492                 var is_redef = mproperty.intro_mclassdef.mclass != page.mclass
1493                 var classes = new Array[String]
1494                 classes.add("type")
1495                 if is_redef then classes.add("redef")
1496                 classes.add(mproperty.visibility.to_s)
1497                 page.append("<article class='{classes.join(" ")}' id='{anchor}'>")
1498                 page.append("<h3 class='signature'>{mproperty.name}: ")
1499                 bound.html_link(page)
1500                 page.append("</h3>")
1501                 html_info(page)
1502                 html_comment(page)
1503                 page.append("</article>")
1504         end
1505
1506         redef fun html_info(page) do
1507                 page.append("<div class='info'>")
1508                 if mproperty.intro_mclassdef.mclass != page.mclass then page.append("redef ")
1509                 page.append("type ")
1510                 mproperty.html_namespace(page)
1511                 page.append("</div>")
1512                 page.append("<div style=\"float: right;\"><a id=\"lblDiffCommit\"></a></div>")
1513         end
1514 end
1515
1516 #
1517 # Nodes redefs
1518 #
1519
1520 redef class AModule
1521         private fun short_comment: String do
1522                 if n_moduledecl != null and n_moduledecl.n_doc != null then
1523                         return n_moduledecl.n_doc.n_comment.first.text.substring_from(2).replace("\n", "").html_escape
1524                 end
1525                 return ""
1526         end
1527
1528         private fun full_comment: String do
1529                 var res = new Buffer
1530                 if n_moduledecl != null and n_moduledecl.n_doc != null then
1531                         for t in n_moduledecl.n_doc.n_comment do
1532                                 res.append(t.text.substring_from(1).html_escape)
1533                         end
1534                 end
1535                 return res.to_s
1536         end
1537 end
1538
1539 redef class AStdClassdef
1540         private fun short_comment: String do
1541                 if n_doc != null then return n_doc.n_comment.first.text.substring_from(2).replace("\n", "").html_escape
1542                 return ""
1543         end
1544
1545         private fun full_comment: String do
1546                 var res = new Buffer
1547                 if n_doc != null then
1548                         for t in n_doc.n_comment do res.append(t.text.substring_from(1).html_escape)
1549                 end
1550                 return res.to_s
1551         end
1552 end
1553
1554 redef class APropdef
1555         private fun short_comment: String is abstract
1556         private fun full_comment: String is abstract
1557         private fun html_signature(page: NitdocPage) is abstract
1558 end
1559
1560 redef class AAttrPropdef
1561         redef fun short_comment do
1562                 if n_doc != null then return n_doc.n_comment.first.text.substring_from(2).replace("\n", "").html_escape
1563                 return ""
1564         end
1565
1566         redef fun full_comment: String do
1567                 var res = new Buffer
1568                 if n_doc != null then
1569                         for t in n_doc.n_comment do res.append(t.text.substring_from(1).html_escape)
1570                 end
1571                 return res.to_s
1572         end
1573
1574         redef fun html_signature(page) do
1575                 if n_type != null then n_type.mtype.html_link(page)
1576         end
1577 end
1578
1579 redef class AMethPropdef
1580         redef fun short_comment do
1581                 if n_doc != null then return n_doc.n_comment.first.text.substring_from(2).replace("\n", "").html_escape
1582                 return ""
1583         end
1584
1585         redef fun full_comment do
1586                 var res = new Buffer
1587                 if n_doc != null then
1588                         for t in n_doc.n_comment do res.append(t.text.substring_from(1).html_escape)
1589                 end
1590                 return res.to_s
1591         end
1592
1593         redef fun html_signature(page) do
1594                 if n_signature != null then n_signature.html_link(page)
1595         end
1596 end
1597
1598 redef class ATypePropdef
1599         redef fun short_comment do
1600                 if n_doc != null then return n_doc.n_comment.first.text.substring_from(2).replace("\n", "").html_escape
1601                 return ""
1602         end
1603
1604         redef fun full_comment do
1605                 var res = new Buffer
1606                 if n_doc != null then
1607                         for t in n_doc.n_comment do res.append(t.text.substring_from(1).html_escape)
1608                 end
1609                 return res.to_s
1610         end
1611
1612         redef fun html_signature(page) do
1613                 mpropdef.bound.html_link(page)
1614         end
1615 end
1616
1617 redef class ASignature
1618         fun html_link(page: NitdocPage) do
1619                 #TODO closures
1620                 if not n_params.is_empty then
1621                         page.append("(")
1622                         for i in [0..n_params.length[ do
1623                                 n_params[i].html_link(page)
1624                                 if i < n_params.length - 1 then page.append(", ")
1625                         end
1626                         page.append(")")
1627                 end
1628                 if n_type != null then
1629                         page.append(":")
1630                         n_type.mtype.html_link(page)
1631                 end
1632         end
1633 end
1634
1635 redef class AParam
1636         fun html_link(page: NitdocPage) do
1637                 page.append(n_id.text)
1638                 if n_type != null then
1639                         page.append(": ")
1640                         n_type.mtype.html_link(page)
1641                         if n_dotdotdot != null then page.append("...")
1642                 end
1643         end
1644 end
1645
1646 var nitdoc = new NitdocContext
1647 nitdoc.generate_nitdoc