src/parser/nit.sablecc3xx

   1
   2 /* This file is part of NIT ( http://www.nitlanguage.org ).
   3  *
   4  * Copyright 2008-2009 Jean Privat <jean@pryen.org>
   5  *
   6  * Licensed under the Apache License, Version 2.0 (the "License");
   7  * you may not use this file except in compliance with the License.
   8  * You may obtain a copy of the License at
   9  *
  10  *     http://www.apache.org/licenses/LICENSE-2.0
  11  *
  12  * Unless required by applicable law or agreed to in writing, software
  13  * distributed under the License is distributed on an "AS IS" BASIS,
  14  * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15  * See the License for the specific language governing permissions and
  16  * limitations under the License.
  17  */
  18
  19 /* This grammar defines the NIT language. */
  20 Package org.nitlanguage.gen;
  21
  22 /*****************************************************************************/
  23 Helpers
  24 /*****************************************************************************/
  25
  26 all = [0 .. 0xFF];
  27 lowercase = ['a' .. 'z'];
  28 uppercase = ['A' .. 'Z'];
  29 digit = ['0' .. '9'];
  30 hexdigit = ['0'..'9'] | ['a'..'f'] | ['A'..'F'];
  31 letter = lowercase | uppercase | digit | '_';
  32
  33 tab = 9;
  34 cr = 13;
  35 lf = 10;
  36 any = [all - [cr + lf]];
  37 eol_helper = cr lf | cr | lf; // This takes care of different platforms
  38
  39 // characers inside strings and super-strings (atomaton powaa)
  40 str_char
  41         = [any - [['"' + '{'] + '\']]
  42         | '\' any
  43         ;
  44 str_body = str_char*;
  45
  46 sstr_char
  47         = [any - [''' + '\']]
  48         | '\' any
  49         ;
  50
  51 sstr_body = sstr_char*;
  52
  53 long_str_char = str_char | cr | lf;
  54
  55 // because no substraction in sablecc3, complex long strings are difficult to express
  56 ls1 = '"' '"'? ;
  57 ls2 = '{' '{'? ;
  58 ls12 = ls1? (ls2 ls1)* ls2?;
  59
  60 long_str_part
  61         = ls12 long_str_char
  62         ;
  63
  64 long_str_body = long_str_part*;
  65 lsend1 = ls2? (ls1 ls2)* '"""' '"'*;
  66 lsend2 = ls1? (ls2 ls1)* '{{{' '{'*;
  67
  68 long_sstr_char = sstr_char | cr | lf;
  69 long_sstr_part
  70         = long_sstr_char
  71         | ''' long_sstr_char
  72         | ''' ''' long_sstr_char
  73         ;
  74
  75 long_sstr_body = long_sstr_part*;
  76
  77
  78 extern_code_char
  79         = [all - ['`' + '\']]
  80         | '\' all
  81         ;
  82 extern_code_body = extern_code_char*;
  83
  84 /*****************************************************************************/
  85 States
  86 /*****************************************************************************/
  87 initial;
  88
  89
  90 /*****************************************************************************/
  91 Tokens
  92 /*****************************************************************************/
  93
  94 blank = (' ' | tab)+;
  95
  96 eol = eol_helper;
  97 comment = '#' any* eol_helper?;
  98
  99 kwpackage = 'package';
 100 kwmodule = 'module';
 101 kwimport = 'import';
 102 kwclass = 'class';
 103 kwabstract = 'abstract';
 104 kwinterface = 'interface';
 105 kwenum = 'universal'|'enum';
 106 kwend = 'end';
 107 kwmeth = 'fun';
 108 kwtype = 'type';
 109 kwinit = 'init';
 110 kwredef = 'redef';
 111 kwis = 'is';
 112 kwdo = 'do';
 113 kwreadable = 'readable';
 114 kwwritable = 'writable';
 115 kwvar = 'var';
 116 kwintern = 'intern';
 117 kwextern = 'extern';
 118 kwpublic = 'public';
 119 kwprotected = 'protected';
 120 kwprivate = 'private';
 121 kwintrude = 'intrude';
 122 kwif = 'if';
 123 kwthen = 'then';
 124 kwelse = 'else';
 125 kwwhile = 'while';
 126 kwloop = 'loop';
 127 kwfor = 'for';
 128 kwin = 'in';
 129 kwand = 'and';
 130 kwor = 'or';
 131 kwnot = 'not';
 132 kwimplies = 'implies';
 133 kwreturn = 'return';
 134 kwcontinue = 'continue';
 135 kwbreak = 'break';
 136 kwabort = 'abort';
 137 kwassert = 'assert';
 138 kwnew = 'new';
 139 kwisa = 'isa';
 140 kwonce = 'once';
 141 kwsuper = 'super';
 142 kwself = 'self';
 143 kwtrue = 'true';
 144 kwfalse = 'false';
 145 kwnull = 'null';
 146 kwas = 'as';
 147 kwnullable = 'nullable';
 148 kwisset = 'isset';
 149 kwlabel = 'label';
 150 kwdebug = '__debug__';
 151
 152 opar = '(';
 153 cpar = ')';
 154 obra = '[';
 155 cbra = ']';
 156 comma = ',';
 157 column = ':';
 158 quad = '::';
 159 assign = '=';
 160 pluseq = '+=';
 161 minuseq = '-=';
 162 dotdotdot = '...';
 163 dotdot = '..';
 164 dot = '.';
 165 plus = '+';
 166 minus = '-';
 167 star = '*';
 168 slash = '/';
 169 percent = '%';
 170 eq = '==';
 171 ne = '!=';
 172 lt = '<';
 173 le = '<=';
 174 ll = '<<';
 175 gt = '>';
 176 ge = '>=';
 177 gg = '>>';
 178 starship = '<=>';
 179 bang='!';
 180 at='@';
 181
 182 classid = uppercase letter*;
 183 id = lowercase letter*;
 184 attrid = '_' lowercase letter*;
 185
 186 number = digit+;
 187 hex_number = ('0x' | '0X') hexdigit+;
 188 float = digit* '.' digit+;
 189 string = '"' str_body '"' | '"' '"' '"' long_str_body lsend1 | ''' ''' ''' long_sstr_body ''' ''' ''';
 190 start_string = '"' str_body '{' | '"' '"' '"' long_str_body lsend2;
 191 mid_string = '}' str_body '{' | '}' '}' '}' long_str_body lsend2;
 192 end_string = '}' str_body '"' | '}' '}' '}' long_str_body lsend1;
 193 char = (''' [[any - '''] - '\'] ''') | (''' '\' any ''');
 194 bad_string = ('"'|'}') str_body | '"' '"' '"' long_str_body | ''' ''' ''' long_sstr_body;
 195 bad_char = ''' '\'? any;
 196
 197 extern_code_segment = '`' '{' extern_code_body '`' '}';
 198
 199 /*****************************************************************************/
 200 Ignored Tokens
 201 /*****************************************************************************/
 202
 203 blank;
 204
 205 /*****************************************************************************/
 206 Productions
 207 /*****************************************************************************/
 208
 209 /* MODULES *******************************************************************/
 210 module
 211         = moduledecl? [imports]:import* [extern_bodies]:extern_code_body* [classdefs]:topdef* implicit_main_class {-> New module(moduledecl, [imports.import], [extern_bodies.extern_code_block], [classdefs.classdef,implicit_main_class.classdef])};
 212
 213 moduledecl
 214         = [doc]:no kwmodule no module_name annotation_withend [n2]:n1 {-> New moduledecl(doc.doc, kwmodule, module_name, annotation_withend.annotations)};
 215
 216 import
 217         = {std} [doc]:no redef visibility kwimport no module_name annotation_withend [n2]:n1 {-> New import.std(visibility, kwimport, module_name, annotation_withend.annotations)}
 218         | {no} [doc]:no redef visibility kwimport no kwend [n2]:n1 {-> New import.no(visibility, kwimport, kwend)}
 219         ;
 220
 221 topdef {-> classdef}
 222         = {classdef} classdef {-> classdef}
 223         | propdefs_toplevel {-> New classdef.top([propdefs_toplevel.propdef])}
 224         ;
 225
 226 implicit_main_class {-> classdef?}
 227         = implicit_main_meth {-> New classdef.main([implicit_main_meth.propdef])}
 228         | {null} n? {-> Null}
 229         ;
 230 implicit_main_meth {-> propdef}
 231         = [doc]:no stmts {-> New propdef.main_meth(Null, stmts.expr)}
 232         | {n} [doc]:no stmtsn {-> New propdef.main_meth(Null, stmtsn.expr)}
 233         ;
 234
 235 /* CLASSES *******************************************************************/
 236 classdef
 237         = [doc]:no redef visibility classkind no qclassid formaldefs line_annotations_forclass? extern_code_block? [superclasses]:superclass* propdefs* [n2]:no kwend {-> New classdef.std(doc.doc, redef.kwredef, visibility, classkind, qclassid.classid, [formaldefs.formaldef], line_annotations_forclass.annotations, extern_code_block, [superclasses.superclass], [propdefs.propdef], kwend)};
 238 redef {-> kwredef?}
 239         = kwredef? {-> kwredef};
 240 classkind
 241         = {concrete} kwclass
 242         | {abstract} kwabstract kwclass
 243         | {interface} kwinterface
 244         | {enum} kwenum
 245         | {extern} kwextern kwclass
 246         ;
 247
 248 formaldefs {-> formaldef*}
 249         = obra no formaldef formaldefs_tail* [n2]:no cbra {-> [formaldef, formaldefs_tail.formaldef]}
 250         | {null} {-> []}
 251         ;
 252 formaldefs_tail {-> formaldef}
 253         = comma no formaldef {-> formaldef};
 254 formaldef
 255         = classid annotations? typing_o {-> New formaldef(classid, typing_o.type, annotations)};
 256
 257 superclass {-> superclass}
 258         = {super} no kwsuper [n2]:no type annotation_withend {-> New superclass(kwsuper, type, annotation_withend.annotations)}
 259         ;
 260
 261 propdefs~toplevel {-> propdef}
 262         = propdef~toplevel n1 {-> propdef~toplevel.propdef}
 263         ;
 264 propdef~toplevel {-> propdef}
 265         = {meth} [doc]:no redef visibility kwmeth methid signature annotation_noend? kwdo stmtso kwend_o {-> New propdef.concrete_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature, annotation_noend.annotations, stmtso.expr)}
 266         | {nobody} [doc]:no redef visibility kwmeth methid signature annotation_withend_nonull {-> New propdef.deferred_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature, annotation_withend_nonull.annotations)}
 267 !toplevel| {deferred} [doc]:no redef visibility kwmeth methid signature kwis kwabstract {-> New propdef.deferred_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature, Null)}
 268         | {intern} [doc]:no redef visibility kwmeth methid signature kwis kwintern {-> New propdef.intern_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature)}
 269 !toplevel| {intern_new} [doc]:no redef visibility kwnew methid? signature kwis kwintern {-> New propdef.intern_new(doc.doc, redef.kwredef, visibility, kwnew, methid, signature)}
 270         | {extern} [doc]:no redef visibility kwmeth methid signature kwis kwextern string_o extern_calls extern_code_block_o {-> New propdef.extern_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature, string_o.string, extern_calls, extern_code_block_o.extern_code_block)}
 271         | {extern_implicit} [doc]:no redef visibility kwmeth methid signature extern_calls extern_code_block {-> New propdef.extern_meth(doc.doc, redef.kwredef, visibility, kwmeth, methid, signature.signature, Null, extern_calls, extern_code_block)}
 272 !toplevel| {var} [doc]:no readable? writable? redef visibility kwvar attrid typing_o {-> New propdef.attr(doc.doc, readable.able, writable.able, redef.kwredef, visibility, kwvar, attrid, Null, typing_o.type, Null, Null)}
 273 !toplevel| {var2} [doc]:no readable? writable? redef visibility kwvar attrid typing_o assign [n2]:no expr {-> New propdef.attr(doc.doc, readable.able, writable.able, redef.kwredef, visibility, kwvar, attrid, Null, typing_o.type, Null, expr)}
 274 !toplevel| {var3} [doc]:no redef visibility kwvar id typing_o writable? annotation_withend {-> New propdef.attr(doc.doc, Null, writable.able, redef.kwredef, visibility, kwvar, Null, id, typing_o.type, annotation_withend.annotations, Null)}
 275 !toplevel| {var4} [doc]:no redef visibility kwvar id typing_o writable? assign [n2]:no expr annotation_withend {-> New propdef.attr(doc.doc, Null, writable.able, redef.kwredef, visibility, kwvar, Null, id, typing_o.type, annotation_withend.annotations, expr.expr)}
 276 !toplevel| {init} [doc]:no redef visibility kwinit methid? signature annotation_noend? kwdo stmtso kwend_o {-> New propdef.concrete_init(doc.doc, redef.kwredef, visibility, kwinit, methid, signature, annotation_noend.annotations, stmtso.expr)}
 277 !toplevel| {type} [doc]:no redef visibility kwtype classid typing annotation_withend {-> New propdef.type(doc.doc, redef.kwredef, visibility, kwtype, classid, typing.type, annotation_withend.annotations)}
 278 !toplevel| {extern_init} [doc]:no redef visibility kwnew methid? signature kwis kwextern string_o extern_calls extern_code_block_o {-> New propdef.extern_init(doc.doc, redef.kwredef, visibility, kwnew, methid, signature, string_o.string, extern_calls, extern_code_block_o.extern_code_block)}
 279 !toplevel| {extern_init_implicit} [doc]:no redef visibility kwnew methid? signature string_o extern_calls extern_code_block {-> New propdef.extern_init(doc.doc, redef.kwredef, visibility, kwnew, methid, signature, string_o.string, extern_calls, extern_code_block)}
 280         ;
 281 annotation_withend~nonull {-> annotations?}
 282         = {oneliner} kwis many_annotations {-> many_annotations.annotations}
 283         | {more} kwis n1 line_annotations kwend {-> line_annotations.annotations}
 284 !nonull | {null} {-> Null}
 285         ;
 286 annotation_noend {-> annotations}
 287         = {oneliner} kwis many_annotations {-> many_annotations.annotations}
 288         | {more} kwis n1 line_annotations {-> line_annotations.annotations}
 289         ;
 290 readable {-> able}
 291         = redef visibility kwreadable {-> New able.read(redef.kwredef, kwreadable)}
 292         ;
 293 writable {-> able}
 294         = redef visibility kwwritable {-> New able.write(redef.kwredef, visibility, kwwritable)}
 295         ;
 296
 297 visibility
 298         = {public} {-> New visibility.public()}
 299         | {private} kwprivate no {-> New visibility.private(kwprivate)}
 300         | {protected} kwprotected no {-> New visibility.protected(kwprotected)}
 301         | {intrude} kwintrude no {-> New visibility.intrude(kwintrude)}
 302         ;
 303
 304 methid {-> methid}
 305         = {id} id {-> New methid.id(id)}
 306         | {plus} plus {-> New methid.plus(plus)}
 307         | {minus} minus {-> New methid.minus(minus)}
 308         | {star} star {-> New methid.star(star)}
 309         | {slash} slash {-> New methid.slash(slash)}
 310         | {percent} percent {-> New methid.percent(percent)}
 311         | {eq} eq {-> New methid.eq(eq)}
 312         | {ne} ne {-> New methid.ne(ne)}
 313         | {le} le {-> New methid.le(le)}
 314         | {ge} ge {-> New methid.ge(ge)}
 315         | {lt} lt {-> New methid.lt(lt)}
 316         | {gt} gt {-> New methid.gt(gt)}
 317         | {ll} ll {-> New methid.ll(ll)}
 318         | {gg} gg {-> New methid.gg(gg)}
 319         | {bra} obra cbra {-> New methid.bra(obra, cbra)}
 320         | {starship} starship {-> New methid.starship(starship)}
 321         | {assign} id assign {-> New methid.assign(id, assign)}
 322         | {braassign} obra cbra assign {-> New methid.braassign(obra, cbra, assign)}
 323         ;
 324
 325 signature {-> signature}
 326         = opar no params cpar typing [no2]:no {-> New signature(opar, [params.param], cpar, typing.type)}
 327         | {noret} opar no params cpar [no2]:no {-> New signature(opar, [params.param], cpar, Null)}
 328         | {nopar} typing no {-> New signature(Null, [], Null, typing.type)}
 329         | {noparnoret} no {-> New signature(Null, [], Null, Null)}
 330         ;
 331
 332 params {-> param*}
 333         = param params_tail* [n2]:no {-> [param, params_tail.param] }
 334         | {null} {-> []}
 335         ;
 336 params_tail {-> param}
 337         = comma no param {-> param};
 338 param
 339         = {untyped} id annotations_o {-> New param(id, Null, Null, annotations_o.annotations)}
 340         | id annotations? typing dotdotdot? {-> New param(id, typing.type, dotdotdot, annotations)}
 341         ;
 342
 343 extern_calls {-> extern_calls?}
 344         = kwimport no extern_call extern_call_tail* {-> New extern_calls( kwimport, [extern_call, extern_call_tail.extern_call] )}
 345         | {null} {-> Null}
 346         ;
 347 extern_call_tail {-> extern_call}
 348         = comma no extern_call {-> extern_call};
 349 extern_call {-> extern_call}
 350         = {prop} extern_call_prop {-> extern_call_prop.extern_call}
 351         | {cast} extern_call_cast {-> extern_call_cast.extern_call}
 352         | {super} kwsuper {-> New extern_call.super( kwsuper )}
 353         ;
 354 extern_call_prop {-> extern_call}
 355         = {local} methid {-> New extern_call.local_prop( methid )}
 356         | {full} type dot methid {-> New extern_call.full_prop( type, dot, methid )}
 357         | {init} type {-> New extern_call.init_prop( type )}
 358         ;
 359 extern_call_cast {-> extern_call}
 360         = {as_cast} [from_type]:type dot kwas [n2]:no opar [n3]:no [to_type]:type [n4]:no cpar {-> New extern_call.cast_as(from_type, dot, kwas, to_type)}
 361         | {as_cast2}[from_type]:type dot kwas [n2]:no [to_type]:type {-> New extern_call.cast_as(from_type, dot, kwas, to_type)}
 362         | {as_nullable} type dot kwas [n2]:no opar [n3]:no kwnullable [n4]:no cpar {-> New extern_call.as_nullable( type, kwas, kwnullable)}
 363         | {as_nullable2}type dot kwas [n2]:no kwnullable {-> New extern_call.as_nullable( type, kwas, kwnullable)}
 364         | {as_not_nullable} type dot kwas [n2]:no opar [n3]:no kwnot [n4]:no kwnullable [n5]:no cpar {-> New extern_call.as_not_nullable( type, kwas, kwnot, kwnullable)}
 365         | {as_not_nullable2}type dot kwas [n2]:no kwnot [n3]:no kwnullable {-> New extern_call.as_not_nullable( type, kwas, kwnot, kwnullable)}
 366         ;
 367
 368 string_o {->string?} = string? {-> string};
 369
 370 in_language = kwin no string [n1]:no {-> New in_language(kwin, string)};
 371 extern_code_block = in_language? extern_code_segment;
 372 extern_code_block_o {-> extern_code_block?}
 373         = extern_code_block {-> extern_code_block}
 374         | {null} {-> Null}
 375         ;
 376 extern_code_body {-> extern_code_block} = no extern_code_block {-> extern_code_block};
 377
 378 /* TYPES *********************************************************************/
 379 type~nobra~nopar {-> type}
 380         = {simple} kwnullable? classid annotations_o~nopar {-> New type(kwnullable, classid, [], annotations_o~nopar.annotations)}
 381 !nobra  | {generic} kwnullable? classid obra no types [n2]:no cbra annotations_o~nopar {-> New type(kwnullable, classid, [types.type], annotations_o~nopar.annotations)}
 382         ;
 383 types {-> type*}
 384         = type types_tail* {-> [type, types_tail.type]};
 385 types_tail {-> type}
 386         = comma no type {-> type};
 387 typing {-> type}
 388         = column no type {-> type};
 389 typing_o {-> type?}
 390         = column no type {-> type}
 391         | {null} {-> Null}
 392         ;
 393
 394 /* STATMENTS *****************************************************************/
 395 stmtso~withelse~withend {-> expr?}
 396         = {block} n stmtsnend {-> stmtsnend.expr}
 397         | {emptyblock} n kwend {-> New expr.block([], kwend)}
 398         | {emptyoneline} kwend {-> New expr.block([], kwend)}
 399 !withend| {oneline} stmt~withelse {-> stmt~withelse.expr}
 400         ;
 401 stmts {-> expr}
 402         = stmt stmts_tail* {-> New expr.block([stmt.expr, stmts_tail.expr], Null)};
 403 stmtsn {-> expr}
 404         = stmt stmts_tail* n {-> New expr.block([stmt.expr, stmts_tail.expr], Null)};
 405 stmtsnend {-> expr}
 406         = stmt stmts_tail* n kwend {-> New expr.block([stmt.expr, stmts_tail.expr], kwend)};
 407 stmts_tail {-> expr}
 408         = n stmt {-> stmt.expr};
 409 stmt~withelse~noexpr~nopar {-> expr}
 410         = {vardecl} vardecl~withelse {-> vardecl~withelse.expr}
 411         | {assign} assignment~withelse~nopar {-> assignment~withelse~nopar.expr}
 412         | {return} kwreturn expr_final~withelse? {-> New expr.return(kwreturn, expr_final~withelse.expr)}
 413         | {break} kwbreak label? expr_final~withelse? {-> New expr.break(kwbreak, label, expr_final~withelse.expr)}
 414         | {abort} kwabort {-> New expr.abort(kwabort)}
 415         | {continue} kwcontinue label? expr_final~withelse? {-> New expr.continue(kwcontinue, label, expr_final~withelse.expr)}
 416         | {do} do~withelse {-> do~withelse.expr}
 417 !noexpr | {if} if~withelse {-> if~withelse.expr}
 418         | {while} while~withelse {-> while~withelse.expr}
 419         | {loop} loop~withelse {-> loop~withelse.expr}
 420         | {for} for~withelse {-> for~withelse.expr}
 421         | {assert} assert~withelse {-> assert~withelse.expr}
 422 !noexpr | {call} recv qid args_nopar {-> New expr.call(recv.expr, qid.id, args_nopar.exprs)}
 423 !noexpr | {super} qualified_o kwsuper args_nopar {-> New expr.super(qualified_o.qualified, kwsuper, args_nopar.exprs)}
 424 !noexpr | {init} recv qualified? kwinit args_nopar {-> New expr.init(recv.expr, kwinit, args_nopar.exprs)}
 425         | {debug_type_is} kwdebug kwtype type column expr_final~withelse {-> New expr.debug_type(kwdebug, kwtype, expr_final~withelse.expr, type) }
 426         ;
 427
 428 label= kwlabel id;
 429
 430 assign_continue~withelse{-> expr}
 431         = expr_final~withelse {-> New expr.continue(Null, Null, expr_final~withelse.expr)}
 432         ;
 433
 434 vardecl~withelse{-> expr}
 435         = kwvar id annotations? typing_o {-> New expr.vardecl(kwvar, id, typing_o.type, Null, Null, annotations)}
 436         | {assign} kwvar id annotations? typing_o assign no expr_final~withelse {-> New expr.vardecl(kwvar, id, typing_o.type, assign, expr_final~withelse.expr, annotations)}
 437         ;
 438
 439 assignment~withelse~nopar {-> expr}
 440         = {attr} recv~nopar qualified_o attrid assign expr_final~withelse {-> New expr.attr_assign(recv~nopar.expr, attrid, assign, expr_final~withelse.expr)}
 441         | {call} recv~nopar qid args assign expr_final~withelse {-> New expr.call_assign(recv~nopar.expr, qid.id, args.exprs, assign,  expr_final~withelse.expr)}
 442         | {bra} expr_atom~nopar braargs assign expr_final~withelse {-> New expr.bra_assign(expr_atom~nopar.expr, braargs.exprs, assign,  expr_final~withelse.expr)}
 443         | {attr_re} recv~nopar qualified_o attrid assign_op expr_final~withelse {-> New expr.attr_reassign(recv~nopar.expr, attrid, assign_op,  expr_final~withelse.expr)}
 444         | {call_re} recv~nopar qid args assign_op expr_final~withelse {-> New expr.call_reassign(recv~nopar.expr, qid.id, args.exprs, assign_op,  expr_final~withelse.expr)}
 445         | {bra_re} expr_atom~nopar braargs assign_op expr_final~withelse {-> New expr.bra_reassign(expr_atom~nopar.expr, braargs.exprs, assign_op,  expr_final~withelse.expr)}
 446         ;
 447 assign_op
 448         = {plus} pluseq
 449         | {minus} minuseq
 450         ;
 451
 452 do~withelse {-> expr}
 453         = kwdo stmtso_withend label {-> New expr.do(kwdo, stmtso_withend.expr, label)}
 454         | {nolabel} kwdo stmtso~withelse {-> New expr.do(kwdo, stmtso~withelse.expr, Null)}
 455         ;
 456
 457 if~withelse {-> expr}
 458         = {onelineelse} kwif no expr [n2]:no kwthen stmt_withelse kwelse stmtso~withelse {-> New expr.if(kwif, expr, stmt_withelse.expr, stmtso~withelse.expr)}
 459 !withelse       | {oneline} kwif no expr [n2]:no kwthen stmt {-> New expr.if(kwif, expr, stmt.expr, Null)}
 460 !withelse       | {block} kwif no expr [n2]:no kwthen [n3]:n stmtsn elsepartblock {-> New expr.if(kwif, expr, stmtsn.expr, elsepartblock.expr)}
 461 !withelse       | {emptyblock} kwif no expr [n2]:no kwthen [n3]:n? elsepartblock {-> New expr.if(kwif, expr, Null, elsepartblock.expr)}
 462         ;
 463 elsepartblock {-> expr?}
 464         = {else} kwelse stmtso {-> stmtso.expr}
 465         | {empty} kwend {-> New expr.block([], kwend)}
 466         ;
 467
 468 loop~withelse {-> expr}
 469         = kwloop stmtso_withend label {-> New expr.loop(kwloop, stmtso_withend.expr, label)}
 470         | {nolabel} kwloop stmtso~withelse {-> New expr.loop(kwloop, stmtso~withelse.expr, Null)}
 471         ;
 472
 473 while~withelse {-> expr}
 474         = kwwhile no expr [n2]:no kwdo stmtso_withend label {-> New expr.while(kwwhile, expr, kwdo, stmtso_withend.expr, label)}
 475         | {nolabel} kwwhile no expr [n2]:no kwdo stmtso~withelse {-> New expr.while(kwwhile, expr, kwdo, stmtso~withelse.expr, Null)}
 476         ;
 477
 478 for~withelse {-> expr}
 479         = kwfor no [ids]:idlist [n2]:no kwin [n3]:no expr [n4]:no kwdo stmtso_withend label {-> New expr.for(kwfor, [ids.id], expr, kwdo, stmtso_withend.expr, label)}
 480         | {nolabel} kwfor no [ids]:idlist [n2]:no kwin [n3]:no expr [n4]:no kwdo stmtso~withelse {-> New expr.for(kwfor, [ids.id], expr, kwdo, stmtso~withelse.expr, Null)}
 481         ;
 482
 483 assert~withelse {-> expr}
 484         = {else} kwassert assertid? expr_final_withelse kwelse stmtso~withelse {-> New expr.assert(kwassert, assertid.id, expr_final_withelse.expr, stmtso~withelse.expr)}
 485 !withelse| {noelse} kwassert assertid? expr_final {-> New expr.assert(kwassert, assertid.id, expr_final.expr, Null)}
 486         ;
 487 assertid {-> id}
 488         = id column {-> id};
 489
 490 /* EXPRESSIONS ***************************************************************/
 491 expr_final~nopar~withelse~nobra {-> expr}
 492         = expr~nopar~nobra {-> expr~nopar~nobra.expr}
 493         ;
 494
 495 expr~nopar~nobra {-> expr}
 496         = expr_and~nopar~nobra {-> expr_and~nopar~nobra.expr}
 497         | {ifexpr} kwif [n1]:no expr [n2]:no kwthen [n3]:no [then]:expr [n4]:no kwelse [n5]:no [else]:expr~nopar~nobra {-> New expr.ifexpr(kwif, expr, kwthen, then, kwelse, else.expr)}
 498         ;
 499
 500 expr_and~nopar~nobra {-> expr}
 501         = expr_not~nopar~nobra {-> expr_not~nopar~nobra.expr}
 502         | {:or} expr_and~nopar~nobra :kwor :no expr_not~nopar~nobra
 503         | {:and} expr_and~nopar~nobra :kwand :no expr_not~nopar~nobra
 504         | {:or_else} expr_and~nopar~nobra :kwor :kwelse :no expr_not~nopar~nobra
 505         | {:implies} expr_and~nopar~nobra :kwimplies :no expr_not~nopar~nobra
 506         ;
 507
 508 expr_not~nopar~nobra {-> expr}
 509         = expr_eq~nopar~nobra {-> expr_eq~nopar~nobra.expr}
 510         | {not} kwnot no expr_not~nopar~nobra {-> New expr.not(kwnot, expr_not~nopar~nobra.expr)}
 511         ;
 512
 513 expr_eq~nopar~nobra {-> expr}
 514         = expr_add~nopar~nobra {-> expr_add~nopar~nobra.expr}
 515         | {:eq} expr_add~nopar~nobra :eq :no [expr2]:expr_add~nopar~nobra
 516         | {:ne} expr_add~nopar~nobra :ne :no [expr2]:expr_add~nopar~nobra
 517         | {:lt} expr_add~nopar~nobra :lt :no [expr2]:expr_add~nopar~nobra
 518         | {:le} expr_add~nopar~nobra :le :no [expr2]:expr_add~nopar~nobra
 519         | {:ll} expr_eq~nopar~nobra :ll :no [expr2]:expr_add~nopar~nobra
 520         | {:gt} expr_add~nopar~nobra :gt :no [expr2]:expr_add~nopar~nobra
 521         | {:ge} expr_add~nopar~nobra :ge :no [expr2]:expr_add~nopar~nobra
 522         | {:gg} expr_eq~nopar~nobra :gg :no [expr2]:expr_add~nopar~nobra
 523         | {:starship} expr_add~nopar~nobra :starship :no [expr2]:expr_add~nopar~nobra
 524         | {:isa} expr_add~nopar~nobra :kwisa :no type~nobra
 525         ;
 526
 527 expr_add~nopar~nobra {-> expr}
 528         =  expr_mul~nopar~nobra {-> expr_mul~nopar~nobra.expr}
 529         | {:plus} expr_add~nopar~nobra :plus :no [expr2]:expr_mul~nopar~nobra
 530         | {:minus} expr_add~nopar~nobra :minus :no [expr2]:expr_mul~nopar~nobra
 531         ;
 532
 533 expr_mul~nopar~nobra {-> expr}
 534         = expr_minus~nopar~nobra {-> expr_minus~nopar~nobra.expr}
 535         | {:star} expr_mul~nopar~nobra :star :no [expr2]:expr_minus~nopar~nobra
 536         | {:slash} expr_mul~nopar~nobra :slash :no [expr2]:expr_minus~nopar~nobra
 537         | {:percent} expr_mul~nopar~nobra :percent :no [expr2]:expr_minus~nopar~nobra
 538         ;
 539
 540 expr_minus~nopar~nobra {-> expr}
 541         = expr_new~nopar~nobra {-> expr_new~nopar~nobra.expr}
 542         | {:uminus} minus :no expr_minus~nopar~nobra
 543         | {:once} kwonce :no expr_minus~nopar~nobra
 544         ;
 545
 546 expr_new~nopar~nobra {-> expr}
 547         = expr_atom~nopar~nobra {-> expr_atom~nopar~nobra.expr}
 548         | {new} kwnew no type~nobra_nopar args {-> New expr.new(kwnew, type~nobra_nopar.type, Null, args.exprs)}
 549         | {isset_attr} kwisset recv~nopar~nobra qualified_o attrid {-> New expr.isset_attr(kwisset, recv~nopar~nobra.expr, attrid)}
 550         ;
 551
 552 expr_atom~nopar~nobra {-> expr}
 553         = {attr} recv~nopar~nobra qualified_o attrid {-> New expr.attr(recv~nopar~nobra.expr, attrid)}
 554         | {call} recv~nopar~nobra qid args {-> New expr.call(recv~nopar~nobra.expr, qid.id, args.exprs)}
 555         | {super} qualified_o kwsuper args {-> New expr.super(qualified_o.qualified, kwsuper, args.exprs)}
 556         | {init} recv~nopar~nobra kwinit args {-> New expr.init(recv~nopar~nobra.expr, kwinit, args.exprs)}
 557 !nobra  | {bra} expr_atom~nopar braargs {-> New expr.bra(expr_atom~nopar.expr, braargs.exprs)}
 558         | {new} kwnew no type~nobra_nopar dot [n2]:no qid args {-> New expr.new(kwnew, type~nobra_nopar.type, qid.id, args.exprs)}
 559 // !nopar to unambiguise 'foo[5].bar' between '(foo[5]).bar' and 'foo([5].bar),
 560 !nobra!nopar    | {range} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no cbra annotations_o {-> New expr.crange(obra, expr, expr2.expr, cbra, annotations_o.annotations)}
 561 !nobra!nopar    | {orange} obra no expr [n2]:no dotdot [n3]:no [expr2]:expr_nobra [n4]:no [cbra]:obra annotations_o {-> New expr.orange(obra, expr, expr2.expr, cbra, annotations_o.annotations)}
 562 !nobra!nopar    | {array} braargs annotations_o {-> New expr.array(braargs.exprs, annotations_o.annotations)}
 563         | {self} kwself annotations_o {-> New expr.self(kwself, annotations_o.annotations)}
 564         | {true} kwtrue annotations_o {-> New expr.true(kwtrue, annotations_o.annotations)}
 565         | {false} kwfalse annotations_o {-> New expr.false(kwfalse, annotations_o.annotations)}
 566         | {null} kwnull annotations_o {-> New expr.null(kwnull, annotations_o.annotations)}
 567         | {int} number annotations_o {-> New expr.dec_int(number, annotations_o.annotations)}
 568         | {hex_int} hex_number annotations_o {-> New expr.hex_int(hex_number, annotations_o.annotations)}
 569         | {float} float annotations_o {-> New expr.float(float, annotations_o.annotations)}
 570         | {char} char annotations_o {-> New expr.char(char, annotations_o.annotations)}
 571         | {string} string annotations_o {-> New expr.string(string, annotations_o.annotations)}
 572         | {superstring} superstring  {-> superstring.expr}
 573 !nopar  | {par} opar no expr [n2]:no cpar annotations_o {-> New expr.par(opar, expr, cpar, annotations_o.annotations)}
 574         | {as_cast} expr_atom~nopar~nobra dot no kwas [n2]:no opar [n3]:no type [n4]:no cpar {-> New expr.as_cast(expr_atom~nopar~nobra.expr, kwas, opar, type, cpar)}
 575         | {as_notnull} expr_atom~nopar~nobra dot no kwas [n2]:no opar [n3]:no kwnot [n4]:no kwnull [n5]:no cpar {-> New expr.as_notnull(expr_atom~nopar~nobra.expr, kwas, opar, kwnot, kwnull, cpar)}
 576         | {as_notnull2}expr_atom~nopar~nobra dot no kwas [n2]:no kwnot [n4]:no kwnull {-> New expr.as_notnull(expr_atom~nopar~nobra.expr, kwas, Null, kwnot, kwnull, Null)}
 577         ;
 578
 579 superstring {-> expr}
 580         = superstring_start superstring_middle* superstring_end annotations_o {-> New expr.superstring([superstring_start.expr, superstring_middle.expr, superstring_end.expr], annotations_o.annotations)};
 581 superstring_start {-> expr*}
 582         = start_string_p no expr [n2]:no {-> [start_string_p.expr, expr]}
 583         | {noexpr} start_string_p no {-> [start_string_p.expr]}
 584         ;
 585 start_string_p {-> expr}
 586         = start_string {-> New expr.start_string(start_string)};
 587 superstring_middle {-> expr*}
 588         = mid_string_p no expr [n2]:no {-> [mid_string_p.expr, expr]}
 589         | {noexpr} mid_string_p no {-> [mid_string_p.expr]}
 590         ;
 591 mid_string_p {-> expr}
 592         = mid_string {-> New expr.mid_string(mid_string)};
 593 superstring_end {-> expr}
 594         = end_string {-> New expr.end_string(end_string)};
 595
 596 /* ANNOTATIONS *******************************************************************/
 597
 598 annotations~nopar {-> annotations}
 599         = {one} at one_annotation~nopar {-> New annotations(at, Null, [one_annotation~nopar.annotation], Null)}
 600         | {many} at opar no annotation_list [n2]:no cpar {-> New annotations(at, opar, [annotation_list.annotation], cpar)}
 601         ;
 602 annotations_o~nopar {-> annotations?}
 603         = annotations~nopar {-> annotations~nopar.annotations}
 604         | {null} {-> Null}
 605         ;
 606
 607 one_annotation~nopar {-> annotation}
 608         = {alone} atid annotations_o~nopar {-> New annotation(atid, Null, [], Null, annotations_o~nopar.annotations)}
 609 // !nopar to unambiguise 'new T@foo(bar)' between 'new T@(foo(bar))' and 'new (T@foo)(bar)'
 610 !nopar  | {args} atid opar no at_args [n2]:no cpar annotations_o~nopar {-> New annotation(atid, opar, [at_args.at_arg], cpar, annotations_o~nopar.annotations)}
 611         ;
 612
 613 many_annotations {-> annotations}
 614         = {many} annotation_list {-> New annotations(Null, Null, [annotation_list.annotation], Null)}
 615         ;
 616
 617 annotation_list {-> annotation*}
 618         = {many} one_annotation annotations_tail* {-> [one_annotation.annotation, annotations_tail.annotation] }
 619         ;
 620
 621 line_annotations~forclass {-> annotations}
 622         = line_annotation~forclass+ {-> New annotations(Null, Null, [line_annotation~forclass.annotation], Null) }
 623         ;
 624 line_annotation~forclass {-> annotation}
 625         = [doc]:no atid~forclass annotations? n1 {-> New annotation(atid~forclass.atid, Null, [], Null, annotations)}
 626         | {args} [doc]:no atid~forclass opar no at_args cpar annotations? n1 {-> New annotation(atid~forclass.atid, opar, [at_args.at_arg], cpar, annotations)}
 627         | {nopar} [doc]:no atid~forclass at_args_nopar n1 {-> New annotation(atid~forclass.atid, Null, [at_args_nopar.at_arg], Null, Null)}
 628         ;
 629
 630 annotations_tail {-> annotation}
 631         = comma no one_annotation {-> one_annotation.annotation}
 632         ;
 633
 634 at_args~nopar {-> at_arg* }
 635         = {many} at_arg~nopar at_args_tail* {-> [at_arg~nopar.at_arg, at_args_tail.at_arg]}
 636         ;
 637
 638 at_args_tail {-> at_arg}
 639         = comma no at_arg {-> at_arg}
 640         ;
 641
 642 at_arg~nopar {-> at_arg}
 643         = {type} type {-> New at_arg.type(type)}
 644         | {expr} expr~nopar {-> New at_arg.expr(expr~nopar.expr)}
 645         | {stmt} stmt_noexpr~nopar {-> New at_arg.expr(stmt_noexpr~nopar.expr)}
 646 !nopar  | {at} annotations {-> New at_arg.at(annotations.annotations)}
 647         ;
 648
 649 atid~forclass {-> atid}
 650         = {id}  id {-> New atid.id(id)}
 651 //!forclass     | {kwextern} kwextern {-> New atid.kwextern(kwextern)}
 652 //!forclass     | {kwintern} kwintern {-> New atid.kwintern(kwintern)}
 653 !forclass       | {kwreadable} kwreadable {-> New atid.kwreadable(kwreadable)}
 654 !forclass       | {kwwritable} kwwritable {-> New atid.kwwritable(kwwritable)}
 655         | {kwimport} kwimport {-> New atid.kwimport(kwimport)}
 656         ;
 657
 658 /* MISC **********************************************************************/
 659
 660 recv~nopar~nobra {-> expr}
 661         = expr_atom~nopar~nobra dot no {-> expr_atom~nopar~nobra.expr}
 662         | {implicit} {-> New expr.implicit_self()}
 663         ;
 664
 665 args {-> exprs}
 666         = opar no expr_list cpar {-> New exprs.par(opar, [expr_list.expr], cpar) }
 667         | {emptypar} opar no cpar {-> New exprs.par(opar, [], cpar) }
 668         | {empty} {-> New exprs.list([])}
 669         ;
 670 args_nopar {-> exprs}
 671         = opar no expr_list cpar {-> New exprs.par(opar, [expr_list.expr], cpar) }
 672         | {onearg} expr_nopar {-> New exprs.list([expr_nopar.expr])}
 673         | {emptypar} opar no cpar {-> New exprs.par(opar, [], cpar) }
 674         | {empty} {-> New exprs.list([])}
 675         ;
 676 braargs {-> exprs}
 677         = obra no expr_list cbra {-> New exprs.bra(obra, [expr_list.expr], cbra)};
 678 expr_list {-> expr*}
 679         = expr [n2]:no expr_tail* {-> [expr, expr_tail.expr]};
 680 expr_tail {-> expr}
 681         = comma no expr [n2]:no {-> expr};
 682 idlist {-> id*}
 683         = opar no idlist_nopar [n2]:no cpar {-> [idlist_nopar.id]}
 684         | {nopar} idlist_nopar {-> [idlist_nopar.id]}
 685         ;
 686 idlist_nopar {-> id*}
 687         = {single} id {-> [id]}
 688         | {more} idlist_nopar no comma [n2]:no id {-> [idlist_nopar.id, id]}
 689         ;
 690
 691 module_name {-> module_name}
 692         = {mod} modquad* id {-> New module_name(Null, [modquad.id], id)}
 693         | {root} quad no modquad* id {-> New module_name(quad, [modquad.id], id)}
 694         ;
 695
 696 qualified
 697         = {cla} modquad* classquad {-> New qualified([modquad.id], classquad.classid)}
 698         | {mod} modquad+ {-> New qualified([modquad.id], Null)}
 699         ;
 700 qualified_o {-> qualified?}
 701         = qualified {-> qualified}
 702         | {null} {-> Null}
 703         ;
 704 qid {-> id}
 705         = qualified? id {-> id}
 706         ;
 707 qclassid {-> classid}
 708         = qualified? classid {-> classid}
 709         ;
 710 modquad {-> id}
 711         = id quad no {-> id};
 712 classquad {-> classid}
 713         = classid quad no {-> classid};
 714
 715 kwend_o {-> kwend?}
 716         = kwend? {-> kwend}
 717         ;
 718
 719 n1      = {a} comment | {b} eol;
 720 n {-> doc?}
 721         = {a} n2? comment+ {-> New doc([comment])}
 722         | {b} n2 {-> Null}
 723         ;
 724 no {-> doc?}
 725         = {empty} {-> Null}
 726         | n {-> n.doc}
 727         ;
 728
 729 n2
 730         = {a} n2? comment+ eol+
 731         | {b} eol+
 732         ;
 733
 734 /*****************************************************************************/
 735 Abstract Syntax Tree
 736 /*****************************************************************************/
 737
 738 module  = moduledecl? [imports]:import* [extern_code_blocks]:extern_code_block* [classdefs]:classdef*;
 739
 740 moduledecl
 741         = doc? kwmodule [name]:module_name annotations?;
 742
 743 import  = {std} visibility kwimport [name]:module_name annotations?
 744         | {no} visibility kwimport kwend
 745         ;
 746
 747 visibility
 748         = {public}
 749         | {private} kwprivate
 750         | {protected} kwprotected
 751         | {intrude} kwintrude
 752         ;
 753
 754 classdef= {std} doc? kwredef? visibility classkind [id]:classid? [formaldefs]:formaldef* annotations? extern_code_block? [superclasses]:superclass* [propdefs]:propdef* kwend
 755         | {top} [propdefs]:propdef*
 756         | {main} [propdefs]:propdef*
 757         ;
 758 classkind
 759         = {concrete} kwclass
 760         | {abstract} kwabstract kwclass
 761         | {interface} kwinterface
 762         | {enum} kwenum
 763         | {extern} kwextern kwclass?
 764         ;
 765 formaldef = [id]:classid type? annotations?;
 766 superclass = kwsuper type annotations?;
 767
 768
 769 propdef = {attr} doc? [readable]:able? [writable]:able? kwredef? visibility kwvar [id]:attrid? [id2]:id? type? annotations? expr?
 770         | {meth} doc? kwredef? visibility methid signature
 771         | {deferred_meth} doc? kwredef? visibility kwmeth methid signature annotations?
 772         | {intern_meth} doc? kwredef? visibility kwmeth methid signature
 773         | {intern_new} doc? kwredef? visibility kwnew methid? signature
 774         | {extern_meth} doc? kwredef? visibility kwmeth methid signature [extern]:string? extern_calls? extern_code_block?
 775         | {concrete_meth} doc? kwredef? visibility kwmeth methid signature annotations? [block]:expr?
 776         | {concrete_init} doc? kwredef? visibility kwinit methid? signature annotations? [block]:expr?
 777         //| {concrete_new} doc? kwredef? visibility kwnew methid? signature [block]:expr?
 778         | {extern_init} doc? kwredef? visibility kwnew methid? signature [extern]:string? extern_calls? extern_code_block?
 779         | {main_meth} kwredef? [block]:expr?
 780         | {type} doc? kwredef? visibility kwtype [id]:classid type annotations?
 781         ;
 782
 783 able    = {read} kwredef? kwreadable
 784         | {write} kwredef? visibility? kwwritable
 785         ;
 786
 787 methid = {id} id | {plus} plus | {minus} minus | {star} star | {slash} slash | {percent} percent | {eq} eq | {ne} ne | {le} le | {ge} ge | {lt} lt | {gt} gt |  {ll} ll | {gg} gg | {bra} obra cbra | {starship} starship | {assign} id assign | {braassign} obra cbra assign;
 788
 789 signature = opar? [params]:param* cpar? type?;
 790
 791 param   = id type? dotdotdot? annotations?
 792         ;
 793
 794 type    = kwnullable? [id]:classid [types]:type* annotations?;
 795
 796 label = kwlabel id;
 797
 798 expr    = {block} expr* kwend?
 799         | {vardecl} kwvar id type? assign? expr? annotations?
 800         | {return} kwreturn? expr?
 801         | {break} kwbreak label? expr?
 802         | {abort} kwabort
 803         | {continue} kwcontinue? label? expr?
 804         | {do} kwdo [block]:expr? label?
 805         | {if} kwif expr [then]:expr? [else]:expr?
 806         | {ifexpr} kwif expr kwthen [then]:expr kwelse [else]:expr
 807         | {while} kwwhile expr kwdo [block]:expr? label?
 808         | {loop} kwloop [block]:expr? label?
 809         | {for} kwfor [ids]:id* expr kwdo [block]:expr? label?
 810         | {assert} kwassert id? expr [else]:expr?
 811         | {once} kwonce expr
 812         | {send} expr
 813         | {binop} expr [expr2]:expr
 814         | {or} expr [expr2]:expr
 815         | {and} expr [expr2]:expr
 816         | {or_else} expr [expr2]:expr
 817         | {implies} expr [expr2]:expr
 818         | {not} kwnot expr
 819         | {eq} expr [expr2]:expr
 820         | {ne} expr [expr2]:expr
 821         | {lt} expr [expr2]:expr
 822         | {le} expr [expr2]:expr
 823         | {ll} expr [expr2]:expr
 824         | {gt} expr [expr2]:expr
 825         | {ge} expr [expr2]:expr
 826         | {gg} expr [expr2]:expr
 827         | {isa} expr type
 828         | {plus} expr [expr2]:expr
 829         | {minus} expr [expr2]:expr
 830         | {starship} expr [expr2]:expr
 831         | {star} expr [expr2]:expr
 832         | {slash} expr [expr2]:expr
 833         | {percent} expr [expr2]:expr
 834         | {uminus} minus expr
 835         | {new} kwnew type id? [args]:exprs
 836         | {attr} expr [id]:attrid
 837         | {attr_assign} expr [id]:attrid assign [value]:expr
 838         | {attr_reassign} expr [id]:attrid assign_op [value]:expr
 839         | {call} expr id [args]:exprs
 840         | {call_assign} expr id [args]:exprs assign [value]:expr
 841         | {call_reassign} expr id [args]:exprs assign_op [value]:expr
 842         | {super} qualified? kwsuper [args]:exprs
 843         | {init} expr kwinit [args]:exprs
 844         | {bra} expr [args]:exprs
 845         | {bra_assign} expr [args]:exprs assign [value]:expr
 846         | {bra_reassign} expr [args]:exprs assign_op [value]:expr
 847         | {var} id
 848         | {var_assign} id assign [value]:expr
 849         | {var_reassign} id assign_op [value]:expr
 850         | {range} expr [expr2]:expr annotations?
 851         | {crange} obra expr [expr2]:expr cbra annotations?
 852         | {orange} obra expr [expr2]:expr [cbra]:obra annotations?
 853         | {array} [exprs]:exprs annotations?
 854         | {self} kwself annotations?
 855         | {implicit_self}
 856         | {true} kwtrue annotations?
 857         | {false} kwfalse annotations?
 858         | {null} kwnull annotations?
 859         | {dec_int} number annotations?
 860         | {hex_int} hex_number annotations?
 861         | {float} float annotations?
 862         | {char} char annotations?
 863         | {string} string annotations?
 864         | {start_string} [string]:start_string
 865         | {mid_string} [string]:mid_string
 866         | {end_string} [string]:end_string
 867         | {superstring} [exprs]:expr* annotations?
 868         | {par} opar expr cpar annotations?
 869         | {as_cast} expr kwas opar? type cpar?
 870         | {as_notnull} expr kwas opar? kwnot kwnull cpar?
 871         | {isset_attr} kwisset expr [id]:attrid
 872         | {debug_type} kwdebug kwtype expr type
 873         ;
 874 exprs
 875         = {list} [exprs]:expr*
 876         | {par} opar [exprs]:expr* cpar
 877         | {bra} obra [exprs]:expr* cbra
 878         ;
 879 assign_op
 880         = {plus} pluseq
 881         | {minus} minuseq
 882         ;
 883
 884 module_name = quad? [path]:id* id;
 885 extern_calls = kwimport [extern_calls]:extern_call*
 886         ;
 887 extern_call =
 888         | {super} kwsuper
 889         | {local_prop} methid
 890         | {full_prop} type dot? methid
 891         | {init_prop} type
 892         | {cast_as} [from_type]:type dot? kwas [to_type]:type
 893         | {as_nullable} type kwas kwnullable
 894         | {as_not_nullable} type kwas kwnot kwnullable
 895         ;
 896 in_language = kwin string;
 897 extern_code_block = in_language? extern_code_segment;
 898
 899 qualified = id* classid? ;
 900
 901 doc = comment+;
 902
 903 annotations = at? opar? [items]:annotation* cpar?;
 904
 905 annotation = atid opar? [args]:at_arg* cpar? annotations?;
 906
 907 at_arg
 908         = {type} type
 909         | {expr} expr
 910         | {at} annotations
 911         ;
 912 atid = {id} id | {kwextern} [id]:kwextern | {kwintern} [id]:kwintern | {kwreadable} [id]:kwreadable | {kwwritable} [id]:kwwritable | {kwimport} [id]:kwimport;
 913
 914 /*****************************************************************************/
 915