lib/popcorn/examples/middlewares/example_advanced_logger.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2016 Alexandre Terrasa <alexandre@moz-code.org>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 import popcorn
  18 import realtime
  19
  20 redef class HttpRequest
  21         # Time that request was received by the Popcorn app.
  22         var timer: nullable Clock = null
  23 end
  24
  25 class RequestTimeHandler
  26         super Handler
  27
  28         redef fun all(req, res) do req.timer = new Clock
  29 end
  30
  31 class AdvancedLoggerHandler
  32         super Handler
  33
  34         redef fun all(req, res) do
  35                 var timer = req.timer
  36                 if timer != null then
  37                         print "{req.method} {req.uri} {res.color_status} ({timer.total}s)"
  38                 else
  39                         print "{req.method} {req.uri} {res.color_status}"
  40                 end
  41         end
  42 end
  43
  44 class AnotherHandler
  45         super Handler
  46
  47         redef fun get(req, res) do res.send "Hello World!"
  48 end
  49
  50 var app = new App
  51 app.use_before("/*", new RequestTimeHandler)
  52 app.use("/", new AnotherHandler)
  53 app.use_after("/*", new AdvancedLoggerHandler)
  54 app.listen("localhost", 3000)