lib/serialization/serialization.nit

   1 # This file is part of NIT ( http://www.nitlanguage.org ).
   2 #
   3 # Copyright 2014 Alexis Laferrière <alexis.laf@xymus.net>
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16
  17 # Abstract services to serialize Nit objects to different formats
  18 #
  19 # This module declares the `serialize` annotation to mark Nit classes as serializable.
  20 # For an introduction to this service, refer to the documentation of the `serialization` group.
  21 # This documentation provides more technical information on interesting entitie of this module.
  22 #
  23 # Interesting entities for end users of serializable classes:
  24 #
  25 # * Serialize an instance subclass of `Serializable` with either
  26 #   `Serializer::serializable` and `Serializable::serialize`.
  27 # * Deserialize an object using `Deserializer::deserialize`.
  28 #   The object type must the be checked with an `assert` or otherwise.
  29 #
  30 # Interesting entities to create custom serializable classes:
  31 #
  32 # * Subclass `Serializable` to declare a class as serializable and to customize
  33 #   the serialization and deserialization behavior.
  34 # * Redefine `Serializable::core_serialize_to` to customize the serialization
  35 #   of the receiver class.
  36 # * Redefine `Deserializer::deserialize_class` to customize the deserialization
  37 #   of a specific class by name.
  38 #
  39 # Interesting entities for serialization format:
  40 #
  41 # * Subclass `Serializer` and `Deserializer` with custom serices.
  42 # * In `Serializer`, `serialize` and `serialize_reference` must be redefined.
  43 # * In `Deserializer`; `deserialize`, `deserialize_attribute and
  44 #   `notify_of_creation` must be redefined.
  45 module serialization is
  46         new_annotation auto_serializable
  47         new_annotation serialize
  48         new_annotation noserialize
  49 end
  50
  51 # Abstract serialization service to be sub-classed by specialized services.
  52 interface Serializer
  53         # Entry point method of this service, serialize the `object`
  54         #
  55         # This method, and refinements, should handle `null` and probably
  56         # use double dispatch to customize the bahavior per serializable objects.
  57         fun serialize(object: nullable Serializable) is abstract
  58
  59         # Serialize an object, with full serialization or a simple reference
  60         protected fun serialize_reference(object: Serializable) is abstract
  61
  62         # Serialize an attribute to compose a serializable object
  63         #
  64         # This method should be called from `Serializable::core_serialize_to`.
  65         fun serialize_attribute(name: String, value: nullable Object)
  66         do
  67                 if not try_to_serialize(value) then
  68                         warn("argument {name} of type {value.class_name} is not serializable.")
  69                 end
  70         end
  71
  72         # Serialize `value` is possie, i.e. it is `Serializable` or `null`
  73         fun try_to_serialize(value: nullable Object): Bool
  74         do
  75                 if value isa Serializable then
  76                         value.serialize_to_or_delay(self)
  77                 else if value == null then
  78                         serialize value
  79                 else return false
  80                 return true
  81         end
  82
  83         # Warn of problems and potential errors (such as if an attribute
  84         # is not serializable)
  85         fun warn(msg: String) do print "Serialization warning: {msg}"
  86 end
  87
  88 # Abstract deserialization service
  89 #
  90 # After initialization of one of its sub-classes, call `deserialize`
  91 abstract class Deserializer
  92         # Main method of this class, returns a Nit object
  93         fun deserialize: nullable Object is abstract
  94
  95         # Internal method to be implemented by sub-classes
  96         fun deserialize_attribute(name: String): nullable Object is abstract
  97
  98         # Internal method called by objects in creation,
  99         # to be implemented by sub-classes
 100         fun notify_of_creation(new_object: Object) is abstract
 101
 102         # Deserialize the next available object as an instance of `class_name`
 103         #
 104         # Returns the deserialized object on success, aborts on error.
 105         #
 106         # This method should be redefined for each custom subclass of `Serializable`.
 107         # All refinement should look for a precise `class_name` and call super
 108         # on unsupported classes.
 109         protected fun deserialize_class(class_name: String): nullable Object do
 110                 return deserialize_class_intern(class_name)
 111         end
 112
 113         # Generated service to deserialize the next available object as an instance of `class_name`
 114         #
 115         # Refinements to this method will be generated by the serialization phase.
 116         # To avoid conflicts, there should not be any other refinements to this method.
 117         # You can instead use `deserialize_class`.
 118         protected fun deserialize_class_intern(class_name: String): nullable Object do
 119                 errors.add new Error("Deserialization Error: Doesn't know how to deserialize class \"{class_name}\"")
 120                 return null
 121         end
 122
 123         # Should `self` keep trying to deserialize an object after an error?
 124         #
 125         # This behavior takes effect after each attribute deserialization with
 126         # errors such as a missing attribute or the value is of the wrong type.
 127         # If `keep_going`, the attribute will be skipped but the engine will
 128         # deserialize the next attribute.
 129         # If `not keep_going`, the engine stops deserializing right away.
 130         #
 131         # When at `true`, this may cause the accumulation of a lot of entries in `errors`.
 132         #
 133         # Default at `true`.
 134         var keep_going: nullable Bool = null is writable
 135
 136         # Errors encountered in the last call to `deserialize`
 137         var errors = new Array[Error]
 138 end
 139
 140 # Deserialization got wrong attribute names
 141 class AttributeTypeError
 142         super Error
 143
 144         # Parent object of the problematic attribute
 145         var receiver: Object
 146
 147         # Name of the problematic attribute in `receiver`
 148         var attribute_name: String
 149
 150         # Deserialized object that isn't of the `expected_type`
 151         var attribute: nullable Object
 152
 153         # Name of the type expected for `attribute`
 154         var expected_type: String
 155
 156         redef fun to_s
 157         do
 158                 var attribute = attribute
 159                 var found_type = if attribute != null then attribute.class_name else "null"
 160
 161                 return "Deserialization Error: {
 162                 }Wrong type on `{receiver.class_name}::{attribute_name}` expected `{expected_type}`, got `{found_type}`"
 163         end
 164 end
 165
 166 # Instances of this class can be passed to `Serializer::serialize`
 167 interface Serializable
 168         # Serialize `self` to `serializer`
 169         #
 170         # This is a shortcut to `Serializer::serialize`.
 171         fun serialize_to(serializer: Serializer) do serializer.serialize(self)
 172
 173         # Actual serialization of `self` to `serializer`
 174         #
 175         # This writes the full data of `self` to `serializer`.
 176         #
 177         # This method can be redefined in sub classes and refinements.
 178         # It should use `Serializer::serialize_attribute` to to register real or
 179         # logical attributes.
 180         #
 181         # Any refinement should have its equivalent refinement of
 182         # `Deserializer::deserialize_class` to support this custom deserialization.
 183         fun core_serialize_to(serializer: Serializer) do end
 184
 185         # Accept references or force direct serialization (using `serialize_to`)
 186         #
 187         # The subclass change the default behavior, which will accept references,
 188         # to force to always serialize copies of `self`.
 189         private fun serialize_to_or_delay(v: Serializer) do v.serialize_reference(self)
 190
 191         # Create an instance of this class from the `deserializer`
 192         #
 193         # This constructor is refined by subclasses to correctly build their instances.
 194         init from_deserializer(deserializer: Deserializer) is nosuper do end
 195 end
 196
 197 redef interface Object
 198         # Is `self` the same as `other` in a serialization context?
 199         #
 200         # Used to determine if an object has already been serialized.
 201         fun is_same_serialized(other: nullable Object): Bool do return is_same_instance(other)
 202
 203         # Hash value use for serialization
 204         #
 205         # Used in combination with `is_same_serialized`. If two objects are the same
 206         # in a serialization context, they must have the same `serialization_hash`.
 207         fun serialization_hash: Int do return object_id
 208 end
 209
 210 # Instances of this class are not delayed and instead serialized immediately
 211 # This applies mainly to `universal` types
 212 interface DirectSerializable
 213         super Serializable
 214
 215         redef fun serialize_to_or_delay(v) do serialize_to(v)
 216 end
 217
 218 redef class Bool super DirectSerializable end
 219 redef class Char super DirectSerializable end
 220 redef class Int super DirectSerializable end
 221 redef class Float super DirectSerializable end
 222 redef class NativeString super DirectSerializable end
 223 redef class String super DirectSerializable end
 224 redef class SimpleCollection[E] super Serializable end
 225 redef class Map[K, V] super Serializable end
 226
 227 redef class Couple[F, S]
 228         super Serializable
 229
 230         redef init from_deserializer(v)
 231         do
 232                 v.notify_of_creation self
 233                 var first = v.deserialize_attribute("first")
 234                 var second = v.deserialize_attribute("second")
 235                 init(first, second)
 236         end
 237
 238         redef fun core_serialize_to(v)
 239         do
 240                 v.serialize_attribute("first", first)
 241                 v.serialize_attribute("second", second)
 242         end
 243 end
 244
 245 redef class Ref[E]
 246         super Serializable
 247
 248         redef init from_deserializer(v)
 249         do
 250                 v.notify_of_creation self
 251                 var item = v.deserialize_attribute("item")
 252                 init item
 253         end
 254
 255         redef fun core_serialize_to(v)
 256         do
 257                 v.serialize_attribute("item", first)
 258         end
 259 end