src/web/web_actions.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 # http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 # Nitcorn actions used by the nitweb server.
  16 module web_actions
  17
  18 import web_views
  19 import uml
  20
  21 # Display the tree of all loaded mentities.
  22 class TreeAction
  23         super ModelHandler
  24
  25         redef fun get(req, res) do
  26                 var model = init_model_view(req)
  27                 var view = new HtmlHomePage(model.to_tree)
  28                 res.send_view(view)
  29         end
  30 end
  31
  32 # Display the doc of a MEntity.
  33 class DocAction
  34         super ModelHandler
  35
  36         # Modelbuilder used to access sources.
  37         var modelbuilder: ModelBuilder
  38
  39         redef fun get(req, res) do
  40                 var namespace = req.param("namespace")
  41                 var model = init_model_view(req)
  42                 var mentity = find_mentity(model, namespace)
  43                 if mentity == null then
  44                         res.error(404)
  45                         return
  46                 end
  47                 if req.is_json_asked then
  48                         res.json(mentity.to_json)
  49                         return
  50                 end
  51
  52                 var view = new HtmlDocPage(modelbuilder, mentity)
  53                 res.send_view(view)
  54         end
  55 end
  56
  57 # Return an UML diagram for `namespace`.
  58 class UMLDiagramAction
  59         super ModelHandler
  60
  61         # Mainmodule used for hierarchy flattening.
  62         var mainmodule: MModule
  63
  64         redef fun get(req, res) do
  65                 var namespace = req.param("namespace")
  66                 var model = init_model_view(req)
  67                 var mentity = find_mentity(model, namespace)
  68                 if mentity == null then
  69                         res.error(404)
  70                         return
  71                 end
  72
  73                 var dot
  74                 if mentity isa MClassDef then mentity = mentity.mclass
  75                 if mentity isa MClass then
  76                         var uml = new UMLModel(model, mainmodule)
  77                         dot = uml.generate_class_uml.write_to_string
  78                 else if mentity isa MModule then
  79                         var uml = new UMLModel(model, mentity)
  80                         dot = uml.generate_package_uml.write_to_string
  81                 else
  82                         res.error(404)
  83                         return
  84                 end
  85                 var view = new HtmlDotPage(dot, mentity.as(not null).html_name)
  86                 res.send_view(view)
  87         end
  88 end