src/parser/nit.sablecc3xx

   1
   2 /* This file is part of NIT ( http://www.nitlanguage.org ).
   3  *
   4  * Copyright 2008-2009 Jean Privat <jean@pryen.org>
   5  *
   6  * Licensed under the Apache License, Version 2.0 (the "License");
   7  * you may not use this file except in compliance with the License.
   8  * You may obtain a copy of the License at
   9  *
  10  *     http://www.apache.org/licenses/LICENSE-2.0
  11  *
  12  * Unless required by applicable law or agreed to in writing, software
  13  * distributed under the License is distributed on an "AS IS" BASIS,
  14  * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15  * See the License for the specific language governing permissions and
  16  * limitations under the License.
  17  */
  18
  19 /* This grammar defines the NIT language. */
  20 Package org.nitlanguage.gen;
  21
  22 /*****************************************************************************/
  23 Helpers
  24 /*****************************************************************************/
  25
  26 all = [0 .. 0xFF];
  27 lowercase = ['a' .. 'z'];
  28 uppercase = ['A' .. 'Z'];
  29 digit = ['0' .. '9'];
  30 hexdigit = ['0'..'9'] | ['a'..'f'] | ['A'..'F'];
  31 letter = lowercase | uppercase | digit | '_';
  32
  33 tab = 9;
  34 cr = 13;
  35 lf = 10;
  36 any = [all - [cr + lf]];
  37 eol_helper = cr lf | cr | lf; // This takes care of different platforms
  38
  39 // characers inside strings and super-strings (atomaton powaa)
  40 str_char
  41         = [any - [['"' + '{'] + '\']]
  42         | '\' any
  43         ;
  44 str_body = str_char*;
  45
  46 sstr_char
  47         = [any - [''' + '\']]
  48         | '\' any
  49         ;
  50
  51 sstr_body = sstr_char*;
  52
  53 long_str_char = str_char | cr | lf;
  54
  55 // because no substraction in sablecc3, complex long strings are difficult to express
  56 ls1 = '"' '"'? ;
  57 ls2 = '{' '{'? ;
  58 ls12 = ls1? (ls2 ls1)* ls2?;
  59
  60 long_str_part
  61         = ls12 long_str_char
  62         ;
  63
  64 long_str_body = long_str_part*;
  65 lsend1 = ls2? (ls1 ls2)* '"""' '"'*;
  66 lsend2 = ls1? (ls2 ls1)* '{{{' '{'*;
  67
  68 long_sstr_char = sstr_char | cr | lf;
  69 long_sstr_part
  70         = long_sstr_char
  71         | ''' long_sstr_char
  72         | ''' ''' long_sstr_char
  73         ;
  74
  75 long_sstr_body = long_sstr_part*;
  76
  77
  78 extern_code_char
  79         = [all - ['`' + '\']]
  80         | '\' all
  81         | '`' [all - '}']
  82         ;
  83 extern_code_body = extern_code_char*;
  84
  85 /*****************************************************************************/
  86 States
  87 /*****************************************************************************/
  88 initial;
  89
  90
  91 /*****************************************************************************/
  92 Tokens
  93 /*****************************************************************************/
  94
  95 blank = (' ' | tab)+;
  96
  97 eol = eol_helper;
  98 comment = '#' any* eol_helper?;
  99
 100 kwpackage = 'package';
 101 kwmodule = 'module';
 102 kwimport = 'import';
 103 kwclass = 'class';
 104 kwabstract = 'abstract';
 105 kwinterface = 'interface';
 106 kwenum = 'universal'|'enum';
 107 kwend = 'end';
 108 kwmeth = 'fun';
 109 kwtype = 'type';
 110 kwinit = 'init';
 111 kwredef = 'redef';
 112 kwis = 'is';
 113 kwdo = 'do';
 114 kwvar = 'var';
 115 kwextern = 'extern';
 116 kwpublic = 'public';
 117 kwprotected = 'protected';
 118 kwprivate = 'private';
 119 kwintrude = 'intrude';
 120 kwif = 'if';
 121 kwthen = 'then';
 122 kwelse = 'else';
 123 kwwhile = 'while';
 124 kwloop = 'loop';
 125 kwfor = 'for';
 126 kwin = 'in';
 127 kwand = 'and';
 128 kwor = 'or';
 129 kwnot = 'not';
 130 kwimplies = 'implies';
 131 kwreturn = 'return';
 132 kwcontinue = 'continue';
 133 kwbreak = 'break';
 134 kwabort = 'abort';
 135 kwassert = 'assert';
 136 kwnew = 'new';
 137 kwisa = 'isa';
 138 kwonce = 'once';
 139 kwsuper = 'super';
 140 kwself = 'self';
 141 kwtrue = 'true';
 142 kwfalse = 'false';
 143 kwnull = 'null';
 144 kwas = 'as';
 145 kwnullable = 'nullable';
 146 kwisset = 'isset';
 147 kwlabel = 'label';
 148 kwdebug = '__debug__';
 149
 150 opar = '(';
 151 cpar = ')';
 152 obra = '[';
 153 cbra = ']';
 154 comma = ',';
 155 column = ':';
 156 quad = '::';
 157 assign = '=';
 158 pluseq = '+=';
 159 minuseq = '-=';
 160 dotdotdot = '...';
 161 dotdot = '..';
 162 dot = '.';
 163 plus = '+';
 164 minus = '-';
 165 star = '*';
 166 starstar = '**';
 167 slash = '/';
 168 percent = '%';
 169 eq = '==';
 170 ne = '!=';
 171 lt = '<';
 172 le = '<=';
 173 ll = '<<';
 174 gt = '>';
 175 ge = '>=';
 176 gg = '>>';
 177 starship = '<=>';
 178 bang='!';
 179 at='@';
 180
 181 classid = uppercase letter*;
 182 id = lowercase letter*;
 183 attrid = '_' lowercase letter*;
 184
 185 number = digit+;
 186 hex_number = ('0x' | '0X') hexdigit+;
 187 float = digit* '.' digit+;
 188 string = '"' str_body '"' | '"' '"' '"' long_str_body lsend1 | ''' ''' ''' long_sstr_body ''' ''' ''';
 189 start_string = '"' str_body '{' | '"' '"' '"' long_str_body lsend2;
 190 mid_string = '}' str_body '{' | '}' '}' '}' long_str_body lsend2;
 191 end_string = '}' str_body '"' | '}' '}' '}' long_str_body lsend1;
 192 char = (''' [[any - '''] - '\'] ''') | (''' '\' any ''');
 193 bad_string = ('"'|'}') str_body | '"' '"' '"' long_str_body | ''' ''' ''' long_sstr_body;
 194 bad_char = ''' '\'? any;
 195
 196 extern_code_segment = '`' '{' extern_code_body '`' '}';
 197
 198 /*****************************************************************************/
 199 Ignored Tokens
 200 /*****************************************************************************/
 201
 202 blank;
 203
 204 /*****************************************************************************/
 205 Productions
 206 /*****************************************************************************/
 207
 208 /* MODULES *******************************************************************/
 209 module
 210         = moduledecl? [imports]:import* [extern_bodies]:extern_code_body* [classdefs]:topdef* implicit_main_class {-> New module(moduledecl, [imports.import], [extern_bodies.extern_code_block], [classdefs.classdef,implicit_main_class.classdef])};
 211
 212 moduledecl
 213         = [doc]:no redef visibility kwmodule no module_name annotation_withend [n2]:n1 {-> New moduledecl(doc.doc, redef.kwredef, visibility, kwmodule, module_name, annotation_withend.annotations)};
 214
 215 import
 216         = {std} [doc]:no redef visibility kwimport no module_name annotation_withend [n2]:n1 {-> New import.std(visibility, kwimport, module_name, annotation_withend.annotations)}
 217         | {no} [doc]:no redef visibility kwimport no kwend [n2]:n1 {-> New import.no(visibility, kwimport, kwend)}
 218         ;
 219
 220 topdef {-> classdef}
 221         = {classdef} classdef {-> classdef}
 222         | propdef_toplevel n1 {-> New classdef.top([propdef_toplevel.propdef])}
 223         ;
 224
 225 implicit_main_class {-> classdef?}
 226         = implicit_main_meth {-> New classdef.main([implicit_main_meth.propdef])}
 227         | {null} n? {-> Null}
 228         ;
 229 implicit_main_meth {-> propdef}
 230         = [doc]:no stmts {-> New propdef.main_meth(Null, stmts.expr)}
 231         | {n} [doc]:no stmtsn {-> New propdef.main_meth(Null, stmtsn.expr)}
 232         ;
 233
 234 /* CLASSES *******************************************************************/
 235 classdef
 236         = [doc]:no redef visibility classkind no qclassid formaldefs extern_code_block? propdefs kwend {-> New classdef.std(doc.doc, redef.kwredef, visibility, classkind, qclassid.classid, [formaldefs.formaldef], extern_code_block, [propdefs.propdef], kwend)};
 237 redef {-> kwredef?}
 238         = kwredef? {-> kwredef};
 239 classkind
 240         = {concrete} kwclass
 241         | {abstract} kwabstract kwclass
 242         | {interface} kwinterface
 243         | {enum} kwenum
 244         | {extern} kwextern kwclass
 245         ;
 246
 247 formaldefs {-> formaldef*}
 248         = obra no formaldef formaldefs_tail* [n2]:no cbra {-> [formaldef, formaldefs_tail.formaldef]}
 249         | {null} {-> []}
 250         ;
 251 formaldefs_tail {-> formaldef}
 252         = comma no formaldef {-> formaldef};
 253 formaldef
 254         = classid annotations? typing_o {-> New formaldef(classid, typing_o.type, annotations)};
 255
 256 superclass {-> propdef}
 257         = {super} [doc]:no redef visibility kwsuper [n2]:no type annotation_withend {-> New propdef.super(doc.doc, redef.kwredef, visibility, kwsuper, type, annotation_withend.annotations)}
 258         ;
 259
 260 propdefs {-> propdef*}
 261         = propdefn+ no {-> [propdefn.propdef]}
 262         | {super} superclass {-> [superclass.propdef]}
 263         | {empty} no {-> []}
 264         ;
 265 propdefn {-> propdef}
 266         = propdef n1 {-> propdef.propdef}
 267         ;
 268 propdef~toplevel {-> propdef}
 269         = {meth} [doc]:no redef visibility kwmeth qmethid signature annotation_noend? kwdo stmtso kwend_o {-> New propdef.meth(doc.doc, redef.kwredef, visibility, kwmeth, Null, Null, qmethid.methid, signature, annotation_noend.annotations, Null, Null, stmtso.expr)}
 270         | {nobody} [doc]:no redef visibility kwmeth qmethid signature annotation_withend_nonull {-> New propdef.meth(doc.doc, redef.kwredef, visibility, kwmeth, Null, Null, qmethid.methid, signature.signature, annotation_withend_nonull.annotations, Null, Null, Null)}
 271 !toplevel| {intern_new} [doc]:no redef visibility kwnew qmethid? signature annotation_withend_nonull {-> New propdef.meth(doc.doc, redef.kwredef, visibility, Null, Null, kwnew, qmethid.methid, signature, annotation_withend_nonull.annotations, Null, Null, Null)}
 272 !toplevel| {new} [doc]:no redef visibility kwnew qmethid? signature annotation_noend? kwdo stmtso kwend_o {-> New propdef.meth(doc.doc, redef.kwredef, visibility, Null, Null, kwnew, qmethid.methid, signature, annotation_noend.annotations, Null, Null, stmtso.expr)}
 273         | {extern_implicit} [doc]:no redef visibility kwmeth qmethid signature annotation_noend? extern_calls extern_code_block {-> New propdef.meth(doc.doc, redef.kwredef, visibility, kwmeth, Null, Null, qmethid.methid, signature.signature, annotation_noend.annotations, extern_calls, extern_code_block, Null)}
 274 !toplevel| {var3} [doc]:no redef visibility kwvar id typing_o annotation_withend {-> New propdef.attr(doc.doc, redef.kwredef, visibility, kwvar, id, typing_o.type, Null, annotation_withend.annotations, Null)}
 275 !toplevel| {var4} [doc]:no redef visibility kwvar id typing_o assign [n2]:no expr annotation_withend {-> New propdef.attr(doc.doc, redef.kwredef, visibility, kwvar, id, typing_o.type, expr.expr, annotation_withend.annotations, Null)}
 276 !toplevel| {var5} [doc]:no redef visibility kwvar id typing_o annotation_noend? kwdo stmtso kwend? {-> New propdef.attr(doc.doc, redef.kwredef, visibility, kwvar, id, typing_o.type, Null, annotation_noend.annotations, stmtso.expr)}
 277 !toplevel| {init} [doc]:no redef visibility kwinit qmethid? signature annotation_noend? kwdo stmtso kwend_o {-> New propdef.meth(doc.doc, redef.kwredef, visibility, Null, kwinit, Null, qmethid.methid, signature, annotation_noend.annotations, Null, Null, stmtso.expr)}
 278 !toplevel| {type} [doc]:no redef visibility kwtype classid typing annotation_withend {-> New propdef.type(doc.doc, redef.kwredef, visibility, kwtype, classid, typing.type, annotation_withend.annotations)}
 279 !toplevel| {extern_init_implicit} [doc]:no redef visibility kwnew qmethid? signature annotation_noend? extern_calls extern_code_block {-> New propdef.meth(doc.doc, redef.kwredef, visibility, Null, Null, kwnew, qmethid.methid, signature, annotation_noend.annotations, extern_calls, extern_code_block, Null)}
 280 !toplevel| {annot} line_annotation_forclass {-> line_annotation_forclass.propdef}
 281 !toplevel| {super} superclass {-> superclass.propdef}
 282         ;
 283 annotation_withend~nonull {-> annotations?}
 284         = {oneliner} kwis many_annotations {-> many_annotations.annotations}
 285         | {more} kwis n1 line_annotations kwend {-> line_annotations.annotations}
 286 !nonull | {null} {-> Null}
 287         ;
 288 annotation_noend {-> annotations}
 289         = {oneliner} kwis many_annotations {-> many_annotations.annotations}
 290         | {more} kwis n1 line_annotations {-> line_annotations.annotations}
 291         ;
 292
 293 visibility
 294         = {public} {-> New visibility.public(Null)}
 295         | {public2} kwpublic no {-> New visibility.public(kwpublic)}
 296         | {private} kwprivate no {-> New visibility.private(kwprivate)}
 297         | {protected} kwprotected no {-> New visibility.protected(kwprotected)}
 298         | {intrude} kwintrude no {-> New visibility.intrude(kwintrude)}
 299         ;
 300
 301 methid~noid {-> methid}
 302         = {plus} plus {-> New methid.plus(plus)}
 303         | {minus} minus {-> New methid.minus(minus)}
 304         | {star} star {-> New methid.star(star)}
 305         | {starstar} starstar {-> New methid.starstar(starstar)}
 306         | {slash} slash {-> New methid.slash(slash)}
 307         | {percent} percent {-> New methid.percent(percent)}
 308         | {eq} eq {-> New methid.eq(eq)}
 309         | {ne} ne {-> New methid.ne(ne)}
 310         | {le} le {-> New methid.le(le)}
 311         | {ge} ge {-> New methid.ge(ge)}
 312         | {lt} lt {-> New methid.lt(lt)}
 313         | {gt} gt {-> New methid.gt(gt)}
 314         | {ll} ll {-> New methid.ll(ll)}
 315         | {gg} gg {-> New methid.gg(gg)}
 316         | {bra} obra cbra {-> New methid.bra(obra, cbra)}
 317         | {starship} starship {-> New methid.starship(starship)}
 318         | {assign} id assign {-> New methid.assign(id, assign)}
 319         | {braassign} obra cbra assign {-> New methid.braassign(obra, cbra, assign)}
 320 !noid   | {id} id {-> New methid.id(id)}
 321         ;
 322
 323 signature {-> signature}
 324         = opar no params cpar typing [no2]:no {-> New signature(opar, [params.param], cpar, typing.type)}
 325         | {noret} opar no params cpar [no2]:no {-> New signature(opar, [params.param], cpar, Null)}
 326         | {nopar} typing no {-> New signature(Null, [], Null, typing.type)}
 327         | {noparnoret} no {-> New signature(Null, [], Null, Null)}
 328         ;
 329
 330 params {-> param*}
 331         = param params_tail* [n2]:no {-> [param, params_tail.param] }
 332         | {null} {-> []}
 333         ;
 334 params_tail {-> param}
 335         = comma no param {-> param};
 336 param
 337         = {untyped} id annotations_o {-> New param(id, Null, Null, annotations_o.annotations)}
 338         | id annotations? typing dotdotdot? {-> New param(id, typing.type, dotdotdot, annotations)}
 339         ;
 340
 341 extern_calls {-> extern_calls?}
 342         = kwimport no extern_call extern_call_tail* {-> New extern_calls( kwimport, [extern_call, extern_call_tail.extern_call] )}
 343         | {null} {-> Null}
 344         ;
 345 extern_call_tail {-> extern_call}
 346         = comma no extern_call {-> extern_call};
 347 extern_call {-> extern_call}
 348         = {prop} extern_call_prop {-> extern_call_prop.extern_call}
 349         | {cast} extern_call_cast {-> extern_call_cast.extern_call}
 350         | {super} kwsuper {-> New extern_call.super( kwsuper )}
 351         ;
 352 extern_call_prop {-> extern_call}
 353         = {local} qmethid {-> New extern_call.local_prop( qmethid.methid )}
 354         | {full} type dot qmethid {-> New extern_call.full_prop( type, dot, qmethid.methid )}
 355         | {init} type {-> New extern_call.init_prop( type )}
 356         ;
 357 extern_call_cast {-> extern_call}
 358         = {as_cast} [from_type]:type dot kwas [n2]:no opar [n3]:no [to_type]:type [n4]:no cpar {-> New extern_call.cast_as(from_type, dot, kwas, to_type)}
 359         | {as_cast2}[from_type]:type dot kwas [n2]:no [to_type]:type {-> New extern_call.cast_as(from_type, dot, kwas, to_type)}
 360         | {as_nullable} type dot kwas [n2]:no opar [n3]:no kwnullable [n4]:no cpar {-> New extern_call.as_nullable( type, kwas, kwnullable)}
 361         | {as_nullable2}type dot kwas [n2]:no kwnullable {-> New extern_call.as_nullable( type, kwas, kwnullable)}
 362         | {as_not_nullable} type dot kwas [n2]:no opar [n3]:no kwnot [n4]:no kwnullable [n5]:no cpar {-> New extern_call.as_not_nullable( type, kwas, kwnot, kwnullable)}
 363         | {as_not_nullable2}type dot kwas [n2]:no kwnot [n3]:no kwnullable {-> New extern_call.as_not_nullable( type, kwas, kwnot, kwnullable)}
 364         ;
 365
 366 string_o {->string?} = string? {-> string};
 367
 368 in_language = kwin no string [n1]:no {-> New in_language(kwin, string)};
 369 extern_code_block = in_language? extern_code_segment;
 370 extern_code_block_o {-> extern_code_block?}
 371         = extern_code_block {-> extern_code_block}
 372         | {null} {-> Null}
 373         ;
 374 extern_code_body {-> extern_code_block} = no extern_code_block {-> extern_code_block};
 375
 376 /* TYPES *********************************************************************/
 377 type~nobra~nopar {-> type}
 378         = {simple} kwnullable? classid annotations_o~nopar {-> New type(kwnullable, classid, [], annotations_o~nopar.annotations)}
 379 !nobra  | {generic} kwnullable? classid obra no types [n2]:no cbra annotations_o~nopar {-> New type(kwnullable, classid, [types.type], annotations_o~nopar.annotations)}
 380         ;
 381 types {-> type*}
 382         = type types_tail* {-> [type, types_tail.type]};
 383 types_tail {-> type}
 384         = comma no type {-> type};
 385 typing {-> type}
 386         = column no type {-> type};
 387 typing_o {-> type?}
 388         = column no type {-> type}
 389         | {null} {-> Null}
 390         ;
 391
 392 /* STATMENTS *****************************************************************/
 393 stmtso~withelse~withend {-> expr?}
 394         = {block} n stmtsnend {-> stmtsnend.expr}
 395         | {emptyblock} n kwend {-> New expr.block([], kwend)}
 396         | {emptyoneline} kwend {-> New expr.block([], kwend)}
 397 !withend| {oneline} stmt~withelse {-> stmt~withelse.expr}
 398         ;
 399 stmts {-> expr}
 400         = stmt stmts_tail* {-> New expr.block([stmt.expr, stmts_tail.expr], Null)};
 401 stmtsn {-> expr}
 402         = stmt stmts_tail* n {-> New expr.block([stmt.expr, stmts_tail.expr], Null)};
 403 stmtsnend {-> expr}
 404         = stmt stmts_tail* n kwend {-> New expr.block([stmt.expr, stmts_tail.expr], kwend)};
 405 stmts_tail {-> expr}
 406         = n stmt {-> stmt.expr};
 407 stmt~withelse~noexpr~nopar {-> expr}
 408         = {vardecl} vardecl {-> vardecl.expr}
 409         | {assign} assignment~nopar {-> assignment~nopar.expr}
 410         | {return} kwreturn expr? {-> New expr.return(kwreturn, expr)}
 411         | {break} kwbreak label? {-> New expr.break(kwbreak, label)}
 412         | {abort} kwabort {-> New expr.abort(kwabort)}
 413         | {continue} kwcontinue label? {-> New expr.continue(kwcontinue, label)}
 414         | {do} do~withelse {-> do~withelse.expr}
 415 !noexpr | {if} if~withelse {-> if~withelse.expr}
 416         | {while} while~withelse {-> while~withelse.expr}
 417         | {loop} loop~withelse {-> loop~withelse.expr}
 418         | {for} for~withelse {-> for~withelse.expr}
 419         | {assert} assert~withelse {-> assert~withelse.expr}
 420 !noexpr | {call} recv qid args_nopar {-> New expr.call(recv.expr, qid.id, args_nopar.exprs)}
 421 !noexpr | {super} qualified_o kwsuper args_nopar {-> New expr.super(qualified_o.qualified, kwsuper, args_nopar.exprs)}
 422 !noexpr | {init} recv qualified? kwinit args_nopar {-> New expr.init(recv.expr, kwinit, args_nopar.exprs)}
 423         | {debug_type_is} kwdebug kwtype type column expr {-> New expr.debug_type(kwdebug, kwtype, expr.expr, type) }
 424         ;
 425
 426 label= kwlabel id?;
 427
 428 vardecl{-> expr}
 429         = kwvar id annotations? typing_o {-> New expr.vardecl(kwvar, id, typing_o.type, Null, Null, annotations)}
 430         | {assign} kwvar id annotations? typing_o assign no expr {-> New expr.vardecl(kwvar, id, typing_o.type, assign, expr.expr, annotations)}
 431         ;
 432
 433 assignment~nopar {-> expr}
 434         = {attr} recv~nopar qualified_o attrid assign expr {-> New expr.attr_assign(recv~nopar.expr, attrid, assign, expr)}
 435         | {call} recv~nopar qid args assign expr {-> New expr.call_assign(recv~nopar.expr, qid.id, args.exprs, assign,  expr)}
 436         | {bra} expr_atom~nopar braargs assign expr {-> New expr.bra_assign(expr_atom~nopar.expr, braargs.exprs, assign,  expr)}
 437         | {attr_re} recv~nopar qualified_o attrid assign_op expr {-> New expr.attr_reassign(recv~nopar.expr, attrid, assign_op,  expr)}
 438         | {call_re} recv~nopar qid args assign_op expr {-> New expr.call_reassign(recv~nopar.expr, qid.id, args.exprs, assign_op,  expr)}
 439         | {bra_re} expr_atom~nopar braargs assign_op expr {-> New expr.bra_reassign(expr_atom~nopar.expr, braargs.exprs, assign_op,  expr)}
 440         ;
 441 assign_op
 442         = {plus} pluseq
 443         | {minus} minuseq
 444         ;
 445
 446 do~withelse {-> expr}
 447         = kwdo stmtso_withend label {-> New expr.do(kwdo, stmtso_withend.expr, label)}
 448         | {nolabel} kwdo stmtso~withelse {-> New expr.do(kwdo, stmtso~withelse.expr, Null)}
 449         ;
 450
 451 if~withelse {-> expr}
 452         = {onelineelse} kwif no expr [n2]:no kwthen stmt_withelse kwelse stmtso~withelse {-> New expr.if(kwif, expr, stmt_withelse.expr, stmtso~withelse.expr)}
 453 !withelse       | {oneline} kwif no expr [n2]:no kwthen stmt {-> New expr.if(kwif, expr, stmt.expr, Null)}
 454 !withelse       | {block} kwif no expr [n2]:no kwthen [n3]:n stmtsn elsepartblock {-> New expr.if(kwif, expr, stmtsn.expr, elsepartblock.expr)}
 455 !withelse       | {emptyblock} kwif no expr [n2]:no kwthen [n3]:n? elsepartblock {-> New expr.if(kwif, expr, Null, elsepartblock.expr)}
 456         ;
 457 elsepartblock {-> expr?}
 458         = {else} kwelse stmtso {-> stmtso.expr}
 459         | {empty} kwend {-> New expr.block([], kwend)}
 460         ;
 461
 462 loop~withelse {-> expr}
 463         = kwloop stmtso_withend label {-> New expr.loop(kwloop, stmtso_withend.expr, label)}
 464         | {nolabel} kwloop stmtso~withelse {-> New expr.loop(kwloop, stmtso~withelse.expr, Null)}
 465         ;
 466
 467 while~withelse {-> expr}
 468         = kwwhile no expr [n2]:no kwdo stmtso_withend label {-> New expr.while(kwwhile, expr, kwdo, stmtso_withend.expr, label)}
 469         | {nolabel} kwwhile no expr [n2]:no kwdo stmtso~withelse {-> New expr.while(kwwhile, expr, kwdo, stmtso~withelse.expr, Null)}
 470         ;
 471
 472 for~withelse {-> expr}
 473         = kwfor no [ids]:idlist [n2]:no kwin [n3]:no expr [n4]:no kwdo stmtso_withend label {-> New expr.for(kwfor, [ids.id], expr, kwdo, stmtso_withend.expr, label)}
 474         | {nolabel} kwfor no [ids]:idlist [n2]:no kwin [n3]:no expr [n4]:no kwdo stmtso~withelse {-> New expr.for(kwfor, [ids.id], expr, kwdo, stmtso~withelse.expr, Null)}
 475         ;
 476
 477 assert~withelse {-> expr}
 478         = {else} kwassert assertid? expr kwelse stmtso~withelse {-> New expr.assert(kwassert, assertid.id, expr, stmtso~withelse.expr)}
 479 !withelse| {noelse} kwassert assertid? expr {-> New expr.assert(kwassert, assertid.id, expr, Null)}
 480         ;
 481 assertid {-> id}
 482         = id column {-> id};
 483
 484 /* EXPRESSIONS ***************************************************************/
 485 expr~nopar~nobra {-> expr}
 486         = expr_and~nopar~nobra {-> expr_and~nopar~nobra.expr}
 487         | {ifexpr} kwif [n1]:no expr [n2]:no kwthen [n3]:no [then]:expr [n4]:no kwelse [n5]:no [else]:expr~nopar~nobra {-> New expr.ifexpr(kwif, expr, kwthen, then, kwelse, else.expr)}
 488         ;
 489
 490 expr_and~nopar~nobra {-> expr}
 491         = expr_not~nopar~nobra {-> expr_not~nopar~nobra.expr}
 492         | {:or} expr_and~nopar~nobra :kwor :no expr_not~nopar~nobra
 493         | {:and} expr_and~nopar~nobra :kwand :no expr_not~nopar~nobra
 494         | {:or_else} expr_and~nopar~nobra :kwor :kwelse :no expr_not~nopar~nobra
 495         | {:implies} expr_and~nopar~nobra :kwimplies :no expr_not~nopar~nobra
 496         ;
 497
 498 expr_not~nopar~nobra {-> expr}
 499         = expr_eq~nopar~nobra {-> expr_eq~nopar~nobra.expr}
 500         | {not} kwnot no expr_not~nopar~nobra {-> New expr.not(kwnot, expr_not~nopar~nobra.expr)}
 501         ;
 502
 503 expr_eq~nopar~nobra {-> expr}
 504         = expr_add~nopar~nobra {-> expr_add~nopar~nobra.expr}
 505         | {:eq} expr_add~nopar~nobra :eq :no [expr2]:expr_add~nopar~nobra
 506         | {:ne} expr_add~nopar~nobra :ne :no [expr2]:expr_add~nopar~nobra
 507         | {:lt} expr_add~nopar~nobra :lt :no [expr2]:expr_add~nopar~nobra
 508         | {:le} expr_add~nopar~nobra :le :no [expr2]:expr_add~nopar~nobra
 509         | {:ll} expr_eq~nopar~nobra :ll :no [expr2]:expr_add~nopar~nobra
 510         | {:gt} expr_add~nopar~nobra :gt :no [expr2]:expr_add~nopar~nobra
 511         | {:ge} expr_add~nopar~nobra :ge :no [expr2]:expr_add~nopar~nobra
 512         | {:gg} expr_eq~nopar~nobra :gg :no [expr2]:expr_add~nopar~nobra
 513         | {:starship} expr_add~nopar~nobra :starship :no [expr2]:expr_add~nopar~nobra
 514         | {:isa} expr_add~nopar~nobra :kwisa :no type~nobra
 515         ;
 516
 517 expr_add~nopar~nobra {-> expr}
 518         =  expr_mul~nopar~nobra {-> expr_mul~nopar~nobra.expr}
 519         | {:plus} expr_add~nopar~nobra :plus :no [expr2]:expr_mul~nopar~nobra
 520         | {:minus} expr_add~nopar~nobra :minus :no [expr2]:expr_mul~nopar~nobra
 521         ;
 522
 523 expr_mul~nopar~nobra {-> expr}
 524         = expr_pow~nopar~nobra {-> expr_pow~nopar~nobra.expr}
 525         | {:star} expr_mul~nopar~nobra :star :no [expr2]:expr_pow~nopar~nobra
 526         | {:slash} expr_mul~nopar~nobra :slash :no [expr2]:expr_pow~nopar~nobra
 527         | {:percent} expr_mul~nopar~nobra :percent :no [expr2]:expr_pow~nopar~nobra
 528         ;
 529
 530 expr_pow~nopar~nobra {-> expr}
 531         = expr_minus~nopar~nobra {-> expr_minus~nopar~nobra.expr}
 532         | {:starstar} expr_minus~nopar~nobra :starstar :no [expr2]:expr_pow~nopar~nobra
 533         ;
 534
 535 expr_minus~nopar~nobra {-> expr}
 536         = expr_new~nopar~nobra {-> expr_new~nopar~nobra.expr}
 537         | {:uminus} minus expr_minus~nobra
 538         | {:once} kwonce :no expr_minus~nobra
 539         ;
 540
 541 expr_new~nopar~nobra {-> expr}
 542         = expr_atom~nopar~nobra {-> expr_atom~nopar~nobra.expr}
 543         | {new} kwnew no type~nobra_nopar args {-> New expr.new(kwnew, type~nobra_nopar.type, Null, args.exprs)}
 544         | {isset_attr} kwisset recv~nopar~nobra qualified_o attrid {-> New expr.isset_attr(kwisset, recv~nopar~nobra.expr, attrid)}
 545         ;
 546
 547 expr_atom~nopar~nobra {-> expr}
 548         = expr_single~nopar~nobra {-> expr_single~nopar~nobra.expr}
 549         | {attr} recv~nopar~nobra qualified_o attrid {-> New expr.attr(recv~nopar~nobra.expr, attrid)}
 550         | {call} recv~nopar~nobra qid args {-> New expr.call(recv~nopar~nobra.expr, qid.id, args.exprs)}
 551         | {super} qualified_o kwsuper args {-> New expr.super(qualified_o.qualified, kwsuper, args.exprs)}
 552         | {init} recv~nopar~nobra kwinit args {-> New expr.init(recv~nopar~nobra.expr, kwinit, args.exprs)}
 553 !nobra  | {bra} expr_atom~nopar braargs {-> New expr.bra(expr_atom~nopar.expr, braargs.exprs)}
 554         | {new} kwnew no type~nobra_nopar dot [n2]:no qid args {-> New expr.new(kwnew, type~nobra_nopar.type, qid.id, args.exprs)}
 555         | {as_cast} expr_atom~nopar~nobra dot no kwas [n2]:no opar [n3]:no type [n4]:no cpar {-> New expr.as_cast(expr_atom~nopar~nobra.expr, kwas, opar, type, cpar)}
 556         | {as_notnull} expr_atom~nopar~nobra dot no kwas [n2]:no opar [n3]:no kwnot [n4]:no kwnull [n5]:no cpar {-> New expr.as_notnull(expr_atom~nopar~nobra.expr, kwas, opar, kwnot, kwnull, cpar)}
 557         | {as_notnull2}expr_atom~nopar~nobra dot no kwas [n2]:no kwnot [n4]:no kwnull {-> New expr.as_notnull(expr_atom~nopar~nobra.expr, kwas, Null, kwnot, kwnull, Null)}
 558         | {vararg} [expr]:expr_atom~nopar~nobra dotdotdot {-> New expr.vararg(expr.expr, dotdotdot)}
 559         ;
 560
 561 expr_single~nopar~nobra {-> expr}
 562         = {self} kwself annotations_o {-> New expr.self(kwself, annotations_o.annotations)}
 563         | {true} kwtrue annotations_o {-> New expr.true(kwtrue, annotations_o.annotations)}
 564         | {false} kwfalse annotations_o {-> New expr.false(kwfalse, annotations_o.annotations)}
 565         | {null} kwnull annotations_o {-> New expr.null(kwnull, annotations_o.annotations)}
 566         | {int} number annotations_o {-> New expr.dec_int(number, annotations_o.annotations)}
 567         | {hex_int} hex_number annotations_o {-> New expr.hex_int(hex_number, annotations_o.annotations)}
 568         | {float} float annotations_o {-> New expr.float(float, annotations_o.annotations)}
 569         | {char} char annotations_o {-> New expr.char(char, annotations_o.annotations)}
 570         | {string} string annotations_o {-> New expr.string(string, annotations_o.annotations)}
 571         | {superstring} superstring  {-> superstring.expr}
 572 !nopar  | {par} expr_par {-> expr_par.expr}
 573 // !nopar to unambiguise 'foo[5].bar' between '(foo[5]).bar' and 'foo([5].bar),
 574 !nobra!nopar    | {range} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no cbra annotations_o {-> New expr.crange(obra, expr, expr2.expr, cbra, annotations_o.annotations)}
 575 !nobra!nopar    | {orange} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no [cbra]:obra annotations_o {-> New expr.orange(obra, expr, expr2.expr, cbra, annotations_o.annotations)}
 576 !nobra!nopar    | {array} obra no array_items typing_o cbra annotations_o {-> New expr.array(obra, [array_items.expr], typing_o.type, cbra, annotations_o.annotations)}
 577         ;
 578
 579 expr_par {-> expr}
 580         = {par} opar no any_expr [n2]:no cpar annotations_o {-> New expr.par(opar, any_expr.expr, cpar, annotations_o.annotations)}
 581         | {tuple} opar no many_expr [n2]:no cpar annotations_o {-> New expr.par(opar, many_expr.expr, cpar, annotations_o.annotations)}
 582         ;
 583
 584 many_expr {->expr}
 585         = any_expr many_expr_tail+ {-> New expr.many([any_expr.expr, many_expr_tail.expr])}
 586         ;
 587
 588 many_expr_tail {->expr}
 589         = comma no any_expr {-> any_expr.expr}
 590         ;
 591
 592 array_items {-> expr*}
 593         = array_item array_items_tail* {-> [array_item.expr, array_items_tail.expr]}
 594         ;
 595 array_items_tail {-> expr}
 596         = comma no array_item {-> array_item.expr}
 597         ;
 598 array_item {-> expr}
 599         = expr no {-> expr}
 600         | {for} kwfor no [ids]:idlist [n2]:no kwin [n3]:no expr [n4]:no kwdo [block]:array_item {-> New expr.for(kwfor, [ids.id], expr, kwdo, block.expr, Null)}
 601         | {if} kwif [n1]:no expr [n2]:no kwthen [n3]:no [then]:array_item {-> New expr.if(kwif, expr, then.expr, Null)}
 602         ;
 603
 604 superstring {-> expr}
 605         = superstring_start superstring_middle* superstring_end annotations_o {-> New expr.superstring([superstring_start.expr, superstring_middle.expr, superstring_end.expr], annotations_o.annotations)};
 606 superstring_start {-> expr*}
 607         = start_string_p no expr [n2]:no {-> [start_string_p.expr, expr]}
 608         | {noexpr} start_string_p no {-> [start_string_p.expr]}
 609         ;
 610 start_string_p {-> expr}
 611         = start_string {-> New expr.start_string(start_string)};
 612 superstring_middle {-> expr*}
 613         = mid_string_p no expr [n2]:no {-> [mid_string_p.expr, expr]}
 614         | {noexpr} mid_string_p no {-> [mid_string_p.expr]}
 615         ;
 616 mid_string_p {-> expr}
 617         = mid_string {-> New expr.mid_string(mid_string)};
 618 superstring_end {-> expr}
 619         = end_string {-> New expr.end_string(end_string)};
 620
 621 /* ANNOTATIONS *******************************************************************/
 622
 623 annotations~nopar {-> annotations}
 624         = {one} at one_annotation~nopar {-> New annotations(at, Null, [one_annotation~nopar.annotation], Null)}
 625         | {many} at opar no annotation_list [n2]:no cpar {-> New annotations(at, opar, [annotation_list.annotation], cpar)}
 626         ;
 627 annotations_o~nopar {-> annotations?}
 628         = annotations~nopar {-> annotations~nopar.annotations}
 629         | {null} {-> Null}
 630         ;
 631
 632 one_annotation~nopar {-> annotation}
 633         = {alone} redef visibility atid annotations_o~nopar {-> New annotation(Null, redef.kwredef, visibility, atid, Null, [], Null, annotations_o~nopar.annotations)}
 634 // !nopar to unambiguise 'new T@foo(bar)' between 'new T@(foo(bar))' and 'new (T@foo)(bar)'
 635 !nopar  | {args} redef visibility atid opar no at_args [n2]:no cpar annotations_o~nopar {-> New annotation(Null, redef.kwredef, visibility, atid, opar, [at_args.expr], cpar, annotations_o~nopar.annotations)}
 636         ;
 637
 638 many_annotations {-> annotations}
 639         = {many} annotation_list {-> New annotations(Null, Null, [annotation_list.annotation], Null)}
 640         ;
 641
 642 annotation_list {-> annotation*}
 643         = {many} one_annotation_list annotations_tail* {-> [one_annotation_list.annotation, annotations_tail.annotation] }
 644         ;
 645
 646 one_annotation_list~nopar {-> annotation}
 647         = {alone} redef visibility atid annotations_o~nopar {-> New annotation(Null, redef.kwredef, visibility, atid, Null, [], Null, annotations_o~nopar.annotations)}
 648 // !nopar to unambiguise 'new T@foo(bar)' between 'new T@(foo(bar))' and 'new (T@foo)(bar)'
 649 !nopar  | {args} redef visibility atid opar no at_args [n2]:no cpar annotations_o~nopar {-> New annotation(Null, redef.kwredef, visibility, atid, opar, [at_args.expr], cpar, annotations_o~nopar.annotations)}
 650 !nopar  | {nopar} redef visibility atid at_arg_single {-> New annotation(Null, redef.kwredef, visibility, atid, Null, [at_arg_single.expr], Null, Null)}
 651         ;
 652 at_arg_single {-> expr}
 653 // FIXME: why expr_single but not expr_atom is not clear :(
 654         = {expr} [expr]:expr_single_nopar {-> expr.expr}
 655         ;
 656
 657 annotations_tail {-> annotation}
 658         = comma no one_annotation_list {-> one_annotation_list.annotation}
 659         ;
 660
 661 line_annotations {-> annotations}
 662         = line_annotation+ {-> New annotations(Null, Null, [line_annotation.annotation], Null) }
 663         ;
 664 line_annotation {-> annotation}
 665         = [doc]:no redef visibility atid annotations? n1 {-> New annotation(doc.doc, redef.kwredef, visibility, atid.atid, Null, [], Null, annotations)}
 666         | {args} [doc]:no redef visibility atid opar no at_args cpar annotations? n1 {-> New annotation(doc.doc, redef.kwredef, visibility, atid.atid, opar, [at_args.expr], cpar, annotations)}
 667         | {nopar} [doc]:no redef visibility atid at_args_nopar n1 {-> New annotation(doc.doc, redef.kwredef, visibility, atid.atid, Null, [at_args_nopar.expr], Null, Null)}
 668         ;
 669 line_annotation_forclass {-> propdef}
 670         = [doc]:no atid_forclass annotations? {-> New propdef.annot(doc.doc, Null, Null, atid_forclass.atid, Null, [], Null, annotations)}
 671         | {args} [doc]:no atid_forclass opar no at_args cpar annotations? {-> New propdef.annot(doc.doc, Null, Null, atid_forclass.atid, opar, [at_args.expr], cpar, annotations)}
 672         | {nopar} [doc]:no atid_forclass at_args_nopar {-> New propdef.annot(doc.doc, Null, Null, atid_forclass.atid, Null, [at_args_nopar.expr], Null, Null)}
 673         ;
 674
 675 at_args~nopar {-> expr* }
 676         = {many} any_expr~nopar at_args_tail* {-> [any_expr~nopar.expr, at_args_tail.expr]}
 677         ;
 678
 679 at_args_tail {-> expr}
 680         = comma no any_expr {-> any_expr.expr}
 681         ;
 682
 683 any_expr~nopar {-> expr}
 684         = {type} type {-> New expr.type(type)}
 685         | {expr} expr~nopar {-> expr~nopar.expr}
 686         | {stmt} stmt_noexpr~nopar {-> stmt_noexpr~nopar.expr}
 687         | {methid} recv~nopar qmethid_noid {-> New expr.methid(recv~nopar.expr, qmethid_noid.methid)}
 688 !nopar  | {at} annotations {-> New expr.at(annotations.annotations)}
 689         ;
 690
 691 atid~forclass {-> atid}
 692         = {id}  id {-> New atid.id(id)}
 693 !forclass       | {kwextern} kwextern {-> New atid.kwextern(kwextern)}
 694 //      | {kwimport} kwimport {-> New atid.kwimport(kwimport)}
 695         | {kwabstract} kwabstract {-> New atid.kwabstract(kwabstract)}
 696         ;
 697
 698 /* MISC **********************************************************************/
 699
 700 recv~nopar~nobra {-> expr}
 701         = expr_atom~nopar~nobra dot no {-> expr_atom~nopar~nobra.expr}
 702         | {implicit} {-> New expr.implicit_self()}
 703         ;
 704
 705 args {-> exprs}
 706         = args_n {-> args_n.exprs}
 707         | {empty} {-> New exprs.list([])}
 708         ;
 709 args_n {-> exprs}
 710         = opar no expr_list cpar {-> New exprs.par(opar, [expr_list.expr], cpar) }
 711         | {emptypar} opar no cpar {-> New exprs.par(opar, [], cpar) }
 712         ;
 713 args_nopar {-> exprs}
 714         = opar no expr_list cpar {-> New exprs.par(opar, [expr_list.expr], cpar) }
 715         | {onearg} expr_nopar {-> New exprs.list([expr_nopar.expr])}
 716         | {emptypar} opar no cpar {-> New exprs.par(opar, [], cpar) }
 717         | {empty} {-> New exprs.list([])}
 718         ;
 719 braargs {-> exprs}
 720         = obra no expr_list cbra {-> New exprs.bra(obra, [expr_list.expr], cbra)};
 721 args_list {-> exprs}
 722         = expr_list {-> New exprs.list([expr_list.expr])};
 723 expr_list {-> expr*}
 724         = expr [n2]:no expr_tail* {-> [expr, expr_tail.expr]};
 725 expr_tail {-> expr}
 726         = comma no expr [n2]:no {-> expr};
 727 idlist {-> id*}
 728         = opar no idlist_nopar [n2]:no cpar {-> [idlist_nopar.id]}
 729         | {nopar} idlist_nopar {-> [idlist_nopar.id]}
 730         ;
 731 idlist_nopar {-> id*}
 732         = {single} id {-> [id]}
 733         | {more} idlist_nopar comma [n2]:no id {-> [idlist_nopar.id, id]}
 734         ;
 735
 736 module_name {-> module_name}
 737         = {mod} modquad* id {-> New module_name(Null, [modquad.id], id)}
 738         | {root} quad no modquad* id {-> New module_name(quad, [modquad.id], id)}
 739         ;
 740
 741 qualified
 742         = {cla} modquad* classquad {-> New qualified([modquad.id], classquad.classid)}
 743         | {mod} modquad+ {-> New qualified([modquad.id], Null)}
 744         ;
 745 qualified_o {-> qualified?}
 746         = qualified {-> qualified}
 747         | {null} {-> Null}
 748         ;
 749 qid {-> id}
 750         = qualified? id {-> id}
 751         ;
 752 qclassid {-> classid}
 753         = qualified? classid {-> classid}
 754         ;
 755 qmethid~noid {-> methid}
 756         = qualified? methid~noid {-> methid~noid.methid}
 757         ;
 758 modquad {-> id}
 759         = id quad no {-> id};
 760 classquad {-> classid}
 761         = classid quad no {-> classid};
 762
 763 kwend_o {-> kwend?}
 764         = kwend? {-> kwend}
 765         ;
 766
 767 n1      = {a} comment | {b} eol;
 768 n {-> doc?}
 769         = {a} n2? comment+ {-> New doc([comment])}
 770         | {b} n2 {-> Null}
 771         ;
 772 no {-> doc?}
 773         = {empty} {-> Null}
 774         | n {-> n.doc}
 775         ;
 776
 777 n2
 778         = {a} n2? comment+ eol+
 779         | {b} eol+
 780         ;
 781
 782 /*****************************************************************************/
 783 Abstract Syntax Tree
 784 /*****************************************************************************/
 785
 786 module  = moduledecl? [imports]:import* [extern_code_blocks]:extern_code_block* [classdefs]:classdef*;
 787
 788 moduledecl
 789         = doc? kwredef? visibility kwmodule [name]:module_name annotations?;
 790
 791 import  = {std} visibility kwimport [name]:module_name annotations?
 792         | {no} visibility kwimport kwend
 793         ;
 794
 795 visibility
 796         = {public} kwpublic?
 797         | {private} kwprivate
 798         | {protected} kwprotected
 799         | {intrude} kwintrude
 800         ;
 801
 802 classdef= {std} doc? kwredef? visibility classkind [id]:classid? [formaldefs]:formaldef* extern_code_block? [propdefs]:propdef* kwend
 803         | {top} [propdefs]:propdef*
 804         | {main} [propdefs]:propdef*
 805         ;
 806 classkind
 807         = {concrete} kwclass
 808         | {abstract} kwabstract kwclass
 809         | {interface} kwinterface
 810         | {enum} kwenum
 811         | {extern} kwextern kwclass?
 812         ;
 813 formaldef = [id]:classid type? annotations?;
 814
 815
 816 propdef = {attr} doc? kwredef? visibility kwvar [id2]:id type? expr? annotations? [block]:expr?
 817         | {main_meth} kwredef? [block]:expr?
 818         | {type} doc? kwredef? visibility kwtype [id]:classid type annotations?
 819         | {meth} doc? kwredef? visibility kwmeth? kwinit? kwnew? methid? signature annotations? extern_calls? extern_code_block? [block]:expr?
 820         | {super} doc? kwredef? visibility kwsuper type annotations?
 821         | {annot} doc? kwredef? visibility? atid opar? [args]:expr* cpar? annotations?
 822         ;
 823
 824 methid = {id} id | {plus} plus | {minus} minus | {star} star | {starstar} starstar | {slash} slash | {percent} percent | {eq} eq | {ne} ne | {le} le | {ge} ge | {lt} lt | {gt} gt |  {ll} ll | {gg} gg | {bra} obra cbra | {starship} starship | {assign} id assign | {braassign} obra cbra assign;
 825
 826 signature = opar? [params]:param* cpar? type?;
 827
 828 param   = id type? dotdotdot? annotations?
 829         ;
 830
 831 type    = kwnullable? [id]:classid [types]:type* annotations?;
 832
 833 label = kwlabel id?;
 834
 835 expr    = {block} expr* kwend?
 836         | {vardecl} kwvar id type? assign? expr? annotations?
 837         | {return} kwreturn? expr?
 838         | {break} kwbreak label?
 839         | {abort} kwabort
 840         | {continue} kwcontinue? label?
 841         | {do} kwdo [block]:expr? label?
 842         | {if} kwif expr [then]:expr? [else]:expr?
 843         | {ifexpr} kwif expr kwthen [then]:expr kwelse [else]:expr
 844         | {while} kwwhile expr kwdo [block]:expr? label?
 845         | {loop} kwloop [block]:expr? label?
 846         | {for} kwfor [ids]:id* expr kwdo [block]:expr? label?
 847         | {assert} kwassert id? expr [else]:expr?
 848         | {once} kwonce expr
 849         | {send} expr
 850         | {binop} expr [expr2]:expr
 851         | {or} expr [expr2]:expr
 852         | {and} expr [expr2]:expr
 853         | {or_else} expr [expr2]:expr
 854         | {implies} expr [expr2]:expr
 855         | {not} kwnot expr
 856         | {eq} expr [expr2]:expr
 857         | {ne} expr [expr2]:expr
 858         | {lt} expr [expr2]:expr
 859         | {le} expr [expr2]:expr
 860         | {ll} expr [expr2]:expr
 861         | {gt} expr [expr2]:expr
 862         | {ge} expr [expr2]:expr
 863         | {gg} expr [expr2]:expr
 864         | {isa} expr type
 865         | {plus} expr [expr2]:expr
 866         | {minus} expr [expr2]:expr
 867         | {starship} expr [expr2]:expr
 868         | {star} expr [expr2]:expr
 869         | {starstar} expr [expr2]:expr
 870         | {slash} expr [expr2]:expr
 871         | {percent} expr [expr2]:expr
 872         | {uminus} minus expr
 873         | {new} kwnew type id? [args]:exprs
 874         | {attr} expr [id]:attrid
 875         | {attr_assign} expr [id]:attrid assign [value]:expr
 876         | {attr_reassign} expr [id]:attrid assign_op [value]:expr
 877         | {call} expr id [args]:exprs
 878         | {call_assign} expr id [args]:exprs assign [value]:expr
 879         | {call_reassign} expr id [args]:exprs assign_op [value]:expr
 880         | {super} qualified? kwsuper [args]:exprs
 881         | {init} expr kwinit [args]:exprs
 882         | {bra} expr [args]:exprs
 883         | {bra_assign} expr [args]:exprs assign [value]:expr
 884         | {bra_reassign} expr [args]:exprs assign_op [value]:expr
 885         | {var} id
 886         | {var_assign} id assign [value]:expr
 887         | {var_reassign} id assign_op [value]:expr
 888         | {range} expr [expr2]:expr annotations?
 889         | {crange} obra expr [expr2]:expr cbra annotations?
 890         | {orange} obra expr [expr2]:expr [cbra]:obra annotations?
 891         | {array} obra [exprs]:expr* type? cbra annotations?
 892         | {self} kwself annotations?
 893         | {implicit_self}
 894         | {true} kwtrue annotations?
 895         | {false} kwfalse annotations?
 896         | {null} kwnull annotations?
 897         | {dec_int} number annotations?
 898         | {hex_int} hex_number annotations?
 899         | {float} float annotations?
 900         | {char} char annotations?
 901         | {string} string annotations?
 902         | {start_string} [string]:start_string
 903         | {mid_string} [string]:mid_string
 904         | {end_string} [string]:end_string
 905         | {superstring} [exprs]:expr* annotations?
 906         | {par} opar expr cpar annotations?
 907         | {as_cast} expr kwas opar? type cpar?
 908         | {as_notnull} expr kwas opar? kwnot kwnull cpar?
 909         | {isset_attr} kwisset expr [id]:attrid
 910         | {debug_type} kwdebug kwtype expr type
 911         | {vararg} expr dotdotdot
 912         | {type} type
 913         | {methid} expr [id]:methid
 914         | {at} annotations
 915         | {many} [exprs]:expr*
 916         ;
 917 exprs
 918         = {list} [exprs]:expr*
 919         | {par} opar [exprs]:expr* cpar
 920         | {bra} obra [exprs]:expr* cbra
 921         ;
 922 assign_op
 923         = {plus} pluseq
 924         | {minus} minuseq
 925         ;
 926
 927 module_name = quad? [path]:id* id;
 928 extern_calls = kwimport [extern_calls]:extern_call*
 929         ;
 930 extern_call =
 931         | {super} kwsuper
 932         | {local_prop} methid
 933         | {full_prop} type dot? methid
 934         | {init_prop} type
 935         | {cast_as} [from_type]:type dot? kwas [to_type]:type
 936         | {as_nullable} type kwas kwnullable
 937         | {as_not_nullable} type kwas kwnot kwnullable
 938         ;
 939 in_language = kwin string;
 940 extern_code_block = in_language? extern_code_segment;
 941
 942 qualified = id* classid? ;
 943
 944 doc = comment+;
 945
 946 annotations = at? opar? [items]:annotation* cpar?;
 947
 948 annotation = doc? kwredef? visibility? atid opar? [args]:expr* cpar? annotations?;
 949
 950 atid = {id} id | {kwextern} [id]:kwextern | {kwabstract} [id]:kwabstract | {kwimport} [id]:kwimport;
 951
 952 /*****************************************************************************/
 953