src/syntax/syntax_base.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2008 Jean Privat <jean@pryen.org>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Common syntax structures for syntax analysis of NIT AST.
  18 package syntax_base
  19
  20 import parser
  21 import mmloader
  22
  23 # Concrete NIT source module
  24 class MMSrcModule
  25 special MMModule
  26         # The related AST node
  27         readable attr _node: AModule
  28
  29         # Concrete NIT source local classs by name
  30         readable attr _src_local_classes: Map[Symbol, MMSrcLocalClass]
  31
  32         init(c: MMContext, source: AModule, dir: MMDirectory, name: Symbol, filename: String)
  33         do
  34                 super(name, dir, c, filename)
  35                 _node = source
  36                 _src_local_classes = new HashMap[Symbol, MMSrcLocalClass]
  37         end
  38 end
  39
  40 redef class MMGlobalClass
  41         # Check that a module can access a class
  42         meth check_visibility(v: AbsSyntaxVisitor, n: PNode, cm: MMSrcModule): Bool do
  43                 var pm = intro.module
  44                 assert pm isa MMSrcModule
  45                 var vpm = cm.visibility_for(pm)
  46                 if vpm == 3 then
  47                         return true
  48                 else if vpm == 0 then
  49                         v.error(n, "Visibility error: Class {self} comes from the hidden module {cm}.") # TODO: should not occur
  50                         return false
  51                 else if visibility_level >= 3 then
  52                         v.error(n, "Visibility error: Class {self} is private.")
  53                         return false
  54                 end
  55                 return true
  56         end
  57 end
  58
  59 # Concrete NIT source local classes
  60 class MMSrcLocalClass
  61 special MMConcreteClass
  62         # The related AST nodes
  63         readable attr _nodes: Array[PClassdef]
  64
  65         # Concrete NIT source generic formal parameter by name
  66         readable writable attr _formal_dict: Map[Symbol, MMTypeFormalParameter]
  67
  68         # Concrete NIT source properties by name
  69         readable attr _src_local_properties: Map[Symbol, MMLocalProperty]
  70
  71         init(mod: MMSrcModule, n: Symbol, cla: PClassdef, a: Int)
  72         do
  73                 super(mod, n, a)
  74                 _nodes = [cla]
  75                 _src_local_properties = new HashMap[Symbol, MMLocalProperty]
  76         end
  77 end
  78
  79 redef class MMGlobalProperty
  80         # Check that a module can access a property
  81         meth check_visibility(v: AbsSyntaxVisitor, n: PNode, cm: MMSrcModule, allows_protected: Bool): Bool do
  82                 var pm = local_class.module
  83                 assert pm isa MMSrcModule
  84                 var vpm = cm.visibility_for(pm)
  85                 if vpm == 3 then
  86                         return true
  87                 else if vpm == 0 then
  88                         # TODO: should not occurs
  89                         v.error(n, "Visibility error: Property {self} comes from the hidden module {cm}.")
  90                         return false
  91                 else if visibility_level >= 3 then
  92                         v.error(n, "Visibility error: Property {self} is private.")
  93                         return false
  94                 else if visibility_level >= 2 and not allows_protected then
  95                         v.error(n, "Visibility error: Property {self} is protected and can only acceded by self.")
  96                         return false
  97                 end
  98                 return true
  99         end
 100 end
 101
 102 redef class MMLocalProperty
 103         # The attached node (if any)
 104         meth node: PNode do return null
 105
 106         # Is the concrete method defined as init
 107         meth is_init: Bool do return false
 108 end
 109
 110 # Concrete NIT source attribute
 111 class MMSrcAttribute
 112 special MMAttribute
 113         redef readable attr _node: AAttrPropdef
 114         init(name: Symbol, cla: MMLocalClass, n: AAttrPropdef)
 115         do
 116                 super(name, cla)
 117                 _node = n
 118         end
 119 end
 120
 121 # Concrete NIT source method
 122 class MMSrcMethod
 123 special MMMethod
 124 end
 125
 126 # Concrete NIT source method for an automatic accesor
 127 class MMAttrImplementationMethod
 128 special MMSrcMethod
 129         redef readable attr _node: AAttrPropdef
 130         init(name: Symbol, cla: MMLocalClass, n: AAttrPropdef)
 131         do
 132                 super(name, cla)
 133                 _node = n
 134         end
 135 end
 136
 137 # Concrete NIT source method for an automatic read accesor
 138 class MMReadImplementationMethod
 139 special MMAttrImplementationMethod
 140         init(name: Symbol, cla: MMLocalClass, n: AAttrPropdef)
 141         do
 142                 super(name, cla, n)
 143         end
 144 end
 145
 146 # Concrete NIT source method for an automatic write accesor
 147 class MMWriteImplementationMethod
 148 special MMAttrImplementationMethod
 149         init(name: Symbol, cla: MMLocalClass, n: AAttrPropdef)
 150         do
 151                 super(name, cla, n)
 152         end
 153 end
 154
 155 # Concrete NIT source method for an explicit method
 156 class MMMethSrcMethod
 157 special MMSrcMethod
 158         redef meth is_init do return _node isa AConcreteInitPropdef
 159         redef readable attr _node: AMethPropdef
 160         init(name: Symbol, cla: MMLocalClass, n: AMethPropdef)
 161         do
 162                 super(name, cla)
 163                 _node = n
 164         end
 165 end
 166
 167 # Concrete NIT source virtual type
 168 class MMSrcTypeProperty
 169 special MMLocalProperty
 170 special MMTypeProperty
 171         redef readable attr _node: ATypePropdef
 172         init(name: Symbol, cla: MMLocalClass, n: ATypePropdef)
 173         do
 174                 super(name, cla)
 175                 _node = n
 176         end
 177 end
 178
 179 # Concrete NIT implicit constructor
 180 class MMImplicitInit
 181 special MMMethSrcMethod
 182         redef meth is_init do return true
 183         readable attr _unassigned_attributes: Array[MMSrcAttribute]
 184         readable attr _super_inits: Array[MMLocalProperty]
 185         init(cla: MMLocalClass, unassigned_attributes: Array[MMSrcAttribute], super_inits: Array[MMLocalProperty])
 186         do
 187                 super(once "init".to_symbol, cla, null)
 188                 _unassigned_attributes = unassigned_attributes
 189                 _super_inits = super_inits
 190         end
 191 end
 192
 193 # Local variables
 194 abstract class Variable
 195         # Name of the variable
 196         readable attr _name: Symbol
 197
 198         # Declaration AST node
 199         readable attr _decl: PNode
 200
 201         # Static type
 202         readable writable attr _stype: MMType
 203
 204         redef meth to_s do return _name.to_s
 205
 206         meth kind: String is abstract
 207
 208         init(n: Symbol, d: PNode)
 209         do
 210                 #assert n != null
 211                 #assert d != null
 212                 _name = n
 213                 _decl = d
 214         end
 215 end
 216
 217 # Variable declared with 'var'
 218 class VarVariable
 219 special Variable
 220         redef meth kind do return once "variable"
 221         init(n: Symbol, d: PNode) do super
 222 end
 223
 224 # Parameter of method (declared in signature)
 225 class ParamVariable
 226 special Variable
 227         redef meth kind do return once "parameter"
 228         init(n: Symbol, d: PNode) do super
 229 end
 230
 231 # Automatic variable (like in the 'for' statement)
 232 class AutoVariable
 233 special Variable
 234         redef meth kind do return once "automatic variable"
 235         init(n: Symbol, d: PNode) do super
 236 end
 237
 238 # False variable corresponding to closures declared in signatures
 239 # Lives in the same namespace than variables
 240 class ClosureVariable
 241 special Variable
 242         redef meth kind do return once "closure"
 243
 244         # The signature of the closure
 245         readable attr _closure: MMClosure
 246
 247         init(n: Symbol, d: PNode, c: MMClosure)
 248         do
 249                 super(n, d)
 250                 _closure = c
 251         end
 252 end
 253
 254 ###############################################################################
 255
 256 # Visitor used during the syntax analysis
 257 class AbsSyntaxVisitor
 258 special Visitor
 259         # The root type Object
 260         meth type_object: MMType
 261         do
 262                 return _module.class_by_name(once ("Object".to_symbol)).get_type
 263         end
 264
 265         # The primitive type Bool
 266         meth type_bool: MMType
 267         do
 268                 return _module.class_by_name(once ("Bool".to_symbol)).get_type
 269         end
 270
 271         # The primitive type Int
 272         meth type_int: MMType
 273         do
 274                 return _module.class_by_name(once ("Int".to_symbol)).get_type
 275         end
 276
 277         # The primitive type Float
 278         meth type_float: MMType
 279         do
 280                 return _module.class_by_name(once ("Float".to_symbol)).get_type
 281         end
 282
 283         # The primitive type Char
 284         meth type_char: MMType
 285         do
 286                 return _module.class_by_name(once ("Char".to_symbol)).get_type
 287         end
 288
 289         # The primitive type String
 290         meth type_string: MMType
 291         do
 292                 return _module.class_by_name(once ("String".to_symbol)).get_type
 293         end
 294
 295         # The primitive type Collection[Object]
 296         meth type_collection: MMType
 297         do
 298                 return _module.class_by_name(once ("Collection".to_symbol)).get_type
 299         end
 300
 301         # The primitive type Array[?]
 302         meth type_array(stype: MMType): MMType
 303         do
 304                 return _module.class_by_name(once ("Array".to_symbol)).get_instantiate_type([stype])
 305         end
 306
 307         # The primitive type Discrete
 308         meth type_discrete: MMType
 309         do
 310                 return _module.class_by_name(once ("Discrete".to_symbol)).get_type
 311         end
 312
 313         # The primitive type Range[?]
 314         meth type_range(stype: MMType): MMType
 315         do
 316                 return _module.class_by_name(once ("Range".to_symbol)).get_instantiate_type([stype])
 317         end
 318
 319         # The primitive type of null
 320         meth type_none: MMType
 321         do
 322                 return _module.type_none
 323         end
 324
 325         # The current module
 326         readable writable attr _module: MMSrcModule
 327
 328         # The current class
 329         readable writable attr _local_class: MMSrcLocalClass
 330
 331         # The current property
 332         readable writable attr _local_property: MMLocalProperty
 333
 334         # The current tool configuration/status
 335         readable attr _tc: ToolContext
 336
 337         # Display an error for a given syntax node
 338         meth error(n: PNode, s: String)
 339         do
 340                 _tc.error("{locate(n)}: {s}")
 341         end
 342
 343         # Display a warning for a given syntax node
 344         meth warning(n: PNode, s: String)
 345         do
 346                 _tc.warning("{locate(n)}: {s}")
 347         end
 348
 349         #
 350         meth locate(n: PNode): String
 351         do
 352                 if n != null then return n.locate
 353                 return _module.filename
 354         end
 355
 356         # Check conformity and display error
 357         meth check_conform(n: PNode, subtype: MMType, stype: MMType): Bool
 358         do
 359                 if stype == null or subtype == null then
 360                         return false
 361                 end
 362                 if subtype < stype then
 363                         return true
 364                 end
 365                 # Do not enforce nullable subtype rules yet
 366                 if subtype isa MMTypeNone or subtype.as_notnull < stype.as_notnull then
 367                         warning(n, "Nullable type warning: expected {stype}, got {subtype}")
 368                         return true
 369                 end
 370                 error(n, "Type error: expected {stype}, got {subtype}")
 371                 return false
 372         end
 373
 374         # Check that an expression has a static type and that
 375         # Display an error and return false if n is a statement
 376         # Require that the static type of n is known
 377         meth check_expr(n: PExpr): Bool
 378         do
 379                 if not n.is_typed then
 380                         if tc.error_count == 0 then
 381                                 print("{n.locate} not typed but not error")
 382                                 abort
 383                         end
 384                         # An error occured in a sub node,
 385                         # sillently cascade fail
 386                         return false
 387                 else if n.is_statement then
 388                         error(n, "Type error: expected expression.")
 389                         return false
 390                 end
 391                 return true
 392         end
 393
 394         # Combine check_conform and check_expr
 395         meth check_conform_expr(n: PExpr, stype: MMType): Bool
 396         do
 397                 if check_expr(n) then return check_conform(n, n.stype, stype) else return false
 398         end
 399
 400         # Check conformance between multiple expressions and a static type
 401         # Conformance is granted if among them there is a most general type
 402         # Return the most general type if a conformance is found
 403         # Display an error and return null if no conformance is found
 404         # @param stype is a possible additional type (without node)
 405         # Examples:
 406         #   Int, Int, Object => return Object
 407         #   Int, Float => display error, return null
 408         meth check_conform_multiexpr(stype: MMType, nodes: Collection[PExpr]): MMType
 409         do
 410                 var node: PExpr = null # candidate node
 411                 for n in nodes do
 412                         if not check_expr(n) then return null
 413                         var ntype = n.stype
 414                         if stype == null or (ntype != null and stype < ntype) then
 415                                 stype = ntype
 416                                 node = n
 417                         end
 418                 end
 419                 for n in nodes do
 420                         if not n.stype < stype then
 421                                 if node == null then
 422                                         error(n, "Type error: no most general type. Got {n.stype} and {stype}.")
 423                                 else
 424                                         error(n, "Type error: no most general type. Got {n.stype} and {stype} at {node.locate}.")
 425                                 end
 426                                 return null
 427                         end
 428                 end
 429                 return stype
 430         end
 431
 432         protected init(tc: ToolContext, module: MMSrcModule)
 433         do
 434                 _tc = tc
 435                 _module = module
 436         end
 437 end
 438
 439 ###############################################################################
 440
 441 redef class PNode
 442         protected meth accept_abs_syntax_visitor(v: AbsSyntaxVisitor) do visit_all(v)
 443 end
 444
 445 redef class Token
 446         attr _symbol: Symbol
 447
 448         # Symbol associated with the text
 449         # Lazily computed
 450         meth to_symbol: Symbol
 451         do
 452                 var s = _symbol
 453                 if s == null then
 454                         s = text.to_symbol
 455                         _symbol = s
 456                 end
 457                 return s
 458         end
 459 end
 460
 461 redef class PClassdef
 462         # Associated class (MM entity)
 463         meth local_class: MMSrcLocalClass is abstract
 464 end
 465
 466 redef class AAttrPropdef
 467         # Associated attribute (MM entity)
 468         meth prop: MMSrcAttribute is abstract
 469
 470         # Associated read accessor (MM entity)
 471         meth readmethod: MMSrcMethod is abstract
 472
 473         # Associated write accessor (MM entity)
 474         meth writemethod: MMSrcMethod is abstract
 475 end
 476
 477 redef class AMethPropdef
 478         # Associated method (MM entity)
 479         meth method: MMMethSrcMethod is abstract
 480
 481         # Associated 'self' variable
 482         meth self_var: ParamVariable is abstract
 483 end
 484
 485 redef class ATypePropdef
 486         # Associated formal type (MM entity)
 487         meth prop: MMSrcTypeProperty is abstract
 488 end
 489
 490 redef class PParam
 491         # Position in the signature
 492         meth position: Int is abstract
 493
 494         # Associated local variable
 495         meth variable: ParamVariable is abstract
 496 end
 497
 498 redef class PClosureDecl
 499         # Associated closure variable
 500         meth variable: ClosureVariable is abstract
 501 end
 502
 503 redef class PType
 504         # Retrieve the local class corresponding to the type.
 505         # Display an error and return null if there is no class
 506         # Display an error and return null if the type is not class based (formal one)
 507         meth get_local_class(v: AbsSyntaxVisitor): MMLocalClass is abstract
 508
 509         # Retrieve corresponding static type.
 510         # Display an error and return null if there is a problem
 511         meth get_stype(v: AbsSyntaxVisitor): MMType is abstract
 512
 513         # Retrieve corresponding static type.
 514         # Display an error and return null if there is a problem
 515         # But do not performs any subtype check.
 516         # get_unchecked_stype should be called to check that the static type is fully valid
 517         meth get_unchecked_stype(v: AbsSyntaxVisitor): MMType is abstract
 518
 519         # Check that a static definition type is conform with regard to formal types
 520         # Useful with get_unchecked_stype
 521         # Remember that conformance check need that ancestors are totaly computed
 522         meth check_conform(v: AbsSyntaxVisitor) is abstract
 523 end
 524
 525 redef class AType
 526         attr _stype_cache: MMType
 527         attr _stype_cached: Bool = false
 528
 529         redef meth get_local_class(v)
 530         do
 531                 var name = n_id.to_symbol
 532                 var mod = v.module
 533                 var cla = v.local_class
 534
 535                 if (cla.formal_dict != null and cla.formal_dict.has_key(name)) or (cla.global_properties != null and cla.has_global_property_by_name(name)) then
 536                         v.error(n_id, "Type error: {name} is a formal type")
 537                         _stype_cached = true
 538                         return null
 539                 end
 540
 541                 if not mod.has_global_class_named(name) then
 542                         v.error(n_id, "Type error: class {name} not found in module {mod}.")
 543                         _stype_cached = true
 544                         return null
 545                 end
 546
 547                 var local_class = mod.class_by_name(name)
 548                 local_class.global.check_visibility(v, self, mod)
 549                 return local_class
 550         end
 551
 552         redef meth get_unchecked_stype(v)
 553         do
 554                 if _stype_cached then return _stype_cache
 555                 _stype_cached = true
 556
 557                 var name = n_id.to_symbol
 558                 var mod = v.module
 559                 var cla = v.local_class
 560                 var t: MMType
 561
 562                 if cla.formal_dict.has_key(name) then
 563                         if n_types.length > 0 then
 564                                 v.error(self, "Type error: formal type {name} cannot have formal parameters.")
 565                                 return null
 566                         end
 567                         t = cla.formal_dict[name]
 568                         if n_kwnullable != null then t = t.as_nullable
 569                         _stype_cache = t
 570                         return t
 571                 end
 572
 573                 if cla.global_properties != null and cla.has_global_property_by_name(name) then
 574                         if n_types.length > 0 then
 575                                 v.error(self, "Type error: formal type {name} cannot have formal parameters.")
 576                                 return null
 577                         end
 578                         t = cla.get_type.local_class.select_virtual_type(name).stype_for(cla.get_type)
 579                         if t == null then
 580                                 v.error(self, "Type error: circular definition in formal type {name}.")
 581                                 return null
 582                         end
 583                         if n_kwnullable != null then t = t.as_nullable
 584                         _stype_cache = t
 585                         return t
 586                 end
 587
 588                 var local_class = get_local_class(v)
 589                 if local_class == null then return null
 590
 591                 var arity = n_types.length
 592                 if local_class.arity != arity then
 593                         v.error(self, "Type error: '{local_class}' has {local_class.arity} parameters which differs from the {arity} params.")
 594                         return null
 595                 end
 596
 597                 if arity > 0 then
 598                         var tab = new Array[MMType]
 599                         for p in n_types do
 600                                 tab.add(p.get_unchecked_stype(v))
 601                         end
 602                         t = local_class.get_instantiate_type(tab)
 603                 else
 604                         t = local_class.get_type
 605                 end
 606                 if n_kwnullable != null then t = t.as_nullable
 607                 _stype_cache = t
 608                 return t
 609         end
 610
 611         redef meth get_stype(v)
 612         do
 613                 var t = get_unchecked_stype(v)
 614                 if t == null then return null
 615                 if not t.is_valid then return null
 616                 check_conform(v)
 617                 return t
 618         end
 619
 620         redef meth check_conform(v)
 621         do
 622                 var st = get_unchecked_stype(v)
 623                 if st == null then return
 624                 var local_class = st.local_class
 625                 var arity = n_types.length
 626                 if arity > 0 then
 627                         for i in [0..arity[ do
 628                                 var p = n_types[i]
 629                                 var pt = p.get_stype(v)
 630                                 var b = local_class.get_formal(i)
 631                                 if not b.is_valid then return
 632                                 var bt = b.bound
 633                                 bt = bt.adapt_to(st) # We need to abapt because of F-genericity
 634                                 v.check_conform(p, pt, bt)
 635                         end
 636                 end
 637         end
 638 end
 639
 640 redef class PExpr
 641         # Is the expression node correcly typed
 642         # Return false if typed was not yet computed or
 643         # if an error occured during the typing computation
 644         meth is_typed: Bool is abstract
 645
 646         # Is the expression node a statement? (ie has no return value)
 647         # require: is_typed
 648         meth is_statement: Bool is abstract
 649
 650         # The static type of the expression
 651         # require: is_typed and not is_statement
 652         meth stype: MMType is abstract
 653 end
 654
 655 redef class AVardeclExpr
 656         # Assiociated local variable
 657         readable writable attr _variable: VarVariable
 658 end
 659
 660 redef class AForExpr
 661         # Associated automatic local variable
 662         readable writable attr _variable: AutoVariable
 663 end
 664
 665 redef class ASelfExpr
 666         # Associated local variable
 667         readable writable attr _variable: ParamVariable
 668 end
 669
 670 redef class AVarFormExpr
 671         # Associated local variable
 672         readable writable attr _variable: Variable
 673 end
 674
 675 redef class AClosureCallExpr
 676         # Associated closure variable
 677         readable writable attr _variable: ClosureVariable
 678 end
 679
 680 redef class PClosureDef
 681         # Associated closure
 682         readable writable attr _closure: MMClosure
 683
 684         # Automatic variables
 685         readable writable attr _variables: Array[AutoVariable]
 686 end