src/parser/nit.sablecc3xx

   1
   2 /* This file is part of NIT ( http://www.nitlanguage.org ).
   3  *
   4  * Copyright 2008-2009 Jean Privat <jean@pryen.org>
   5  *
   6  * Licensed under the Apache License, Version 2.0 (the "License");
   7  * you may not use this file except in compliance with the License.
   8  * You may obtain a copy of the License at
   9  *
  10  *     http://www.apache.org/licenses/LICENSE-2.0
  11  *
  12  * Unless required by applicable law or agreed to in writing, software
  13  * distributed under the License is distributed on an "AS IS" BASIS,
  14  * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15  * See the License for the specific language governing permissions and
  16  * limitations under the License.
  17  */
  18
  19 /* This grammar defines the NIT language. */
  20
  21 /*****************************************************************************/
  22 Helpers
  23 /*****************************************************************************/
  24
  25 all = [0 .. 0xFF];
  26 lowercase = ['a' .. 'z'];
  27 uppercase = ['A' .. 'Z'];
  28 digit = ['0' .. '9'];
  29 letter = lowercase | uppercase | digit | '_';
  30
  31 tab = 9;
  32 cr = 13;
  33 lf = 10;
  34 any = [all - [cr + lf]];
  35
  36 // characers inside strings and super-strings (atomaton powaa)
  37 str_char
  38         = [any - [['"' + '{'] + '\']]
  39         | '\' any
  40         ;
  41 str_body = str_char*;
  42
  43 eol_helper = cr lf | cr | lf; // This takes care of different platforms
  44
  45 /*****************************************************************************/
  46 States
  47 /*****************************************************************************/
  48 initial;
  49
  50
  51 /*****************************************************************************/
  52 Tokens
  53 /*****************************************************************************/
  54
  55 blank = (' ' | tab)+;
  56
  57 eol = eol_helper;
  58 comment = '#' any* eol_helper;
  59
  60 kwpackage = 'package';
  61 kwimport = 'import';
  62 kwclass = 'class';
  63 kwabstract = 'abstract';
  64 kwinterface = 'interface';
  65 kwuniversal = 'universal';
  66 kwspecial = 'special';
  67 kwend = 'end';
  68 kwmeth = 'meth';
  69 kwtype = 'type';
  70 kwattr = 'attr';
  71 kwinit = 'init';
  72 kwredef = 'redef';
  73 kwis = 'is';
  74 kwdo = 'do';
  75 kwreadable = 'readable';
  76 kwwritable = 'writable';
  77 kwvar = 'var';
  78 kwintern = 'intern';
  79 kwextern = 'extern';
  80 kwprotected = 'protected';
  81 kwprivate = 'private';
  82 kwintrude = 'intrude';
  83 kwif = 'if';
  84 kwthen = 'then';
  85 kwelse = 'else';
  86 kwwhile = 'while';
  87 kwfor = 'for';
  88 kwin = 'in';
  89 kwand = 'and';
  90 kwor = 'or';
  91 kwnot = 'not';
  92 kwreturn = 'return';
  93 kwcontinue = 'continue';
  94 kwbreak = 'break';
  95 kwabort = 'abort';
  96 kwassert = 'assert';
  97 kwnew = 'new';
  98 kwisa = 'isa';
  99 kwonce = 'once';
 100 kwsuper = 'super';
 101 kwself = 'self';
 102 kwtrue = 'true';
 103 kwfalse = 'false';
 104 kwnull = 'null';
 105 kwas = 'as';
 106 kwwith = 'with';
 107
 108 opar = '(';
 109 cpar = ')';
 110 obra = '[';
 111 cbra = ']';
 112 comma = ',';
 113 column = ':';
 114 quad = '::';
 115 assign = '=';
 116 pluseq = '+=';
 117 minuseq = '-=';
 118 dotdotdot = '...';
 119 dotdot = '..';
 120 dot = '.';
 121 plus = '+';
 122 minus = '-';
 123 star = '*';
 124 slash = '/';
 125 percent = '%';
 126 eq = '==';
 127 ne = '!=';
 128 lt = '<';
 129 le = '<=';
 130 gt = '>';
 131 ge = '>=';
 132 starship = '<=>';
 133
 134 classid = uppercase letter*;
 135 id = lowercase letter*;
 136 attrid = '_' lowercase letter*;
 137
 138 number = digit+;
 139 float = digit* '.' digit+;
 140 char = ''' [any - ''']* ''';
 141 string = '"' str_body '"';
 142 start_string = '"' str_body '{';
 143 mid_string = '}' str_body '{';
 144 end_string = '}' str_body '"';
 145
 146
 147 /*****************************************************************************/
 148 Ignored Tokens
 149 /*****************************************************************************/
 150
 151 blank;
 152
 153 /*****************************************************************************/
 154 Productions
 155 /*****************************************************************************/
 156
 157 /* MODULES *******************************************************************/
 158 module
 159         = packagedecl? [imports]:import* [classdefs]:classdef* implicit_top_class? implicit_main_class? {-> New module(packagedecl, [imports.import],[classdefs.classdef,implicit_top_class.classdef,implicit_main_class.classdef])};
 160
 161 packagedecl
 162         = [doc]:no kwpackage no id [n2]:n1 {-> New packagedecl(doc.doc, kwpackage, id)};
 163
 164 import
 165         = [doc]:no visibility kwimport no id [n2]:n1            {-> New import(visibility, kwimport, id)}
 166         | {no} [doc]:no visibility kwimport no kwend [n2]:n1    {-> New import.no(visibility, kwimport, kwend)}
 167         ;
 168
 169 implicit_top_class {-> classdef}
 170         = propdefs_toplevel {-> New classdef.top([propdefs_toplevel.propdef])};
 171
 172 implicit_main_class {-> classdef?}
 173         = implicit_main_meth {-> New classdef.main([implicit_main_meth.propdef])}
 174         | {null} n {-> Null}
 175         ;
 176 implicit_main_meth {-> propdef}
 177         = [doc]:no stmts no {-> New propdef.main_meth(Null, stmts.expr)};
 178
 179 /* CLASSES *******************************************************************/
 180 classdef
 181         = [doc]:no redef visibility classkind no classid formaldefs? [specials]:special* propdefs? [n2]:no kwend {-> New classdef(doc.doc, redef.kwredef, visibility, classkind, classid, [formaldefs.formaldef], [specials.superclass], [propdefs.propdef])};
 182 redef {-> kwredef?}
 183         = kwredef? {-> kwredef};
 184 classkind
 185         = {concrete} kwclass
 186         | {abstract} kwabstract kwclass
 187         | {interface} kwinterface
 188         | {universal} kwuniversal
 189         ;
 190
 191 formaldefs {-> formaldef*}
 192         = obra no formaldef formaldefs_tail* [n2]:no cbra {-> [formaldef, formaldefs_tail.formaldef]};
 193 formaldefs_tail {-> formaldef}
 194         = comma no formaldef {-> formaldef};
 195 formaldef
 196         = classid typing? {-> New formaldef(classid, typing.type)};
 197
 198 special {-> superclass}
 199         = no kwspecial [n2]:no type {-> New superclass(kwspecial, type)};
 200
 201 propdefs~toplevel {-> propdef*}
 202         = propdef~toplevel n1 propdefs_tail~toplevel* {-> [propdef~toplevel.propdef, propdefs_tail~toplevel.propdef]}
 203         ;
 204 propdefs_tail~toplevel {-> propdef}
 205         = propdef~toplevel n1 {-> propdef~toplevel.propdef}
 206         ;
 207 propdef~toplevel {-> propdef}
 208         = {meth} [doc]:no redef visibility kwmeth methid signature kwdo stmtso kwend? {-> New propdef.concrete_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature, stmtso.expr)}
 209 !toplevel| {deferred} [doc]:no redef visibility kwmeth methid signature kwis kwabstract {-> New propdef.deferred_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature)}
 210 !toplevel| {intern} [doc]:no redef visibility kwmeth methid signature kwis kwintern {-> New propdef.intern_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature)}
 211         | {extern} [doc]:no redef visibility kwmeth methid signature kwis kwextern string? {-> New propdef.extern_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature, string)}
 212 !toplevel| {attr} [doc]:no readable writable redef visibility kwattr attrid typing? {-> New propdef.attr(doc.doc, readable.able, writable.able, redef.kwredef, visibility, kwattr, attrid, typing.type, Null)}
 213 !toplevel| {attr2} [doc]:no readable writable redef visibility kwattr attrid typing? assign [n2]:no expr {-> New propdef.attr(doc.doc, readable.able, writable.able, redef.kwredef, visibility, kwattr, attrid, typing.type, expr)}
 214 !toplevel| {init} [doc]:no redef visibility kwinit methid? signature kwdo stmtso kwend? {-> New propdef.concrete_init(doc.doc, redef.kwredef, visibility, kwinit, methid, signature, stmtso.expr)}
 215 !toplevel| {type} [doc]:no redef visibility kwtype classid typing {-> New propdef.type(doc.doc, redef.kwredef, visibility, kwtype, classid, typing.type)}
 216         ;
 217 readable {-> able?}
 218         = redef kwreadable {-> New able.read(redef.kwredef, kwreadable)}
 219         | {empty} {-> Null}
 220         ;
 221 writable {-> able?}
 222         = redef kwwritable {-> New able.write(redef.kwredef, kwwritable)}
 223         | {empty} {-> Null}
 224         ;
 225
 226 visibility
 227         = {public} {-> New visibility.public()}
 228         | {private} kwprivate no {-> New visibility.private(kwprivate)}
 229         | {protected} kwprotected no {-> New visibility.protected(kwprotected)}
 230         | {intrude} kwintrude no {-> New visibility.intrude(kwintrude)}
 231         ;
 232
 233 methid
 234         = {id} id
 235         | {plus} plus
 236         | {minus} minus
 237         | {star} star
 238         | {slash} slash
 239         | {percent} percent
 240         | {eq} eq
 241         | {ne} ne
 242         | {le} le
 243         | {ge} ge
 244         | {lt} lt
 245         | {gt} gt
 246         | {bra} obra cbra
 247         | {starship} starship
 248         | {assign} id assign
 249         | {braassign} obra cbra assign
 250         ;
 251
 252 signature
 253         = params? typing? closure_decls {-> New signature([params.param], typing.type, [closure_decls.closure_decl])}
 254         | {noclosures} params? typing? no {-> New signature([params.param], typing.type, [])}
 255         ;
 256
 257 signature_noclosures {-> signature}
 258         = params? typing? {-> New signature([params.param], typing.type, [])};
 259
 260 params {-> param*}
 261         = opar no param params_tail* [n2]:no cpar {-> [param, params_tail.param]}
 262         | {empty} opar no cpar {-> []}
 263         ;
 264 params_tail {-> param}
 265         = comma no param {-> param};
 266 param
 267         = {untyped} id {-> New param(id, Null, Null)}
 268         | id typing dotdotdot? {-> New param(id, typing.type, dotdotdot)}
 269         ;
 270
 271 closure_decls {->closure_decl*}
 272         = no closure_decl+ {-> [closure_decl]};
 273 closure_decl
 274         = kwwith kwbreak? [no2]:no id signature_noclosures n {-> New closure_decl(kwwith, kwbreak, id, signature_noclosures.signature, Null)}
 275         | {optionnal} kwwith kwbreak? [no2]:no id signature_noclosures kwdo stmtso n {-> New closure_decl(kwwith, kwbreak, id, signature_noclosures.signature, stmtso.expr)}
 276         ;
 277
 278 /* TYPES *********************************************************************/
 279 type~nopar~nobra {-> type}
 280         = {simple} classid {-> New type(classid, [])}
 281 !nobra  | {generic} classid obra no types [n2]:no cbra {-> New type(classid, [types.type])}
 282         ;
 283 types {-> type*}
 284         = type types_tail* {-> [type, types_tail.type]};
 285 types_tail {-> type}
 286         = comma no type {-> type};
 287 typing {-> type}
 288         = column no type {-> type};
 289
 290 /* STATMENTS *****************************************************************/
 291 stmtso~withelse {-> expr?}
 292         = {oneline} stmt~withelse {-> stmt~withelse.expr}
 293         | {block} n stmts [n2]:n kwend {-> stmts.expr}
 294         | {emptyblock} n kwend {-> New expr.block([])}
 295         | {emptyoneline} kwend {-> New expr.block([])}
 296         ;
 297 stmts {-> expr}
 298         = stmt stmts_tail* {-> New expr.block([stmt.expr, stmts_tail.expr])};
 299 stmts_tail {-> expr}
 300         = n stmt {-> stmt.expr};
 301 stmt~withelse {-> expr}
 302         = {vardecl} vardecl~withelse {-> vardecl~withelse.expr}
 303         | {assign} assignment~withelse {-> assignment~withelse.expr}
 304         | {return} kwreturn expr_final~withelse? {-> New expr.return(kwreturn, expr_final~withelse.expr)}
 305         | {break} kwbreak expr_final~withelse? {-> New expr.break(kwbreak, expr_final~withelse.expr)}
 306         | {abort} kwabort {-> New expr.abort(kwabort)}
 307         | {continue} kwcontinue expr_final~withelse? {-> New expr.continue(kwcontinue, expr_final~withelse.expr)}
 308         | {do} do~withelse {-> do~withelse.expr}
 309         | {if} if~withelse {-> if~withelse.expr}
 310         | {while} while~withelse {-> while~withelse.expr}
 311         | {for} for~withelse {-> for~withelse.expr}
 312         | {assert} assert~withelse {-> assert~withelse.expr}
 313 //      | {expr} expr {-> expr.expr}
 314         | {call} recv id args_nopar closure_defs~withelse? {-> New expr.call(recv.expr, id, [args_nopar.expr], [closure_defs~withelse.closure_def])}
 315         | {super} qualified? kwsuper args_nopar {-> New expr.super(qualified, kwsuper, [args_nopar.expr])}
 316         | {init} recv kwinit args_nopar {-> New expr.init(recv.expr, kwinit, [args_nopar.expr])}
 317         ;
 318
 319 closure_defs~withelse {-> closure_def*}
 320         = {one} closure_def_last~withelse {-> [closure_def_last~withelse.closure_def]}
 321         | closure_def closure_defs~withelse {-> [closure_def, closure_defs~withelse.closure_def]}
 322         ;
 323
 324 closure_def_last~withelse {-> closure_def}
 325         = kwwith idlist? kwdo stmtso~withelse {-> New closure_def(kwwith, [idlist.id], kwdo, stmtso~withelse.expr)}
 326         ;
 327
 328 closure_def {-> closure_def}
 329         = kwwith idlist? kwdo n stmts [n2]:n {-> New closure_def(kwwith, [idlist.id], kwdo, stmts.expr)}
 330         | {empty} kwwith idlist? kwdo n {-> New closure_def(kwwith, [idlist.id], kwdo, Null)}
 331         ;
 332
 333 vardecl~withelse{-> expr}
 334         = kwvar id typing? {-> New expr.vardecl(kwvar, id, typing.type, Null, Null)}
 335         | {assign} kwvar id typing? assign no expr_final~withelse {-> New expr.vardecl(kwvar, id, typing.type, assign, expr_final~withelse.expr)}
 336         ;
 337
 338 assignment~withelse {-> expr}
 339         = {attr} recv attrid assign expr_final~withelse {-> New expr.attr_assign(recv.expr, attrid, assign, expr_final~withelse.expr)}
 340         | {call} recv id args assign expr_final~withelse {-> New expr.call_assign(recv.expr, id, [args.expr], assign,  expr_final~withelse.expr)}
 341         | {bra} expr_atom braargs assign expr_final~withelse {-> New expr.bra_assign(expr_atom.expr, [braargs.expr], assign,  expr_final~withelse.expr)}
 342         | {attr_re} recv attrid assign_op expr_final~withelse {-> New expr.attr_reassign(recv.expr, attrid, assign_op,  expr_final~withelse.expr)}
 343         | {call_re} recv id args assign_op expr_final~withelse {-> New expr.call_reassign(recv.expr, id, [args.expr], assign_op,  expr_final~withelse.expr)}
 344         | {bra_re} expr_atom braargs assign_op expr_final~withelse {-> New expr.bra_reassign(expr_atom.expr, [braargs.expr], assign_op,  expr_final~withelse.expr)}
 345         ;
 346 assign_op
 347         = {plus} pluseq
 348         | {minus} minuseq
 349         ;
 350
 351 do~withelse {-> expr}
 352         = kwdo stmtso~withelse {-> New expr.do(kwdo, stmtso~withelse.expr)}
 353         ;
 354
 355 if~withelse {-> expr}
 356         = {onelineelse} kwif no expr [n2]:no kwthen stmt_withelse kwelse stmtso~withelse {-> New expr.if(kwif, expr, stmt_withelse.expr, stmtso~withelse.expr)}
 357 !withelse       | {oneline} kwif no expr [n2]:no kwthen stmt {-> New expr.if(kwif, expr, stmt.expr, Null)}
 358 !withelse       | {block} kwif no expr [n2]:no kwthen [n3]:n stmts [n4]:n elsepartblock {-> New expr.if(kwif, expr, stmts.expr, elsepartblock.expr)}
 359 !withelse       | {emptyblock} kwif no expr [n2]:no kwthen [n3]:n? elsepartblock {-> New expr.if(kwif, expr, Null, elsepartblock.expr)}
 360         ;
 361 elsepartblock {-> expr?}
 362         = {else} kwelse stmtso {-> stmtso.expr}
 363         | {empty} kwend {-> Null}
 364         ;
 365
 366 while~withelse {-> expr}
 367         = kwwhile no expr [n2]:no kwdo stmtso~withelse {-> New expr.while(kwwhile, expr, kwdo, stmtso~withelse.expr)};
 368
 369 for~withelse {-> expr}
 370         = kwfor no id [n2]:no kwin [n3]:no expr [n4]:no kwdo stmtso~withelse {-> New expr.for(kwfor, id, expr, kwdo, stmtso~withelse.expr)};
 371
 372 assert~withelse {-> expr}
 373         = kwassert assertid? expr_final~withelse {-> New expr.assert(kwassert, assertid.id, expr_final~withelse.expr)};
 374 assertid {-> id}
 375         = id column {-> id};
 376
 377 /* EXPRESSIONS ***************************************************************/
 378 expr_final~nopar~withelse~nobra {-> expr}
 379         = expr~nopar~nobra {-> expr~nopar~nobra.expr}
 380         | {closure_call} recv~nobra id args closure_defs~withelse {-> New expr.call(recv~nobra.expr, id, [args.expr], [closure_defs~withelse.closure_def])}
 381 !nobra!nopar    | {closure_bra} expr_atom braargs closure_defs~withelse {-> New expr.bra(expr_atom.expr, [braargs.expr], [closure_defs~withelse.closure_def])}
 382         ;
 383
 384 expr~nopar~nobra {-> expr}
 385         = expr_and~nopar~nobra {-> expr_and~nopar~nobra.expr}
 386         | {ifexpr} kwif [n1]:no expr [n2]:no kwthen [n3]:no [then]:expr [n4]:no kwelse [n5]:no [else]:expr~nopar~nobra {-> New expr.ifexpr(kwif, expr, kwthen, then, kwelse, else.expr)}
 387         ;
 388
 389 expr_and~nopar~nobra {-> expr}
 390         = expr_not~nopar~nobra {-> expr_not~nopar~nobra.expr}
 391         | {or} expr_and~nopar~nobra kwor no expr_not~nopar~nobra {-> New expr.or(expr_and~nopar~nobra.expr, expr_not~nopar~nobra.expr)}
 392         | {and} expr_and~nopar~nobra kwand no expr_not~nopar~nobra {-> New expr.and(expr_and~nopar~nobra.expr, expr_not~nopar~nobra.expr)}
 393         ;
 394
 395 expr_not~nopar~nobra {-> expr}
 396         = expr_eq~nopar~nobra {-> expr_eq~nopar~nobra.expr}
 397         | {not} kwnot no expr_not~nopar~nobra {-> New expr.not(kwnot, expr_not~nopar~nobra.expr)}
 398         ;
 399
 400 expr_eq~nopar~nobra {-> expr}
 401         = expr_add~nopar~nobra {-> expr_add~nopar~nobra.expr}
 402         | {eq} expr_add~nopar~nobra eq no [expr2]:expr_add~nopar~nobra {-> New expr.eq(expr_add~nopar~nobra.expr, expr2.expr)}
 403         | {ee} expr_add~nopar~nobra kwis no [expr2]:expr_add~nopar~nobra {-> New expr.ee(expr_add~nopar~nobra.expr, expr2.expr)}
 404         | {ne} expr_add~nopar~nobra ne no [expr2]:expr_add~nopar~nobra {-> New expr.ne(expr_add~nopar~nobra.expr, expr2.expr)}
 405         | {lt} expr_add~nopar~nobra lt no [expr2]:expr_add~nopar~nobra {-> New expr.lt(expr_add~nopar~nobra.expr, expr2.expr)}
 406         | {le} expr_add~nopar~nobra le no [expr2]:expr_add~nopar~nobra {-> New expr.le(expr_add~nopar~nobra.expr, expr2.expr)}
 407         | {gt} expr_add~nopar~nobra gt no [expr2]:expr_add~nopar~nobra {-> New expr.gt(expr_add~nopar~nobra.expr, expr2.expr)}
 408         | {ge} expr_add~nopar~nobra ge no [expr2]:expr_add~nopar~nobra {-> New expr.ge(expr_add~nopar~nobra.expr, expr2.expr)}
 409         | {starship} expr_add~nopar~nobra starship no [expr2]:expr_add~nopar~nobra {-> New expr.starship(expr_add~nopar~nobra.expr, expr2.expr)}
 410         | {isa} expr_add~nopar~nobra kwisa no type~nopar~nobra {-> New expr.isa(expr_add~nopar~nobra.expr, type~nopar~nobra.type)}
 411         ;
 412
 413 expr_add~nopar~nobra {-> expr}
 414         =  expr_mul~nopar~nobra {-> expr_mul~nopar~nobra.expr}
 415         | {plus} expr_add~nopar~nobra plus no [expr2]:expr_mul~nopar~nobra {-> New expr.plus(expr_add~nopar~nobra.expr, expr2.expr)}
 416         | {minus} expr_add~nopar~nobra minus no [expr2]:expr_mul~nopar~nobra {-> New expr.minus(expr_add~nopar~nobra.expr, expr2.expr)}
 417         ;
 418
 419 expr_mul~nopar~nobra {-> expr}
 420         = expr_minus~nopar~nobra {-> expr_minus~nopar~nobra.expr}
 421         | {star} expr_mul~nopar~nobra star no [expr2]:expr_minus~nopar~nobra {-> New expr.star(expr_mul~nopar~nobra.expr, expr2.expr)}
 422         | {slash} expr_mul~nopar~nobra slash no [expr2]:expr_minus~nopar~nobra {-> New expr.slash(expr_mul~nopar~nobra.expr, expr2.expr)}
 423         | {percent} expr_mul~nopar~nobra percent no [expr2]:expr_minus~nopar~nobra {-> New expr.percent(expr_mul~nopar~nobra.expr, expr2.expr)}
 424         ;
 425
 426 expr_minus~nopar~nobra {-> expr}
 427         = expr_new~nopar~nobra {-> expr_new~nopar~nobra.expr}
 428         | {minus} minus no expr_minus~nopar~nobra {-> New expr.uminus(minus, expr_minus~nopar~nobra.expr)}
 429         | {once} kwonce no expr_minus~nopar~nobra {-> New expr.once(kwonce, expr_minus~nopar~nobra.expr)}
 430         ;
 431
 432 expr_new~nopar~nobra {-> expr}
 433         = expr_atom~nopar~nobra {-> expr_atom~nopar~nobra.expr}
 434         | {new} kwnew no type~nopar~nobra args {-> New expr.new(kwnew, type~nopar~nobra.type, Null, [args.expr])}
 435         ;
 436
 437 expr_atom~nopar~nobra {-> expr}
 438         = {attr} recv~nopar~nobra attrid {-> New expr.attr(recv~nopar~nobra.expr, attrid)}
 439         | {call} recv~nopar~nobra id args {-> New expr.call(recv~nopar~nobra.expr, id, [args.expr], [])}
 440         | {super} qualified? kwsuper args {-> New expr.super(qualified, kwsuper, [args.expr])}
 441         | {init} recv~nopar~nobra kwinit args {-> New expr.init(recv~nopar~nobra.expr, kwinit, [args.expr])}
 442 !nobra!nopar    | {bra} expr_atom braargs {-> New expr.bra(expr_atom.expr, [braargs.expr], [])}
 443         | {new} kwnew no type~nopar~nobra dot [n2]:no id args {-> New expr.new(kwnew, type~nopar~nobra.type, id, [args.expr])}
 444 !nobra!nopar    | {range} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no cbra {-> New expr.crange(expr, expr2.expr)}
 445 !nobra!nopar    | {orange} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no [cbra]:obra  {-> New expr.orange(expr, expr2.expr)}
 446 !nobra!nopar    | {array} braargs {-> New expr.array([braargs.expr])}
 447         | {self} kwself {-> New expr.self(kwself)}
 448         | {true} kwtrue {-> New expr.true(kwtrue)}
 449         | {false} kwfalse {-> New expr.false(kwfalse)}
 450         | {null} kwnull {-> New expr.null(kwnull)}
 451         | {int} number  {-> New expr.int(number)}
 452         | {float} float  {-> New expr.float(float)}
 453         | {char} char  {-> New expr.char(char)}
 454         | {string} string  {-> New expr.string(string)}
 455         | {superstring} superstring  {-> superstring.expr}
 456 !nopar  | {par} opar expr cpar {-> expr}
 457         | {as_cast} expr_atom~nopar~nobra dot no kwas [n2]:no opar [n3]:no type [n4]:no cpar {-> New expr.as_cast(expr_atom~nopar~nobra.expr, kwas, type)}
 458         ;
 459
 460 superstring {-> expr}
 461         = superstring_start superstring_middle* superstring_end {-> New expr.superstring([superstring_start.expr, superstring_middle.expr, superstring_end.expr])};
 462 superstring_start {-> expr*}
 463         = start_string_p no expr [n2]:no {-> [start_string_p.expr, expr]};
 464 start_string_p {-> expr}
 465         = start_string {-> New expr.start_string(start_string)};
 466 superstring_middle {-> expr*}
 467         = mid_string_p no expr [n2]:no {-> [mid_string_p.expr, expr]};
 468 mid_string_p {-> expr}
 469         = mid_string {-> New expr.mid_string(mid_string)};
 470 superstring_end {-> expr}
 471         = end_string {-> New expr.end_string(end_string)};
 472
 473 /* MISC **********************************************************************/
 474
 475 recv~nopar~nobra {-> expr}
 476         = expr_atom~nopar~nobra dot no {-> expr_atom~nopar~nobra.expr}
 477         | {implicit} {-> New expr.implicit_self()}
 478         ;
 479
 480 args {-> expr*}
 481         = opar no expr [n2]:no args_tail* cpar {-> [expr, args_tail.expr]}
 482         | {emptypar} opar no cpar {-> []}
 483         | {empty} {-> []}
 484         ;
 485 args_nopar {-> expr*}
 486         = opar no expr [n2]:no args_tail* cpar {-> [expr, args_tail.expr]}
 487         | {onearg} expr_nopar {-> [expr_nopar.expr]}
 488         | {emptypar} opar no cpar {-> []}
 489         | {empty} {-> []}
 490         ;
 491 braargs {-> expr*}
 492         = obra no expr [n2]:no args_tail* cbra {-> [expr, args_tail.expr]};
 493 args_tail {-> expr}
 494         = comma no expr [n2]:no {-> expr};
 495 idlist {-> id*}
 496         = {single} id {-> [id]}
 497         | {more} idlist no comma [n2]:no id {-> [idlist.id, id]}
 498         ;
 499
 500 qualified
 501         = {cla} modquad* classquad {-> New qualified([modquad.id], classquad.classid)}
 502         | {mod} modquad+ {-> New qualified([modquad.id], Null)}
 503         ;
 504 modquad {-> id}
 505         = id quad no {-> id};
 506 classquad {-> classid}
 507         = classid quad no {-> classid};
 508
 509 n1      = {a} comment | {b} eol;
 510 n {-> doc?}
 511         = {a} n2? comment+ {-> New doc([comment])}
 512         | {b} n2 {-> Null}
 513         ;
 514 no {-> doc?}
 515         = {empty} {-> Null}
 516         | n {-> n.doc}
 517         ;
 518
 519 n2
 520         = {a} n2? comment+ eol+
 521         | {b} eol+
 522         ;
 523
 524 /*****************************************************************************/
 525 Abstract Syntax Tree
 526 /*****************************************************************************/
 527
 528 module  = packagedecl? [imports]:import* [classdefs]:classdef*;
 529
 530 packagedecl
 531         = doc? kwpackage id;
 532
 533 import  =  visibility kwimport id
 534         | {no} visibility kwimport kwend
 535         ;
 536
 537 visibility
 538         = {public}
 539         | {private} kwprivate
 540         | {protected} kwprotected
 541         | {intrude} kwintrude
 542         ;
 543
 544 classdef = doc? kwredef? visibility classkind [id]:classid? [formaldefs]:formaldef* [superclasses]:superclass* [propdefs]:propdef*
 545         | {top} [propdefs]:propdef*
 546         | {main} [propdefs]:propdef*
 547         ;
 548 classkind
 549         = {concrete} kwclass
 550         | {abstract} kwabstract kwclass
 551         | {interface} kwinterface
 552         | {universal} kwuniversal
 553         ;
 554 formaldef = [id]:classid type?;
 555 superclass = kwspecial type;
 556
 557
 558 propdef = {attr} doc? [readable]:able? [writable]:able? kwredef? visibility kwattr [id]:attrid type? expr?
 559         | {meth} doc? kwredef? visibility methid signature
 560         | {deferred_meth} doc? kwredef? visibility kwmeth methid signature
 561         | {intern_meth} doc? kwredef? visibility kwmeth methid signature
 562         | {extern_meth} doc? kwredef? visibility kwmeth methid signature [extern]:string?
 563         | {concrete_meth} doc? kwredef? visibility kwmeth methid signature [block]:expr?
 564         | {concrete_init} doc? kwredef? visibility kwinit methid? signature [block]:expr?
 565         | {main_meth} kwredef? [block]:expr?
 566         | {type} doc? kwredef? visibility kwtype [id]:classid type
 567         ;
 568
 569 able    = {read} kwredef? kwreadable
 570         | {write} kwredef? kwwritable
 571         ;
 572
 573 methid = {id} id | {plus} plus | {minus} minus | {star} star | {slash} slash | {percent} percent | {eq} eq | {ne} ne | {le} le | {ge} ge | {lt} lt | {gt} gt | {bra} obra cbra | {starship} starship | {assign} id assign | {braassign} obra cbra assign;
 574
 575 signature = [params]:param* type? [closure_decls]:closure_decl*;
 576
 577 param   = id type? dotdotdot?
 578         ;
 579
 580 closure_decl = kwwith kwbreak? id signature expr?
 581         ;
 582
 583 type    = [id]:classid [types]:type*;
 584
 585 expr    = {block} expr*
 586         | {vardecl} kwvar id type? assign? expr?
 587         | {return} kwreturn expr?
 588         | {break} kwbreak expr?
 589         | {abort} kwabort
 590         | {continue} kwcontinue expr?
 591         | {do} kwdo [block]:expr?
 592         | {if} kwif expr [then]:expr? [else]:expr?
 593         | {ifexpr} kwif expr kwthen [then]:expr kwelse [else]:expr
 594         | {while} kwwhile expr kwdo [block]:expr?
 595         | {for} kwfor id expr kwdo [block]:expr?
 596         | {assert} kwassert id? expr
 597         | {once} kwonce expr
 598         | {send} expr
 599         | {binop} expr [expr2]:expr
 600         | {or} expr [expr2]:expr
 601         | {and} expr [expr2]:expr
 602         | {not} kwnot expr
 603         | {eq} expr [expr2]:expr
 604         | {ee} expr [expr2]:expr
 605         | {ne} expr [expr2]:expr
 606         | {lt} expr [expr2]:expr
 607         | {le} expr [expr2]:expr
 608         | {gt} expr [expr2]:expr
 609         | {ge} expr [expr2]:expr
 610         | {isa} expr type
 611         | {plus} expr [expr2]:expr
 612         | {minus} expr [expr2]:expr
 613         | {starship} expr [expr2]:expr
 614         | {star} expr [expr2]:expr
 615         | {slash} expr [expr2]:expr
 616         | {percent} expr [expr2]:expr
 617         | {uminus} minus expr
 618         | {new} kwnew type id? [args]:expr*
 619         | {attr} expr [id]:attrid
 620         | {attr_assign} expr [id]:attrid assign [value]:expr
 621         | {attr_reassign} expr [id]:attrid assign_op [value]:expr
 622         | {call} expr id [args]:expr* [closure_defs]:closure_def*
 623         | {call_assign} expr id [args]:expr* assign [value]:expr
 624         | {call_reassign} expr id [args]:expr* assign_op [value]:expr
 625         | {super} qualified? kwsuper [args]:expr*
 626         | {init} expr kwinit [args]:expr*
 627         | {bra} expr [args]:expr* [closure_defs]:closure_def*
 628         | {bra_assign} expr [args]:expr* assign [value]:expr
 629         | {bra_reassign} expr [args]:expr* assign_op [value]:expr
 630         | {var} id
 631         | {var_assign} id assign [value]:expr
 632         | {var_reassign} id assign_op [value]:expr
 633         | {range} expr [expr2]:expr
 634         | {crange} expr [expr2]:expr
 635         | {orange} expr [expr2]:expr
 636         | {array} [exprs]:expr*
 637         | {self} kwself
 638         | {implicit_self}
 639         | {true} kwtrue
 640         | {false} kwfalse
 641         | {null} kwnull
 642         | {int} number
 643         | {float} float
 644         | {char} char
 645         | {string} string
 646         | {start_string} [string]:start_string
 647         | {mid_string} [string]:mid_string
 648         | {end_string} [string]:end_string
 649         | {superstring} [exprs]:expr*
 650         | {par} expr
 651         | {as_cast} expr kwas type
 652         ;
 653 assign_op
 654         = {plus} pluseq
 655         | {minus} minuseq
 656         ;
 657
 658 closure_def
 659         = kwwith id* kwdo expr?
 660         ;
 661
 662 qualified = id* classid? ;
 663
 664 doc = comment+;
 665
 666 /*****************************************************************************/
 667