src/metrics/ast_metrics.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2012 Jean Privat <jean@pryen.org>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Metrics about the nodes and identifiers in the AST
  18 module ast_metrics
  19 import metrics_base
  20
  21 redef class ToolContext
  22         var ast_metrics_phase: Phase = new AstMetricsPhase(self, null)
  23 end
  24
  25 private class AstMetricsPhase
  26         super Phase
  27         var node_counter = new Counter[String]
  28         var id_counter = new Counter[String]
  29
  30         redef fun process_mainmodule(mainmodule, given_mmodules)
  31         do
  32                 if not toolcontext.opt_ast.value and not toolcontext.opt_all.value then return
  33                 print "--- AST Metrics ---"
  34                 # Visit all the source code to collect data
  35                 var visitor = new AstMetricsVisitor(self)
  36                 for nmodule in toolcontext.modelbuilder.nmodules do
  37                         visitor.enter_visit(nmodule)
  38                 end
  39                 print "## All nodes of the AST"
  40                 node_counter.print_summary
  41                 node_counter.print_elements(10)
  42                 print "## All identifiers of the AST"
  43                 id_counter.print_summary
  44                 id_counter.print_elements(10)
  45         end
  46 end
  47
  48 private class AstMetricsVisitor
  49         super Visitor
  50
  51         var phase: AstMetricsPhase
  52
  53         redef fun visit(n)
  54         do
  55                 n.visit_all(self)
  56                 phase.node_counter.inc(n.class_name)
  57                 if n isa TId or n isa TAttrid or n isa TClassid then
  58                         assert n isa Token
  59                         phase.id_counter.inc(n.text)
  60                 end
  61         end
  62 end