lib/markdown/man.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Simple *groff* decorator restricted for manpages.
  16 module man
  17
  18 import markdown
  19
  20 # `Decorator` that outputs markdown.
  21 class ManDecorator
  22         super Decorator
  23
  24         redef var headlines = new ArrayMap[String, HeadLine]
  25
  26         redef fun add_ruler(v, block) do v.add "***\n"
  27
  28         redef fun add_headline(v, block) do
  29                 var lvl = block.depth
  30                 if lvl == 1 then
  31                         v.add ".SH "
  32                 else if lvl == 2 then
  33                         v.add ".SS "
  34                 else if lvl >= 3 then
  35                         # We use dictionary (titled paragraph) to simulate a 3rd level (or more)
  36                         v.add ".TP\n"
  37                 end
  38                 v.emit_in block
  39                 v.addn
  40         end
  41
  42         redef fun add_paragraph(v, block) do
  43                 if not in_unorderedlist and not in_orderedlist then
  44                         v.addn
  45                         v.emit_in block
  46                         v.addn
  47                 else
  48                         v.emit_in block
  49                 end
  50         end
  51
  52         redef fun add_code(v, block) do
  53                 v.add ".RS\n.nf\n\\f[C]\n"
  54                 v.emit_in block
  55                 v.addn
  56                 v.add "\\f[]\n.fi\n.RE\n"
  57         end
  58
  59         redef fun add_blockquote(v, block) do
  60                 v.add ".RS\n"
  61                 v.emit_in block
  62                 v.add ".RE\n"
  63         end
  64
  65         redef fun add_unorderedlist(v, block) do
  66                 v.add ".RS\n"
  67                 in_unorderedlist = true
  68                 v.emit_in block
  69                 in_unorderedlist = false
  70                 v.add ".RE\n"
  71         end
  72         private var in_unorderedlist = false
  73
  74         redef fun add_orderedlist(v, block) do
  75                 v.add ".RS\n"
  76                 in_orderedlist = true
  77                 current_li = 0
  78                 v.emit_in block
  79                 in_orderedlist = false
  80                 v.add ".RE\n"
  81         end
  82         private var in_orderedlist = false
  83         private var current_li = 0
  84
  85         redef fun add_listitem(v, block) do
  86                 if in_unorderedlist then
  87                         v.add ".IP \\[bu] 3\n"
  88                 else if in_orderedlist then
  89                         current_li += 1
  90                         v.add ".IP \"{current_li}.\" 3\n"
  91                 end
  92                 v.emit_in block
  93                 v.addn
  94         end
  95
  96         redef fun add_em(v, text) do
  97                 v.add "\\f[I]"
  98                 v.add text
  99                 v.add "\\f[]"
 100         end
 101
 102         redef fun add_strong(v, text) do
 103                 v.add "\\f[B]"
 104                 v.add text
 105                 v.add "\\f[]"
 106         end
 107
 108         redef fun add_strike(v, text) do
 109                 v.add "[STRIKEOUT:"
 110                 v.add text
 111                 v.add "]"
 112         end
 113
 114         redef fun add_image(v, link, name, comment) do
 115                 v.add name
 116                 v.add " ("
 117                 append_value(v, link)
 118                 if comment != null and not comment.is_empty then
 119                         v.add " "
 120                         append_value(v, comment)
 121                 end
 122                 v.add ")"
 123         end
 124
 125         redef fun add_link(v, link, name, comment) do
 126                 v.add name
 127                 v.add " ("
 128                 append_value(v, link)
 129                 if comment != null and not comment.is_empty then
 130                         v.add " "
 131                         append_value(v, comment)
 132                 end
 133                 v.add ")"
 134         end
 135
 136         redef fun add_abbr(v, name, comment) do
 137                 v.add "\">"
 138                 v.emit_text(name)
 139                 v.add " ("
 140                 append_value(v, comment)
 141                 v.add ")"
 142         end
 143
 144         redef fun add_span_code(v, text, from, to) do
 145                 v.add "\\f[C]"
 146                 append_code(v, text, from, to)
 147                 v.add "\\f[]"
 148         end
 149
 150         redef fun add_line_break(v) do
 151                 v.addn
 152         end
 153
 154         redef fun append_value(v, text) do for c in text do escape_char(v, c)
 155
 156         redef fun add_char(v, c) do
 157                 # Escape - because manpages
 158                 if c == '-' then
 159                         v.addc '\\'
 160                 end
 161                 v.addc(c)
 162         end
 163
 164         redef fun escape_char(v, c) do add_char(v, c)
 165
 166         redef fun append_code(v, buffer, from, to) do
 167                 for i in [from..to[ do
 168                         var c = buffer[i]
 169                         if c == '-' or c == ' ' then
 170                                 v.addc '\\'
 171                         end
 172                         v.addc c
 173                 end
 174         end
 175 end